/[lmdze]/trunk/Sources/phylmd/clqh.f
ViewVC logotype

Contents of /trunk/Sources/phylmd/clqh.f

Parent Directory Parent Directory | Revision Log Revision Log


Revision 222 - (show annotations)
Tue Apr 25 15:31:48 2017 UTC (6 years, 11 months ago) by guez
File size: 9548 byte(s)
In interfsurf_hq, changed names of variables : tsurf becomes ts (name of
actual argument), tsurf_temp  can then become simply tsurf.

1 module clqh_m
2
3 IMPLICIT none
4
5 contains
6
7 SUBROUTINE clqh(dtime, julien, debut, nisurf, knindex, tsoil, qsol, rmu0, &
8 rugos, rugoro, u1lay, v1lay, coef, t, q, ts, paprs, pplay, delp, &
9 radsol, albedo, snow, qsurf, precip_rain, precip_snow, fder, fluxlat, &
10 pctsrf_new_sic, agesno, d_t, d_q, d_ts, z0_new, flux_t, flux_q, &
11 dflux_s, dflux_l, fqcalving, ffonte, run_off_lic_0)
12
13 ! Author: Z. X. Li (LMD/CNRS)
14 ! Date: 1993/08/18
15 ! Objet : diffusion verticale de "q" et de "h"
16
17 USE conf_phys_m, ONLY: iflag_pbl
18 USE dimphy, ONLY: klev, klon
19 USE interfsurf_hq_m, ONLY: interfsurf_hq
20 USE suphec_m, ONLY: rcpd, rd, rg, rkappa
21
22 REAL, intent(in):: dtime ! intervalle du temps (s)
23 integer, intent(in):: julien ! jour de l'annee en cours
24 logical, intent(in):: debut
25 integer, intent(in):: nisurf
26 integer, intent(in):: knindex(:) ! (knon)
27 REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx)
28
29 REAL, intent(inout):: qsol(klon)
30 ! column-density of water in soil, in kg m-2
31
32 real, intent(in):: rmu0(klon) ! cosinus de l'angle solaire zenithal
33 real rugos(klon) ! rugosite
34 REAL rugoro(klon)
35 REAL u1lay(klon) ! vitesse u de la 1ere couche (m / s)
36 REAL v1lay(klon) ! vitesse v de la 1ere couche (m / s)
37
38 REAL, intent(in):: coef(:, :) ! (knon, klev)
39 ! Le coefficient d'echange (m**2 / s) multiplie par le cisaillement
40 ! du vent (dV / dz). La premiere valeur indique la valeur de Cdrag
41 ! (sans unite).
42
43 REAL t(klon, klev) ! temperature (K)
44 REAL q(klon, klev) ! humidite specifique (kg / kg)
45 REAL, intent(in):: ts(:) ! (knon) temperature du sol (K)
46 REAL paprs(klon, klev + 1) ! pression a inter-couche (Pa)
47 REAL pplay(klon, klev) ! pression au milieu de couche (Pa)
48 REAL delp(klon, klev) ! epaisseur de couche en pression (Pa)
49
50 REAL, intent(inout):: radsol(:) ! (knon)
51 ! rayonnement net au sol (Solaire + IR) W / m2
52
53 REAL, intent(inout):: albedo(:) ! (knon) albedo de la surface
54 REAL, intent(inout):: snow(:) ! (knon) ! hauteur de neige
55 REAL qsurf(klon) ! humidite de l'air au dessus de la surface
56
57 real, intent(in):: precip_rain(klon)
58 ! liquid water mass flux (kg / m2 / s), positive down
59
60 real, intent(in):: precip_snow(klon)
61 ! solid water mass flux (kg / m2 / s), positive down
62
63 real, intent(inout):: fder(:) ! (knon)
64 real, intent(out):: fluxlat(:) ! (knon)
65 real, intent(in):: pctsrf_new_sic(:) ! (klon)
66 REAL, intent(inout):: agesno(:) ! (knon)
67 REAL d_t(klon, klev) ! incrementation de "t"
68 REAL d_q(klon, klev) ! incrementation de "q"
69 REAL, intent(out):: d_ts(:) ! (knon) variation of surface temperature
70 real z0_new(klon)
71
72 REAL, intent(out):: flux_t(:) ! (knon)
73 ! (diagnostic) flux de chaleur sensible (Cp T) à la surface,
74 ! positif vers le bas, W / m2
75
76 REAL, intent(out):: flux_q(:) ! (knon)
77 ! flux de la vapeur d'eau à la surface, en kg / (m**2 s)
78
79 REAL dflux_s(:) ! (knon) derivee du flux sensible dF / dTs
80 REAL dflux_l(:) ! (knon) derivee du flux latent dF / dTs
81
82 ! Flux d'eau "perdue" par la surface et n\'ecessaire pour que limiter la
83 ! hauteur de neige, en kg / m2 / s
84 REAL fqcalving(klon)
85
86 ! Flux thermique utiliser pour fondre la neige
87 REAL ffonte(klon)
88
89 REAL run_off_lic_0(klon)! runof glacier au pas de temps precedent
90
91 ! Local:
92
93 INTEGER knon
94 REAL evap(size(knindex)) ! (knon) evaporation au sol
95
96 INTEGER i, k
97 REAL zx_cq(klon, klev)
98 REAL zx_dq(klon, klev)
99 REAL zx_ch(klon, klev)
100 REAL zx_dh(klon, klev)
101 REAL zx_buf1(klon)
102 REAL zx_buf2(klon)
103 REAL zx_coef(klon, klev)
104 REAL local_h(klon, klev) ! enthalpie potentielle
105 REAL local_q(klon, klev)
106 REAL psref(klon) ! pression de reference pour temperature potent.
107 REAL zx_pkh(klon, klev), zx_pkf(klon, klev)
108
109 ! contre-gradient pour la vapeur d'eau: (kg / kg) / metre
110 REAL gamq(klon, 2:klev)
111 ! contre-gradient pour la chaleur sensible: Kelvin / metre
112 REAL gamt(klon, 2:klev)
113 REAL z_gamaq(klon, 2:klev), z_gamah(klon, 2:klev)
114 REAL zdelz
115
116 real temp_air(klon), spechum(klon)
117 real tq_cdrag(klon), petAcoef(klon), peqAcoef(klon)
118 real petBcoef(klon), peqBcoef(klon)
119 real p1lay(klon)
120
121 real tsurf_new(size(knindex)) ! (knon)
122 real zzpk
123
124 !----------------------------------------------------------------
125
126 knon = size(knindex)
127
128 if (iflag_pbl == 1) then
129 do k = 3, klev
130 do i = 1, knon
131 gamq(i, k)= 0.0
132 gamt(i, k)= - 1.0e-03
133 enddo
134 enddo
135 do i = 1, knon
136 gamq(i, 2) = 0.0
137 gamt(i, 2) = - 2.5e-03
138 enddo
139 else
140 do k = 2, klev
141 do i = 1, knon
142 gamq(i, k) = 0.0
143 gamt(i, k) = 0.0
144 enddo
145 enddo
146 endif
147
148 DO i = 1, knon
149 psref(i) = paprs(i, 1) !pression de reference est celle au sol
150 ENDDO
151 DO k = 1, klev
152 DO i = 1, knon
153 zx_pkh(i, k) = (psref(i) / paprs(i, k))**RKAPPA
154 zx_pkf(i, k) = (psref(i) / pplay(i, k))**RKAPPA
155 local_h(i, k) = RCPD * t(i, k) * zx_pkf(i, k)
156 local_q(i, k) = q(i, k)
157 ENDDO
158 ENDDO
159
160 ! Convertir les coefficients en variables convenables au calcul:
161
162 DO k = 2, klev
163 DO i = 1, knon
164 zx_coef(i, k) = coef(i, k) * RG / (pplay(i, k - 1) - pplay(i, k)) &
165 * (paprs(i, k) * 2 / (t(i, k) + t(i, k - 1)) / RD)**2
166 zx_coef(i, k) = zx_coef(i, k) * dtime * RG
167 ENDDO
168 ENDDO
169
170 ! Preparer les flux lies aux contre-gardients
171
172 DO k = 2, klev
173 DO i = 1, knon
174 zdelz = RD * (t(i, k - 1) + t(i, k)) / 2.0 / RG / paprs(i, k) &
175 * (pplay(i, k - 1) - pplay(i, k))
176 z_gamaq(i, k) = gamq(i, k) * zdelz
177 z_gamah(i, k) = gamt(i, k) * zdelz * RCPD * zx_pkh(i, k)
178 ENDDO
179 ENDDO
180 DO i = 1, knon
181 zx_buf1(i) = zx_coef(i, klev) + delp(i, klev)
182 zx_cq(i, klev) = (local_q(i, klev) * delp(i, klev) &
183 - zx_coef(i, klev) * z_gamaq(i, klev)) / zx_buf1(i)
184 zx_dq(i, klev) = zx_coef(i, klev) / zx_buf1(i)
185
186 zzpk=(pplay(i, klev) / psref(i))**RKAPPA
187 zx_buf2(i) = zzpk * delp(i, klev) + zx_coef(i, klev)
188 zx_ch(i, klev) = (local_h(i, klev) * zzpk * delp(i, klev) &
189 - zx_coef(i, klev) * z_gamah(i, klev)) / zx_buf2(i)
190 zx_dh(i, klev) = zx_coef(i, klev) / zx_buf2(i)
191 ENDDO
192 DO k = klev - 1, 2, - 1
193 DO i = 1, knon
194 zx_buf1(i) = delp(i, k) + zx_coef(i, k) &
195 + zx_coef(i, k + 1) * (1. - zx_dq(i, k + 1))
196 zx_cq(i, k) = (local_q(i, k) * delp(i, k) &
197 + zx_coef(i, k + 1) * zx_cq(i, k + 1) &
198 + zx_coef(i, k + 1) * z_gamaq(i, k + 1) &
199 - zx_coef(i, k) * z_gamaq(i, k)) / zx_buf1(i)
200 zx_dq(i, k) = zx_coef(i, k) / zx_buf1(i)
201
202 zzpk=(pplay(i, k) / psref(i))**RKAPPA
203 zx_buf2(i) = zzpk * delp(i, k) + zx_coef(i, k) &
204 + zx_coef(i, k + 1) * (1. - zx_dh(i, k + 1))
205 zx_ch(i, k) = (local_h(i, k) * zzpk * delp(i, k) &
206 + zx_coef(i, k + 1) * zx_ch(i, k + 1) &
207 + zx_coef(i, k + 1) * z_gamah(i, k + 1) &
208 - zx_coef(i, k) * z_gamah(i, k)) / zx_buf2(i)
209 zx_dh(i, k) = zx_coef(i, k) / zx_buf2(i)
210 ENDDO
211 ENDDO
212
213 DO i = 1, knon
214 zx_buf1(i) = delp(i, 1) + zx_coef(i, 2) * (1. - zx_dq(i, 2))
215 zx_cq(i, 1) = (local_q(i, 1) * delp(i, 1) &
216 + zx_coef(i, 2) * (z_gamaq(i, 2) + zx_cq(i, 2))) / zx_buf1(i)
217 zx_dq(i, 1) = - 1. * RG / zx_buf1(i)
218
219 zzpk=(pplay(i, 1) / psref(i))**RKAPPA
220 zx_buf2(i) = zzpk * delp(i, 1) + zx_coef(i, 2) * (1. - zx_dh(i, 2))
221 zx_ch(i, 1) = (local_h(i, 1) * zzpk * delp(i, 1) &
222 + zx_coef(i, 2) * (z_gamah(i, 2) + zx_ch(i, 2))) / zx_buf2(i)
223 zx_dh(i, 1) = - 1. * RG / zx_buf2(i)
224 ENDDO
225
226 ! Appel \`a interfsurf (appel g\'en\'erique) routine d'interface
227 ! avec la surface
228
229 ! Initialisation
230 petAcoef =0.
231 peqAcoef = 0.
232 petBcoef =0.
233 peqBcoef = 0.
234 p1lay =0.
235
236 petAcoef(1:knon) = zx_ch(1:knon, 1)
237 peqAcoef(1:knon) = zx_cq(1:knon, 1)
238 petBcoef(1:knon) = zx_dh(1:knon, 1)
239 peqBcoef(1:knon) = zx_dq(1:knon, 1)
240 tq_cdrag(1:knon) =coef(:knon, 1)
241 temp_air(1:knon) =t(1:knon, 1)
242 spechum(1:knon)=q(1:knon, 1)
243 p1lay(1:knon) = pplay(1:knon, 1)
244
245 CALL interfsurf_hq(dtime, julien, rmu0, nisurf, knindex, debut, tsoil, &
246 qsol, u1lay, v1lay, temp_air, spechum, tq_cdrag, petAcoef, peqAcoef, &
247 petBcoef, peqBcoef, precip_rain, precip_snow, fder, rugos, rugoro, &
248 snow, qsurf, ts, p1lay, psref, radsol, evap, flux_t, fluxlat, &
249 dflux_l, dflux_s, tsurf_new, albedo, z0_new, pctsrf_new_sic, agesno, &
250 fqcalving, ffonte, run_off_lic_0)
251
252 flux_q = - evap
253 d_ts = tsurf_new - ts
254
255 DO i = 1, knon
256 local_h(i, 1) = zx_ch(i, 1) + zx_dh(i, 1) * flux_t(i) * dtime
257 local_q(i, 1) = zx_cq(i, 1) + zx_dq(i, 1) * flux_q(i) * dtime
258 ENDDO
259 DO k = 2, klev
260 DO i = 1, knon
261 local_q(i, k) = zx_cq(i, k) + zx_dq(i, k) * local_q(i, k - 1)
262 local_h(i, k) = zx_ch(i, k) + zx_dh(i, k) * local_h(i, k - 1)
263 ENDDO
264 ENDDO
265
266 ! Calcul des tendances
267 DO k = 1, klev
268 DO i = 1, knon
269 d_t(i, k) = local_h(i, k) / zx_pkf(i, k) / RCPD - t(i, k)
270 d_q(i, k) = local_q(i, k) - q(i, k)
271 ENDDO
272 ENDDO
273
274 END SUBROUTINE clqh
275
276 end module clqh_m

  ViewVC Help
Powered by ViewVC 1.1.21