Sources/dyn3d/exner_hyb.f

module exner_hyb_m

  IMPLICIT NONE

contains

  SUBROUTINE exner_hyb(ps, p, pks, pk)

    ! From dyn3d/exner_hyb.F, version 1.1.1.1, 2004/05/19 12:53:07
    ! Authors: P. Le Van, F. Hourdin

    ! Calcule la fonction d'Exner :
    ! pk = Cp * p ** kappa
    ! aux milieux des "llm" couches.
    ! "Pk(l)" est calcul\'e au milieu de la couche "l", entre les pressions
    ! "p(l)" et "p(l+1)", d\'efinies aux interfaces des couches.

    ! Au sommet de l'atmosph\`ere :
    ! p(llm+1) = 0
    ! "ps" et "pks" sont la pression et la fonction d'Exner au sol.

    ! \`A partir des relations :
    !(1) \overline{p * \delta_z pk}^z = kappa * pk * \delta_z p
    !(2) pk(l) = beta(l) * pk(l-1)
    ! (cf. documentation), on d\'etermine successivement, du haut vers
    ! le bas des couches, les coefficients : beta(llm), ..., beta(l), ...,
    ! beta(2) puis "pk(:, :, 1)". Ensuite, on calcule, du bas vers le
    ! haut des couches, "pk(:, :, l)" donn\'e par la relation (2), pour
    ! l = 2 \`a l = llm.

    use dimens_m, only: llm
    use comconst, only: kappa, cpp
    use disvert_m, only: preff

    REAL, intent(in):: ps(:, :) ! (longitude, latitude)
    REAL, intent(in):: p(:, :, :) ! (longitude, latitude, llm + 1)

    real, intent(out):: pks(:, :) ! (longitude, latitude)
    real, intent(out):: pk(:, :, :) ! (longitude, latitude, llm)

    ! Variables locales :
    real beta(size(ps, 1), size(ps, 2), 2:llm)
    INTEGER l
    REAL unpl2k

    !-------------------------------------

    pks = cpp * (ps / preff)**kappa
    unpl2k = 1. + 2 * kappa

    beta(:, :, llm) = 1. / unpl2k
    DO l = llm - 1, 2, -1
       beta(:, :, l) = p(:, :, l) &
            / (p(:, :, l) * unpl2k + p(:, :, l+1) * (beta(:, :, l+1) - unpl2k))
    ENDDO

    pk(:, :, 1) = ps * pks &
         / (ps * (1. + kappa) + 0.5 * (beta(:, :, 2) - unpl2k) * p(:, :, 2))
    DO l = 2, llm
       pk(:, :, l) = beta(:, :, l) * pk(:, :, l - 1)
    ENDDO

  END SUBROUTINE exner_hyb

end module exner_hyb_m
1	module exner_hyb_m
2
3	IMPLICIT NONE
4
5	contains
6
7	SUBROUTINE exner_hyb(ps, p, pks, pk)
8
9	! From dyn3d/exner_hyb.F, version 1.1.1.1, 2004/05/19 12:53:07
10	! Authors: P. Le Van, F. Hourdin
11
12	! Calcule la fonction d'Exner :
13	! pk = Cp * p ** kappa
14	! aux milieux des "llm" couches.
15	! "Pk(l)" est calcul\'e au milieu de la couche "l", entre les pressions
16	! "p(l)" et "p(l+1)", d\'efinies aux interfaces des couches.
17
18	! Au sommet de l'atmosph\`ere :
19	! p(llm+1) = 0
20	! "ps" et "pks" sont la pression et la fonction d'Exner au sol.
21
22	! \`A partir des relations :
23	!(1) \overline{p * \delta_z pk}^z = kappa * pk * \delta_z p
24	!(2) pk(l) = beta(l) * pk(l-1)
25	! (cf. documentation), on d\'etermine successivement, du haut vers
26	! le bas des couches, les coefficients : beta(llm), ..., beta(l), ...,
27	! beta(2) puis "pk(:, :, 1)". Ensuite, on calcule, du bas vers le
28	! haut des couches, "pk(:, :, l)" donn\'e par la relation (2), pour
29	! l = 2 \`a l = llm.
30
31	use dimens_m, only: llm
32	use comconst, only: kappa, cpp
33	use disvert_m, only: preff
34
35	REAL, intent(in):: ps(:, :) ! (longitude, latitude)
36	REAL, intent(in):: p(:, :, :) ! (longitude, latitude, llm + 1)
37
38	real, intent(out):: pks(:, :) ! (longitude, latitude)
39	real, intent(out):: pk(:, :, :) ! (longitude, latitude, llm)
40
41	! Variables locales :
42	real beta(size(ps, 1), size(ps, 2), 2:llm)
43	INTEGER l
44	REAL unpl2k
45
46	!-------------------------------------
47
48	pks = cpp * (ps / preff)**kappa
49	unpl2k = 1. + 2 * kappa
50
51	beta(:, :, llm) = 1. / unpl2k
52	DO l = llm - 1, 2, -1
53	beta(:, :, l) = p(:, :, l) &
54	/ (p(:, :, l) * unpl2k + p(:, :, l+1) * (beta(:, :, l+1) - unpl2k))
55	ENDDO
56
57	pk(:, :, 1) = ps * pks &
58	/ (ps * (1. + kappa) + 0.5 * (beta(:, :, 2) - unpl2k) * p(:, :, 2))
59	DO l = 2, llm
60	pk(:, :, l) = beta(:, :, l) * pk(:, :, l - 1)
61	ENDDO
62
63	END SUBROUTINE exner_hyb
64
65	end module exner_hyb_m