1 |
module calcul_fluxs_m |
2 |
|
3 |
implicit none |
4 |
|
5 |
contains |
6 |
|
7 |
SUBROUTINE calcul_fluxs(dtime, tsurf, p1lay, cal, beta, coef1lay, ps, & |
8 |
qsurf, radsol, dif_grnd, t1lay, q1lay, u1lay, v1lay, petAcoef, & |
9 |
peqAcoef, petBcoef, peqBcoef, tsurf_new, evap, fluxlat, fluxsens, & |
10 |
dflux_s, dflux_l) |
11 |
|
12 |
! Cette routine calcule les fluxs en h et q à l'interface et une |
13 |
! température de surface. |
14 |
|
15 |
! L. Fairhead April 2000 |
16 |
|
17 |
USE abort_gcm_m, ONLY: abort_gcm |
18 |
USE fcttre, ONLY: dqsatl, dqsats, foede, foeew, qsatl, qsats, thermcep |
19 |
USE indicesol, ONLY: is_ter |
20 |
use nr_util, only: assert_eq |
21 |
USE suphec_m, ONLY: rcpd, rd, retv, rkappa, rlstt, rlvtt, rtt |
22 |
USE yoethf_m, ONLY: r2es, r5ies, r5les, rvtmp2 |
23 |
|
24 |
real, intent(IN):: dtime |
25 |
real, intent(IN):: tsurf(:) ! (knon) temperature de surface |
26 |
real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche) |
27 |
real, intent(IN):: cal(:) ! (knon) capacité calorifique du sol |
28 |
real, intent(IN):: beta(:) ! (knon) evap reelle |
29 |
real, intent(IN):: coef1lay(:) ! (knon) coefficient d'échange |
30 |
real, intent(IN):: ps(:) ! (knon) pression au sol |
31 |
real, intent(OUT):: qsurf(:) ! (knon) humidite de l'air au dessus du sol |
32 |
real, intent(IN):: radsol(:) ! (knon) rayonnement net au sol (LW + SW) |
33 |
|
34 |
real, intent(IN):: dif_grnd(:) ! (knon) |
35 |
! coefficient diffusion vers le sol profond |
36 |
|
37 |
real, intent(IN):: t1lay(:), q1lay(:), u1lay(:), v1lay(:) ! (knon) |
38 |
|
39 |
real, intent(IN):: petAcoef(:), peqAcoef(:) ! (knon) |
40 |
! coefficients A de la résolution de la couche limite pour t et q |
41 |
|
42 |
real, intent(IN):: petBcoef(:), peqBcoef(:) ! (knon) |
43 |
! coeff. B de la resolution de la CL pour t et q |
44 |
|
45 |
real, intent(OUT):: tsurf_new(:) ! (knon) température au sol |
46 |
real, intent(OUT):: evap(:) ! (knon) |
47 |
|
48 |
real, intent(OUT):: fluxlat(:), fluxsens(:) ! (knon) |
49 |
! flux de chaleur latente et sensible |
50 |
|
51 |
real, intent(OUT):: dflux_s(:), dflux_l(:) ! (knon) |
52 |
! dérivées des flux de chaleurs sensible et latente par rapport à |
53 |
! Ts (W m-2 K-1) |
54 |
|
55 |
! Local: |
56 |
integer i |
57 |
integer knon ! nombre de points a traiter |
58 |
real, dimension(size(ps)):: mh, oh, mq, nq, oq |
59 |
real, dimension(size(ps)):: dq_s_dt, coef |
60 |
real qsat(size(ps)) ! qsat en kg/kg |
61 |
real sl(size(ps)) ! chaleur latente d'evaporation ou de sublimation |
62 |
logical delta |
63 |
real zcor |
64 |
real, parameter:: t_grnd = 271.35, t_coup = 273.15 |
65 |
|
66 |
!--------------------------------------------------------------------- |
67 |
|
68 |
knon = assert_eq((/size(tsurf), size(p1lay), size(cal), size(beta), & |
69 |
size(coef1lay), size(ps), size(qsurf), size(radsol), size(dif_grnd), & |
70 |
size(t1lay), size(q1lay), size(u1lay), size(v1lay), size(petAcoef), & |
71 |
size(peqAcoef), size(petBcoef), size(peqBcoef), size(tsurf_new), & |
72 |
size(evap), size(fluxlat), size(fluxsens), size(dflux_s), & |
73 |
size(dflux_l)/), "calcul_fluxs knon") |
74 |
|
75 |
! Traitement humidite du sol |
76 |
|
77 |
IF (thermcep) THEN |
78 |
DO i = 1, knon |
79 |
delta = rtt >= tsurf(i) |
80 |
qsat(i) = MIN(0.5, r2es * FOEEW(tsurf(i), delta) / ps(i)) |
81 |
zcor = 1. / (1. - retv * qsat(i)) |
82 |
qsat(i) = qsat(i) * zcor |
83 |
dq_s_dt(i) = RCPD * FOEDE(tsurf(i), delta, merge(R5IES * RLSTT, & |
84 |
R5LES * RLVTT, delta) / RCPD / (1. + RVTMP2 * q1lay(i)), & |
85 |
qsat(i), zcor) / RLVTT |
86 |
ENDDO |
87 |
ELSE |
88 |
DO i = 1, knon |
89 |
IF (tsurf(i) < t_coup) THEN |
90 |
qsat(i) = qsats(tsurf(i)) / ps(i) |
91 |
dq_s_dt(i) = RCPD * dqsats(tsurf(i), qsat(i)) / RLVTT |
92 |
ELSE |
93 |
qsat(i) = qsatl(tsurf(i)) / ps(i) |
94 |
dq_s_dt(i) = RCPD * dqsatl(tsurf(i), qsat(i)) / RLVTT |
95 |
ENDIF |
96 |
ENDDO |
97 |
ENDIF |
98 |
|
99 |
coef = coef1lay * (1. + SQRT(u1lay**2 + v1lay**2)) * p1lay / (RD * t1lay) |
100 |
sl = merge(RLSTT, RLVTT, tsurf < RTT) |
101 |
|
102 |
! Q |
103 |
oq = 1. - (beta * coef * peqBcoef * dtime) |
104 |
mq = beta * coef * (peqAcoef - qsat + dq_s_dt * tsurf) / oq |
105 |
nq = beta * coef * (- 1. * dq_s_dt) / oq |
106 |
|
107 |
! H |
108 |
oh = 1. - (coef * petBcoef * dtime) |
109 |
mh = coef * petAcoef / oh |
110 |
dflux_s = - (coef * RCPD)/ oh |
111 |
|
112 |
! Tsurface |
113 |
tsurf_new = (tsurf + cal / RCPD * dtime * (radsol + mh + sl * mq) & |
114 |
+ dif_grnd * t_grnd * dtime) / (1. - dtime * cal / RCPD * (dflux_s & |
115 |
+ sl * nq) + dtime * dif_grnd) |
116 |
|
117 |
evap = - mq - nq * tsurf_new |
118 |
fluxlat = - evap * sl |
119 |
fluxsens = mh + dflux_s * tsurf_new |
120 |
dflux_l = sl * nq |
121 |
|
122 |
! Nouvelle valeur de l'humidité au dessus du sol : |
123 |
qsurf = (peqAcoef - peqBcoef * evap * dtime) * (1. - beta) + beta * (qsat & |
124 |
+ dq_s_dt * (tsurf_new - tsurf)) |
125 |
|
126 |
END SUBROUTINE calcul_fluxs |
127 |
|
128 |
end module calcul_fluxs_m |