libf/dyn3d/startdyn.f90

MODULE startdyn

  ! From startvar.F, version 1.4
  ! 2006/01/27 15:14:22 Fairhead

  IMPLICIT NONE

  private
  public start_init_dyn, start_inter_3d

  INTEGER fid_dyn, iml_dyn, jml_dyn, llm_dyn, ttm_dyn

  REAL, ALLOCATABLE:: lon_ini(:), lat_ini(:)
  ! (longitude and latitude from the input file, converted to rad)

  real, ALLOCATABLE:: levdyn_ini(:)

CONTAINS

  SUBROUTINE start_init_dyn(tsol_2d, psol)

    ! Host associated variables appearing and modified in this procedure :
    ! iml_dyn, jml_dyn, llm_dyn, ttm_dyn, fid_dyn, lon_ini, lat_ini, levdyn_ini

    USE flincom, only: flininfo, flinopen_nozoom
    use flinget_m, only: flinget
    use comgeom, only: aire_2d, apoln, apols
    use conf_dat2d_m, only: conf_dat2d
    use inter_barxy_m, only: inter_barxy
    use comconst, only: pi
    use comgeom, only: rlonu, rlatv
    use dimens_m, only: iim, jjm
    use gr_int_dyn_m, only: gr_int_dyn
    use start_init_orog_m, only: phis
    use start_init_phys_m, only: start_init_phys
    use nr_util, only: assert

    REAL, intent(out):: tsol_2d(:, :)
    REAL, intent(out):: psol(:, :) ! surface pressure, in Pa

    ! Local:

    REAL date, dt
    INTEGER itau(1)
    INTEGER i, j
    REAL, ALLOCATABLE:: lon_rad(:), lat_rad(:)

    REAL, ALLOCATABLE:: lon_dyn(:, :), lat_dyn(:, :)
    ! (longitude and latitude from the input file, in rad or degrees)

    REAL, ALLOCATABLE:: var_ana(:, :)
    real z(iim + 1, jjm + 1)
    real tmp_var(iim, jjm + 1)

    !--------------------------

    print *, "Call sequence information: start_init_dyn"
    call assert((/size(tsol_2d, 1), size(psol, 1)/) == iim + 1, &
         "start_init_phys size 1")
    call assert((/size(tsol_2d, 2), size(psol, 2)/) == jjm + 1, &
         "start_init_phys size 2")
    CALL flininfo('ECDYN.nc', iml_dyn, jml_dyn, llm_dyn, ttm_dyn, fid_dyn)
    print *, "iml_dyn = ", iml_dyn, ", jml_dyn = ", jml_dyn, &
         ", llm_dyn = ", llm_dyn, ", ttm_dyn = ", ttm_dyn

    ALLOCATE(lat_dyn(iml_dyn, jml_dyn))
    ALLOCATE(lon_dyn(iml_dyn, jml_dyn))
    ALLOCATE(levdyn_ini(llm_dyn))

    CALL flinopen_nozoom(iml_dyn, jml_dyn, llm_dyn, &
         lon_dyn, lat_dyn, levdyn_ini, ttm_dyn, itau, date, dt, fid_dyn)

    ALLOCATE(var_ana(iml_dyn, jml_dyn))
    ALLOCATE(lon_rad(iml_dyn))
    ALLOCATE(lon_ini(iml_dyn))

    IF (MAXVAL(lon_dyn) > pi) THEN
       ! Assume "lon_dyn" is in degrees 
       lon_ini = lon_dyn(:, 1) * pi / 180.
    ELSE
       lon_ini = lon_dyn(:, 1) 
    ENDIF

    ALLOCATE(lat_rad(jml_dyn))
    ALLOCATE(lat_ini(jml_dyn))

    IF (MAXVAL(lat_dyn) > pi) THEN
       lat_ini = lat_dyn(1, :) * pi / 180.
    ELSE
       lat_ini = lat_dyn(1, :) 
    ENDIF

    ! 'Z': Surface geopotential
    CALL flinget(fid_dyn, 'Z', iml_dyn, jml_dyn, 0, ttm_dyn, 1, 1, var_ana)
    CALL conf_dat2d(lon_ini, lat_ini, lon_rad, lat_rad, var_ana)
    CALL inter_barxy(lon_rad, lat_rad(:jml_dyn -1), var_ana, rlonu(:iim), &
         rlatv, tmp_var)
    z = gr_int_dyn(tmp_var)

    ! 'SP': Surface pressure
    CALL flinget(fid_dyn, 'SP', iml_dyn, jml_dyn, 0, ttm_dyn, 1, 1, var_ana)
    CALL conf_dat2d(lon_ini, lat_ini, lon_rad, lat_rad, var_ana)
    CALL inter_barxy(lon_rad, lat_rad(:jml_dyn -1), var_ana, rlonu(:iim), &
         rlatv, tmp_var) 
    psol = gr_int_dyn(tmp_var)
    CALL start_init_phys(tsol_2d)

    psol(:iim, :) = psol(:iim, :) &
         * (1. + (z(:iim, :) - phis(:iim, :)) / 287. / tsol_2d(:iim, :))
    psol(iim + 1, :) = psol(1, :)

    psol(:, 1) = SUM(aire_2d(:iim, 1) * psol(:iim, 1)) / apoln
    psol(:, jjm + 1) = SUM(aire_2d(:iim, jjm + 1) * psol(:iim, jjm + 1)) &
         / apols

  END SUBROUTINE start_init_dyn

  !********************************

  subroutine start_inter_3d(varname, lon_in2, lat_in2, pls_in, var3d)

    ! This procedure gets a 3D variable from a file and interpolates it.

    use flinget_m, only: flinget
    use nr_util, only: assert_eq
    use numer_rec, only: spline, splint
    use inter_barxy_m, only: inter_barxy
    use gr_int_dyn_m, only: gr_int_dyn
    use conf_dat3d_m, only: conf_dat3d

    CHARACTER(len=*), intent(in):: varname
    REAL, intent(in):: lon_in2(:) ! (iml)
    REAL, intent(in):: lat_in2(:)
    REAL, intent(in):: pls_in(:, :, :) ! (iml, jml, lml)
    REAL, intent(out):: var3d(:, :, :) ! (iml, jml, lml)

    ! LOCAL:
    INTEGER iml, jml, lml
    INTEGER ii, ij, il
    REAL lon_rad(iml_dyn), lat_rad(jml_dyn)
    REAL lev_dyn(llm_dyn)
    REAL var_tmp2d(size(lon_in2)-1, size(pls_in, 2))
    real var_tmp3d(size(lon_in2), size(pls_in, 2), llm_dyn)
    REAL ax(llm_dyn), ay(llm_dyn), yder(llm_dyn)
    real var_ana3d(iml_dyn, jml_dyn, llm_dyn)

    !--------------------------------

    print *, "Call sequence information: start_inter_3d"

    iml = assert_eq(size(pls_in, 1), size(lon_in2), size(var3d, 1), &
         "start_inter_3d iml")
    jml = assert_eq(size(pls_in, 2), size(var3d, 2), "start_inter_3d jml")
    lml = assert_eq(size(pls_in, 3), size(var3d, 3), "start_inter_3d lml")

    print *, "iml = ", iml, ", jml = ", jml
    print *, "varname = ", varname
    print *, 'Going into flinget to extract the 3D field.'
    CALL flinget(fid_dyn, varname, iml_dyn, jml_dyn, llm_dyn, ttm_dyn, 1, 1, &
         var_ana3d)
    CALL conf_dat3d(lon_ini, lat_ini, levdyn_ini, lon_rad, lat_rad, lev_dyn, &
         var_ana3d)

    DO il = 1, llm_dyn
       CALL inter_barxy(lon_rad, lat_rad(:jml_dyn-1), var_ana3d(:, :, il), &
            lon_in2(:iml-1), lat_in2, var_tmp2d) 
       var_tmp3d(:, :, il) = gr_int_dyn(var_tmp2d)
    ENDDO

    ! Pour l'interpolation verticale, on interpole du haut de l'atmosphère
    ! vers le sol :
    ax = lev_dyn(llm_dyn:1:-1)
    DO ij=1, jml
       DO ii=1, iml-1
          ay = var_tmp3d(ii, ij, llm_dyn:1:-1)
          yder = SPLINE(ax, ay)
          do il=1, lml
             var3d(ii, ij, il) = SPLINT(ax, ay, yder, pls_in(ii, ij, il))
          END do
       ENDDO
    ENDDO
    var3d(iml, :, :) = var3d(1, :, :) 

  END subroutine start_inter_3d

