trunk/dyn3d/dynetat0.f90

module dynetat0_m

  use dimensions, only: iim, jjm

  IMPLICIT NONE

  private iim, jjm

  INTEGER, protected, save:: day_ini 
  ! day number at the beginning of the run, based at value 1 on
  ! January 1st of annee_ref

  real, protected, save:: rlatu(jjm + 1)
  ! latitudes of points of the "scalar" and "u" grid, in rad

  real, protected, save:: rlatv(jjm) 
  ! latitudes of points of the "v" grid, in rad, in decreasing order

  real, protected, save:: rlonu(iim + 1)
  ! longitudes of points of the "u" grid, in rad

  real, protected, save:: rlonv(iim + 1)
  ! longitudes of points of the "scalar" and "v" grid, in rad

  real, protected, save:: xprimu(iim + 1), xprimv(iim + 1)
  ! 2 pi / iim * (derivative of the longitudinal zoom function)(rlon[uv])

  REAL, protected, save:: xprimm025(iim + 1), xprimp025(iim + 1)
  REAL, protected, save:: rlatu1(jjm), rlatu2(jjm), yprimu1(jjm), yprimu2(jjm)
  REAL, save:: ang0, etot0, ptot0, ztot0, stot0
  INTEGER, PARAMETER, private:: nmax = 30000
  INTEGER, save:: itau_dyn

