| 1 |
PROGRAM gcm |
| 2 |
|
| 3 |
! Authors: P. Le Van, L. Fairhead, F. Hourdin |
| 4 |
! From "gcm.F", version 1.4, 2006/04/04 15:05:16 |
| 5 |
|
| 6 |
! General circulation model of LMD. Avec coordonnée verticale |
| 7 |
! hybride, avec nouveaux opérateurs de dissipation "*" ("gradiv2", |
| 8 |
! "divgrad2", "nxgraro2"). Possibilité de choisir le schéma pour |
| 9 |
! l'advection de "q", en modifiant "iadv" dans "traceur.def". |
| 10 |
|
| 11 |
USE calendar, only: ioconf_calendar |
| 12 |
use comconst, only: daysec, cpp, dtvr, g, rad, r |
| 13 |
use comgeom, only: rlatu, aire_2d, cu_2d, cv_2d, rlonv, inigeom |
| 14 |
use comgeomphy, only: airephy, cuphy, cvphy, rlatd, rlond |
| 15 |
use conf_gcm_m, only: day_step, iperiod, anneeref, dayref, iecri, iphysiq, & |
| 16 |
nday, raz_date, periodav, conf_gcm, iflag_phys |
| 17 |
use dimens_m, only: iim, jjm, llm, nqmx |
| 18 |
use dimphy, only: klon |
| 19 |
use dynetat0_m, only: dynetat0, day_ini |
| 20 |
use dynredem0_m, only: dynredem0 |
| 21 |
use grid_change, only: dyn_phy, init_dyn_phy |
| 22 |
use histclo_m, only: histclo |
| 23 |
use iniadvtrac_m, only: iniadvtrac |
| 24 |
use inidissip_m, only: inidissip |
| 25 |
use inifilr_m, only: inifilr |
| 26 |
use initdynav_m, only: initdynav |
| 27 |
use inithist_m, only: inithist |
| 28 |
use init_dynzon_m, only: init_dynzon |
| 29 |
use jumble, only: new_unit |
| 30 |
use leapfrog_m, only: leapfrog |
| 31 |
use suphec_m, only: suphec |
| 32 |
use temps, only: day_ref, annee_ref, day_end, itau_dyn |
| 33 |
use tracstoke, only: istdyn, istphy |
| 34 |
use unit_nml_m, only: unit_nml |
| 35 |
use yoethf_m, only: yoethf |
| 36 |
|
| 37 |
IMPLICIT NONE |
| 38 |
|
| 39 |
REAL zdtvr ! time step for dynamics, in s |
| 40 |
|
| 41 |
! Variables dynamiques : |
| 42 |
REAL ucov(iim + 1, jjm + 1, llm), vcov(iim + 1, jjm, llm) ! vent covariant |
| 43 |
REAL teta(iim + 1, jjm + 1, llm) ! température potentielle |
| 44 |
REAL q(iim + 1, jjm + 1, llm, nqmx) ! champs advectés |
| 45 |
REAL ps(iim + 1, jjm + 1) ! pression au sol (Pa) |
| 46 |
REAL masse(iim + 1, jjm + 1, llm) ! masse d'air |
| 47 |
REAL phis(iim + 1, jjm + 1) ! géopotentiel au sol |
| 48 |
|
| 49 |
! Variables pour le fichier histoire : |
| 50 |
REAL time_0 ! time in day, as a fraction of day, in [0, 1[ |
| 51 |
|
| 52 |
! Calendrier : |
| 53 |
LOGICAL:: true_calendar = .false. ! default value |
| 54 |
|
| 55 |
logical mask_v(iim + 1, jjm) |
| 56 |
! (mask for points in the "v" grid, first index is for longitude, |
| 57 |
! second index is for latitude) |
| 58 |
|
| 59 |
namelist /main_nml/true_calendar |
| 60 |
|
| 61 |
!------------------------------------------------------------ |
| 62 |
|
| 63 |
call new_unit(unit_nml) |
| 64 |
open(unit_nml, file="used_namelists", status="replace", action="write") |
| 65 |
|
| 66 |
CALL conf_gcm |
| 67 |
|
| 68 |
print *, "Enter namelist 'main_nml'." |
| 69 |
read (unit=*, nml=main_nml) |
| 70 |
write(unit_nml, nml=main_nml) |
| 71 |
|
| 72 |
! Choix du calendrier : |
| 73 |
if (true_calendar) then |
| 74 |
call ioconf_calendar('gregorian') |
| 75 |
else |
| 76 |
call ioconf_calendar('360d') |
| 77 |
endif |
| 78 |
|
| 79 |
! Initialisation des traceurs |
| 80 |
! Choix du schéma pour l'advection dans le fichier "traceur.def" ou via INCA |
| 81 |
call iniadvtrac |
| 82 |
|
| 83 |
! Lecture du fichier "start.nc" : |
| 84 |
CALL dynetat0(vcov, ucov, teta, q, masse, ps, phis, time_0) |
| 85 |
|
| 86 |
! On remet le calendrier à zero si demandé : |
| 87 |
if (annee_ref /= anneeref .or. day_ref /= dayref) then |
| 88 |
print *, 'Attention : les dates initiales lues dans le fichier ' // & |
| 89 |
'"start" ne correspondent pas à celles lues dans "gcm.def".' |
| 90 |
if (raz_date) then |
| 91 |
print *, 'On réinitialise à la date lue dans "gcm.def".' |
| 92 |
annee_ref = anneeref |
| 93 |
day_ref = dayref |
| 94 |
day_ini = dayref |
| 95 |
itau_dyn = 0 |
| 96 |
time_0 = 0. |
| 97 |
else |
| 98 |
print *, 'On garde les dates du fichier "start".' |
| 99 |
endif |
| 100 |
ELSE |
| 101 |
raz_date = .false. |
| 102 |
endif |
| 103 |
|
| 104 |
! On recalcule éventuellement le pas de temps : |
| 105 |
zdtvr = daysec / REAL(day_step) |
| 106 |
IF (dtvr /= zdtvr) THEN |
| 107 |
print *, 'Warning: the time steps in the ".def" file and in ' // & |
| 108 |
'"start.nc" are different' |
| 109 |
print *, 'dtvr (from "start.nc") = ', dtvr |
| 110 |
print *, 'zdtvr (from ".def") = ', zdtvr |
| 111 |
print *, 'Using the value from the ".def" file.' |
| 112 |
dtvr = zdtvr |
| 113 |
ENDIF |
| 114 |
|
| 115 |
CALL iniconst |
| 116 |
CALL inigeom ! initialisation de la géometrie |
| 117 |
CALL inifilr ! initialisation du filtre |
| 118 |
CALL inidissip |
| 119 |
call init_dyn_phy |
| 120 |
|
| 121 |
! Initialisation de la physique : |
| 122 |
IF (iflag_phys == 1) THEN |
| 123 |
rlatd(1)=rlatu(1) |
| 124 |
rlatd(2:klon-1) = pack(spread(rlatu(2:jjm), 1, iim), .true.) |
| 125 |
rlatd(klon)= rlatu(jjm + 1) |
| 126 |
|
| 127 |
rlond(1)=0. |
| 128 |
rlond(2:klon-1) = pack(spread(rlonv(:iim), 2, jjm - 1), .true.) |
| 129 |
rlond(klon)= 0. |
| 130 |
|
| 131 |
cuphy = pack(cu_2d, dyn_phy) |
| 132 |
|
| 133 |
! Construct a mask for points in the "v" grid: |
| 134 |
mask_v = .true. |
| 135 |
mask_v(2:, 1) = .false. |
| 136 |
mask_v(iim + 1, 2:) = .false. |
| 137 |
|
| 138 |
cvphy(:klon - 1) = pack(cv_2d, mask_v) |
| 139 |
cvphy(klon) = cv_2d(1, jjm) |
| 140 |
! (that value of "cv_2d" is used twice in "cvphy") |
| 141 |
|
| 142 |
airephy = pack(aire_2d, dyn_phy) |
| 143 |
CALL suphec |
| 144 |
call yoethf |
| 145 |
ENDIF |
| 146 |
|
| 147 |
! Initialisation des entrées-sorties : |
| 148 |
day_end = day_ini + nday |
| 149 |
print *, "day_ini = ", day_ini |
| 150 |
print *, "day_end = ", day_end |
| 151 |
|
| 152 |
CALL dynredem0("restart.nc", day_end, phis) |
| 153 |
CALL inithist(day_ref, annee_ref, zdtvr, nqmx, t_ops = iecri * daysec, & |
| 154 |
t_wrt = iecri * daysec) |
| 155 |
CALL initdynav(day_ref, annee_ref, zdtvr, nqmx, t_ops = iperiod * zdtvr, & |
| 156 |
t_wrt = periodav * daysec) |
| 157 |
call init_dynzon(dt_app = dtvr * iperiod) |
| 158 |
|
| 159 |
! Choix des fréquences de stockage pour le hors-ligne : |
| 160 |
istdyn = day_step / 4 ! stockage toutes les 6 h = 1 jour / 4 |
| 161 |
istphy = istdyn / iphysiq |
| 162 |
|
| 163 |
! Intégration temporelle du modèle : |
| 164 |
CALL leapfrog(ucov, vcov, teta, ps, masse, phis, q, time_0) |
| 165 |
|
| 166 |
close(unit_nml) |
| 167 |
call histclo |
| 168 |
print *, 'Simulation finished' |
| 169 |
print *, 'Everything is cool' |
| 170 |
|
| 171 |
END PROGRAM gcm |
Parent Directory
| 
Revision Log