END MODULE startdyn
1	guez	3	MODULE startdyn
2
3			! From startvar.F, version 1.4
4			! 2006/01/27 15:14:22 Fairhead
5
6			IMPLICIT NONE
7
8			private
9			public start_init_dyn, start_inter_3d
10
11			INTEGER fid_dyn, iml_dyn, jml_dyn, llm_dyn, ttm_dyn
12
13			REAL, ALLOCATABLE:: lon_ini(:), lat_ini(:)
14			! (longitude and latitude from the input file, converted to rad)
15
16			real, ALLOCATABLE:: levdyn_ini(:)
17
18			CONTAINS
19
20			SUBROUTINE start_init_dyn(tsol_2d, psol)
21
22			! Host associated variables appearing and modified in this procedure :
23			! iml_dyn, jml_dyn, llm_dyn, ttm_dyn, fid_dyn, lon_ini, lat_ini, levdyn_ini
24
25	guez	32	USE flincom, only: flininfo, flinopen_nozoom
26			use flinget_m, only: flinget
27	guez	3	use comgeom, only: aire_2d, apoln, apols
28			use conf_dat2d_m, only: conf_dat2d
29			use inter_barxy_m, only: inter_barxy
30			use comconst, only: pi
31			use comgeom, only: rlonu, rlatv
32			use dimens_m, only: iim, jjm
33			use gr_int_dyn_m, only: gr_int_dyn
34			use start_init_orog_m, only: phis
35			use start_init_phys_m, only: start_init_phys
36	guez	36	use nr_util, only: assert
37	guez	3
38			REAL, intent(out):: tsol_2d(:, :)
39			REAL, intent(out):: psol(:, :) ! surface pressure, in Pa
40
41			! Local:
42
43			REAL date, dt
44			INTEGER itau(1)
45			INTEGER i, j
46			REAL, ALLOCATABLE:: lon_rad(:), lat_rad(:)
47
48			REAL, ALLOCATABLE:: lon_dyn(:, :), lat_dyn(:, :)
49			! (longitude and latitude from the input file, in rad or degrees)
50
51	guez	36	REAL, ALLOCATABLE:: var_ana(:, :)
52			real z(iim + 1, jjm + 1)
53	guez	3	real tmp_var(iim, jjm + 1)
54
55			!--------------------------
56
57			print *, "Call sequence information: start_init_dyn"
58	guez	36	call assert((/size(tsol_2d, 1), size(psol, 1)/) == iim + 1, &
59			"start_init_phys size 1")
60			call assert((/size(tsol_2d, 2), size(psol, 2)/) == jjm + 1, &
61			"start_init_phys size 2")
62			CALL flininfo('ECDYN.nc', iml_dyn, jml_dyn, llm_dyn, ttm_dyn, fid_dyn)
63	guez	3	print *, "iml_dyn = ", iml_dyn, ", jml_dyn = ", jml_dyn, &
64			", llm_dyn = ", llm_dyn, ", ttm_dyn = ", ttm_dyn
65
66			ALLOCATE(lat_dyn(iml_dyn, jml_dyn))
67			ALLOCATE(lon_dyn(iml_dyn, jml_dyn))
68			ALLOCATE(levdyn_ini(llm_dyn))
69
70	guez	32	CALL flinopen_nozoom(iml_dyn, jml_dyn, llm_dyn, &
71	guez	3	lon_dyn, lat_dyn, levdyn_ini, ttm_dyn, itau, date, dt, fid_dyn)
72
73			ALLOCATE(var_ana(iml_dyn, jml_dyn))
74			ALLOCATE(lon_rad(iml_dyn))
75			ALLOCATE(lon_ini(iml_dyn))
76
77	guez	36	IF (MAXVAL(lon_dyn) > pi) THEN
78	guez	3	! Assume "lon_dyn" is in degrees
79	guez	36	lon_ini = lon_dyn(:, 1) * pi / 180.
80	guez	3	ELSE
81	guez	36	lon_ini = lon_dyn(:, 1)
82	guez	3	ENDIF
83
84			ALLOCATE(lat_rad(jml_dyn))
85			ALLOCATE(lat_ini(jml_dyn))
86
87	guez	36	IF (MAXVAL(lat_dyn) > pi) THEN
88			lat_ini = lat_dyn(1, :) * pi / 180.
89	guez	3	ELSE
90	guez	36	lat_ini = lat_dyn(1, :)
91	guez	3	ENDIF
92
93			! 'Z': Surface geopotential
94			CALL flinget(fid_dyn, 'Z', iml_dyn, jml_dyn, 0, ttm_dyn, 1, 1, var_ana)
95			CALL conf_dat2d(lon_ini, lat_ini, lon_rad, lat_rad, var_ana)
96			CALL inter_barxy(lon_rad, lat_rad(:jml_dyn -1), var_ana, rlonu(:iim), &
97			rlatv, tmp_var)
98	guez	36	z = gr_int_dyn(tmp_var)
99	guez	3
100			! 'SP': Surface pressure
101			CALL flinget(fid_dyn, 'SP', iml_dyn, jml_dyn, 0, ttm_dyn, 1, 1, var_ana)
102			CALL conf_dat2d(lon_ini, lat_ini, lon_rad, lat_rad, var_ana)
103			CALL inter_barxy(lon_rad, lat_rad(:jml_dyn -1), var_ana, rlonu(:iim), &
104			rlatv, tmp_var)
105	guez	36	psol = gr_int_dyn(tmp_var)
106	guez	3	CALL start_init_phys(tsol_2d)
107
108	guez	36	psol(:iim, :) = psol(:iim, :) &
109			* (1. + (z(:iim, :) - phis(:iim, :)) / 287. / tsol_2d(:iim, :))
110	guez	3	psol(iim + 1, :) = psol(1, :)
111
112	guez	36	psol(:, 1) = SUM(aire_2d(:iim, 1) * psol(:iim, 1)) / apoln
113			psol(:, jjm + 1) = SUM(aire_2d(:iim, jjm + 1) * psol(:iim, jjm + 1)) &
114			/ apols
115	guez	3
116			END SUBROUTINE start_init_dyn
117
118			!********************************
119
120	guez	23	subroutine start_inter_3d(varname, lon_in2, lat_in2, pls_in, var3d)
121	guez	3
122	guez	36	! This procedure gets a 3D variable from a file and interpolates it.
123	guez	3
124	guez	32	use flinget_m, only: flinget
125	guez	36	use nr_util, only: assert_eq
126			use numer_rec, only: spline, splint
127	guez	3	use inter_barxy_m, only: inter_barxy
128			use gr_int_dyn_m, only: gr_int_dyn
129			use conf_dat3d_m, only: conf_dat3d
130
131			CHARACTER(len=*), intent(in):: varname
132	guez	36	REAL, intent(in):: lon_in2(:) ! (iml)
133			REAL, intent(in):: lat_in2(:)
134			REAL, intent(in):: pls_in(:, :, :) ! (iml, jml, lml)
135			REAL, intent(out):: var3d(:, :, :) ! (iml, jml, lml)
136	guez	3
137			! LOCAL:
138			INTEGER iml, jml, lml
139			INTEGER ii, ij, il
140			REAL lon_rad(iml_dyn), lat_rad(jml_dyn)
141			REAL lev_dyn(llm_dyn)
142			REAL var_tmp2d(size(lon_in2)-1, size(pls_in, 2))
143			real var_tmp3d(size(lon_in2), size(pls_in, 2), llm_dyn)
144			REAL ax(llm_dyn), ay(llm_dyn), yder(llm_dyn)
145			real var_ana3d(iml_dyn, jml_dyn, llm_dyn)
146
147			!--------------------------------
148
149			print *, "Call sequence information: start_inter_3d"
150
151	guez	23	iml = assert_eq(size(pls_in, 1), size(lon_in2), size(var3d, 1), &
152			"start_inter_3d iml")
153			jml = assert_eq(size(pls_in, 2), size(var3d, 2), "start_inter_3d jml")
154			lml = assert_eq(size(pls_in, 3), size(var3d, 3), "start_inter_3d lml")
155	guez	3
156			print *, "iml = ", iml, ", jml = ", jml
157	guez	23	print *, "varname = ", varname
158	guez	20	print *, 'Going into flinget to extract the 3D field.'
159	guez	3	CALL flinget(fid_dyn, varname, iml_dyn, jml_dyn, llm_dyn, ttm_dyn, 1, 1, &
160			var_ana3d)
161			CALL conf_dat3d(lon_ini, lat_ini, levdyn_ini, lon_rad, lat_rad, lev_dyn, &
162			var_ana3d)
163
164			DO il = 1, llm_dyn
165			CALL inter_barxy(lon_rad, lat_rad(:jml_dyn-1), var_ana3d(:, :, il), &
166			lon_in2(:iml-1), lat_in2, var_tmp2d)
167			var_tmp3d(:, :, il) = gr_int_dyn(var_tmp2d)
168			ENDDO
169
170			! Pour l'interpolation verticale, on interpole du haut de l'atmosphère
171			! vers le sol :
172	guez	36	ax = lev_dyn(llm_dyn:1:-1)
173	guez	3	DO ij=1, jml
174			DO ii=1, iml-1
175	guez	36	ay = var_tmp3d(ii, ij, llm_dyn:1:-1)
176			yder = SPLINE(ax, ay)
177	guez	3	do il=1, lml
178	guez	24	var3d(ii, ij, il) = SPLINT(ax, ay, yder, pls_in(ii, ij, il))
179	guez	3	END do
180			ENDDO
181			ENDDO
182	guez	23	var3d(iml, :, :) = var3d(1, :, :)
183	guez	3
184	guez	23	END subroutine start_inter_3d
185	guez	3
186			END MODULE startdyn