phylmd/Interface_surf/calbeta.f

module calbeta_m

  IMPLICIT NONE

contains

  SUBROUTINE calbeta(indice, snow, qsol, beta, vcal, vdif)

    ! Author: Z. X. Li (LMD/CNRS)
    ! Date: April 14th, 1994

    ! Calcul de quelques paramètres pour appliquer la couche limite.

    USE indicesol, ONLY: is_lic, is_oce, is_sic, is_ter

    INTEGER, intent(in):: indice
    REAL, intent(in):: snow(:)

    REAL, intent(in):: qsol(:) ! (knon)
    ! column-density of water in soil, in kg m-2

    REAL, intent(out):: beta(:), vcal(:), vdif(:) ! (knon)

    ! Local:

    REAL, PARAMETER:: tau_gl = 86400. * 5. 
    ! temps de relaxation pour la glace de mer

    REAL, PARAMETER:: max_eau_sol = 150. ! in kg m-2

    ! Pour une épaisseur du sol de 15 cm :
    REAL, PARAMETER:: calsol = 1. / (2.5578E6 * 0.15)
    REAL, PARAMETER:: calsno = 1. / (2.3867E6 * 0.15)
    REAL, PARAMETER:: calice = 1. / (5.1444E6 * 0.15)

    !------------------------------------------------------------

    select case (indice)
    case(is_oce)
       beta = 1.
       vcal = 0.
       vdif = 0.

    case (is_sic)
       beta = 1.
       vcal = merge(calsno, calice, snow > 0.)
       vdif = 1. / tau_gl

    case (is_ter)
       beta = min(2. * qsol / max_eau_sol, 1.)
       vcal = merge(calsno, calsol, snow > 0.)
       vdif = 0.

    case (is_lic)
       beta = 1.
       vcal = merge(calsno, calice, snow > 0.)
       vdif = 0.
    END select

  END SUBROUTINE calbeta

end module calbeta_m
1	module calbeta_m
2
3	IMPLICIT NONE
4
5	contains
6
7	SUBROUTINE calbeta(indice, snow, qsol, beta, vcal, vdif)
8
9	! Author: Z. X. Li (LMD/CNRS)
10	! Date: April 14th, 1994
11
12	! Calcul de quelques paramètres pour appliquer la couche limite.
13
14	USE indicesol, ONLY: is_lic, is_oce, is_sic, is_ter
15
16	INTEGER, intent(in):: indice
17	REAL, intent(in):: snow(:)
18
19	REAL, intent(in):: qsol(:) ! (knon)
20	! column-density of water in soil, in kg m-2
21
22	REAL, intent(out):: beta(:), vcal(:), vdif(:) ! (knon)
23
24	! Local:
25
26	REAL, PARAMETER:: tau_gl = 86400. * 5.
27	! temps de relaxation pour la glace de mer
28
29	REAL, PARAMETER:: max_eau_sol = 150. ! in kg m-2
30
31	! Pour une épaisseur du sol de 15 cm :
32	REAL, PARAMETER:: calsol = 1. / (2.5578E6 * 0.15)
33	REAL, PARAMETER:: calsno = 1. / (2.3867E6 * 0.15)
34	REAL, PARAMETER:: calice = 1. / (5.1444E6 * 0.15)
35
36	!------------------------------------------------------------
37
38	select case (indice)
39	case(is_oce)
40	beta = 1.
41	vcal = 0.
42	vdif = 0.
43
44	case (is_sic)
45	beta = 1.
46	vcal = merge(calsno, calice, snow > 0.)
47	vdif = 1. / tau_gl
48
49	case (is_ter)
50	beta = min(2. * qsol / max_eau_sol, 1.)
51	vcal = merge(calsno, calsol, snow > 0.)
52	vdif = 0.
53
54	case (is_lic)
55	beta = 1.
56	vcal = merge(calsno, calice, snow > 0.)
57	vdif = 0.
58	END select
59
60	END SUBROUTINE calbeta
61
62	end module calbeta_m