| 1 |
module etat0_m |
| 2 |
|
| 3 |
IMPLICIT NONE |
| 4 |
|
| 5 |
contains |
| 6 |
|
| 7 |
SUBROUTINE etat0(phis, pctsrf) |
| 8 |
|
| 9 |
! From "etat0_netcdf.F", version 1.3, 2005/05/25 13:10:09 |
| 10 |
|
| 11 |
use caldyn0_m, only: caldyn0 |
| 12 |
use comconst, only: cpp, kappa, iniconst |
| 13 |
use comgeom, only: aire_2d, apoln, apols, cu_2d, cv_2d, inigeom |
| 14 |
use conf_gcm_m, only: nday |
| 15 |
use dimensions, only: iim, jjm, llm, nqmx |
| 16 |
use dimphy, only: klon |
| 17 |
use dimsoil, only: nsoilmx |
| 18 |
use disvert_m, only: ap, bp, preff, pa, disvert |
| 19 |
use dynetat0_m, only: day_ref, annee_ref, rlatu, rlatv, rlonu, rlonv, & |
| 20 |
fyhyp, fxhyp |
| 21 |
use dynredem0_m, only: dynredem0 |
| 22 |
use dynredem1_m, only: dynredem1 |
| 23 |
use exner_hyb_m, only: exner_hyb |
| 24 |
use geopot_m, only: geopot |
| 25 |
use grille_m_m, only: grille_m |
| 26 |
use grid_change, only: init_dyn_phy, dyn_phy |
| 27 |
use indicesol, only: is_oce, is_sic, is_ter, is_lic, epsfra, nbsrf |
| 28 |
use iniadvtrac_m, only: iniadvtrac |
| 29 |
use inifilr_m, only: inifilr |
| 30 |
use massdair_m, only: massdair |
| 31 |
use netcdf, only: nf90_nowrite |
| 32 |
use netcdf95, only: nf95_close, nf95_get_var, nf95_gw_var, nf95_put_var, & |
| 33 |
nf95_inq_varid, nf95_open |
| 34 |
use nr_util, only: pi, assert |
| 35 |
use phyetat0_m, only: zmasq, phyetat0_new |
| 36 |
use phyredem0_m, only: phyredem0, ncid_restartphy |
| 37 |
use phyredem_m, only: phyredem |
| 38 |
use q_sat_m, only: q_sat |
| 39 |
use regr_lat_time_coefoz_m, only: regr_lat_time_coefoz |
| 40 |
use regr_pr_o3_m, only: regr_pr_o3 |
| 41 |
use startdyn, only: start_init_dyn |
| 42 |
USE start_init_orog_m, only: start_init_orog |
| 43 |
use start_init_phys_m, only: start_init_phys |
| 44 |
use start_inter_3d_m, only: start_inter_3d |
| 45 |
use test_disvert_m, only: test_disvert |
| 46 |
use unit_nml_m, only: unit_nml |
| 47 |
|
| 48 |
REAL, intent(out):: phis(:, :) ! (iim + 1, jjm + 1) |
| 49 |
! surface geopotential, in m2 s-2 |
| 50 |
|
| 51 |
REAL, intent(out):: pctsrf(:, :) ! (klon, nbsrf) |
| 52 |
! "pctsrf(i, :)" is the composition of the surface at horizontal |
| 53 |
! position "i". |
| 54 |
|
| 55 |
! Local: |
| 56 |
|
| 57 |
REAL, dimension(iim + 1, jjm + 1, llm):: ucov, t3d, teta |
| 58 |
REAL vcov(iim + 1, jjm, llm) |
| 59 |
|
| 60 |
REAL q(iim + 1, jjm + 1, llm, nqmx) |
| 61 |
! (mass fractions of trace species |
| 62 |
! "q(i, j, l)" is at longitude "rlonv(i)", latitude "rlatu(j)" |
| 63 |
! and pressure level "pls(i, j, l)".) |
| 64 |
|
| 65 |
real qsat(iim + 1, jjm + 1, llm) ! mass fraction of saturating water vapor |
| 66 |
REAL qsolsrf(klon, nbsrf), snsrf(klon, nbsrf) |
| 67 |
REAL albe(klon, nbsrf), evap(klon, nbsrf) |
| 68 |
REAL tsoil(klon, nsoilmx, nbsrf) |
| 69 |
REAL null_array(klon) |
| 70 |
REAL solsw(klon), sollw(klon) |
| 71 |
!IM "slab" ocean |
| 72 |
REAL frugs(klon, nbsrf), agesno(klon, nbsrf) |
| 73 |
REAL rugmer(klon) |
| 74 |
real, dimension(iim + 1, jjm + 1):: zmea_2d, zstd_2d, zsig_2d, zgam_2d |
| 75 |
real, dimension(iim + 1, jjm + 1):: zthe_2d, zpic_2d, zval_2d |
| 76 |
real, dimension(iim + 1, jjm + 1):: tsol_2d, qsol_2d, ps |
| 77 |
REAL zmea(klon), zstd(klon) |
| 78 |
REAL zsig(klon), zgam(klon) |
| 79 |
REAL zthe(klon) |
| 80 |
REAL zpic(klon), zval(klon) |
| 81 |
REAL t_ancien(klon, llm), q_ancien(klon, llm) |
| 82 |
real clwcon(klon, llm), rnebcon(klon, llm), ratqs(klon, llm) |
| 83 |
|
| 84 |
! D\'eclarations pour lecture glace de mer : |
| 85 |
INTEGER iml_lic, jml_lic |
| 86 |
INTEGER ncid, varid |
| 87 |
REAL, ALLOCATABLE:: dlon_lic(:), dlat_lic(:) |
| 88 |
REAL, ALLOCATABLE:: fraclic(:, :) ! fraction land ice |
| 89 |
REAL flic_tmp(iim + 1, jjm + 1) ! fraction land ice temporary |
| 90 |
|
| 91 |
INTEGER l, ji |
| 92 |
|
| 93 |
REAL pk(iim + 1, jjm + 1, llm) ! fonction d'Exner aux milieux des couches |
| 94 |
real pks(iim + 1, jjm + 1) |
| 95 |
REAL masse(iim + 1, jjm + 1, llm) |
| 96 |
REAL phi(iim + 1, jjm + 1, llm) |
| 97 |
real sig1(klon, llm) ! section adiabatic updraft |
| 98 |
real w01(klon, llm) ! vertical velocity within adiabatic updraft |
| 99 |
|
| 100 |
real pls(iim + 1, jjm + 1, llm) |
| 101 |
! (pressure at mid-layer of LMDZ grid, in Pa) |
| 102 |
! "pls(i, j, l)" is at longitude "rlonv(i)", latitude "rlatu(j)", |
| 103 |
! for layer "l") |
| 104 |
|
| 105 |
REAL p3d(iim + 1, jjm + 1, llm+1) ! pressure at layer interfaces, in Pa |
| 106 |
! ("p3d(i, j, l)" is at longitude "rlonv(i)", latitude "rlatu(j)", |
| 107 |
! for interface "l") |
| 108 |
|
| 109 |
namelist /etat0_nml/ day_ref, annee_ref |
| 110 |
|
| 111 |
!--------------------------------- |
| 112 |
|
| 113 |
print *, "Call sequence information: etat0" |
| 114 |
|
| 115 |
print *, "Enter namelist 'etat0_nml'." |
| 116 |
read(unit=*, nml=etat0_nml) |
| 117 |
write(unit_nml, nml=etat0_nml) |
| 118 |
|
| 119 |
CALL iniconst |
| 120 |
|
| 121 |
! Construct a grid: |
| 122 |
|
| 123 |
pa = 5e4 |
| 124 |
CALL disvert |
| 125 |
call test_disvert |
| 126 |
CALL fyhyp |
| 127 |
CALL fxhyp |
| 128 |
CALL inigeom |
| 129 |
CALL inifilr |
| 130 |
call start_init_orog(phis, zmea_2d, zstd_2d, zsig_2d, zgam_2d, zthe_2d, & |
| 131 |
zpic_2d, zval_2d) ! also compute "mask" |
| 132 |
call init_dyn_phy ! define the mask "dyn_phy" for distinct grid points |
| 133 |
call phyetat0_new |
| 134 |
|
| 135 |
call start_init_phys(tsol_2d, qsol_2d) |
| 136 |
CALL start_init_dyn(tsol_2d, phis, ps) |
| 137 |
|
| 138 |
! Compute pressure on intermediate levels: |
| 139 |
forall(l = 1: llm + 1) p3d(:, :, l) = ap(l) + bp(l) * ps |
| 140 |
CALL exner_hyb(ps, p3d, pks, pk) |
| 141 |
call assert(MINVAL(pk) /= MAXVAL(pk), '"pk" should not be constant') |
| 142 |
|
| 143 |
pls = preff * (pk / cpp)**(1. / kappa) |
| 144 |
PRINT *, "minval(pls) = ", minval(pls) |
| 145 |
print *, "maxval(pls) = ", maxval(pls) |
| 146 |
|
| 147 |
call start_inter_3d('U', rlonv, rlatv, pls, ucov) |
| 148 |
forall (l = 1: llm) ucov(:iim, :, l) = ucov(:iim, :, l) * cu_2d(:iim, :) |
| 149 |
ucov(iim+1, :, :) = ucov(1, :, :) |
| 150 |
|
| 151 |
call start_inter_3d('V', rlonu, rlatu(:jjm), pls(:, :jjm, :), vcov) |
| 152 |
forall (l = 1: llm) vcov(:iim, :, l) = vcov(:iim, :, l) * cv_2d(:iim, :) |
| 153 |
vcov(iim + 1, :, :) = vcov(1, :, :) |
| 154 |
|
| 155 |
call start_inter_3d('TEMP', rlonu, rlatv, pls, t3d) |
| 156 |
PRINT *, 'minval(t3d) = ', minval(t3d) |
| 157 |
print *, "maxval(t3d) = ", maxval(t3d) |
| 158 |
|
| 159 |
teta(:iim, :, :) = t3d(:iim, :, :) * cpp / pk(:iim, :, :) |
| 160 |
teta(iim + 1, :, :) = teta(1, :, :) |
| 161 |
DO l = 1, llm |
| 162 |
teta(:, 1, l) = SUM(aire_2d(:, 1) * teta(:, 1, l)) / apoln |
| 163 |
teta(:, jjm + 1, l) = SUM(aire_2d(:, jjm + 1) * teta(:, jjm + 1, l)) & |
| 164 |
/ apols |
| 165 |
ENDDO |
| 166 |
|
| 167 |
! Calcul de l'humidit\'e \`a saturation : |
| 168 |
qsat = q_sat(t3d, pls) |
| 169 |
PRINT *, "minval(qsat) = ", minval(qsat) |
| 170 |
print *, "maxval(qsat) = ", maxval(qsat) |
| 171 |
IF (MINVAL(qsat) == MAXVAL(qsat)) stop '"qsat" should not be constant' |
| 172 |
|
| 173 |
! Water vapor: |
| 174 |
call start_inter_3d('R', rlonu, rlatv, pls, q(:, :, :, 1)) |
| 175 |
q(:, :, :, 1) = 0.01 * q(:, :, :, 1) * qsat |
| 176 |
WHERE (q(:, :, :, 1) < 0.) q(:, :, :, 1) = 1E-10 |
| 177 |
DO l = 1, llm |
| 178 |
q(:, 1, l, 1) = SUM(aire_2d(:, 1) * q(:, 1, l, 1)) / apoln |
| 179 |
q(:, jjm + 1, l, 1) & |
| 180 |
= SUM(aire_2d(:, jjm + 1) * q(:, jjm + 1, l, 1)) / apols |
| 181 |
ENDDO |
| 182 |
|
| 183 |
q(:, :, :, 2:4) = 0. ! liquid water, radon and lead |
| 184 |
|
| 185 |
if (nqmx >= 5) then |
| 186 |
! Ozone: |
| 187 |
call regr_lat_time_coefoz |
| 188 |
call regr_pr_o3(p3d, q(:, :, :, 5)) |
| 189 |
! Convert from mole fraction to mass fraction: |
| 190 |
q(:, :, :, 5) = q(:, :, :, 5) * 48. / 29. |
| 191 |
end if |
| 192 |
|
| 193 |
null_array = 0. |
| 194 |
rugmer = 0.001 |
| 195 |
zmea = pack(zmea_2d, dyn_phy) |
| 196 |
zstd = pack(zstd_2d, dyn_phy) |
| 197 |
zsig = pack(zsig_2d, dyn_phy) |
| 198 |
zgam = pack(zgam_2d, dyn_phy) |
| 199 |
zthe = pack(zthe_2d, dyn_phy) |
| 200 |
zpic = pack(zpic_2d, dyn_phy) |
| 201 |
zval = pack(zval_2d, dyn_phy) |
| 202 |
|
| 203 |
! On initialise les sous-surfaces. |
| 204 |
! Lecture du fichier glace de terre pour fixer la fraction de terre |
| 205 |
! et de glace de terre : |
| 206 |
|
| 207 |
call nf95_open("landiceref.nc", nf90_nowrite, ncid) |
| 208 |
|
| 209 |
call nf95_inq_varid(ncid, 'longitude', varid) |
| 210 |
call nf95_gw_var(ncid, varid, dlon_lic) |
| 211 |
iml_lic = size(dlon_lic) |
| 212 |
|
| 213 |
call nf95_inq_varid(ncid, 'latitude', varid) |
| 214 |
call nf95_gw_var(ncid, varid, dlat_lic) |
| 215 |
jml_lic = size(dlat_lic) |
| 216 |
|
| 217 |
call nf95_inq_varid(ncid, 'landice', varid) |
| 218 |
ALLOCATE(fraclic(iml_lic, jml_lic)) |
| 219 |
call nf95_get_var(ncid, varid, fraclic) |
| 220 |
|
| 221 |
call nf95_close(ncid) |
| 222 |
|
| 223 |
! Interpolation sur la grille T du mod\`ele : |
| 224 |
PRINT *, 'Dimensions de "landiceref.nc"' |
| 225 |
print *, "iml_lic = ", iml_lic |
| 226 |
print *, "jml_lic = ", jml_lic |
| 227 |
|
| 228 |
! Si les coordonn\'ees sont en degr\'es, on les transforme : |
| 229 |
IF (MAXVAL(dlon_lic) > pi) THEN |
| 230 |
dlon_lic = dlon_lic * pi / 180. |
| 231 |
ENDIF |
| 232 |
IF (maxval(dlat_lic) > pi) THEN |
| 233 |
dlat_lic = dlat_lic * pi/ 180. |
| 234 |
ENDIF |
| 235 |
|
| 236 |
flic_tmp(:iim, :) = grille_m(dlon_lic, dlat_lic, fraclic, rlonv(:iim), & |
| 237 |
rlatu) |
| 238 |
flic_tmp(iim + 1, :) = flic_tmp(1, :) |
| 239 |
|
| 240 |
! Passage sur la grille physique : |
| 241 |
pctsrf = 0. |
| 242 |
pctsrf(:, is_lic) = pack(flic_tmp, dyn_phy) |
| 243 |
|
| 244 |
! Ad\'equation avec le maque terre/mer : |
| 245 |
WHERE (pctsrf(:, is_lic) < EPSFRA) pctsrf(:, is_lic) = 0. |
| 246 |
WHERE (zmasq < EPSFRA) pctsrf(:, is_lic) = 0. |
| 247 |
where (zmasq <= EPSFRA) pctsrf(:, is_ter) = zmasq |
| 248 |
where (zmasq > EPSFRA) |
| 249 |
where (pctsrf(:, is_lic) >= zmasq) |
| 250 |
pctsrf(:, is_lic) = zmasq |
| 251 |
pctsrf(:, is_ter) = 0. |
| 252 |
elsewhere |
| 253 |
pctsrf(:, is_ter) = zmasq - pctsrf(:, is_lic) |
| 254 |
where (pctsrf(:, is_ter) < EPSFRA) |
| 255 |
pctsrf(:, is_ter) = 0. |
| 256 |
pctsrf(:, is_lic) = zmasq |
| 257 |
end where |
| 258 |
end where |
| 259 |
end where |
| 260 |
|
| 261 |
! Sous-surface oc\'ean et glace de mer (pour d\'emarrer on met glace |
| 262 |
! de mer \`a 0) : |
| 263 |
pctsrf(:, is_oce) = 1. - zmasq |
| 264 |
WHERE (pctsrf(:, is_oce) < EPSFRA) pctsrf(:, is_oce) = 0. |
| 265 |
|
| 266 |
! V\'erification que la somme des sous-surfaces vaut 1 : |
| 267 |
ji = count(abs(sum(pctsrf, dim = 2) - 1.) > EPSFRA) |
| 268 |
IF (ji /= 0) then |
| 269 |
PRINT *, 'Bad surface percentages for ', ji, 'points' |
| 270 |
end IF |
| 271 |
|
| 272 |
! Calcul interm\'ediaire : |
| 273 |
CALL massdair(p3d, masse) |
| 274 |
|
| 275 |
forall (l = 1:llm) |
| 276 |
masse(:, 1, l) = SUM(aire_2d(:iim, 1) * masse(:iim, 1, l)) / apoln |
| 277 |
masse(:, jjm + 1, l) = & |
| 278 |
SUM(aire_2d(:iim, jjm + 1) * masse(:iim, jjm + 1, l)) / apols |
| 279 |
END forall |
| 280 |
|
| 281 |
call iniadvtrac |
| 282 |
CALL geopot(teta, pk , pks, phis, phi) |
| 283 |
CALL caldyn0(ucov, vcov, teta, ps, pk, phis, phi) |
| 284 |
CALL dynredem0(day_ref, phis) |
| 285 |
CALL dynredem1(vcov, ucov, teta, q, masse, ps, itau = 0) |
| 286 |
|
| 287 |
! Initialisations : |
| 288 |
snsrf = 0. |
| 289 |
albe(:, is_ter) = 0.08 |
| 290 |
albe(:, is_lic) = 0.6 |
| 291 |
albe(:, is_oce) = 0.5 |
| 292 |
albe(:, is_sic) = 0.6 |
| 293 |
evap = 0. |
| 294 |
qsolsrf = 150. |
| 295 |
tsoil = spread(spread(pack(tsol_2d, dyn_phy), 2, nsoilmx), 3, nbsrf) |
| 296 |
solsw = 165. |
| 297 |
sollw = -53. |
| 298 |
t_ancien = 273.15 |
| 299 |
q_ancien = 0. |
| 300 |
agesno = 0. |
| 301 |
|
| 302 |
frugs(:, is_oce) = rugmer |
| 303 |
frugs(:, is_ter) = MAX(1e-5, zstd * zsig / 2) |
| 304 |
frugs(:, is_lic) = MAX(1e-5, zstd * zsig / 2) |
| 305 |
frugs(:, is_sic) = 0.001 |
| 306 |
clwcon = 0. |
| 307 |
rnebcon = 0. |
| 308 |
ratqs = 0. |
| 309 |
sig1 = 0. |
| 310 |
w01 = 0. |
| 311 |
|
| 312 |
nday = 0 |
| 313 |
call phyredem0 |
| 314 |
|
| 315 |
call nf95_inq_varid(ncid_restartphy, "trs", varid) |
| 316 |
call nf95_put_var(ncid_restartphy, varid, null_array) |
| 317 |
|
| 318 |
call phyredem(pctsrf, tsoil(:, 1, :), tsoil, qsolsrf, & |
| 319 |
pack(qsol_2d, dyn_phy), snsrf, albe, evap, null_array, null_array, & |
| 320 |
solsw, sollw, null_array, null_array, frugs, agesno, zmea, zstd, & |
| 321 |
zsig, zgam, zthe, zpic, zval, t_ancien, q_ancien, rnebcon, ratqs, & |
| 322 |
clwcon, null_array, sig1, w01) |
| 323 |
|
| 324 |
END SUBROUTINE etat0 |
| 325 |
|
| 326 |
end module etat0_m |
Parent Directory
| 
Revision Log