Sources/dyn3d/leapfrog.f

module leapfrog_m

  IMPLICIT NONE

contains

  SUBROUTINE leapfrog(ucov, vcov, teta, ps, masse, phis, q, time_0)

    ! From dyn3d/leapfrog.F, version 1.6, 2005/04/13 08:58:34
    ! Authors: P. Le Van, L. Fairhead, F. Hourdin

    USE calfis_m, ONLY: calfis
    USE com_io_dyn, ONLY: histaveid
    USE comconst, ONLY: daysec, dtphys, dtvr
    USE comgeom, ONLY: aire_2d, apoln, apols
    USE comvert, ONLY: ap, bp
    USE conf_gcm_m, ONLY: day_step, iconser, iperiod, iphysiq, nday, offline, &
         periodav
    USE dimens_m, ONLY: iim, jjm, llm, nqmx
    USE dynetat0_m, ONLY: day_ini
    use dynredem1_m, only: dynredem1
    USE exner_hyb_m, ONLY: exner_hyb
    use filtreg_m, only: filtreg
    USE guide_m, ONLY: guide
    use inidissip_m, only: idissip
    USE logic, ONLY: iflag_phys, ok_guide
    USE paramet_m, ONLY: ip1jmp1
    USE pression_m, ONLY: pression
    USE pressure_var, ONLY: p3d
    USE temps, ONLY: itau_dyn

    ! Variables dynamiques:
    REAL vcov((iim + 1) * jjm, llm), ucov(ip1jmp1, llm) ! vents covariants
    REAL, intent(inout):: teta(iim + 1, jjm + 1, llm) ! potential temperature
    REAL ps(iim + 1, jjm + 1) ! pression au sol, en Pa

    REAL masse(ip1jmp1, llm) ! masse d'air
    REAL phis(ip1jmp1) ! geopotentiel au sol
    REAL q(ip1jmp1, llm, nqmx) ! mass fractions of advected fields
    REAL, intent(in):: time_0

    ! Variables local to the procedure:

    ! Variables dynamiques:

    REAL pks(ip1jmp1) ! exner au sol
    REAL pk(iim + 1, jjm + 1, llm) ! exner au milieu des couches
    REAL pkf(ip1jmp1, llm) ! exner filt.au milieu des couches
    REAL phi(ip1jmp1, llm) ! geopotential
    REAL w(ip1jmp1, llm) ! vitesse verticale

    ! variables dynamiques intermediaire pour le transport
    REAL pbaru(ip1jmp1, llm), pbarv((iim + 1) * jjm, llm) !flux de masse

    ! variables dynamiques au pas - 1
    REAL vcovm1((iim + 1) * jjm, llm), ucovm1(ip1jmp1, llm)
    REAL tetam1(iim + 1, jjm + 1, llm), psm1(iim + 1, jjm + 1)
    REAL massem1(ip1jmp1, llm)

    ! tendances dynamiques
    REAL dv((iim + 1) * jjm, llm), du(ip1jmp1, llm)
    REAL dteta(ip1jmp1, llm), dq(ip1jmp1, llm, nqmx), dp(ip1jmp1)

    ! tendances de la dissipation
    REAL dvdis((iim + 1) * jjm, llm), dudis(ip1jmp1, llm)
    REAL dtetadis(iim + 1, jjm + 1, llm)

    ! tendances physiques
    REAL dvfi((iim + 1) * jjm, llm), dufi(ip1jmp1, llm)
    REAL dtetafi(ip1jmp1, llm), dqfi(ip1jmp1, llm, nqmx), dpfi(ip1jmp1)

    ! variables pour le fichier histoire

    INTEGER itau ! index of the time step of the dynamics, starts at 0
    INTEGER itaufin
    INTEGER iday ! jour julien
    REAL time ! time of day, as a fraction of day length
    real finvmaold(ip1jmp1, llm)
    LOGICAL:: lafin=.false.
    INTEGER l

    REAL rdayvrai, rdaym_ini

    ! Variables test conservation energie
    REAL ecin(iim + 1, jjm + 1, llm), ecin0(iim + 1, jjm + 1, llm)
    ! Tendance de la temp. potentiel d (theta) / d t due a la 
    ! tansformation d'energie cinetique en energie thermique
    ! cree par la dissipation
    REAL dtetaecdt(iim + 1, jjm + 1, llm)
    REAL vcont((iim + 1) * jjm, llm), ucont(ip1jmp1, llm)
    logical forward, leapf
    REAL dt

    !---------------------------------------------------

    print *, "Call sequence information: leapfrog"

    itaufin = nday * day_step
    itau = 0
    iday = day_ini
    time = time_0
    dq = 0.
    ! On initialise la pression et la fonction d'Exner :
    CALL pression(ip1jmp1, ap, bp, ps, p3d)
    CALL exner_hyb(ps, p3d, pks, pk, pkf)

    ! Début de l'integration temporelle :
    outer_loop:do
       if (ok_guide .and. (itaufin - itau - 1) * dtvr > 21600.) &
            call guide(itau, ucov, vcov, teta, q, masse, ps)
       vcovm1 = vcov
       ucovm1 = ucov
       tetam1 = teta
       massem1 = masse
       psm1 = ps
       forward = .TRUE.
       leapf = .FALSE.
       dt = dtvr
       finvmaold = masse
       CALL filtreg(finvmaold, jjm + 1, llm, - 2, 2, .TRUE., 1)

       do
          ! Calcul des tendances dynamiques:
          CALL geopot(ip1jmp1, teta, pk, pks, phis, phi)
          CALL caldyn(itau, ucov, vcov, teta, ps, masse, pk, pkf, phis, phi, &
               MOD(itau, iconser) == 0, du, dv, dteta, dp, w, pbaru, pbarv, &
               time + iday - day_ini)

          IF (forward .OR. leapf) THEN
             ! Calcul des tendances advection des traceurs (dont l'humidité)
             CALL caladvtrac(q, pbaru, pbarv, p3d, masse, dq, teta, pk)
             IF (offline) THEN
                ! Stokage du flux de masse pour traceurs off-line
                CALL fluxstokenc(pbaru, pbarv, masse, teta, phi, phis, dtvr, &
                     itau)
             ENDIF
          ENDIF

          ! integrations dynamique et traceurs:
          CALL integrd(2, vcovm1, ucovm1, tetam1, psm1, massem1, dv, du, &
               dteta, dq, dp, vcov, ucov, teta, q, ps, masse, phis, &
               finvmaold, leapf, dt)

          IF (MOD(itau + 1, iphysiq) == 0 .AND. iflag_phys /= 0) THEN
             ! calcul des tendances physiques:
             IF (itau + 1 == itaufin) lafin = .TRUE.

             CALL pression(ip1jmp1, ap, bp, ps, p3d)
             CALL exner_hyb(ps, p3d, pks, pk, pkf)

             rdaym_ini = itau * dtvr / daysec
             rdayvrai = rdaym_ini + day_ini

             CALL calfis(nqmx, lafin, rdayvrai, time, ucov, vcov, teta, q, &
                  masse, ps, pk, phis, phi, du, dv, dteta, dq, w, &
                  dufi, dvfi, dtetafi, dqfi, dpfi)

             ! ajout des tendances physiques:
             CALL addfi(nqmx, dtphys, ucov, vcov, teta, q, ps, dufi, dvfi, &
                  dtetafi, dqfi, dpfi)
          ENDIF

          CALL pression(ip1jmp1, ap, bp, ps, p3d)
          CALL exner_hyb(ps, p3d, pks, pk, pkf)

          IF (MOD(itau + 1, idissip) == 0) THEN
             ! dissipation horizontale et verticale des petites echelles:

             ! calcul de l'energie cinetique avant dissipation
             call covcont(llm, ucov, vcov, ucont, vcont)
             call enercin(vcov, ucov, vcont, ucont, ecin0)

             ! dissipation
             CALL dissip(vcov, ucov, teta, p3d, dvdis, dudis, dtetadis)
             ucov=ucov + dudis
             vcov=vcov + dvdis

             ! On rajoute la tendance due à la transformation Ec -> E
             ! thermique créée lors de la dissipation
             call covcont(llm, ucov, vcov, ucont, vcont)
             call enercin(vcov, ucov, vcont, ucont, ecin)
             dtetaecdt= (ecin0 - ecin) / pk
             dtetadis=dtetadis + dtetaecdt
             teta=teta + dtetadis

             ! Calcul de la valeur moyenne unique de h aux pôles
             forall (l = 1: llm)
                teta(:, 1, l) = SUM(aire_2d(:iim, 1) * teta(:iim, 1, l)) &
                     / apoln
                teta(:, jjm + 1, l) = SUM(aire_2d(:iim, jjm+1) &
                     * teta(:iim, jjm + 1, l)) / apols
             END forall

             ps(:, 1) = SUM(aire_2d(:iim, 1) * ps(:iim, 1)) / apoln
             ps(:, jjm + 1) = SUM(aire_2d(:iim, jjm+1) * ps(:iim, jjm + 1)) &
                  / apols
          END IF

          ! fin de l'intégration dynamique et physique pour le pas "itau"
          ! préparation du pas d'intégration suivant

          ! schema matsuno + leapfrog
          IF (forward .OR. leapf) THEN
             itau = itau + 1
             iday = day_ini + itau / day_step
             time = REAL(itau - (iday - day_ini) * day_step) / day_step &
                  + time_0
             IF (time > 1.) THEN
                time = time - 1.
                iday = iday + 1
             ENDIF
          ENDIF

          IF (itau == itaufin + 1) exit outer_loop

          IF (MOD(itau, iperiod) == 0 .OR. itau == itaufin) THEN
             ! ecriture du fichier histoire moyenne:
             CALL writedynav(histaveid, nqmx, itau, vcov, &
                  ucov, teta, pk, phi, q, masse, ps, phis)
             call bilan_dyn(2, dtvr * iperiod, dtvr * day_step * periodav, &
                  ps, masse, pk, pbaru, pbarv, teta, phi, ucov, vcov, q)
          ENDIF

          IF (itau == itaufin) CALL dynredem1("restart.nc", vcov, ucov, teta, &
               q, masse, ps, itau=itau_dyn+itaufin)

          ! gestion de l'integration temporelle:
          IF (MOD(itau, iperiod) == 0) exit
          IF (MOD(itau - 1, iperiod) == 0) THEN
             IF (forward) THEN
                ! fin du pas forward et debut du pas backward
                forward = .FALSE.
                leapf = .FALSE.
             ELSE
                ! fin du pas backward et debut du premier pas leapfrog
                leapf = .TRUE.
                dt = 2. * dtvr
             END IF
          ELSE
             ! pas leapfrog
             leapf = .TRUE.
             dt = 2. * dtvr
          END IF
       end do
    end do outer_loop

  END SUBROUTINE leapfrog

end module leapfrog_m
1	module leapfrog_m
2
3	IMPLICIT NONE
4
5	contains
6
7	SUBROUTINE leapfrog(ucov, vcov, teta, ps, masse, phis, q, time_0)
8
9	! From dyn3d/leapfrog.F, version 1.6, 2005/04/13 08:58:34
10	! Authors: P. Le Van, L. Fairhead, F. Hourdin
11
12	USE calfis_m, ONLY: calfis
13	USE com_io_dyn, ONLY: histaveid
14	USE comconst, ONLY: daysec, dtphys, dtvr
15	USE comgeom, ONLY: aire_2d, apoln, apols
16	USE comvert, ONLY: ap, bp
17	USE conf_gcm_m, ONLY: day_step, iconser, iperiod, iphysiq, nday, offline, &
18	periodav
19	USE dimens_m, ONLY: iim, jjm, llm, nqmx
20	USE dynetat0_m, ONLY: day_ini
21	use dynredem1_m, only: dynredem1
22	USE exner_hyb_m, ONLY: exner_hyb
23	use filtreg_m, only: filtreg
24	USE guide_m, ONLY: guide
25	use inidissip_m, only: idissip
26	USE logic, ONLY: iflag_phys, ok_guide
27	USE paramet_m, ONLY: ip1jmp1
28	USE pression_m, ONLY: pression
29	USE pressure_var, ONLY: p3d
30	USE temps, ONLY: itau_dyn
31
32	! Variables dynamiques:
33	REAL vcov((iim + 1) * jjm, llm), ucov(ip1jmp1, llm) ! vents covariants
34	REAL, intent(inout):: teta(iim + 1, jjm + 1, llm) ! potential temperature
35	REAL ps(iim + 1, jjm + 1) ! pression au sol, en Pa
36
37	REAL masse(ip1jmp1, llm) ! masse d'air
38	REAL phis(ip1jmp1) ! geopotentiel au sol
39	REAL q(ip1jmp1, llm, nqmx) ! mass fractions of advected fields
40	REAL, intent(in):: time_0
41
42	! Variables local to the procedure:
43
44	! Variables dynamiques:
45
46	REAL pks(ip1jmp1) ! exner au sol
47	REAL pk(iim + 1, jjm + 1, llm) ! exner au milieu des couches
48	REAL pkf(ip1jmp1, llm) ! exner filt.au milieu des couches
49	REAL phi(ip1jmp1, llm) ! geopotential
50	REAL w(ip1jmp1, llm) ! vitesse verticale
51
52	! variables dynamiques intermediaire pour le transport
53	REAL pbaru(ip1jmp1, llm), pbarv((iim + 1) * jjm, llm) !flux de masse
54
55	! variables dynamiques au pas - 1
56	REAL vcovm1((iim + 1) * jjm, llm), ucovm1(ip1jmp1, llm)
57	REAL tetam1(iim + 1, jjm + 1, llm), psm1(iim + 1, jjm + 1)
58	REAL massem1(ip1jmp1, llm)
59
60	! tendances dynamiques
61	REAL dv((iim + 1) * jjm, llm), du(ip1jmp1, llm)
62	REAL dteta(ip1jmp1, llm), dq(ip1jmp1, llm, nqmx), dp(ip1jmp1)
63
64	! tendances de la dissipation
65	REAL dvdis((iim + 1) * jjm, llm), dudis(ip1jmp1, llm)
66	REAL dtetadis(iim + 1, jjm + 1, llm)
67
68	! tendances physiques
69	REAL dvfi((iim + 1) * jjm, llm), dufi(ip1jmp1, llm)
70	REAL dtetafi(ip1jmp1, llm), dqfi(ip1jmp1, llm, nqmx), dpfi(ip1jmp1)
71
72	! variables pour le fichier histoire
73
74	INTEGER itau ! index of the time step of the dynamics, starts at 0
75	INTEGER itaufin
76	INTEGER iday ! jour julien
77	REAL time ! time of day, as a fraction of day length
78	real finvmaold(ip1jmp1, llm)
79	LOGICAL:: lafin=.false.
80	INTEGER l
81
82	REAL rdayvrai, rdaym_ini
83
84	! Variables test conservation energie
85	REAL ecin(iim + 1, jjm + 1, llm), ecin0(iim + 1, jjm + 1, llm)
86	! Tendance de la temp. potentiel d (theta) / d t due a la
87	! tansformation d'energie cinetique en energie thermique
88	! cree par la dissipation
89	REAL dtetaecdt(iim + 1, jjm + 1, llm)
90	REAL vcont((iim + 1) * jjm, llm), ucont(ip1jmp1, llm)
91	logical forward, leapf
92	REAL dt
93
94	!---------------------------------------------------
95
96	print *, "Call sequence information: leapfrog"
97
98	itaufin = nday * day_step
99	itau = 0
100	iday = day_ini
101	time = time_0
102	dq = 0.
103	! On initialise la pression et la fonction d'Exner :
104	CALL pression(ip1jmp1, ap, bp, ps, p3d)
105	CALL exner_hyb(ps, p3d, pks, pk, pkf)
106
107	! Début de l'integration temporelle :
108	outer_loop:do
109	if (ok_guide .and. (itaufin - itau - 1) * dtvr > 21600.) &
110	call guide(itau, ucov, vcov, teta, q, masse, ps)
111	vcovm1 = vcov
112	ucovm1 = ucov
113	tetam1 = teta
114	massem1 = masse
115	psm1 = ps
116	forward = .TRUE.
117	leapf = .FALSE.
118	dt = dtvr
119	finvmaold = masse
120	CALL filtreg(finvmaold, jjm + 1, llm, - 2, 2, .TRUE., 1)
121
122	do
123	! Calcul des tendances dynamiques:
124	CALL geopot(ip1jmp1, teta, pk, pks, phis, phi)
125	CALL caldyn(itau, ucov, vcov, teta, ps, masse, pk, pkf, phis, phi, &
126	MOD(itau, iconser) == 0, du, dv, dteta, dp, w, pbaru, pbarv, &
127	time + iday - day_ini)
128
129	IF (forward .OR. leapf) THEN
130	! Calcul des tendances advection des traceurs (dont l'humidité)
131	CALL caladvtrac(q, pbaru, pbarv, p3d, masse, dq, teta, pk)
132	IF (offline) THEN
133	! Stokage du flux de masse pour traceurs off-line
134	CALL fluxstokenc(pbaru, pbarv, masse, teta, phi, phis, dtvr, &
135	itau)
136	ENDIF
137	ENDIF
138
139	! integrations dynamique et traceurs:
140	CALL integrd(2, vcovm1, ucovm1, tetam1, psm1, massem1, dv, du, &
141	dteta, dq, dp, vcov, ucov, teta, q, ps, masse, phis, &
142	finvmaold, leapf, dt)
143
144	IF (MOD(itau + 1, iphysiq) == 0 .AND. iflag_phys /= 0) THEN
145	! calcul des tendances physiques:
146	IF (itau + 1 == itaufin) lafin = .TRUE.
147
148	CALL pression(ip1jmp1, ap, bp, ps, p3d)
149	CALL exner_hyb(ps, p3d, pks, pk, pkf)
150
151	rdaym_ini = itau * dtvr / daysec
152	rdayvrai = rdaym_ini + day_ini
153
154	CALL calfis(nqmx, lafin, rdayvrai, time, ucov, vcov, teta, q, &
155	masse, ps, pk, phis, phi, du, dv, dteta, dq, w, &
156	dufi, dvfi, dtetafi, dqfi, dpfi)
157
158	! ajout des tendances physiques:
159	CALL addfi(nqmx, dtphys, ucov, vcov, teta, q, ps, dufi, dvfi, &
160	dtetafi, dqfi, dpfi)
161	ENDIF
162
163	CALL pression(ip1jmp1, ap, bp, ps, p3d)
164	CALL exner_hyb(ps, p3d, pks, pk, pkf)
165
166	IF (MOD(itau + 1, idissip) == 0) THEN
167	! dissipation horizontale et verticale des petites echelles:
168
169	! calcul de l'energie cinetique avant dissipation
170	call covcont(llm, ucov, vcov, ucont, vcont)
171	call enercin(vcov, ucov, vcont, ucont, ecin0)
172
173	! dissipation
174	CALL dissip(vcov, ucov, teta, p3d, dvdis, dudis, dtetadis)
175	ucov=ucov + dudis
176	vcov=vcov + dvdis
177
178	! On rajoute la tendance due à la transformation Ec -> E
179	! thermique créée lors de la dissipation
180	call covcont(llm, ucov, vcov, ucont, vcont)
181	call enercin(vcov, ucov, vcont, ucont, ecin)
182	dtetaecdt= (ecin0 - ecin) / pk
183	dtetadis=dtetadis + dtetaecdt
184	teta=teta + dtetadis
185
186	! Calcul de la valeur moyenne unique de h aux pôles
187	forall (l = 1: llm)
188	teta(:, 1, l) = SUM(aire_2d(:iim, 1) * teta(:iim, 1, l)) &
189	/ apoln
190	teta(:, jjm + 1, l) = SUM(aire_2d(:iim, jjm+1) &
191	* teta(:iim, jjm + 1, l)) / apols
192	END forall
193
194	ps(:, 1) = SUM(aire_2d(:iim, 1) * ps(:iim, 1)) / apoln
195	ps(:, jjm + 1) = SUM(aire_2d(:iim, jjm+1) * ps(:iim, jjm + 1)) &
196	/ apols
197	END IF
198
199	! fin de l'intégration dynamique et physique pour le pas "itau"
200	! préparation du pas d'intégration suivant
201
202	! schema matsuno + leapfrog
203	IF (forward .OR. leapf) THEN
204	itau = itau + 1
205	iday = day_ini + itau / day_step
206	time = REAL(itau - (iday - day_ini) * day_step) / day_step &
207	+ time_0
208	IF (time > 1.) THEN
209	time = time - 1.
210	iday = iday + 1
211	ENDIF
212	ENDIF
213
214	IF (itau == itaufin + 1) exit outer_loop
215
216	IF (MOD(itau, iperiod) == 0 .OR. itau == itaufin) THEN
217	! ecriture du fichier histoire moyenne:
218	CALL writedynav(histaveid, nqmx, itau, vcov, &
219	ucov, teta, pk, phi, q, masse, ps, phis)
220	call bilan_dyn(2, dtvr * iperiod, dtvr * day_step * periodav, &
221	ps, masse, pk, pbaru, pbarv, teta, phi, ucov, vcov, q)
222	ENDIF
223
224	IF (itau == itaufin) CALL dynredem1("restart.nc", vcov, ucov, teta, &
225	q, masse, ps, itau=itau_dyn+itaufin)
226
227	! gestion de l'integration temporelle:
228	IF (MOD(itau, iperiod) == 0) exit
229	IF (MOD(itau - 1, iperiod) == 0) THEN
230	IF (forward) THEN
231	! fin du pas forward et debut du pas backward
232	forward = .FALSE.
233	leapf = .FALSE.
234	ELSE
235	! fin du pas backward et debut du premier pas leapfrog
236	leapf = .TRUE.
237	dt = 2. * dtvr
238	END IF
239	ELSE
240	! pas leapfrog
241	leapf = .TRUE.
242	dt = 2. * dtvr
243	END IF
244	end do
245	end do outer_loop
246
247	END SUBROUTINE leapfrog
248
249	end module leapfrog_m