contains

  SUBROUTINE dynetat0(vcov, ucov, teta, q, masse, ps, phis)

    ! From dynetat0.F, version 1.2, 2004/06/22 11:45:30
    ! Authors: P. Le Van, L. Fairhead
    ! This procedure reads the initial state of the atmosphere.

    ! Libraries:
    use netcdf, only: NF90_NOWRITE, NF90_NOERR
    use netcdf95, only: NF95_GET_VAR, nf95_open, nf95_inq_varid, NF95_CLOSE, &
         NF95_Gw_VAR
    use nr_util, only: assert

    use conf_gcm_m, only: raz_date
    use dimensions, only: iim, jjm, llm, nqmx
    use dynetat0_chosen_m, only: day_ref
    use iniadvtrac_m, only: tname

    REAL, intent(out):: vcov(: , :, :) ! (iim + 1, jjm, llm)
    REAL, intent(out):: ucov(:, :, :) ! (iim + 1, jjm + 1, llm)
    REAL, intent(out):: teta(:, :, :) ! (iim + 1, jjm + 1, llm)
    REAL, intent(out):: q(:, :, :, :) ! (iim + 1, jjm + 1, llm, nqmx)
    REAL, intent(out):: masse(:, :, :) ! (iim + 1, jjm + 1, llm)
    REAL, intent(out):: ps(:, :) ! (iim + 1, jjm + 1) in Pa
    REAL, intent(out):: phis(:, :) ! (iim + 1, jjm + 1)

    ! Local variables: 
    INTEGER iq
    REAL, allocatable:: tab_cntrl(:) ! tableau des param\`etres du run
    INTEGER ierr, ncid, varid

    !-----------------------------------------------------------------------

    print *, "Call sequence information: dynetat0"

    call assert((/size(ucov, 1), size(vcov, 1), size(masse, 1), size(ps, 1), &
         size(phis, 1), size(q, 1), size(teta, 1)/) == iim + 1, "dynetat0 iim")
    call assert((/size(ucov, 2), size(vcov, 2) + 1, size(masse, 2), &
         size(ps, 2), size(phis, 2), size(q, 2), size(teta, 2)/) == jjm + 1, &
         "dynetat0 jjm")
    call assert((/size(vcov, 3), size(ucov, 3), size(teta, 3), size(q, 3), &
         size(masse, 3)/) == llm, "dynetat0 llm")
    call assert(size(q, 4) == nqmx, "dynetat0 q nqmx")

    ! Fichier \'etat initial :
    call nf95_open("start.nc", NF90_NOWRITE, ncid)

    call nf95_inq_varid(ncid, "controle", varid)
    call NF95_Gw_VAR(ncid, varid, tab_cntrl)

    etot0 = tab_cntrl(13)
    ptot0 = tab_cntrl(14)
    ztot0 = tab_cntrl(15)
    stot0 = tab_cntrl(16)
    ang0 = tab_cntrl(17)

    if (raz_date) then
       print *, 'Resetting the date.'
       day_ini = day_ref
       itau_dyn = 0
    else
       itau_dyn = tab_cntrl(31)
       day_ini = tab_cntrl(30)
    end if

    print *, "day_ini = ", day_ini

    call NF95_INQ_VARID (ncid, "rlonu", varid)
    call NF95_GET_VAR(ncid, varid, rlonu)

    call NF95_INQ_VARID (ncid, "rlatu", varid)
    call NF95_GET_VAR(ncid, varid, rlatu)

    call NF95_INQ_VARID (ncid, "rlonv", varid)
    call NF95_GET_VAR(ncid, varid, rlonv)

    call NF95_INQ_VARID (ncid, "rlatv", varid)
    call NF95_GET_VAR(ncid, varid, rlatv)

    CALL nf95_inq_varid(ncid, 'xprimu', varid)
    CALL nf95_get_var(ncid, varid, xprimu)

    CALL nf95_inq_varid(ncid, 'xprimv', varid)
    CALL nf95_get_var(ncid, varid, xprimv)

    CALL nf95_inq_varid(ncid, 'xprimm025', varid)
    CALL nf95_get_var(ncid, varid, xprimm025)

    CALL nf95_inq_varid(ncid, 'xprimp025', varid)
    CALL nf95_get_var(ncid, varid, xprimp025)

    call NF95_INQ_VARID (ncid, "rlatu1", varid)
    call NF95_GET_VAR(ncid, varid, rlatu1)

    call NF95_INQ_VARID (ncid, "rlatu2", varid)
    call NF95_GET_VAR(ncid, varid, rlatu2)

    CALL nf95_inq_varid(ncid, 'yprimu1', varid)
    CALL nf95_get_var(ncid, varid, yprimu1)

    CALL nf95_inq_varid(ncid, 'yprimu2', varid)
    CALL nf95_get_var(ncid, varid, yprimu2)

    call NF95_INQ_VARID (ncid, "phis", varid)
    call NF95_GET_VAR(ncid, varid, phis)

    call NF95_INQ_VARID (ncid, "ucov", varid)
    call NF95_GET_VAR(ncid, varid, ucov)

    call NF95_INQ_VARID (ncid, "vcov", varid)
    call NF95_GET_VAR(ncid, varid, vcov)

    call NF95_INQ_VARID (ncid, "teta", varid)
    call NF95_GET_VAR(ncid, varid, teta)

    DO iq = 1, nqmx
       call NF95_INQ_VARID(ncid, tname(iq), varid, ierr)
       IF (ierr == NF90_NOERR) THEN
          call NF95_GET_VAR(ncid, varid, q(:, :, :, iq))
       ELSE
          PRINT *, 'dynetat0: "' // tname(iq) // '" not found, ' // &
               "setting it to zero..."
          q(:, :, :, iq) = 0.
       ENDIF
    ENDDO

    call NF95_INQ_VARID (ncid, "masse", varid)
    call NF95_GET_VAR(ncid, varid, masse)

    call NF95_INQ_VARID (ncid, "ps", varid)
    call NF95_GET_VAR(ncid, varid, ps)
    ! Check that there is a single value at each pole:
    call assert(ps(1, 1) == ps(2:, 1), "dynetat0 ps north pole")
    call assert(ps(1, jjm + 1) == ps(2:, jjm + 1), "dynetat0 ps south pole")

    call NF95_CLOSE(ncid)

  END SUBROUTINE dynetat0

  !********************************************************************

  SUBROUTINE fyhyp

    ! From LMDZ4/libf/dyn3d/fyhyp.F, version 1.2, 2005/06/03 09:11:32

    ! Author: P. Le Van, from analysis by R. Sadourny 

    ! Define rlatu, rlatv, rlatu2, yprimu2, rlatu1, yprimu1.
    
    ! Calcule les latitudes et dérivées dans la grille du GCM pour une
    ! fonction f(y) à dérivée tangente hyperbolique.

    ! Il vaut mieux avoir : grossismy * dzoom < pi / 2

    use coefpoly_m, only: coefpoly, a0, a1, a2, a3
    USE dimensions, only: jjm
    use dynetat0_chosen_m, only: clat, grossismy, dzoomy, tauy
    use heavyside_m, only: heavyside

    ! Local: 

    INTEGER, PARAMETER:: nmax2 = 2 * nmax
    REAL dzoom ! distance totale de la zone du zoom (en radians)
    DOUBLE PRECISION ylat(jjm + 1), yprim(jjm + 1)
    DOUBLE PRECISION yuv
    DOUBLE PRECISION, save:: yt(0:nmax2)
    DOUBLE PRECISION fhyp(0:nmax2), beta
    DOUBLE PRECISION, save:: ytprim(0:nmax2)
    DOUBLE PRECISION fxm(0:nmax2)
    DOUBLE PRECISION, save:: yf(0:nmax2)
    DOUBLE PRECISION yypr(0:nmax2)
    DOUBLE PRECISION yvrai(jjm + 1), yprimm(jjm + 1), ylatt(jjm + 1)
    DOUBLE PRECISION pi, pis2, epsilon, pisjm
    DOUBLE PRECISION yo1, yi, ylon2, ymoy, yprimin
    DOUBLE PRECISION yfi, yf1, ffdy
    DOUBLE PRECISION ypn
    DOUBLE PRECISION, save::deply, y00

    INTEGER i, j, it, ik, iter, jlat, jjpn
    INTEGER, save:: jpn
    DOUBLE PRECISION yi2, heavyy0, heavyy0m
    DOUBLE PRECISION fa(0:nmax2), fb(0:nmax2)
    REAL y0min, y0max

    !-------------------------------------------------------------------

    print *, "Call sequence information: fyhyp"

    pi = 2.*asin(1.)
    pis2 = pi/2.
    pisjm = pi/real(jjm)
    epsilon = 1e-3
    dzoom = dzoomy*pi

    DO i = 0, nmax2
       yt(i) = -pis2 + real(i)*pi/nmax2
    END DO

    heavyy0m = heavyside(-clat)
    heavyy0 = heavyside(clat)
    y0min = 2.*clat*heavyy0m - pis2
    y0max = 2.*clat*heavyy0 + pis2

    fa = 999.999
    fb = 999.999

    DO i = 0, nmax2
       IF (yt(i)<clat) THEN
          fa(i) = tauy*(yt(i)-clat + dzoom/2.)
          fb(i) = (yt(i)-2.*clat*heavyy0m + pis2)*(clat-yt(i))
       ELSE IF (yt(i)>clat) THEN
          fa(i) = tauy*(clat-yt(i) + dzoom/2.)
          fb(i) = (2.*clat*heavyy0-yt(i) + pis2)*(yt(i)-clat)
       END IF

       IF (200.*fb(i)<-fa(i)) THEN
          fhyp(i) = -1.
       ELSE IF (200.*fb(i)<fa(i)) THEN
          fhyp(i) = 1.
       ELSE
          fhyp(i) = tanh(fa(i)/fb(i))
       END IF

       IF (yt(i)==clat) fhyp(i) = 1.
       IF (yt(i)==y0min .OR. yt(i)==y0max) fhyp(i) = -1.
    END DO

    ! Calcul de beta 

    ffdy = 0.

    DO i = 1, nmax2
       ymoy = 0.5*(yt(i-1) + yt(i))
       IF (ymoy<clat) THEN
          fa(i) = tauy*(ymoy-clat + dzoom/2.)
          fb(i) = (ymoy-2.*clat*heavyy0m + pis2)*(clat-ymoy)
       ELSE IF (ymoy>clat) THEN
          fa(i) = tauy*(clat-ymoy + dzoom/2.)
          fb(i) = (2.*clat*heavyy0-ymoy + pis2)*(ymoy-clat)
       END IF

       IF (200.*fb(i)<-fa(i)) THEN
          fxm(i) = -1.
       ELSE IF (200.*fb(i)<fa(i)) THEN
          fxm(i) = 1.
       ELSE
          fxm(i) = tanh(fa(i)/fb(i))
       END IF
       IF (ymoy==clat) fxm(i) = 1.
       IF (ymoy==y0min .OR. yt(i)==y0max) fxm(i) = -1.
       ffdy = ffdy + fxm(i)*(yt(i)-yt(i-1))
    END DO

    beta = (grossismy*ffdy-pi)/(ffdy-pi)

    IF (2. * beta - grossismy <= 0.) THEN
       print *, 'Attention ! La valeur beta calculee dans la routine fyhyp ' &
            // 'est mauvaise. Modifier les valeurs de grossismy, tauy ou ' &
            // 'dzoomy et relancer.'
       STOP 1
    END IF

    ! calcul de Ytprim 

    DO i = 0, nmax2
       ytprim(i) = beta + (grossismy-beta)*fhyp(i)
    END DO

    ! Calcul de Yf 

    yf(0) = -pis2
    DO i = 1, nmax2
       yypr(i) = beta + (grossismy-beta)*fxm(i)
    END DO

    DO i = 1, nmax2
       yf(i) = yf(i-1) + yypr(i)*(yt(i)-yt(i-1))
    END DO

    ! yuv = 0. si calcul des latitudes aux pts. U 
    ! yuv = 0.5 si calcul des latitudes aux pts. V 

    loop_ik: DO ik = 1, 4
       IF (ik==1) THEN
          yuv = 0.
          jlat = jjm + 1
       ELSE IF (ik==2) THEN
          yuv = 0.5
          jlat = jjm
       ELSE IF (ik==3) THEN
          yuv = 0.25
          jlat = jjm
       ELSE IF (ik==4) THEN
          yuv = 0.75
          jlat = jjm
       END IF

       yo1 = 0.
       DO j = 1, jlat
          yo1 = 0.
          ylon2 = -pis2 + pisjm*(real(j) + yuv-1.)
          yfi = ylon2

          it = nmax2
          DO while (it >= 1 .and. yfi < yf(it))
             it = it - 1
          END DO

          yi = yt(it)
          IF (it==nmax2) THEN
             it = nmax2 - 1
             yf(it + 1) = pis2
          END IF

          ! Interpolation entre yi(it) et yi(it + 1) pour avoir Y(yi)
          ! et Y'(yi) 

          CALL coefpoly(yf(it), yf(it + 1), ytprim(it), ytprim(it + 1), &
               yt(it), yt(it + 1))

          yf1 = yf(it)
          yprimin = a1 + 2.*a2*yi + 3.*a3*yi*yi

          iter = 1
          DO
             yi = yi - (yf1-yfi)/yprimin
             IF (abs(yi-yo1)<=epsilon .or. iter == 300) exit
             yo1 = yi
             yi2 = yi*yi
             yf1 = a0 + a1*yi + a2*yi2 + a3*yi2*yi
             yprimin = a1 + 2.*a2*yi + 3.*a3*yi2
          END DO
          if (abs(yi-yo1) > epsilon) then
             print *, 'Pas de solution.', j, ylon2
             STOP 1
          end if

          yprimin = a1 + 2.*a2*yi + 3.*a3*yi*yi
          yprim(j) = pi/(jjm*yprimin)
          yvrai(j) = yi
       END DO

       DO j = 1, jlat - 1
          IF (yvrai(j + 1)<yvrai(j)) THEN
             print *, 'Problème avec rlat(', j + 1, ') plus petit que rlat(', &
                  j, ')'
             STOP 1
          END IF
       END DO

       print *, 'Reorganisation des latitudes pour avoir entre - pi/2 et pi/2'

       IF (ik==1) THEN
          ypn = pis2
          DO j = jjm + 1, 1, -1
             IF (yvrai(j)<=ypn) exit
          END DO

          jpn = j
          y00 = yvrai(jpn)
          deply = pis2 - y00
       END IF

       DO j = 1, jjm + 1 - jpn
          ylatt(j) = -pis2 - y00 + yvrai(jpn + j-1)
          yprimm(j) = yprim(jpn + j-1)
       END DO

       jjpn = jpn
       IF (jlat==jjm) jjpn = jpn - 1

       DO j = 1, jjpn
          ylatt(j + jjm + 1-jpn) = yvrai(j) + deply
          yprimm(j + jjm + 1-jpn) = yprim(j)
       END DO

       ! Fin de la reorganisation

       DO j = 1, jlat
          ylat(j) = ylatt(jlat + 1-j)
          yprim(j) = yprimm(jlat + 1-j)
       END DO

       DO j = 1, jlat
          yvrai(j) = ylat(j)*180./pi
       END DO

       IF (ik==1) THEN
          DO j = 1, jjm + 1
             rlatu(j) = ylat(j)
          END DO
       ELSE IF (ik==2) THEN
          DO j = 1, jjm
             rlatv(j) = ylat(j)
          END DO
       ELSE IF (ik==3) THEN
          DO j = 1, jjm
             rlatu2(j) = ylat(j)
             yprimu2(j) = yprim(j)
          END DO
       ELSE IF (ik==4) THEN
          DO j = 1, jjm
             rlatu1(j) = ylat(j)
             yprimu1(j) = yprim(j)
          END DO
       END IF
    END DO loop_ik

    DO j = 1, jjm
       ylat(j) = rlatu(j) - rlatu(j + 1)
    END DO

    DO j = 1, jjm
       IF (rlatu1(j) <= rlatu2(j)) THEN
          print *, 'Attention ! rlatu1 < rlatu2 ', rlatu1(j), rlatu2(j), j
          STOP 13
       ENDIF

       IF (rlatu2(j) <= rlatu(j+1)) THEN
          print *, 'Attention ! rlatu2 < rlatup1 ', rlatu2(j), rlatu(j+1), j
          STOP 14
       ENDIF

       IF (rlatu(j) <= rlatu1(j)) THEN
          print *, ' Attention ! rlatu < rlatu1 ', rlatu(j), rlatu1(j), j
          STOP 15
       ENDIF

       IF (rlatv(j) <= rlatu2(j)) THEN
          print *, ' Attention ! rlatv < rlatu2 ', rlatv(j), rlatu2(j), j
          STOP 16
       ENDIF

       IF (rlatv(j) >= rlatu1(j)) THEN
          print *, ' Attention ! rlatv > rlatu1 ', rlatv(j), rlatu1(j), j
          STOP 17
       ENDIF

       IF (rlatv(j) >= rlatu(j)) THEN
          print *, ' Attention ! rlatv > rlatu ', rlatv(j), rlatu(j), j
          STOP 18
       ENDIF
    ENDDO

    print *, 'Latitudes'
    print 3, minval(ylat(:jjm)) *180d0/pi, maxval(ylat(:jjm))*180d0/pi

3   Format(1x, ' Au centre du zoom, la longueur de la maille est', &
         ' d environ ', f0.2, ' degres ', /, &
         ' alors que la maille en dehors de la zone du zoom est ', &
         "d'environ ", f0.2, ' degres ')

    rlatu(1) = pi / 2.
    rlatu(jjm + 1) = -rlatu(1)

  END SUBROUTINE fyhyp

  !********************************************************************

  SUBROUTINE fxhyp

    ! From LMDZ4/libf/dyn3d/fxhyp.F, version 1.2, 2005/06/03 09:11:32
    ! Author: P. Le Van, from formulas by R. Sadourny

    ! Compute xprimm025, rlonv, xprimv, rlonu, xprimu, xprimp025.
    
    ! Calcule les longitudes et dérivées dans la grille du GCM pour
    ! une fonction $x_f(\tilde x)$ à dérivée tangente hyperbolique.

    ! Il vaut mieux avoir : grossismx $\times$ delta < pi

    ! Le premier point scalaire pour une grille regulière (grossismx =
    ! 1) avec clon = 0 est à - 180 degrés.

    use nr_util, only: pi, pi_d, twopi, twopi_d, arth, assert, rad_to_deg

    USE dimensions, ONLY: iim
    use dynetat0_chosen_m, only: clon, grossismx, dzoomx, taux
    use invert_zoom_x_m, only: invert_zoom_x
    use principal_cshift_m, only: principal_cshift
    use tanh_cautious_m, only: tanh_cautious

    ! Local:
    real rlonm025(iim + 1), rlonp025(iim + 1), d_rlonv(iim)
    REAL delta, h
    DOUBLE PRECISION, dimension(0:nmax):: xtild, fhyp, G, Xf, ffdx
    DOUBLE PRECISION beta
    INTEGER i, is2
    DOUBLE PRECISION xmoy(nmax), fxm(nmax)

    !----------------------------------------------------------------------

    print *, "Call sequence information: fxhyp"

    if (grossismx == 1.) then
       h = twopi / iim

       xprimm025(:iim) = h
       xprimp025(:iim) = h
       xprimv(:iim) = h
       xprimu(:iim) = h

       rlonv(:iim) = arth(- pi + clon, h, iim)
       rlonm025(:iim) = rlonv(:iim) - 0.25 * h
       rlonp025(:iim) = rlonv(:iim) + 0.25 * h
       rlonu(:iim) = rlonv(:iim) + 0.5 * h
    else
       delta = dzoomx * twopi_d
       xtild = arth(0d0, pi_d / nmax, nmax + 1)
       forall (i = 1:nmax) xmoy(i) = 0.5d0 * (xtild(i-1) + xtild(i))

       ! Compute fhyp:
       fhyp(1:nmax - 1) = tanh_cautious(taux * (delta / 2d0 &
            - xtild(1:nmax - 1)), xtild(1:nmax - 1) &
            * (pi_d - xtild(1:nmax - 1)))
       fhyp(0) = 1d0
       fhyp(nmax) = -1d0

       fxm = tanh_cautious(taux * (delta / 2d0 - xmoy), xmoy * (pi_d - xmoy))

       ! Compute \int_0 ^{\tilde x} F:

       ffdx(0) = 0d0

       DO i = 1, nmax
          ffdx(i) = ffdx(i - 1) + fxm(i) * (xtild(i) - xtild(i-1))
       END DO

       print *, "ffdx(nmax) = ", ffdx(nmax)
       beta = (pi_d - grossismx * ffdx(nmax)) / (pi_d - ffdx(nmax))
       print *, "beta = ", beta

       IF (2d0 * beta - grossismx <= 0d0) THEN
          print *, 'Bad choice of grossismx, taux, dzoomx.'
          print *, 'Decrease dzoomx or grossismx.'
          STOP 1
       END IF

       G = beta + (grossismx - beta) * fhyp

       Xf(:nmax - 1) = beta * xtild(:nmax - 1) + (grossismx - beta) &
            * ffdx(:nmax - 1)
       Xf(nmax) = pi_d

       call invert_zoom_x(beta, xf, xtild, G, rlonm025(:iim), xprimm025(:iim), &
            xuv = - 0.25d0)
       call invert_zoom_x(beta, xf, xtild, G, rlonv(:iim), xprimv(:iim), &
            xuv = 0d0)
       call invert_zoom_x(beta, xf, xtild, G, rlonu(:iim), xprimu(:iim), &
            xuv = 0.5d0)
       call invert_zoom_x(beta, xf, xtild, G, rlonp025(:iim), xprimp025(:iim), &
            xuv = 0.25d0)
    end if

    is2 = 0

    IF (MINval(rlonm025(:iim)) < - pi - 0.1 &
         .or. MAXval(rlonm025(:iim)) > pi + 0.1) THEN
       IF (clon <= 0.) THEN
          is2 = 1

          do while (rlonm025(is2) < - pi .and. is2 < iim)
             is2 = is2 + 1
          end do

          call assert(rlonm025(is2) >= - pi, &
               "fxhyp -- rlonm025 should be >= - pi")
       ELSE
          is2 = iim

          do while (rlonm025(is2) > pi .and. is2 > 1)
             is2 = is2 - 1
          end do

          if (rlonm025(is2) > pi) then
             print *, 'Rlonm025 plus grand que pi !'
             STOP 1
          end if
       END IF
    END IF

    call principal_cshift(is2, rlonm025, xprimm025)
    call principal_cshift(is2, rlonv, xprimv)
    call principal_cshift(is2, rlonu, xprimu)
    call principal_cshift(is2, rlonp025, xprimp025)

    forall (i = 1: iim) d_rlonv(i) = rlonv(i + 1) - rlonv(i)
    print *, "Minimum longitude step:", MINval(d_rlonv) * rad_to_deg, "degrees"
    print *, "Maximum longitude step:", MAXval(d_rlonv) * rad_to_deg, "degrees"

    ! Check that rlonm025 <= rlonv <= rlonp025 <= rlonu:
    DO i = 1, iim + 1
       IF (rlonp025(i) < rlonv(i)) THEN
          print *, 'rlonp025(', i, ') = ', rlonp025(i)
          print *, "< rlonv(", i, ") = ", rlonv(i)
          STOP 1
       END IF

       IF (rlonv(i) < rlonm025(i)) THEN 
          print *, 'rlonv(', i, ') = ', rlonv(i)
          print *, "< rlonm025(", i, ") = ", rlonm025(i)
          STOP 1
       END IF

       IF (rlonp025(i) > rlonu(i)) THEN
          print *, 'rlonp025(', i, ') = ', rlonp025(i)
          print *, "> rlonu(", i, ") = ", rlonu(i)
          STOP 1
       END IF
    END DO

  END SUBROUTINE fxhyp

end module dynetat0_m
1	guez	3	module dynetat0_m
2
3	guez	265	use dimensions, only: iim, jjm
4	guez	139
5	guez	3	IMPLICIT NONE
6
7	guez	314	private iim, jjm
8	guez	139
9	guez	313	INTEGER, protected, save:: day_ini
10	guez	130	! day number at the beginning of the run, based at value 1 on
11			! January 1st of annee_ref
12	guez	25
13	guez	313	real, protected, save:: rlatu(jjm + 1)
14	guez	156	! latitudes of points of the "scalar" and "u" grid, in rad
15	guez	139
16	guez	313	real, protected, save:: rlatv(jjm)
17	guez	156	! latitudes of points of the "v" grid, in rad, in decreasing order
18	guez	139
19	guez	313	real, protected, save:: rlonu(iim + 1)
20	guez	278	! longitudes of points of the "u" grid, in rad
21	guez	139
22	guez	313	real, protected, save:: rlonv(iim + 1)
23	guez	156	! longitudes of points of the "scalar" and "v" grid, in rad
24	guez	139
25	guez	313	real, protected, save:: xprimu(iim + 1), xprimv(iim + 1)
26	guez	156	! 2 pi / iim * (derivative of the longitudinal zoom function)(rlon[uv])
27	guez	139
28	guez	313	REAL, protected, save:: xprimm025(iim + 1), xprimp025(iim + 1)
29			REAL, protected, save:: rlatu1(jjm), rlatu2(jjm), yprimu1(jjm), yprimu2(jjm)
30			REAL, save:: ang0, etot0, ptot0, ztot0, stot0
31	guez	277	INTEGER, PARAMETER, private:: nmax = 30000
32	guez	313	INTEGER, save:: itau_dyn
33	guez	139
34	guez	3	contains
35
36	guez	128	SUBROUTINE dynetat0(vcov, ucov, teta, q, masse, ps, phis)
37	guez	3
38	guez	38	! From dynetat0.F, version 1.2, 2004/06/22 11:45:30
39			! Authors: P. Le Van, L. Fairhead
40	guez	39	! This procedure reads the initial state of the atmosphere.
41	guez	3
42	guez	313	! Libraries:
43	guez	67	use netcdf, only: NF90_NOWRITE, NF90_NOERR
44	guez	44	use netcdf95, only: NF95_GET_VAR, nf95_open, nf95_inq_varid, NF95_CLOSE, &
45			NF95_Gw_VAR
46	guez	36	use nr_util, only: assert
47	guez	3
48	guez	313	use conf_gcm_m, only: raz_date
49			use dimensions, only: iim, jjm, llm, nqmx
50			use dynetat0_chosen_m, only: day_ref
51			use iniadvtrac_m, only: tname
52
53	guez	55	REAL, intent(out):: vcov(: , :, :) ! (iim + 1, jjm, llm)
54			REAL, intent(out):: ucov(:, :, :) ! (iim + 1, jjm + 1, llm)
55	guez	43	REAL, intent(out):: teta(:, :, :) ! (iim + 1, jjm + 1, llm)
56	guez	40	REAL, intent(out):: q(:, :, :, :) ! (iim + 1, jjm + 1, llm, nqmx)
57	guez	55	REAL, intent(out):: masse(:, :, :) ! (iim + 1, jjm + 1, llm)
58	guez	39	REAL, intent(out):: ps(:, :) ! (iim + 1, jjm + 1) in Pa
59			REAL, intent(out):: phis(:, :) ! (iim + 1, jjm + 1)
60	guez	3
61	guez	44	! Local variables:
62	guez	38	INTEGER iq
63	guez	225	REAL, allocatable:: tab_cntrl(:) ! tableau des param\`etres du run
64	guez	38	INTEGER ierr, ncid, varid
65	guez	3
66			!-----------------------------------------------------------------------
67
68			print *, "Call sequence information: dynetat0"
69
70	guez	55	call assert((/size(ucov, 1), size(vcov, 1), size(masse, 1), size(ps, 1), &
71			size(phis, 1), size(q, 1), size(teta, 1)/) == iim + 1, "dynetat0 iim")
72			call assert((/size(ucov, 2), size(vcov, 2) + 1, size(masse, 2), &
73			size(ps, 2), size(phis, 2), size(q, 2), size(teta, 2)/) == jjm + 1, &
74			"dynetat0 jjm")
75			call assert((/size(vcov, 3), size(ucov, 3), size(teta, 3), size(q, 3), &
76			size(masse, 3)/) == llm, "dynetat0 llm")
77	guez	40	call assert(size(q, 4) == nqmx, "dynetat0 q nqmx")
78	guez	3
79	guez	139	! Fichier \'etat initial :
80	guez	25	call nf95_open("start.nc", NF90_NOWRITE, ncid)
81	guez	3
82	guez	38	call nf95_inq_varid(ncid, "controle", varid)
83	guez	44	call NF95_Gw_VAR(ncid, varid, tab_cntrl)
84	guez	3
85	guez	38	etot0 = tab_cntrl(13)
86			ptot0 = tab_cntrl(14)
87			ztot0 = tab_cntrl(15)
88			stot0 = tab_cntrl(16)
89			ang0 = tab_cntrl(17)
90	guez	113
91	guez	129	if (raz_date) then
92	guez	313	print *, 'Resetting the date.'
93	guez	129	day_ini = day_ref
94			itau_dyn = 0
95			else
96			itau_dyn = tab_cntrl(31)
97			day_ini = tab_cntrl(30)
98			end if
99
100			print *, "day_ini = ", day_ini
101
102	guez	38	call NF95_INQ_VARID (ncid, "rlonu", varid)
103			call NF95_GET_VAR(ncid, varid, rlonu)
104	guez	3
105	guez	38	call NF95_INQ_VARID (ncid, "rlatu", varid)
106			call NF95_GET_VAR(ncid, varid, rlatu)
107	guez	3
108	guez	38	call NF95_INQ_VARID (ncid, "rlonv", varid)
109			call NF95_GET_VAR(ncid, varid, rlonv)
110	guez	3
111	guez	38	call NF95_INQ_VARID (ncid, "rlatv", varid)
112			call NF95_GET_VAR(ncid, varid, rlatv)
113	guez	3
114	guez	139	CALL nf95_inq_varid(ncid, 'xprimu', varid)
115			CALL nf95_get_var(ncid, varid, xprimu)
116	guez	3
117	guez	139	CALL nf95_inq_varid(ncid, 'xprimv', varid)
118			CALL nf95_get_var(ncid, varid, xprimv)
119	guez	3
120	guez	139	CALL nf95_inq_varid(ncid, 'xprimm025', varid)
121			CALL nf95_get_var(ncid, varid, xprimm025)
122	guez	3
123	guez	139	CALL nf95_inq_varid(ncid, 'xprimp025', varid)
124			CALL nf95_get_var(ncid, varid, xprimp025)
125
126			call NF95_INQ_VARID (ncid, "rlatu1", varid)
127			call NF95_GET_VAR(ncid, varid, rlatu1)
128
129			call NF95_INQ_VARID (ncid, "rlatu2", varid)
130			call NF95_GET_VAR(ncid, varid, rlatu2)
131
132			CALL nf95_inq_varid(ncid, 'yprimu1', varid)
133			CALL nf95_get_var(ncid, varid, yprimu1)
134
135			CALL nf95_inq_varid(ncid, 'yprimu2', varid)
136			CALL nf95_get_var(ncid, varid, yprimu2)
137
138	guez	228	call NF95_INQ_VARID (ncid, "phis", varid)
139	guez	38	call NF95_GET_VAR(ncid, varid, phis)
140	guez	3
141	guez	38	call NF95_INQ_VARID (ncid, "ucov", varid)
142	guez	55	call NF95_GET_VAR(ncid, varid, ucov)
143	guez	3
144	guez	38	call NF95_INQ_VARID (ncid, "vcov", varid)
145	guez	55	call NF95_GET_VAR(ncid, varid, vcov)
146	guez	3
147	guez	38	call NF95_INQ_VARID (ncid, "teta", varid)
148	guez	43	call NF95_GET_VAR(ncid, varid, teta)
149	guez	3
150			DO iq = 1, nqmx
151	guez	38	call NF95_INQ_VARID(ncid, tname(iq), varid, ierr)
152	guez	157	IF (ierr == NF90_NOERR) THEN
153			call NF95_GET_VAR(ncid, varid, q(:, :, :, iq))
154			ELSE
155	guez	38	PRINT *, 'dynetat0: "' // tname(iq) // '" not found, ' // &
156			"setting it to zero..."
157	guez	40	q(:, :, :, iq) = 0.
158	guez	3	ENDIF
159			ENDDO
160
161	guez	38	call NF95_INQ_VARID (ncid, "masse", varid)
162	guez	55	call NF95_GET_VAR(ncid, varid, masse)
163	guez	3
164	guez	38	call NF95_INQ_VARID (ncid, "ps", varid)
165	guez	39	call NF95_GET_VAR(ncid, varid, ps)
166	guez	85	! Check that there is a single value at each pole:
167			call assert(ps(1, 1) == ps(2:, 1), "dynetat0 ps north pole")
168			call assert(ps(1, jjm + 1) == ps(2:, jjm + 1), "dynetat0 ps south pole")
169	guez	3
170	guez	25	call NF95_CLOSE(ncid)
171	guez	3
172			END SUBROUTINE dynetat0
173
174	guez	276	!********************************************************************
175
176	guez	277	SUBROUTINE fyhyp
177
178			! From LMDZ4/libf/dyn3d/fyhyp.F, version 1.2, 2005/06/03 09:11:32
179
180			! Author: P. Le Van, from analysis by R. Sadourny
181
182	guez	313	! Define rlatu, rlatv, rlatu2, yprimu2, rlatu1, yprimu1.
183	guez	277
184			! Calcule les latitudes et dérivées dans la grille du GCM pour une
185			! fonction f(y) à dérivée tangente hyperbolique.
186
187			! Il vaut mieux avoir : grossismy * dzoom < pi / 2
188
189			use coefpoly_m, only: coefpoly, a0, a1, a2, a3
190			USE dimensions, only: jjm
191	guez	313	use dynetat0_chosen_m, only: clat, grossismy, dzoomy, tauy
192	guez	277	use heavyside_m, only: heavyside
193
194			! Local:
195
196	guez	314	INTEGER, PARAMETER:: nmax2 = 2 * nmax
197	guez	277	REAL dzoom ! distance totale de la zone du zoom (en radians)
198			DOUBLE PRECISION ylat(jjm + 1), yprim(jjm + 1)
199			DOUBLE PRECISION yuv
200			DOUBLE PRECISION, save:: yt(0:nmax2)
201			DOUBLE PRECISION fhyp(0:nmax2), beta
202			DOUBLE PRECISION, save:: ytprim(0:nmax2)
203			DOUBLE PRECISION fxm(0:nmax2)
204			DOUBLE PRECISION, save:: yf(0:nmax2)
205			DOUBLE PRECISION yypr(0:nmax2)
206			DOUBLE PRECISION yvrai(jjm + 1), yprimm(jjm + 1), ylatt(jjm + 1)
207			DOUBLE PRECISION pi, pis2, epsilon, pisjm
208			DOUBLE PRECISION yo1, yi, ylon2, ymoy, yprimin
209			DOUBLE PRECISION yfi, yf1, ffdy
210			DOUBLE PRECISION ypn
211			DOUBLE PRECISION, save::deply, y00
212
213			INTEGER i, j, it, ik, iter, jlat, jjpn
214			INTEGER, save:: jpn
215			DOUBLE PRECISION yi2, heavyy0, heavyy0m
216			DOUBLE PRECISION fa(0:nmax2), fb(0:nmax2)
217			REAL y0min, y0max
218
219			!-------------------------------------------------------------------
220
221			print *, "Call sequence information: fyhyp"
222
223			pi = 2.*asin(1.)
224			pis2 = pi/2.
225			pisjm = pi/real(jjm)
226			epsilon = 1e-3
227			dzoom = dzoomy*pi
228
229			DO i = 0, nmax2
230			yt(i) = -pis2 + real(i)*pi/nmax2
231			END DO
232
233			heavyy0m = heavyside(-clat)
234			heavyy0 = heavyside(clat)
235			y0min = 2.clatheavyy0m - pis2
236			y0max = 2.clatheavyy0 + pis2
237
238			fa = 999.999
239			fb = 999.999
240
241			DO i = 0, nmax2
242			IF (yt(i)<clat) THEN
243			fa(i) = tauy*(yt(i)-clat + dzoom/2.)
244			fb(i) = (yt(i)-2.clatheavyy0m + pis2)*(clat-yt(i))
245			ELSE IF (yt(i)>clat) THEN
246			fa(i) = tauy*(clat-yt(i) + dzoom/2.)
247			fb(i) = (2.clatheavyy0-yt(i) + pis2)*(yt(i)-clat)
248			END IF
249
250			IF (200.*fb(i)<-fa(i)) THEN
251			fhyp(i) = -1.
252			ELSE IF (200.*fb(i)<fa(i)) THEN
253			fhyp(i) = 1.
254			ELSE
255			fhyp(i) = tanh(fa(i)/fb(i))
256			END IF
257
258			IF (yt(i)==clat) fhyp(i) = 1.
259			IF (yt(i)==y0min .OR. yt(i)==y0max) fhyp(i) = -1.
260			END DO
261
262			! Calcul de beta
263
264			ffdy = 0.
265
266			DO i = 1, nmax2
267			ymoy = 0.5*(yt(i-1) + yt(i))
268			IF (ymoy<clat) THEN
269			fa(i) = tauy*(ymoy-clat + dzoom/2.)
270			fb(i) = (ymoy-2.clatheavyy0m + pis2)*(clat-ymoy)
271			ELSE IF (ymoy>clat) THEN
272			fa(i) = tauy*(clat-ymoy + dzoom/2.)
273			fb(i) = (2.clatheavyy0-ymoy + pis2)*(ymoy-clat)
274			END IF
275
276			IF (200.*fb(i)<-fa(i)) THEN
277			fxm(i) = -1.
278			ELSE IF (200.*fb(i)<fa(i)) THEN
279			fxm(i) = 1.
280			ELSE
281			fxm(i) = tanh(fa(i)/fb(i))
282			END IF
283			IF (ymoy==clat) fxm(i) = 1.
284			IF (ymoy==y0min .OR. yt(i)==y0max) fxm(i) = -1.
285			ffdy = ffdy + fxm(i)*(yt(i)-yt(i-1))
286			END DO
287
288			beta = (grossismy*ffdy-pi)/(ffdy-pi)
289
290			IF (2. * beta - grossismy <= 0.) THEN
291			print *, 'Attention ! La valeur beta calculee dans la routine fyhyp ' &
292			// 'est mauvaise. Modifier les valeurs de grossismy, tauy ou ' &
293			// 'dzoomy et relancer.'
294			STOP 1
295			END IF
296
297			! calcul de Ytprim
298
299			DO i = 0, nmax2
300			ytprim(i) = beta + (grossismy-beta)*fhyp(i)
301			END DO
302
303			! Calcul de Yf
304
305			yf(0) = -pis2
306			DO i = 1, nmax2
307			yypr(i) = beta + (grossismy-beta)*fxm(i)
308			END DO
309
310			DO i = 1, nmax2
311			yf(i) = yf(i-1) + yypr(i)*(yt(i)-yt(i-1))
312			END DO
313
314			! yuv = 0. si calcul des latitudes aux pts. U
315			! yuv = 0.5 si calcul des latitudes aux pts. V
316
317			loop_ik: DO ik = 1, 4
318			IF (ik==1) THEN
319			yuv = 0.
320			jlat = jjm + 1
321			ELSE IF (ik==2) THEN
322			yuv = 0.5
323			jlat = jjm
324			ELSE IF (ik==3) THEN
325			yuv = 0.25
326			jlat = jjm
327			ELSE IF (ik==4) THEN
328			yuv = 0.75
329			jlat = jjm
330			END IF
331
332			yo1 = 0.
333			DO j = 1, jlat
334			yo1 = 0.
335			ylon2 = -pis2 + pisjm*(real(j) + yuv-1.)
336			yfi = ylon2
337
338			it = nmax2
339			DO while (it >= 1 .and. yfi < yf(it))
340			it = it - 1
341			END DO
342
343			yi = yt(it)
344			IF (it==nmax2) THEN
345			it = nmax2 - 1
346			yf(it + 1) = pis2
347			END IF
348
349			! Interpolation entre yi(it) et yi(it + 1) pour avoir Y(yi)
350			! et Y'(yi)
351
352			CALL coefpoly(yf(it), yf(it + 1), ytprim(it), ytprim(it + 1), &
353			yt(it), yt(it + 1))
354
355			yf1 = yf(it)
356			yprimin = a1 + 2.a2yi + 3.a3yi*yi
357
358			iter = 1
359			DO
360			yi = yi - (yf1-yfi)/yprimin
361			IF (abs(yi-yo1)<=epsilon .or. iter == 300) exit
362			yo1 = yi
363			yi2 = yi*yi
364			yf1 = a0 + a1yi + a2yi2 + a3yi2yi
365			yprimin = a1 + 2.a2yi + 3.a3yi2
366			END DO
367			if (abs(yi-yo1) > epsilon) then
368			print *, 'Pas de solution.', j, ylon2
369			STOP 1
370			end if
371
372			yprimin = a1 + 2.a2yi + 3.a3yi*yi
373			yprim(j) = pi/(jjm*yprimin)
374			yvrai(j) = yi
375			END DO
376
377			DO j = 1, jlat - 1
378			IF (yvrai(j + 1)<yvrai(j)) THEN
379			print *, 'Problème avec rlat(', j + 1, ') plus petit que rlat(', &
380			j, ')'
381			STOP 1
382			END IF
383			END DO
384
385			print *, 'Reorganisation des latitudes pour avoir entre - pi/2 et pi/2'
386
387			IF (ik==1) THEN
388			ypn = pis2
389			DO j = jjm + 1, 1, -1
390			IF (yvrai(j)<=ypn) exit
391			END DO
392
393			jpn = j
394			y00 = yvrai(jpn)
395			deply = pis2 - y00
396			END IF
397
398			DO j = 1, jjm + 1 - jpn
399			ylatt(j) = -pis2 - y00 + yvrai(jpn + j-1)
400			yprimm(j) = yprim(jpn + j-1)
401			END DO
402
403			jjpn = jpn
404			IF (jlat==jjm) jjpn = jpn - 1
405
406			DO j = 1, jjpn
407			ylatt(j + jjm + 1-jpn) = yvrai(j) + deply
408			yprimm(j + jjm + 1-jpn) = yprim(j)
409			END DO
410
411			! Fin de la reorganisation
412
413			DO j = 1, jlat
414			ylat(j) = ylatt(jlat + 1-j)
415			yprim(j) = yprimm(jlat + 1-j)
416			END DO
417
418			DO j = 1, jlat
419			yvrai(j) = ylat(j)*180./pi
420			END DO
421
422			IF (ik==1) THEN
423			DO j = 1, jjm + 1
424			rlatu(j) = ylat(j)
425			END DO
426			ELSE IF (ik==2) THEN
427			DO j = 1, jjm
428			rlatv(j) = ylat(j)
429			END DO
430			ELSE IF (ik==3) THEN
431			DO j = 1, jjm
432			rlatu2(j) = ylat(j)
433			yprimu2(j) = yprim(j)
434			END DO
435			ELSE IF (ik==4) THEN
436			DO j = 1, jjm
437			rlatu1(j) = ylat(j)
438			yprimu1(j) = yprim(j)
439			END DO
440			END IF
441			END DO loop_ik
442
443			DO j = 1, jjm
444			ylat(j) = rlatu(j) - rlatu(j + 1)
445			END DO
446
447			DO j = 1, jjm
448			IF (rlatu1(j) <= rlatu2(j)) THEN
449			print *, 'Attention ! rlatu1 < rlatu2 ', rlatu1(j), rlatu2(j), j
450			STOP 13
451			ENDIF
452
453			IF (rlatu2(j) <= rlatu(j+1)) THEN
454			print *, 'Attention ! rlatu2 < rlatup1 ', rlatu2(j), rlatu(j+1), j
455			STOP 14
456			ENDIF
457
458			IF (rlatu(j) <= rlatu1(j)) THEN
459			print *, ' Attention ! rlatu < rlatu1 ', rlatu(j), rlatu1(j), j
460			STOP 15
461			ENDIF
462
463			IF (rlatv(j) <= rlatu2(j)) THEN
464			print *, ' Attention ! rlatv < rlatu2 ', rlatv(j), rlatu2(j), j
465			STOP 16
466			ENDIF
467
468			IF (rlatv(j) >= rlatu1(j)) THEN
469			print *, ' Attention ! rlatv > rlatu1 ', rlatv(j), rlatu1(j), j
470			STOP 17
471			ENDIF
472
473			IF (rlatv(j) >= rlatu(j)) THEN
474			print *, ' Attention ! rlatv > rlatu ', rlatv(j), rlatu(j), j
475			STOP 18
476			ENDIF
477			ENDDO
478
479			print *, 'Latitudes'
480			print 3, minval(ylat(:jjm)) 180d0/pi, maxval(ylat(:jjm))180d0/pi
481
482			3 Format(1x, ' Au centre du zoom, la longueur de la maille est', &
483			' d environ ', f0.2, ' degres ', /, &
484			' alors que la maille en dehors de la zone du zoom est ', &
485			"d'environ ", f0.2, ' degres ')
486
487			rlatu(1) = pi / 2.
488			rlatu(jjm + 1) = -rlatu(1)
489
490			END SUBROUTINE fyhyp
491
492			!********************************************************************
493
494			SUBROUTINE fxhyp
495
496			! From LMDZ4/libf/dyn3d/fxhyp.F, version 1.2, 2005/06/03 09:11:32
497			! Author: P. Le Van, from formulas by R. Sadourny
498
499	guez	313	! Compute xprimm025, rlonv, xprimv, rlonu, xprimu, xprimp025.
500	guez	277
501			! Calcule les longitudes et dérivées dans la grille du GCM pour
502	guez	311	! une fonction $x_f(\tilde x)$ à dérivée tangente hyperbolique.
503	guez	277
504	guez	311	! Il vaut mieux avoir : grossismx $\times$ delta < pi
505	guez	277
506			! Le premier point scalaire pour une grille regulière (grossismx =
507			! 1) avec clon = 0 est à - 180 degrés.
508
509	guez	278	use nr_util, only: pi, pi_d, twopi, twopi_d, arth, assert, rad_to_deg
510
511	guez	277	USE dimensions, ONLY: iim
512	guez	313	use dynetat0_chosen_m, only: clon, grossismx, dzoomx, taux
513	guez	314	use invert_zoom_x_m, only: invert_zoom_x
514			use principal_cshift_m, only: principal_cshift
515	guez	277	use tanh_cautious_m, only: tanh_cautious
516
517			! Local:
518			real rlonm025(iim + 1), rlonp025(iim + 1), d_rlonv(iim)
519			REAL delta, h
520			DOUBLE PRECISION, dimension(0:nmax):: xtild, fhyp, G, Xf, ffdx
521			DOUBLE PRECISION beta
522			INTEGER i, is2
523			DOUBLE PRECISION xmoy(nmax), fxm(nmax)
524
525			!----------------------------------------------------------------------
526
527			print *, "Call sequence information: fxhyp"
528
529			if (grossismx == 1.) then
530			h = twopi / iim
531
532			xprimm025(:iim) = h
533			xprimp025(:iim) = h
534			xprimv(:iim) = h
535			xprimu(:iim) = h
536
537			rlonv(:iim) = arth(- pi + clon, h, iim)
538			rlonm025(:iim) = rlonv(:iim) - 0.25 * h
539			rlonp025(:iim) = rlonv(:iim) + 0.25 * h
540			rlonu(:iim) = rlonv(:iim) + 0.5 * h
541			else
542			delta = dzoomx * twopi_d
543			xtild = arth(0d0, pi_d / nmax, nmax + 1)
544			forall (i = 1:nmax) xmoy(i) = 0.5d0 * (xtild(i-1) + xtild(i))
545
546			! Compute fhyp:
547			fhyp(1:nmax - 1) = tanh_cautious(taux * (delta / 2d0 &
548			- xtild(1:nmax - 1)), xtild(1:nmax - 1) &
549			* (pi_d - xtild(1:nmax - 1)))
550			fhyp(0) = 1d0
551			fhyp(nmax) = -1d0
552
553			fxm = tanh_cautious(taux * (delta / 2d0 - xmoy), xmoy * (pi_d - xmoy))
554
555			! Compute \int_0 ^{\tilde x} F:
556
557			ffdx(0) = 0d0
558
559			DO i = 1, nmax
560			ffdx(i) = ffdx(i - 1) + fxm(i) * (xtild(i) - xtild(i-1))
561			END DO
562
563			print *, "ffdx(nmax) = ", ffdx(nmax)
564			beta = (pi_d - grossismx * ffdx(nmax)) / (pi_d - ffdx(nmax))
565			print *, "beta = ", beta
566
567			IF (2d0 * beta - grossismx <= 0d0) THEN
568			print *, 'Bad choice of grossismx, taux, dzoomx.'
569			print *, 'Decrease dzoomx or grossismx.'
570			STOP 1
571			END IF
572
573			G = beta + (grossismx - beta) * fhyp
574
575			Xf(:nmax - 1) = beta * xtild(:nmax - 1) + (grossismx - beta) &
576			* ffdx(:nmax - 1)
577			Xf(nmax) = pi_d
578
579			call invert_zoom_x(beta, xf, xtild, G, rlonm025(:iim), xprimm025(:iim), &
580			xuv = - 0.25d0)
581			call invert_zoom_x(beta, xf, xtild, G, rlonv(:iim), xprimv(:iim), &
582			xuv = 0d0)
583			call invert_zoom_x(beta, xf, xtild, G, rlonu(:iim), xprimu(:iim), &
584			xuv = 0.5d0)
585			call invert_zoom_x(beta, xf, xtild, G, rlonp025(:iim), xprimp025(:iim), &
586			xuv = 0.25d0)
587			end if
588
589			is2 = 0
590
591			IF (MINval(rlonm025(:iim)) < - pi - 0.1 &
592			.or. MAXval(rlonm025(:iim)) > pi + 0.1) THEN
593			IF (clon <= 0.) THEN
594			is2 = 1
595
596			do while (rlonm025(is2) < - pi .and. is2 < iim)
597			is2 = is2 + 1
598			end do
599
600	guez	278	call assert(rlonm025(is2) >= - pi, &
601			"fxhyp -- rlonm025 should be >= - pi")
602	guez	277	ELSE
603			is2 = iim
604
605			do while (rlonm025(is2) > pi .and. is2 > 1)
606			is2 = is2 - 1
607			end do
608
609			if (rlonm025(is2) > pi) then
610			print *, 'Rlonm025 plus grand que pi !'
611			STOP 1
612			end if
613			END IF
614			END IF
615
616			call principal_cshift(is2, rlonm025, xprimm025)
617			call principal_cshift(is2, rlonv, xprimv)
618			call principal_cshift(is2, rlonu, xprimu)
619			call principal_cshift(is2, rlonp025, xprimp025)
620
621			forall (i = 1: iim) d_rlonv(i) = rlonv(i + 1) - rlonv(i)
622	guez	278	print , "Minimum longitude step:", MINval(d_rlonv) rad_to_deg, "degrees"
623			print , "Maximum longitude step:", MAXval(d_rlonv) rad_to_deg, "degrees"
624	guez	277
625			! Check that rlonm025 <= rlonv <= rlonp025 <= rlonu:
626			DO i = 1, iim + 1
627			IF (rlonp025(i) < rlonv(i)) THEN
628			print *, 'rlonp025(', i, ') = ', rlonp025(i)
629			print *, "< rlonv(", i, ") = ", rlonv(i)
630			STOP 1
631			END IF
632
633			IF (rlonv(i) < rlonm025(i)) THEN
634			print *, 'rlonv(', i, ') = ', rlonv(i)
635			print *, "< rlonm025(", i, ") = ", rlonm025(i)
636			STOP 1
637			END IF
638
639			IF (rlonp025(i) > rlonu(i)) THEN
640			print *, 'rlonp025(', i, ') = ', rlonp025(i)
641			print *, "> rlonu(", i, ") = ", rlonu(i)
642			STOP 1
643			END IF
644			END DO
645
646			END SUBROUTINE fxhyp
647
648	guez	3	end module dynetat0_m