| 1 |
module clmain_m |
| 2 |
|
| 3 |
IMPLICIT NONE |
| 4 |
|
| 5 |
contains |
| 6 |
|
| 7 |
SUBROUTINE clmain(dtime, pctsrf, t, q, u, v, julien, mu0, ftsol, cdmmax, & |
| 8 |
cdhmax, ksta, ksta_ter, ok_kzmin, ftsoil, qsol, paprs, pplay, fsnow, & |
| 9 |
qsurf, evap, falbe, fluxlat, rain_fall, snow_f, fsolsw, fsollw, frugs, & |
| 10 |
agesno, rugoro, d_t, d_q, d_u, d_v, d_ts, flux_t, flux_q, flux_u, & |
| 11 |
flux_v, cdragh, cdragm, q2, dflux_t, dflux_q, ycoefh, t2m, q2m, & |
| 12 |
u10m_srf, v10m_srf, pblh, capcl, oliqcl, cteicl, pblt, therm, trmb1, & |
| 13 |
trmb2, trmb3, plcl, fqcalving, ffonte, run_off_lic_0) |
| 14 |
|
| 15 |
! From phylmd/clmain.F, version 1.6, 2005/11/16 14:47:19 |
| 16 |
! Author: Z. X. Li (LMD/CNRS), date: 1993/08/18 |
| 17 |
! Objet : interface de couche limite (diffusion verticale) |
| 18 |
|
| 19 |
! Tout ce qui a trait aux traceurs est dans "phytrac". Le calcul |
| 20 |
! de la couche limite pour les traceurs se fait avec "cltrac" et |
| 21 |
! ne tient pas compte de la diff\'erentiation des sous-fractions |
| 22 |
! de sol. |
| 23 |
|
| 24 |
use clqh_m, only: clqh |
| 25 |
use clvent_m, only: clvent |
| 26 |
use coefkz_m, only: coefkz |
| 27 |
use coefkzmin_m, only: coefkzmin |
| 28 |
use coefkz2_m, only: coefkz2 |
| 29 |
USE conf_gcm_m, ONLY: lmt_pas |
| 30 |
USE conf_phys_m, ONLY: iflag_pbl |
| 31 |
USE dimphy, ONLY: klev, klon, zmasq |
| 32 |
USE dimsoil, ONLY: nsoilmx |
| 33 |
use hbtm_m, only: hbtm |
| 34 |
USE indicesol, ONLY: epsfra, is_lic, is_oce, is_sic, is_ter, nbsrf |
| 35 |
USE interfoce_lim_m, ONLY: interfoce_lim |
| 36 |
use stdlevvar_m, only: stdlevvar |
| 37 |
USE suphec_m, ONLY: rd, rg, rkappa |
| 38 |
use time_phylmdz, only: itap |
| 39 |
use ustarhb_m, only: ustarhb |
| 40 |
use yamada4_m, only: yamada4 |
| 41 |
|
| 42 |
REAL, INTENT(IN):: dtime ! interval du temps (secondes) |
| 43 |
|
| 44 |
REAL, INTENT(inout):: pctsrf(klon, nbsrf) |
| 45 |
! tableau des pourcentages de surface de chaque maille |
| 46 |
|
| 47 |
REAL, INTENT(IN):: t(klon, klev) ! temperature (K) |
| 48 |
REAL, INTENT(IN):: q(klon, klev) ! vapeur d'eau (kg / kg) |
| 49 |
REAL, INTENT(IN):: u(klon, klev), v(klon, klev) ! vitesse |
| 50 |
INTEGER, INTENT(IN):: julien ! jour de l'annee en cours |
| 51 |
REAL, intent(in):: mu0(klon) ! cosinus de l'angle solaire zenithal |
| 52 |
REAL, INTENT(IN):: ftsol(:, :) ! (klon, nbsrf) temp\'erature du sol (en K) |
| 53 |
REAL, INTENT(IN):: cdmmax, cdhmax ! seuils cdrm, cdrh |
| 54 |
REAL, INTENT(IN):: ksta, ksta_ter |
| 55 |
LOGICAL, INTENT(IN):: ok_kzmin |
| 56 |
|
| 57 |
REAL, INTENT(inout):: ftsoil(klon, nsoilmx, nbsrf) |
| 58 |
! soil temperature of surface fraction |
| 59 |
|
| 60 |
REAL, INTENT(inout):: qsol(:) ! (klon) |
| 61 |
! column-density of water in soil, in kg m-2 |
| 62 |
|
| 63 |
REAL, INTENT(IN):: paprs(klon, klev + 1) ! pression a intercouche (Pa) |
| 64 |
REAL, INTENT(IN):: pplay(klon, klev) ! pression au milieu de couche (Pa) |
| 65 |
REAL, INTENT(inout):: fsnow(:, :) ! (klon, nbsrf) \'epaisseur neigeuse |
| 66 |
REAL qsurf(klon, nbsrf) |
| 67 |
REAL evap(klon, nbsrf) |
| 68 |
REAL, intent(inout):: falbe(klon, nbsrf) |
| 69 |
REAL, intent(out):: fluxlat(:, :) ! (klon, nbsrf) |
| 70 |
|
| 71 |
REAL, intent(in):: rain_fall(klon) |
| 72 |
! liquid water mass flux (kg / m2 / s), positive down |
| 73 |
|
| 74 |
REAL, intent(in):: snow_f(klon) |
| 75 |
! solid water mass flux (kg / m2 / s), positive down |
| 76 |
|
| 77 |
REAL, INTENT(IN):: fsolsw(klon, nbsrf), fsollw(klon, nbsrf) |
| 78 |
REAL, intent(inout):: frugs(klon, nbsrf) ! longueur de rugosit\'e (en m) |
| 79 |
real agesno(klon, nbsrf) |
| 80 |
REAL, INTENT(IN):: rugoro(klon) |
| 81 |
|
| 82 |
REAL d_t(klon, klev), d_q(klon, klev) |
| 83 |
! d_t------output-R- le changement pour "t" |
| 84 |
! d_q------output-R- le changement pour "q" |
| 85 |
|
| 86 |
REAL, intent(out):: d_u(klon, klev), d_v(klon, klev) |
| 87 |
! changement pour "u" et "v" |
| 88 |
|
| 89 |
REAL, intent(out):: d_ts(:, :) ! (klon, nbsrf) variation of ftsol |
| 90 |
|
| 91 |
REAL, intent(out):: flux_t(klon, nbsrf) |
| 92 |
! flux de chaleur sensible (Cp T) (W / m2) (orientation positive vers |
| 93 |
! le bas) à la surface |
| 94 |
|
| 95 |
REAL, intent(out):: flux_q(klon, nbsrf) |
| 96 |
! flux de vapeur d'eau (kg / m2 / s) à la surface |
| 97 |
|
| 98 |
REAL, intent(out):: flux_u(klon, nbsrf), flux_v(klon, nbsrf) |
| 99 |
! tension du vent (flux turbulent de vent) à la surface, en Pa |
| 100 |
|
| 101 |
REAL, INTENT(out):: cdragh(klon), cdragm(klon) |
| 102 |
real q2(klon, klev + 1, nbsrf) |
| 103 |
|
| 104 |
REAL, INTENT(out):: dflux_t(klon), dflux_q(klon) |
| 105 |
! dflux_t derive du flux sensible |
| 106 |
! dflux_q derive du flux latent |
| 107 |
! IM "slab" ocean |
| 108 |
|
| 109 |
REAL, intent(out):: ycoefh(klon, klev) |
| 110 |
! Pour pouvoir extraire les coefficients d'\'echange, le champ |
| 111 |
! "ycoefh" a \'et\'e cr\'e\'e. Nous avons moyenn\'e les valeurs de |
| 112 |
! ce champ sur les quatre sous-surfaces du mod\`ele. |
| 113 |
|
| 114 |
REAL, INTENT(inout):: t2m(klon, nbsrf), q2m(klon, nbsrf) |
| 115 |
|
| 116 |
REAL, INTENT(inout):: u10m_srf(:, :), v10m_srf(:, :) ! (klon, nbsrf) |
| 117 |
! composantes du vent \`a 10m sans spirale d'Ekman |
| 118 |
|
| 119 |
! Ionela Musat. Cf. Anne Mathieu : planetary boundary layer, hbtm. |
| 120 |
! Comme les autres diagnostics on cumule dans physiq ce qui permet |
| 121 |
! de sortir les grandeurs par sous-surface. |
| 122 |
REAL pblh(klon, nbsrf) ! height of planetary boundary layer |
| 123 |
REAL capcl(klon, nbsrf) |
| 124 |
REAL oliqcl(klon, nbsrf) |
| 125 |
REAL cteicl(klon, nbsrf) |
| 126 |
REAL, INTENT(inout):: pblt(klon, nbsrf) ! T au nveau HCL |
| 127 |
REAL therm(klon, nbsrf) |
| 128 |
REAL trmb1(klon, nbsrf) |
| 129 |
! trmb1-------deep_cape |
| 130 |
REAL trmb2(klon, nbsrf) |
| 131 |
! trmb2--------inhibition |
| 132 |
REAL trmb3(klon, nbsrf) |
| 133 |
! trmb3-------Point Omega |
| 134 |
REAL plcl(klon, nbsrf) |
| 135 |
REAL fqcalving(klon, nbsrf), ffonte(klon, nbsrf) |
| 136 |
! ffonte----Flux thermique utilise pour fondre la neige |
| 137 |
! fqcalving-Flux d'eau "perdue" par la surface et necessaire pour limiter la |
| 138 |
! hauteur de neige, en kg / m2 / s |
| 139 |
REAL run_off_lic_0(klon) |
| 140 |
|
| 141 |
! Local: |
| 142 |
|
| 143 |
LOGICAL:: firstcal = .true. |
| 144 |
|
| 145 |
! la nouvelle repartition des surfaces sortie de l'interface |
| 146 |
REAL, save:: pctsrf_new_oce(klon) |
| 147 |
REAL, save:: pctsrf_new_sic(klon) |
| 148 |
|
| 149 |
REAL y_fqcalving(klon), y_ffonte(klon) |
| 150 |
real y_run_off_lic_0(klon) |
| 151 |
REAL rugmer(klon) |
| 152 |
REAL ytsoil(klon, nsoilmx) |
| 153 |
REAL yts(klon), yrugos(klon), ypct(klon), yz0_new(klon) |
| 154 |
REAL yalb(klon) |
| 155 |
REAL snow(klon), yqsurf(klon), yagesno(klon) |
| 156 |
real yqsol(klon) ! column-density of water in soil, in kg m-2 |
| 157 |
REAL yrain_f(klon) ! liquid water mass flux (kg / m2 / s), positive down |
| 158 |
REAL ysnow_f(klon) ! solid water mass flux (kg / m2 / s), positive down |
| 159 |
REAL yrugm(klon), yrads(klon), yrugoro(klon) |
| 160 |
REAL yfluxlat(klon) |
| 161 |
REAL y_d_ts(klon) |
| 162 |
REAL y_d_t(klon, klev), y_d_q(klon, klev) |
| 163 |
REAL y_d_u(klon, klev), y_d_v(klon, klev) |
| 164 |
REAL y_flux_t(klon), y_flux_q(klon) |
| 165 |
REAL y_flux_u(klon), y_flux_v(klon) |
| 166 |
REAL y_dflux_t(klon), y_dflux_q(klon) |
| 167 |
REAL coefh(klon, klev), coefm(klon, klev) |
| 168 |
REAL yu(klon, klev), yv(klon, klev) |
| 169 |
REAL yt(klon, klev), yq(klon, klev) |
| 170 |
REAL ypaprs(klon, klev + 1), ypplay(klon, klev), ydelp(klon, klev) |
| 171 |
REAL ycoefm0(klon, klev), ycoefh0(klon, klev) |
| 172 |
REAL yzlay(klon, klev), zlev(klon, klev + 1), yteta(klon, klev) |
| 173 |
REAL ykmm(klon, klev + 1), ykmn(klon, klev + 1) |
| 174 |
REAL ykmq(klon, klev + 1) |
| 175 |
REAL yq2(klon, klev + 1) |
| 176 |
REAL delp(klon, klev) |
| 177 |
INTEGER i, k, nsrf |
| 178 |
INTEGER ni(klon), knon, j |
| 179 |
|
| 180 |
REAL pctsrf_pot(klon, nbsrf) |
| 181 |
! "pourcentage potentiel" pour tenir compte des \'eventuelles |
| 182 |
! apparitions ou disparitions de la glace de mer |
| 183 |
|
| 184 |
REAL yt2m(klon), yq2m(klon), wind10m(klon) |
| 185 |
REAL ustar(klon) |
| 186 |
|
| 187 |
REAL yt10m(klon), yq10m(klon) |
| 188 |
REAL ypblh(klon) |
| 189 |
REAL ylcl(klon) |
| 190 |
REAL ycapcl(klon) |
| 191 |
REAL yoliqcl(klon) |
| 192 |
REAL ycteicl(klon) |
| 193 |
REAL ypblt(klon) |
| 194 |
REAL ytherm(klon) |
| 195 |
REAL ytrmb1(klon) |
| 196 |
REAL ytrmb2(klon) |
| 197 |
REAL ytrmb3(klon) |
| 198 |
REAL u1(klon), v1(klon) |
| 199 |
REAL tair1(klon), qair1(klon), tairsol(klon) |
| 200 |
REAL psfce(klon), patm(klon) |
| 201 |
|
| 202 |
REAL qairsol(klon), zgeo1(klon) |
| 203 |
REAL rugo1(klon) |
| 204 |
|
| 205 |
!------------------------------------------------------------ |
| 206 |
|
| 207 |
ytherm = 0. |
| 208 |
|
| 209 |
DO k = 1, klev ! epaisseur de couche |
| 210 |
DO i = 1, klon |
| 211 |
delp(i, k) = paprs(i, k) - paprs(i, k + 1) |
| 212 |
END DO |
| 213 |
END DO |
| 214 |
|
| 215 |
! Initialization: |
| 216 |
rugmer = 0. |
| 217 |
cdragh = 0. |
| 218 |
cdragm = 0. |
| 219 |
dflux_t = 0. |
| 220 |
dflux_q = 0. |
| 221 |
ypct = 0. |
| 222 |
yqsurf = 0. |
| 223 |
yrain_f = 0. |
| 224 |
ysnow_f = 0. |
| 225 |
yrugos = 0. |
| 226 |
ypaprs = 0. |
| 227 |
ypplay = 0. |
| 228 |
ydelp = 0. |
| 229 |
yu = 0. |
| 230 |
yv = 0. |
| 231 |
yt = 0. |
| 232 |
yq = 0. |
| 233 |
y_dflux_t = 0. |
| 234 |
y_dflux_q = 0. |
| 235 |
yrugoro = 0. |
| 236 |
d_ts = 0. |
| 237 |
flux_t = 0. |
| 238 |
flux_q = 0. |
| 239 |
flux_u = 0. |
| 240 |
flux_v = 0. |
| 241 |
fluxlat = 0. |
| 242 |
d_t = 0. |
| 243 |
d_q = 0. |
| 244 |
d_u = 0. |
| 245 |
d_v = 0. |
| 246 |
ycoefh = 0. |
| 247 |
|
| 248 |
! Initialisation des "pourcentages potentiels". On consid\`ere ici qu'on |
| 249 |
! peut avoir potentiellement de la glace sur tout le domaine oc\'eanique |
| 250 |
! (\`a affiner) |
| 251 |
|
| 252 |
pctsrf_pot(:, is_ter) = pctsrf(:, is_ter) |
| 253 |
pctsrf_pot(:, is_lic) = pctsrf(:, is_lic) |
| 254 |
pctsrf_pot(:, is_oce) = 1. - zmasq |
| 255 |
pctsrf_pot(:, is_sic) = 1. - zmasq |
| 256 |
|
| 257 |
! Tester si c'est le moment de lire le fichier: |
| 258 |
if (mod(itap - 1, lmt_pas) == 0) then |
| 259 |
CALL interfoce_lim(julien, pctsrf_new_oce, pctsrf_new_sic) |
| 260 |
endif |
| 261 |
|
| 262 |
! Boucler sur toutes les sous-fractions du sol: |
| 263 |
|
| 264 |
loop_surface: DO nsrf = 1, nbsrf |
| 265 |
! Chercher les indices : |
| 266 |
ni = 0 |
| 267 |
knon = 0 |
| 268 |
DO i = 1, klon |
| 269 |
! Pour d\'eterminer le domaine \`a traiter, on utilise les surfaces |
| 270 |
! "potentielles" |
| 271 |
IF (pctsrf_pot(i, nsrf) > epsfra) THEN |
| 272 |
knon = knon + 1 |
| 273 |
ni(knon) = i |
| 274 |
END IF |
| 275 |
END DO |
| 276 |
|
| 277 |
if_knon: IF (knon /= 0) then |
| 278 |
DO j = 1, knon |
| 279 |
i = ni(j) |
| 280 |
ypct(j) = pctsrf(i, nsrf) |
| 281 |
yts(j) = ftsol(i, nsrf) |
| 282 |
snow(j) = fsnow(i, nsrf) |
| 283 |
yqsurf(j) = qsurf(i, nsrf) |
| 284 |
yalb(j) = falbe(i, nsrf) |
| 285 |
yrain_f(j) = rain_fall(i) |
| 286 |
ysnow_f(j) = snow_f(i) |
| 287 |
yagesno(j) = agesno(i, nsrf) |
| 288 |
yrugos(j) = frugs(i, nsrf) |
| 289 |
yrugoro(j) = rugoro(i) |
| 290 |
yrads(j) = fsolsw(i, nsrf) + fsollw(i, nsrf) |
| 291 |
ypaprs(j, klev + 1) = paprs(i, klev + 1) |
| 292 |
y_run_off_lic_0(j) = run_off_lic_0(i) |
| 293 |
END DO |
| 294 |
|
| 295 |
! For continent, copy soil water content |
| 296 |
IF (nsrf == is_ter) yqsol(:knon) = qsol(ni(:knon)) |
| 297 |
|
| 298 |
ytsoil(:knon, :) = ftsoil(ni(:knon), :, nsrf) |
| 299 |
|
| 300 |
DO k = 1, klev |
| 301 |
DO j = 1, knon |
| 302 |
i = ni(j) |
| 303 |
ypaprs(j, k) = paprs(i, k) |
| 304 |
ypplay(j, k) = pplay(i, k) |
| 305 |
ydelp(j, k) = delp(i, k) |
| 306 |
yu(j, k) = u(i, k) |
| 307 |
yv(j, k) = v(i, k) |
| 308 |
yt(j, k) = t(i, k) |
| 309 |
yq(j, k) = q(i, k) |
| 310 |
END DO |
| 311 |
END DO |
| 312 |
|
| 313 |
! calculer Cdrag et les coefficients d'echange |
| 314 |
CALL coefkz(nsrf, ypaprs, ypplay, ksta, ksta_ter, yts(:knon), & |
| 315 |
yrugos, yu, yv, yt, yq, yqsurf(:knon), coefm(:knon, 2:), & |
| 316 |
coefh(:knon, 2:), coefm(:knon, 1), coefh(:knon, 1)) |
| 317 |
|
| 318 |
IF (iflag_pbl == 1) THEN |
| 319 |
CALL coefkz2(nsrf, knon, ypaprs, ypplay, yt, ycoefm0(:knon, 2:), & |
| 320 |
ycoefh0(:knon, 2:)) |
| 321 |
ycoefm0(:knon, 1) = 0. |
| 322 |
ycoefh0(:knon, 1) = 0. |
| 323 |
coefm(:knon, :) = max(coefm(:knon, :), ycoefm0(:knon, :)) |
| 324 |
coefh(:knon, :) = max(coefh(:knon, :), ycoefh0(:knon, :)) |
| 325 |
END IF |
| 326 |
|
| 327 |
! on met un seuil pour coefm et coefh |
| 328 |
IF (nsrf == is_oce) THEN |
| 329 |
coefm(:knon, 1) = min(coefm(:knon, 1), cdmmax) |
| 330 |
coefh(:knon, 1) = min(coefh(:knon, 1), cdhmax) |
| 331 |
END IF |
| 332 |
|
| 333 |
IF (ok_kzmin) THEN |
| 334 |
! Calcul d'une diffusion minimale pour les conditions tres stables |
| 335 |
CALL coefkzmin(knon, ypaprs, ypplay, yu, yv, yt, yq, & |
| 336 |
coefm(:knon, 1), ycoefm0(:knon, 2:), ycoefh0(:knon, 2:)) |
| 337 |
coefm(:knon, :) = max(coefm(:knon, :), ycoefm0(:knon, :)) |
| 338 |
coefh(:knon, :) = max(coefh(:knon, :), ycoefh0(:knon, :)) |
| 339 |
END IF |
| 340 |
|
| 341 |
IF (iflag_pbl >= 6) THEN |
| 342 |
! Mellor et Yamada adapt\'e \`a Mars, Richard Fournier et |
| 343 |
! Fr\'ed\'eric Hourdin |
| 344 |
yzlay(:knon, 1) = rd * yt(:knon, 1) / (0.5 * (ypaprs(:knon, 1) & |
| 345 |
+ ypplay(:knon, 1))) & |
| 346 |
* (ypaprs(:knon, 1) - ypplay(:knon, 1)) / rg |
| 347 |
|
| 348 |
DO k = 2, klev |
| 349 |
yzlay(:knon, k) = yzlay(:knon, k-1) & |
| 350 |
+ rd * 0.5 * (yt(1:knon, k-1) + yt(1:knon, k)) & |
| 351 |
/ ypaprs(1:knon, k) & |
| 352 |
* (ypplay(1:knon, k-1) - ypplay(1:knon, k)) / rg |
| 353 |
END DO |
| 354 |
|
| 355 |
DO k = 1, klev |
| 356 |
yteta(1:knon, k) = yt(1:knon, k) * (ypaprs(1:knon, 1) & |
| 357 |
/ ypplay(1:knon, k))**rkappa * (1. + 0.61 * yq(1:knon, k)) |
| 358 |
END DO |
| 359 |
|
| 360 |
zlev(:knon, 1) = 0. |
| 361 |
zlev(:knon, klev + 1) = 2. * yzlay(:knon, klev) & |
| 362 |
- yzlay(:knon, klev - 1) |
| 363 |
|
| 364 |
DO k = 2, klev |
| 365 |
zlev(:knon, k) = 0.5 * (yzlay(:knon, k) + yzlay(:knon, k-1)) |
| 366 |
END DO |
| 367 |
|
| 368 |
DO k = 1, klev + 1 |
| 369 |
DO j = 1, knon |
| 370 |
i = ni(j) |
| 371 |
yq2(j, k) = q2(i, k, nsrf) |
| 372 |
END DO |
| 373 |
END DO |
| 374 |
|
| 375 |
ustar(:knon) = ustarhb(yu(:knon, 1), yv(:knon, 1), coefm(:knon, 1)) |
| 376 |
CALL yamada4(dtime, rg, zlev(:knon, :), yzlay(:knon, :), & |
| 377 |
yu(:knon, :), yv(:knon, :), yteta(:knon, :), & |
| 378 |
coefm(:knon, 1), yq2(:knon, :), ykmm(:knon, :), & |
| 379 |
ykmn(:knon, :), ykmq(:knon, :), ustar(:knon)) |
| 380 |
coefm(:knon, 2:) = ykmm(:knon, 2:klev) |
| 381 |
coefh(:knon, 2:) = ykmn(:knon, 2:klev) |
| 382 |
END IF |
| 383 |
|
| 384 |
CALL clvent(dtime, yu(:knon, 1), yv(:knon, 1), coefm(:knon, 2:), & |
| 385 |
coefm(:knon, 1), yt(:knon, :), yu(:knon, :), ypaprs(:knon, :), & |
| 386 |
ypplay(:knon, :), ydelp(:knon, :), y_d_u(:knon, :), & |
| 387 |
y_flux_u(:knon)) |
| 388 |
CALL clvent(dtime, yu(:knon, 1), yv(:knon, 1), coefm(:knon, 2:), & |
| 389 |
coefm(:knon, 1), yt(:knon, :), yv(:knon, :), ypaprs(:knon, :), & |
| 390 |
ypplay(:knon, :), ydelp(:knon, :), y_d_v(:knon, :), & |
| 391 |
y_flux_v(:knon)) |
| 392 |
|
| 393 |
! calculer la diffusion de "q" et de "h" |
| 394 |
CALL clqh(dtime, julien, firstcal, nsrf, ni(:knon), & |
| 395 |
ytsoil(:knon, :), yqsol(:knon), mu0, yrugos, yrugoro, & |
| 396 |
yu(:knon, 1), yv(:knon, 1), coefh(:knon, :), yt, yq, & |
| 397 |
yts(:knon), ypaprs, ypplay, ydelp, yrads(:knon), yalb(:knon), & |
| 398 |
snow(:knon), yqsurf, yrain_f, ysnow_f, yfluxlat(:knon), & |
| 399 |
pctsrf_new_sic, yagesno(:knon), y_d_t, y_d_q, y_d_ts(:knon), & |
| 400 |
yz0_new, y_flux_t(:knon), y_flux_q(:knon), y_dflux_t(:knon), & |
| 401 |
y_dflux_q(:knon), y_fqcalving, y_ffonte, y_run_off_lic_0) |
| 402 |
|
| 403 |
! calculer la longueur de rugosite sur ocean |
| 404 |
yrugm = 0. |
| 405 |
IF (nsrf == is_oce) THEN |
| 406 |
DO j = 1, knon |
| 407 |
yrugm(j) = 0.018 * coefm(j, 1) * (yu(j, 1)**2 + yv(j, 1)**2) & |
| 408 |
/ rg + 0.11 * 14E-6 & |
| 409 |
/ sqrt(coefm(j, 1) * (yu(j, 1)**2 + yv(j, 1)**2)) |
| 410 |
yrugm(j) = max(1.5E-05, yrugm(j)) |
| 411 |
END DO |
| 412 |
END IF |
| 413 |
DO j = 1, knon |
| 414 |
y_dflux_t(j) = y_dflux_t(j) * ypct(j) |
| 415 |
y_dflux_q(j) = y_dflux_q(j) * ypct(j) |
| 416 |
END DO |
| 417 |
|
| 418 |
DO k = 1, klev |
| 419 |
DO j = 1, knon |
| 420 |
i = ni(j) |
| 421 |
coefh(j, k) = coefh(j, k) * ypct(j) |
| 422 |
coefm(j, k) = coefm(j, k) * ypct(j) |
| 423 |
y_d_t(j, k) = y_d_t(j, k) * ypct(j) |
| 424 |
y_d_q(j, k) = y_d_q(j, k) * ypct(j) |
| 425 |
y_d_u(j, k) = y_d_u(j, k) * ypct(j) |
| 426 |
y_d_v(j, k) = y_d_v(j, k) * ypct(j) |
| 427 |
END DO |
| 428 |
END DO |
| 429 |
|
| 430 |
flux_t(ni(:knon), nsrf) = y_flux_t(:knon) |
| 431 |
flux_q(ni(:knon), nsrf) = y_flux_q(:knon) |
| 432 |
flux_u(ni(:knon), nsrf) = y_flux_u(:knon) |
| 433 |
flux_v(ni(:knon), nsrf) = y_flux_v(:knon) |
| 434 |
|
| 435 |
evap(:, nsrf) = -flux_q(:, nsrf) |
| 436 |
|
| 437 |
falbe(:, nsrf) = 0. |
| 438 |
fsnow(:, nsrf) = 0. |
| 439 |
qsurf(:, nsrf) = 0. |
| 440 |
frugs(:, nsrf) = 0. |
| 441 |
DO j = 1, knon |
| 442 |
i = ni(j) |
| 443 |
d_ts(i, nsrf) = y_d_ts(j) |
| 444 |
falbe(i, nsrf) = yalb(j) |
| 445 |
fsnow(i, nsrf) = snow(j) |
| 446 |
qsurf(i, nsrf) = yqsurf(j) |
| 447 |
frugs(i, nsrf) = yz0_new(j) |
| 448 |
fluxlat(i, nsrf) = yfluxlat(j) |
| 449 |
IF (nsrf == is_oce) THEN |
| 450 |
rugmer(i) = yrugm(j) |
| 451 |
frugs(i, nsrf) = yrugm(j) |
| 452 |
END IF |
| 453 |
agesno(i, nsrf) = yagesno(j) |
| 454 |
fqcalving(i, nsrf) = y_fqcalving(j) |
| 455 |
ffonte(i, nsrf) = y_ffonte(j) |
| 456 |
cdragh(i) = cdragh(i) + coefh(j, 1) |
| 457 |
cdragm(i) = cdragm(i) + coefm(j, 1) |
| 458 |
dflux_t(i) = dflux_t(i) + y_dflux_t(j) |
| 459 |
dflux_q(i) = dflux_q(i) + y_dflux_q(j) |
| 460 |
END DO |
| 461 |
IF (nsrf == is_ter) THEN |
| 462 |
qsol(ni(:knon)) = yqsol(:knon) |
| 463 |
else IF (nsrf == is_lic) THEN |
| 464 |
DO j = 1, knon |
| 465 |
i = ni(j) |
| 466 |
run_off_lic_0(i) = y_run_off_lic_0(j) |
| 467 |
END DO |
| 468 |
END IF |
| 469 |
|
| 470 |
ftsoil(:, :, nsrf) = 0. |
| 471 |
ftsoil(ni(:knon), :, nsrf) = ytsoil(:knon, :) |
| 472 |
|
| 473 |
DO j = 1, knon |
| 474 |
i = ni(j) |
| 475 |
DO k = 1, klev |
| 476 |
d_t(i, k) = d_t(i, k) + y_d_t(j, k) |
| 477 |
d_q(i, k) = d_q(i, k) + y_d_q(j, k) |
| 478 |
d_u(i, k) = d_u(i, k) + y_d_u(j, k) |
| 479 |
d_v(i, k) = d_v(i, k) + y_d_v(j, k) |
| 480 |
ycoefh(i, k) = ycoefh(i, k) + coefh(j, k) |
| 481 |
END DO |
| 482 |
END DO |
| 483 |
|
| 484 |
! diagnostic t, q a 2m et u, v a 10m |
| 485 |
|
| 486 |
DO j = 1, knon |
| 487 |
i = ni(j) |
| 488 |
u1(j) = yu(j, 1) + y_d_u(j, 1) |
| 489 |
v1(j) = yv(j, 1) + y_d_v(j, 1) |
| 490 |
tair1(j) = yt(j, 1) + y_d_t(j, 1) |
| 491 |
qair1(j) = yq(j, 1) + y_d_q(j, 1) |
| 492 |
zgeo1(j) = rd * tair1(j) / (0.5 * (ypaprs(j, 1) + ypplay(j, & |
| 493 |
1))) * (ypaprs(j, 1)-ypplay(j, 1)) |
| 494 |
tairsol(j) = yts(j) + y_d_ts(j) |
| 495 |
rugo1(j) = yrugos(j) |
| 496 |
IF (nsrf == is_oce) THEN |
| 497 |
rugo1(j) = frugs(i, nsrf) |
| 498 |
END IF |
| 499 |
psfce(j) = ypaprs(j, 1) |
| 500 |
patm(j) = ypplay(j, 1) |
| 501 |
|
| 502 |
qairsol(j) = yqsurf(j) |
| 503 |
END DO |
| 504 |
|
| 505 |
CALL stdlevvar(klon, knon, nsrf, u1(:knon), v1(:knon), tair1(:knon), & |
| 506 |
qair1, zgeo1, tairsol, qairsol, rugo1, psfce, patm, yt2m, & |
| 507 |
yq2m, yt10m, yq10m, wind10m(:knon), ustar) |
| 508 |
|
| 509 |
DO j = 1, knon |
| 510 |
i = ni(j) |
| 511 |
t2m(i, nsrf) = yt2m(j) |
| 512 |
q2m(i, nsrf) = yq2m(j) |
| 513 |
|
| 514 |
u10m_srf(i, nsrf) = (wind10m(j) * u1(j)) & |
| 515 |
/ sqrt(u1(j)**2 + v1(j)**2) |
| 516 |
v10m_srf(i, nsrf) = (wind10m(j) * v1(j)) & |
| 517 |
/ sqrt(u1(j)**2 + v1(j)**2) |
| 518 |
END DO |
| 519 |
|
| 520 |
CALL hbtm(ypaprs, ypplay, yt2m, yq2m, ustar(:knon), y_flux_t(:knon), & |
| 521 |
y_flux_q(:knon), yu, yv, yt, yq, ypblh(:knon), ycapcl, & |
| 522 |
yoliqcl, ycteicl, ypblt, ytherm, ytrmb1, ytrmb2, ytrmb3, ylcl) |
| 523 |
|
| 524 |
DO j = 1, knon |
| 525 |
i = ni(j) |
| 526 |
pblh(i, nsrf) = ypblh(j) |
| 527 |
plcl(i, nsrf) = ylcl(j) |
| 528 |
capcl(i, nsrf) = ycapcl(j) |
| 529 |
oliqcl(i, nsrf) = yoliqcl(j) |
| 530 |
cteicl(i, nsrf) = ycteicl(j) |
| 531 |
pblt(i, nsrf) = ypblt(j) |
| 532 |
therm(i, nsrf) = ytherm(j) |
| 533 |
trmb1(i, nsrf) = ytrmb1(j) |
| 534 |
trmb2(i, nsrf) = ytrmb2(j) |
| 535 |
trmb3(i, nsrf) = ytrmb3(j) |
| 536 |
END DO |
| 537 |
|
| 538 |
DO j = 1, knon |
| 539 |
DO k = 1, klev + 1 |
| 540 |
i = ni(j) |
| 541 |
q2(i, k, nsrf) = yq2(j, k) |
| 542 |
END DO |
| 543 |
END DO |
| 544 |
else |
| 545 |
fsnow(:, nsrf) = 0. |
| 546 |
end IF if_knon |
| 547 |
END DO loop_surface |
| 548 |
|
| 549 |
! On utilise les nouvelles surfaces |
| 550 |
frugs(:, is_oce) = rugmer |
| 551 |
pctsrf(:, is_oce) = pctsrf_new_oce |
| 552 |
pctsrf(:, is_sic) = pctsrf_new_sic |
| 553 |
|
| 554 |
firstcal = .false. |
| 555 |
|
| 556 |
END SUBROUTINE clmain |
| 557 |
|
| 558 |
end module clmain_m |
Parent Directory
| 
Revision Log