| 1 |
module cv30_feed_m |
| 2 |
|
| 3 |
implicit none |
| 4 |
|
| 5 |
contains |
| 6 |
|
| 7 |
SUBROUTINE cv30_feed(t1, q1, qs1, p1, ph1, gz1, nk1, icb1, iflag1, tnk1, & |
| 8 |
qnk1, gznk1, plcl1) |
| 9 |
|
| 10 |
! Purpose: convective feed |
| 11 |
|
| 12 |
use cv30_param_m, only: minorig, nl |
| 13 |
USE dimphy, ONLY: klev, klon |
| 14 |
use numer_rec_95, only: locate |
| 15 |
|
| 16 |
real, intent(in):: t1(:, :) ! (klon, klev) |
| 17 |
real, intent(in):: q1(:, :), qs1(:, :), p1(:, :) ! (klon, klev) |
| 18 |
real, intent(in):: ph1(:, :) ! (klon, klev+1) |
| 19 |
real, intent(in):: gz1(:, :) ! (klon, klev) |
| 20 |
|
| 21 |
! outputs: |
| 22 |
|
| 23 |
integer, intent(out):: nk1(:) ! (klon) |
| 24 |
|
| 25 |
integer, intent(out):: icb1(:) ! (klon) |
| 26 |
! first level above lcl, 2 <= icb1 <= nl - 2 |
| 27 |
|
| 28 |
integer, intent(out):: iflag1(:) ! (klon) |
| 29 |
real tnk1(klon), qnk1(klon), gznk1(klon) |
| 30 |
real, intent(out):: plcl1(klon) |
| 31 |
|
| 32 |
! Local: |
| 33 |
integer i |
| 34 |
real pnk(klon), qsnk(klon), rh(klon), chi(klon) |
| 35 |
real, parameter:: A = 1669., B = 122. |
| 36 |
|
| 37 |
!-------------------------------------------------------------------- |
| 38 |
|
| 39 |
iflag1 = 0 |
| 40 |
plcl1 = 0. |
| 41 |
|
| 42 |
! Origin level of ascending parcels |
| 43 |
nk1 = minorig |
| 44 |
|
| 45 |
! Check whether parcel level temperature and specific humidity |
| 46 |
! are reasonable |
| 47 |
|
| 48 |
do i = 1, klon |
| 49 |
if (t1(i, nk1(i)) < 250. .or. q1(i, nk1(i)) <= 0.) iflag1(i) = 7 |
| 50 |
end do |
| 51 |
|
| 52 |
! Calculate lifted condensation level of air at parcel origin level |
| 53 |
! (within 0.2 % of formula of Bolton, Mon. Wea. Rev., 1980) |
| 54 |
|
| 55 |
do i = 1, klon |
| 56 |
if (iflag1(i) == 0) then |
| 57 |
tnk1(i) = t1(i, nk1(i)) |
| 58 |
qnk1(i) = q1(i, nk1(i)) |
| 59 |
gznk1(i) = gz1(i, nk1(i)) |
| 60 |
pnk(i) = p1(i, nk1(i)) |
| 61 |
qsnk(i) = qs1(i, nk1(i)) |
| 62 |
|
| 63 |
rh(i) = qnk1(i) / qsnk(i) |
| 64 |
chi(i) = tnk1(i) / (A - B*rh(i) - tnk1(i)) |
| 65 |
plcl1(i) = pnk(i)*(rh(i)**chi(i)) |
| 66 |
if (plcl1(i) < 200. .or. plcl1(i) >= 2000.) iflag1(i) = 8 |
| 67 |
endif |
| 68 |
end do |
| 69 |
|
| 70 |
! Compute icb1: |
| 71 |
do i = 1, klon |
| 72 |
if (plcl1(i) <= ph1(i, nl - 2)) then |
| 73 |
! Distinguish this case just so that icb1 = nl - 2, not nl = |
| 74 |
! 3, for plcl1 exactly == ph1(i, nl - 2). Maybe not useful. |
| 75 |
icb1(i) = nl - 2 |
| 76 |
else |
| 77 |
icb1(i) = locate(- ph1(i, 3:nl - 2), - plcl1(i), my_lbound = 3) |
| 78 |
! {2 <= icb1(i) <= nl - 3} |
| 79 |
! {ph1(i, icb1(i) + 1) < plcl1(i)} |
| 80 |
! {plcl1(i) <= ph1(i, icb1(i)) or icb1(i) == 2} |
| 81 |
end if |
| 82 |
end do |
| 83 |
|
| 84 |
where (icb1 == nl - 2 .and. iflag1 == 0) iflag1 = 9 |
| 85 |
|
| 86 |
! {(2 <= icb1(i) <= nl - 3 and ph1(i, icb1(i) + 1) < plcl1(i) and |
| 87 |
! (plcl1(i) <= ph1(i, icb1(i)) or icb1(i) == 2)) or iflag1(i) /= |
| 88 |
! 0} |
| 89 |
|
| 90 |
end SUBROUTINE cv30_feed |
| 91 |
|
| 92 |
end module cv30_feed_m |
Parent Directory
| 
Revision Log