trunk/dyn3d/leapfrog.f

module leapfrog_m

  IMPLICIT NONE

contains

  SUBROUTINE leapfrog(ucov, vcov, teta, ps, masse, phis, q, time_0)

    ! From dyn3d/leapfrog.F, version 1.6, 2005/04/13 08:58:34
    ! Authors: P. Le Van, L. Fairhead, F. Hourdin
    ! schema matsuno + leapfrog

    USE calfis_m, ONLY: calfis
    USE com_io_dyn, ONLY: histaveid
    USE comconst, ONLY: daysec, dtphys, dtvr
    USE comgeom, ONLY: aire_2d, apoln, apols
    USE comvert, ONLY: ap, bp
    USE conf_gcm_m, ONLY: day_step, iconser, iperiod, iphysiq, nday, offline, &
         periodav
    USE dimens_m, ONLY: iim, jjm, llm, nqmx
    USE dynetat0_m, ONLY: day_ini
    use dynredem1_m, only: dynredem1
    USE exner_hyb_m, ONLY: exner_hyb
    use filtreg_m, only: filtreg
    USE guide_m, ONLY: guide
    use inidissip_m, only: idissip
    use integrd_m, only: integrd
    USE logic, ONLY: iflag_phys, ok_guide
    USE paramet_m, ONLY: ip1jmp1
    USE pression_m, ONLY: pression
    USE pressure_var, ONLY: p3d
    USE temps, ONLY: itau_dyn

    ! Variables dynamiques:
    REAL, intent(inout):: vcov((iim + 1) * jjm, llm) ! vent covariant
    REAL, intent(inout):: ucov(ip1jmp1, llm) ! vent covariant
    REAL, intent(inout):: teta(iim + 1, jjm + 1, llm) ! potential temperature
    REAL ps(iim + 1, jjm + 1) ! pression au sol, en Pa

    REAL masse(ip1jmp1, llm) ! masse d'air
    REAL phis(ip1jmp1) ! geopotentiel au sol
    REAL q(ip1jmp1, llm, nqmx) ! mass fractions of advected fields
    REAL, intent(in):: time_0

    ! Variables local to the procedure:

    ! Variables dynamiques:

    REAL pks(ip1jmp1) ! exner au sol
    REAL pk(iim + 1, jjm + 1, llm) ! exner au milieu des couches
    REAL pkf(ip1jmp1, llm) ! exner filt.au milieu des couches
    REAL phi(ip1jmp1, llm) ! geopotential
    REAL w(ip1jmp1, llm) ! vitesse verticale

    ! variables dynamiques intermediaire pour le transport
    REAL pbaru(ip1jmp1, llm), pbarv((iim + 1) * jjm, llm) !flux de masse

    ! variables dynamiques au pas - 1
    REAL vcovm1((iim + 1) * jjm, llm), ucovm1(ip1jmp1, llm)
    REAL tetam1(iim + 1, jjm + 1, llm), psm1(iim + 1, jjm + 1)
    REAL massem1(ip1jmp1, llm)

    ! tendances dynamiques
    REAL dv((iim + 1) * jjm, llm), du(ip1jmp1, llm)
    REAL dteta(ip1jmp1, llm), dq(ip1jmp1, llm, nqmx), dp(ip1jmp1)

    ! tendances de la dissipation
    REAL dvdis((iim + 1) * jjm, llm), dudis(ip1jmp1, llm)
    REAL dtetadis(iim + 1, jjm + 1, llm)

    ! tendances physiques
    REAL dvfi((iim + 1) * jjm, llm), dufi(ip1jmp1, llm)
    REAL dtetafi(ip1jmp1, llm), dqfi(ip1jmp1, llm, nqmx), dpfi(ip1jmp1)

    ! variables pour le fichier histoire

    INTEGER itau ! index of the time step of the dynamics, starts at 0
    INTEGER itaufin
    INTEGER iday ! jour julien
    REAL time ! time of day, as a fraction of day length
    real finvmaold(ip1jmp1, llm)
    LOGICAL:: lafin=.false.
    INTEGER i, j, l

    REAL rdayvrai, rdaym_ini

    ! Variables test conservation energie
    REAL ecin(iim + 1, jjm + 1, llm), ecin0(iim + 1, jjm + 1, llm)
    ! Tendance de la temp. potentiel d (theta) / d t due a la 
    ! tansformation d'energie cinetique en energie thermique
    ! cree par la dissipation
    REAL dtetaecdt(iim + 1, jjm + 1, llm)
    REAL vcont((iim + 1) * jjm, llm), ucont(ip1jmp1, llm)

    !---------------------------------------------------

    print *, "Call sequence information: leapfrog"

    itaufin = nday * day_step
    ! "day_step" is a multiple of "iperiod", therefore "itaufin" is one too

    itau = 0
    iday = day_ini
    time = time_0
    dq = 0.
    ! On initialise la pression et la fonction d'Exner :
    CALL pression(ip1jmp1, ap, bp, ps, p3d)
    CALL exner_hyb(ps, p3d, pks, pk, pkf)

    ! Début de l'integration temporelle :
    period_loop:do i = 1, itaufin / iperiod
       ! {"itau" is a multiple of "iperiod"}

       ! 1. Matsuno forward:

       if (ok_guide .and. (itaufin - itau - 1) * dtvr > 21600.) &
            call guide(itau, ucov, vcov, teta, q, masse, ps)
       vcovm1 = vcov
       ucovm1 = ucov
       tetam1 = teta
       massem1 = masse
       psm1 = ps
       finvmaold = masse
       CALL filtreg(finvmaold, jjm + 1, llm, - 2, 2, .TRUE., 1)

       ! Calcul des tendances dynamiques:
       CALL geopot(ip1jmp1, teta, pk, pks, phis, phi)
       CALL caldyn(itau, ucov, vcov, teta, ps, masse, pk, pkf, phis, phi, &
            MOD(itau, iconser) == 0, du, dv, dteta, dp, w, pbaru, pbarv, &
            time + iday - day_ini)

       ! Calcul des tendances advection des traceurs (dont l'humidité)
       CALL caladvtrac(q, pbaru, pbarv, p3d, masse, dq, teta, pk)
       ! Stokage du flux de masse pour traceurs offline:
       IF (offline) CALL fluxstokenc(pbaru, pbarv, masse, teta, phi, phis, &
            dtvr, itau)

       ! integrations dynamique et traceurs:
       CALL integrd(2, vcovm1, ucovm1, tetam1, psm1, massem1, dv, du, dteta, &
            dp, vcov, ucov, teta, q, ps, masse, finvmaold, .false., &
            dtvr)

       CALL pression(ip1jmp1, ap, bp, ps, p3d)
       CALL exner_hyb(ps, p3d, pks, pk, pkf)

       ! 2. Matsuno backward:

       itau = itau + 1
       iday = day_ini + itau / day_step
       time = REAL(itau - (iday - day_ini) * day_step) / day_step + time_0
       IF (time > 1.) THEN
          time = time - 1.
          iday = iday + 1
       ENDIF

       ! Calcul des tendances dynamiques:
       CALL geopot(ip1jmp1, teta, pk, pks, phis, phi)
       CALL caldyn(itau, ucov, vcov, teta, ps, masse, pk, pkf, phis, phi, &
            .false., du, dv, dteta, dp, w, pbaru, pbarv, time + iday - day_ini)

       ! integrations dynamique et traceurs:
       CALL integrd(2, vcovm1, ucovm1, tetam1, psm1, massem1, dv, du, dteta, &
            dp, vcov, ucov, teta, q, ps, masse, finvmaold, .false., &
            dtvr)

       CALL pression(ip1jmp1, ap, bp, ps, p3d)
       CALL exner_hyb(ps, p3d, pks, pk, pkf)

       ! 3. Leapfrog:

       leapfrog_loop: do j = 1, iperiod - 1
          ! Calcul des tendances dynamiques:
          CALL geopot(ip1jmp1, teta, pk, pks, phis, phi)
          CALL caldyn(itau, ucov, vcov, teta, ps, masse, pk, pkf, phis, phi, &
               .false., du, dv, dteta, dp, w, pbaru, pbarv, &
               time + iday - day_ini)

          ! Calcul des tendances advection des traceurs (dont l'humidité)
          CALL caladvtrac(q, pbaru, pbarv, p3d, masse, dq, teta, pk)
          ! Stokage du flux de masse pour traceurs off-line:
          IF (offline) CALL fluxstokenc(pbaru, pbarv, masse, teta, phi, phis, &
               dtvr, itau)

          ! integrations dynamique et traceurs:
          CALL integrd(2, vcovm1, ucovm1, tetam1, psm1, massem1, dv, du, &
               dteta, dp, vcov, ucov, teta, q, ps, masse, &
               finvmaold, .true., 2 * dtvr)

          IF (MOD(itau + 1, iphysiq) == 0 .AND. iflag_phys /= 0) THEN
             ! calcul des tendances physiques:
             IF (itau + 1 == itaufin) lafin = .TRUE.

             CALL pression(ip1jmp1, ap, bp, ps, p3d)
             CALL exner_hyb(ps, p3d, pks, pk, pkf)

             rdaym_ini = itau * dtvr / daysec
             rdayvrai = rdaym_ini + day_ini

             CALL calfis(nqmx, lafin, rdayvrai, time, ucov, vcov, teta, q, &
                  masse, ps, pk, phis, phi, du, dv, dteta, dq, w, &
                  dufi, dvfi, dtetafi, dqfi, dpfi)

             ! ajout des tendances physiques:
             CALL addfi(nqmx, dtphys, ucov, vcov, teta, q, ps, dufi, dvfi, &
                  dtetafi, dqfi, dpfi)
          ENDIF

          CALL pression(ip1jmp1, ap, bp, ps, p3d)
          CALL exner_hyb(ps, p3d, pks, pk, pkf)

          IF (MOD(itau + 1, idissip) == 0) THEN
             ! dissipation horizontale et verticale des petites echelles:

             ! calcul de l'energie cinetique avant dissipation
             call covcont(llm, ucov, vcov, ucont, vcont)
             call enercin(vcov, ucov, vcont, ucont, ecin0)

             ! dissipation
             CALL dissip(vcov, ucov, teta, p3d, dvdis, dudis, dtetadis)
             ucov=ucov + dudis
             vcov=vcov + dvdis

             ! On rajoute la tendance due à la transformation Ec -> E
             ! thermique créée lors de la dissipation
             call covcont(llm, ucov, vcov, ucont, vcont)
             call enercin(vcov, ucov, vcont, ucont, ecin)
             dtetaecdt= (ecin0 - ecin) / pk
             dtetadis=dtetadis + dtetaecdt
             teta=teta + dtetadis

             ! Calcul de la valeur moyenne aux pôles :
             forall (l = 1: llm)
                teta(:, 1, l) = SUM(aire_2d(:iim, 1) * teta(:iim, 1, l)) &
                     / apoln
                teta(:, jjm + 1, l) = SUM(aire_2d(:iim, jjm+1) &
                     * teta(:iim, jjm + 1, l)) / apols
             END forall

             ps(:, 1) = SUM(aire_2d(:iim, 1) * ps(:iim, 1)) / apoln
             ps(:, jjm + 1) = SUM(aire_2d(:iim, jjm+1) * ps(:iim, jjm + 1)) &
                  / apols
          END IF

          itau = itau + 1
          iday = day_ini + itau / day_step
          time = REAL(itau - (iday - day_ini) * day_step) / day_step + time_0
          IF (time > 1.) THEN
             time = time - 1.
             iday = iday + 1
          ENDIF

          IF (MOD(itau, iperiod) == 0) THEN
             ! ecriture du fichier histoire moyenne:
             CALL writedynav(histaveid, nqmx, itau, vcov, &
                  ucov, teta, pk, phi, q, masse, ps, phis)
             call bilan_dyn(2, dtvr * iperiod, dtvr * day_step * periodav, &
                  ps, masse, pk, pbaru, pbarv, teta, phi, ucov, vcov, q)
          ENDIF
       end do leapfrog_loop
    end do period_loop

    ! {itau == itaufin}
    CALL dynredem1("restart.nc", vcov, ucov, teta, q, masse, ps, &
         itau=itau_dyn+itaufin)

    ! Calcul des tendances dynamiques:
    CALL geopot(ip1jmp1, teta, pk, pks, phis, phi)
    CALL caldyn(itaufin, ucov, vcov, teta, ps, masse, pk, pkf, phis, phi, &
         MOD(itaufin, iconser) == 0, du, dv, dteta, dp, w, pbaru, pbarv, &
         time + iday - day_ini)

  END SUBROUTINE leapfrog

end module leapfrog_m
1	module leapfrog_m
2
3	IMPLICIT NONE
4
5	contains
6
7	SUBROUTINE leapfrog(ucov, vcov, teta, ps, masse, phis, q, time_0)
8
9	! From dyn3d/leapfrog.F, version 1.6, 2005/04/13 08:58:34
10	! Authors: P. Le Van, L. Fairhead, F. Hourdin
11	! schema matsuno + leapfrog
12
13	USE calfis_m, ONLY: calfis
14	USE com_io_dyn, ONLY: histaveid
15	USE comconst, ONLY: daysec, dtphys, dtvr
16	USE comgeom, ONLY: aire_2d, apoln, apols
17	USE comvert, ONLY: ap, bp
18	USE conf_gcm_m, ONLY: day_step, iconser, iperiod, iphysiq, nday, offline, &
19	periodav
20	USE dimens_m, ONLY: iim, jjm, llm, nqmx
21	USE dynetat0_m, ONLY: day_ini
22	use dynredem1_m, only: dynredem1
23	USE exner_hyb_m, ONLY: exner_hyb
24	use filtreg_m, only: filtreg
25	USE guide_m, ONLY: guide
26	use inidissip_m, only: idissip
27	use integrd_m, only: integrd
28	USE logic, ONLY: iflag_phys, ok_guide
29	USE paramet_m, ONLY: ip1jmp1
30	USE pression_m, ONLY: pression
31	USE pressure_var, ONLY: p3d
32	USE temps, ONLY: itau_dyn
33
34	! Variables dynamiques:
35	REAL, intent(inout):: vcov((iim + 1) * jjm, llm) ! vent covariant
36	REAL, intent(inout):: ucov(ip1jmp1, llm) ! vent covariant
37	REAL, intent(inout):: teta(iim + 1, jjm + 1, llm) ! potential temperature
38	REAL ps(iim + 1, jjm + 1) ! pression au sol, en Pa
39
40	REAL masse(ip1jmp1, llm) ! masse d'air
41	REAL phis(ip1jmp1) ! geopotentiel au sol
42	REAL q(ip1jmp1, llm, nqmx) ! mass fractions of advected fields
43	REAL, intent(in):: time_0
44
45	! Variables local to the procedure:
46
47	! Variables dynamiques:
48
49	REAL pks(ip1jmp1) ! exner au sol
50	REAL pk(iim + 1, jjm + 1, llm) ! exner au milieu des couches
51	REAL pkf(ip1jmp1, llm) ! exner filt.au milieu des couches
52	REAL phi(ip1jmp1, llm) ! geopotential
53	REAL w(ip1jmp1, llm) ! vitesse verticale
54
55	! variables dynamiques intermediaire pour le transport
56	REAL pbaru(ip1jmp1, llm), pbarv((iim + 1) * jjm, llm) !flux de masse
57
58	! variables dynamiques au pas - 1
59	REAL vcovm1((iim + 1) * jjm, llm), ucovm1(ip1jmp1, llm)
60	REAL tetam1(iim + 1, jjm + 1, llm), psm1(iim + 1, jjm + 1)
61	REAL massem1(ip1jmp1, llm)
62
63	! tendances dynamiques
64	REAL dv((iim + 1) * jjm, llm), du(ip1jmp1, llm)
65	REAL dteta(ip1jmp1, llm), dq(ip1jmp1, llm, nqmx), dp(ip1jmp1)
66
67	! tendances de la dissipation
68	REAL dvdis((iim + 1) * jjm, llm), dudis(ip1jmp1, llm)
69	REAL dtetadis(iim + 1, jjm + 1, llm)
70
71	! tendances physiques
72	REAL dvfi((iim + 1) * jjm, llm), dufi(ip1jmp1, llm)
73	REAL dtetafi(ip1jmp1, llm), dqfi(ip1jmp1, llm, nqmx), dpfi(ip1jmp1)
74
75	! variables pour le fichier histoire
76
77	INTEGER itau ! index of the time step of the dynamics, starts at 0
78	INTEGER itaufin
79	INTEGER iday ! jour julien
80	REAL time ! time of day, as a fraction of day length
81	real finvmaold(ip1jmp1, llm)
82	LOGICAL:: lafin=.false.
83	INTEGER i, j, l
84
85	REAL rdayvrai, rdaym_ini
86
87	! Variables test conservation energie
88	REAL ecin(iim + 1, jjm + 1, llm), ecin0(iim + 1, jjm + 1, llm)
89	! Tendance de la temp. potentiel d (theta) / d t due a la
90	! tansformation d'energie cinetique en energie thermique
91	! cree par la dissipation
92	REAL dtetaecdt(iim + 1, jjm + 1, llm)
93	REAL vcont((iim + 1) * jjm, llm), ucont(ip1jmp1, llm)
94
95	!---------------------------------------------------
96
97	print *, "Call sequence information: leapfrog"
98
99	itaufin = nday * day_step
100	! "day_step" is a multiple of "iperiod", therefore "itaufin" is one too
101
102	itau = 0
103	iday = day_ini
104	time = time_0
105	dq = 0.
106	! On initialise la pression et la fonction d'Exner :
107	CALL pression(ip1jmp1, ap, bp, ps, p3d)
108	CALL exner_hyb(ps, p3d, pks, pk, pkf)
109
110	! Début de l'integration temporelle :
111	period_loop:do i = 1, itaufin / iperiod
112	! {"itau" is a multiple of "iperiod"}
113
114	! 1. Matsuno forward:
115
116	if (ok_guide .and. (itaufin - itau - 1) * dtvr > 21600.) &
117	call guide(itau, ucov, vcov, teta, q, masse, ps)
118	vcovm1 = vcov
119	ucovm1 = ucov
120	tetam1 = teta
121	massem1 = masse
122	psm1 = ps
123	finvmaold = masse
124	CALL filtreg(finvmaold, jjm + 1, llm, - 2, 2, .TRUE., 1)
125
126	! Calcul des tendances dynamiques:
127	CALL geopot(ip1jmp1, teta, pk, pks, phis, phi)
128	CALL caldyn(itau, ucov, vcov, teta, ps, masse, pk, pkf, phis, phi, &
129	MOD(itau, iconser) == 0, du, dv, dteta, dp, w, pbaru, pbarv, &
130	time + iday - day_ini)
131
132	! Calcul des tendances advection des traceurs (dont l'humidité)
133	CALL caladvtrac(q, pbaru, pbarv, p3d, masse, dq, teta, pk)
134	! Stokage du flux de masse pour traceurs offline:
135	IF (offline) CALL fluxstokenc(pbaru, pbarv, masse, teta, phi, phis, &
136	dtvr, itau)
137
138	! integrations dynamique et traceurs:
139	CALL integrd(2, vcovm1, ucovm1, tetam1, psm1, massem1, dv, du, dteta, &
140	dp, vcov, ucov, teta, q, ps, masse, finvmaold, .false., &
141	dtvr)
142
143	CALL pression(ip1jmp1, ap, bp, ps, p3d)
144	CALL exner_hyb(ps, p3d, pks, pk, pkf)
145
146	! 2. Matsuno backward:
147
148	itau = itau + 1
149	iday = day_ini + itau / day_step
150	time = REAL(itau - (iday - day_ini) * day_step) / day_step + time_0
151	IF (time > 1.) THEN
152	time = time - 1.
153	iday = iday + 1
154	ENDIF
155
156	! Calcul des tendances dynamiques:
157	CALL geopot(ip1jmp1, teta, pk, pks, phis, phi)
158	CALL caldyn(itau, ucov, vcov, teta, ps, masse, pk, pkf, phis, phi, &
159	.false., du, dv, dteta, dp, w, pbaru, pbarv, time + iday - day_ini)
160
161	! integrations dynamique et traceurs:
162	CALL integrd(2, vcovm1, ucovm1, tetam1, psm1, massem1, dv, du, dteta, &
163	dp, vcov, ucov, teta, q, ps, masse, finvmaold, .false., &
164	dtvr)
165
166	CALL pression(ip1jmp1, ap, bp, ps, p3d)
167	CALL exner_hyb(ps, p3d, pks, pk, pkf)
168
169	! 3. Leapfrog:
170
171	leapfrog_loop: do j = 1, iperiod - 1
172	! Calcul des tendances dynamiques:
173	CALL geopot(ip1jmp1, teta, pk, pks, phis, phi)
174	CALL caldyn(itau, ucov, vcov, teta, ps, masse, pk, pkf, phis, phi, &
175	.false., du, dv, dteta, dp, w, pbaru, pbarv, &
176	time + iday - day_ini)
177
178	! Calcul des tendances advection des traceurs (dont l'humidité)
179	CALL caladvtrac(q, pbaru, pbarv, p3d, masse, dq, teta, pk)
180	! Stokage du flux de masse pour traceurs off-line:
181	IF (offline) CALL fluxstokenc(pbaru, pbarv, masse, teta, phi, phis, &
182	dtvr, itau)
183
184	! integrations dynamique et traceurs:
185	CALL integrd(2, vcovm1, ucovm1, tetam1, psm1, massem1, dv, du, &
186	dteta, dp, vcov, ucov, teta, q, ps, masse, &
187	finvmaold, .true., 2 * dtvr)
188
189	IF (MOD(itau + 1, iphysiq) == 0 .AND. iflag_phys /= 0) THEN
190	! calcul des tendances physiques:
191	IF (itau + 1 == itaufin) lafin = .TRUE.
192
193	CALL pression(ip1jmp1, ap, bp, ps, p3d)
194	CALL exner_hyb(ps, p3d, pks, pk, pkf)
195
196	rdaym_ini = itau * dtvr / daysec
197	rdayvrai = rdaym_ini + day_ini
198
199	CALL calfis(nqmx, lafin, rdayvrai, time, ucov, vcov, teta, q, &
200	masse, ps, pk, phis, phi, du, dv, dteta, dq, w, &
201	dufi, dvfi, dtetafi, dqfi, dpfi)
202
203	! ajout des tendances physiques:
204	CALL addfi(nqmx, dtphys, ucov, vcov, teta, q, ps, dufi, dvfi, &
205	dtetafi, dqfi, dpfi)
206	ENDIF
207
208	CALL pression(ip1jmp1, ap, bp, ps, p3d)
209	CALL exner_hyb(ps, p3d, pks, pk, pkf)
210
211	IF (MOD(itau + 1, idissip) == 0) THEN
212	! dissipation horizontale et verticale des petites echelles:
213
214	! calcul de l'energie cinetique avant dissipation
215	call covcont(llm, ucov, vcov, ucont, vcont)
216	call enercin(vcov, ucov, vcont, ucont, ecin0)
217
218	! dissipation
219	CALL dissip(vcov, ucov, teta, p3d, dvdis, dudis, dtetadis)
220	ucov=ucov + dudis
221	vcov=vcov + dvdis
222
223	! On rajoute la tendance due à la transformation Ec -> E
224	! thermique créée lors de la dissipation
225	call covcont(llm, ucov, vcov, ucont, vcont)
226	call enercin(vcov, ucov, vcont, ucont, ecin)
227	dtetaecdt= (ecin0 - ecin) / pk
228	dtetadis=dtetadis + dtetaecdt
229	teta=teta + dtetadis
230
231	! Calcul de la valeur moyenne aux pôles :
232	forall (l = 1: llm)
233	teta(:, 1, l) = SUM(aire_2d(:iim, 1) * teta(:iim, 1, l)) &
234	/ apoln
235	teta(:, jjm + 1, l) = SUM(aire_2d(:iim, jjm+1) &
236	* teta(:iim, jjm + 1, l)) / apols
237	END forall
238
239	ps(:, 1) = SUM(aire_2d(:iim, 1) * ps(:iim, 1)) / apoln
240	ps(:, jjm + 1) = SUM(aire_2d(:iim, jjm+1) * ps(:iim, jjm + 1)) &
241	/ apols
242	END IF
243
244	itau = itau + 1
245	iday = day_ini + itau / day_step
246	time = REAL(itau - (iday - day_ini) * day_step) / day_step + time_0
247	IF (time > 1.) THEN
248	time = time - 1.
249	iday = iday + 1
250	ENDIF
251
252	IF (MOD(itau, iperiod) == 0) THEN
253	! ecriture du fichier histoire moyenne:
254	CALL writedynav(histaveid, nqmx, itau, vcov, &
255	ucov, teta, pk, phi, q, masse, ps, phis)
256	call bilan_dyn(2, dtvr * iperiod, dtvr * day_step * periodav, &
257	ps, masse, pk, pbaru, pbarv, teta, phi, ucov, vcov, q)
258	ENDIF
259	end do leapfrog_loop
260	end do period_loop
261
262	! {itau == itaufin}
263	CALL dynredem1("restart.nc", vcov, ucov, teta, q, masse, ps, &
264	itau=itau_dyn+itaufin)
265
266	! Calcul des tendances dynamiques:
267	CALL geopot(ip1jmp1, teta, pk, pks, phis, phi)
268	CALL caldyn(itaufin, ucov, vcov, teta, ps, masse, pk, pkf, phis, phi, &
269	MOD(itaufin, iconser) == 0, du, dv, dteta, dp, w, pbaru, pbarv, &
270	time + iday - day_ini)
271
272	END SUBROUTINE leapfrog
273
274	end module leapfrog_m