| 1 |
module invert_zoom_x_m |
| 2 |
|
| 3 |
implicit none |
| 4 |
|
| 5 |
INTEGER, PARAMETER:: nmax = 30000 |
| 6 |
DOUBLE PRECISION abs_y |
| 7 |
|
| 8 |
private abs_y, funcd |
| 9 |
|
| 10 |
contains |
| 11 |
|
| 12 |
subroutine invert_zoom_x(beta, xf, xtild, G, xlon, xprim, xuv) |
| 13 |
|
| 14 |
use coefpoly_m, only: coefpoly, a1, a2, a3 |
| 15 |
USE dimens_m, ONLY: iim |
| 16 |
use dynetat0_m, only: clon, grossismx |
| 17 |
use nr_util, only: pi_d, twopi_d |
| 18 |
use numer_rec_95, only: hunt, rtsafe |
| 19 |
|
| 20 |
DOUBLE PRECISION, intent(in):: beta, Xf(0:), xtild(0:), G(0:) ! (0:nmax) |
| 21 |
|
| 22 |
real, intent(out):: xlon(:), xprim(:) ! (iim) |
| 23 |
|
| 24 |
DOUBLE PRECISION, intent(in):: xuv |
| 25 |
! between - 0.25 and 0.5 |
| 26 |
! 0. si calcul aux points scalaires |
| 27 |
! 0.5 si calcul aux points U |
| 28 |
|
| 29 |
! Local: |
| 30 |
DOUBLE PRECISION Y |
| 31 |
DOUBLE PRECISION h ! step of the uniform grid |
| 32 |
integer i, it |
| 33 |
|
| 34 |
DOUBLE PRECISION xvrai(iim), Gvrai(iim) |
| 35 |
! intermediary variables because xlon and xprim are single precision |
| 36 |
|
| 37 |
!------------------------------------------------------------------ |
| 38 |
|
| 39 |
print *, "Call sequence information: invert_zoom_x" |
| 40 |
it = 0 ! initial guess |
| 41 |
h = twopi_d / iim |
| 42 |
|
| 43 |
DO i = 1, iim |
| 44 |
Y = - pi_d + (i + xuv - 0.75d0) * h |
| 45 |
! - pi <= y < pi |
| 46 |
abs_y = abs(y) |
| 47 |
|
| 48 |
! Distinguish boundaries in order to avoid roundoff error. |
| 49 |
! funcd should be exactly equal to 0 at xtild(it) or xtild(it + |
| 50 |
! 1) and could be very small with the wrong sign so rtsafe |
| 51 |
! would fail. |
| 52 |
if (abs_y == 0d0) then |
| 53 |
xvrai(i) = 0d0 |
| 54 |
gvrai(i) = grossismx |
| 55 |
else if (abs_y == pi_d) then |
| 56 |
xvrai(i) = pi_d |
| 57 |
gvrai(i) = 2d0 * beta - grossismx |
| 58 |
else |
| 59 |
call hunt(xf, abs_y, it, my_lbound = 0) |
| 60 |
! {0 <= it <= nmax - 1} |
| 61 |
|
| 62 |
! Calcul de xvrai(i) et Gvrai(i) |
| 63 |
CALL coefpoly(Xf(it), Xf(it + 1), G(it), G(it + 1), xtild(it), & |
| 64 |
xtild(it + 1)) |
| 65 |
xvrai(i) = rtsafe(funcd, xtild(it), xtild(it + 1), xacc = 1d-6) |
| 66 |
Gvrai(i) = a1 + xvrai(i) * (2d0 * a2 + xvrai(i) * 3d0 * a3) |
| 67 |
end if |
| 68 |
|
| 69 |
if (y < 0d0) xvrai(i) = - xvrai(i) |
| 70 |
end DO |
| 71 |
|
| 72 |
DO i = 1, iim -1 |
| 73 |
IF (xvrai(i + 1) < xvrai(i)) THEN |
| 74 |
print *, 'xvrai(', i + 1, ') < xvrai(', i, ')' |
| 75 |
STOP 1 |
| 76 |
END IF |
| 77 |
END DO |
| 78 |
|
| 79 |
xlon = xvrai + clon |
| 80 |
xprim = h / Gvrai |
| 81 |
|
| 82 |
end subroutine invert_zoom_x |
| 83 |
|
| 84 |
!********************************************************************** |
| 85 |
|
| 86 |
SUBROUTINE funcd(x, fval, fderiv) |
| 87 |
|
| 88 |
use coefpoly_m, only: a0, a1, a2, a3 |
| 89 |
|
| 90 |
DOUBLE PRECISION, INTENT(IN):: x |
| 91 |
DOUBLE PRECISION, INTENT(OUT):: fval, fderiv |
| 92 |
|
| 93 |
fval = a0 + x * (a1 + x * (a2 + x * a3)) - abs_y |
| 94 |
fderiv = a1 + x * (2d0 * a2 + x * 3d0 * a3) |
| 95 |
|
| 96 |
END SUBROUTINE funcd |
| 97 |
|
| 98 |
end module invert_zoom_x_m |
Parent Directory
| 
Revision Log