1 |
module calcul_fluxs_m |
2 |
|
3 |
implicit none |
4 |
|
5 |
contains |
6 |
|
7 |
SUBROUTINE calcul_fluxs(nisurf, dtime, tsurf, p1lay, cal, beta, coef1lay, & |
8 |
ps, qsurf, radsol, dif_grnd, t1lay, q1lay, u1lay, v1lay, petAcoef, & |
9 |
peqAcoef, petBcoef, peqBcoef, tsurf_new, evap, fluxlat, fluxsens, & |
10 |
dflux_s, dflux_l) |
11 |
|
12 |
! Cette routine calcule les fluxs en h et q à l'interface et une |
13 |
! température de surface. |
14 |
|
15 |
! L. Fairhead April 2000 |
16 |
|
17 |
USE abort_gcm_m, ONLY: abort_gcm |
18 |
USE indicesol, ONLY: is_ter |
19 |
USE fcttre, ONLY: dqsatl, dqsats, foede, foeew, qsatl, qsats, thermcep |
20 |
USE interface_surf, ONLY: run_off |
21 |
use nr_util, only: assert_eq |
22 |
USE suphec_m, ONLY: rcpd, rd, retv, rkappa, rlstt, rlvtt, rtt |
23 |
USE yoethf_m, ONLY: r2es, r5ies, r5les, rvtmp2 |
24 |
|
25 |
integer, intent(IN):: nisurf ! surface a traiter |
26 |
real, intent(IN):: dtime |
27 |
real, intent(IN):: tsurf(:) ! (knon) temperature de surface |
28 |
real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche) |
29 |
real, intent(IN):: cal(:) ! (knon) capacité calorifique du sol |
30 |
real, intent(IN):: beta(:) ! (knon) evap reelle |
31 |
real, intent(IN):: coef1lay(:) ! (knon) coefficient d'échange |
32 |
real, intent(IN):: ps(:) ! (knon) pression au sol |
33 |
real, intent(OUT):: qsurf(:) ! (knon) humidite de l'air au dessus du sol |
34 |
real, intent(IN):: radsol(:) ! (knon) rayonnement net au sol (LW + SW) |
35 |
|
36 |
real, intent(IN):: dif_grnd(:) ! (knon) |
37 |
! coefficient diffusion vers le sol profond |
38 |
|
39 |
real, intent(IN):: t1lay(:), q1lay(:), u1lay(:), v1lay(:) ! (knon) |
40 |
|
41 |
real, intent(IN):: petAcoef(:), peqAcoef(:) ! (knon) |
42 |
! coefficients A de la résolution de la couche limite pour t et q |
43 |
|
44 |
real, intent(IN):: petBcoef(:), peqBcoef(:) ! (knon) |
45 |
! petBcoef coeff. B de la resolution de la CL pour t |
46 |
! peqBcoef coeff. B de la resolution de la CL pour q |
47 |
|
48 |
real, intent(OUT):: tsurf_new(:) ! (knon) température au sol |
49 |
real, intent(OUT):: evap(:), fluxlat(:), fluxsens(:) ! (knon) |
50 |
! fluxlat flux de chaleur latente |
51 |
! fluxsens flux de chaleur sensible |
52 |
real, intent(OUT):: dflux_s(:), dflux_l(:) ! (knon) |
53 |
! Dérivées des flux dF/dTs (W m-2 K-1) |
54 |
! dflux_s derivee du flux de chaleur sensible / Ts |
55 |
! dflux_l derivee du flux de chaleur latente / Ts |
56 |
|
57 |
! Local: |
58 |
integer i |
59 |
integer knon ! nombre de points a traiter |
60 |
real, dimension(size(ps)):: mh, oh, mq, nq, oq |
61 |
real, dimension(size(ps)):: dq_s_dt, coef |
62 |
real qsat(size(ps)) ! qsat en kg/kg |
63 |
real sl(size(ps)) ! chaleur latente d'evaporation ou de sublimation |
64 |
logical delta |
65 |
real zcor |
66 |
real, parameter:: t_grnd = 271.35, t_coup = 273.15 |
67 |
|
68 |
!--------------------------------------------------------------------- |
69 |
|
70 |
knon = assert_eq((/size(tsurf), size(p1lay), size(cal), size(beta), & |
71 |
size(coef1lay), size(ps), size(qsurf), size(radsol), size(dif_grnd), & |
72 |
size(t1lay), size(q1lay), size(u1lay), size(v1lay), size(petAcoef), & |
73 |
size(peqAcoef), size(petBcoef), size(peqBcoef), size(tsurf_new), & |
74 |
size(evap), size(fluxlat), size(fluxsens), size(dflux_s), & |
75 |
size(dflux_l)/), "calcul_fluxs knon") |
76 |
|
77 |
if (size(run_off) /= knon .AND. nisurf == is_ter) then |
78 |
print *, 'Bizarre, le nombre de points continentaux' |
79 |
print *, 'a change entre deux appels. J''arrete.' |
80 |
call abort_gcm('calcul_fluxs', 'Pb run_off', 1) |
81 |
endif |
82 |
|
83 |
! Traitement humidite du sol |
84 |
|
85 |
IF (thermcep) THEN |
86 |
DO i = 1, knon |
87 |
delta = rtt >= tsurf(i) |
88 |
qsat(i) = MIN(0.5, r2es * FOEEW(tsurf(i), delta) / ps(i)) |
89 |
zcor = 1. / (1. - retv * qsat(i)) |
90 |
qsat(i) = qsat(i) * zcor |
91 |
dq_s_dt(i) = RCPD * FOEDE(tsurf(i), delta, merge(R5IES * RLSTT, & |
92 |
R5LES * RLVTT, delta) / RCPD / (1. + RVTMP2 * q1lay(i)), & |
93 |
qsat(i), zcor) / RLVTT |
94 |
ENDDO |
95 |
ELSE |
96 |
DO i = 1, knon |
97 |
IF (tsurf(i) < t_coup) THEN |
98 |
qsat(i) = qsats(tsurf(i)) / ps(i) |
99 |
dq_s_dt(i) = RCPD * dqsats(tsurf(i), qsat(i)) / RLVTT |
100 |
ELSE |
101 |
qsat(i) = qsatl(tsurf(i)) / ps(i) |
102 |
dq_s_dt(i) = RCPD * dqsatl(tsurf(i), qsat(i)) / RLVTT |
103 |
ENDIF |
104 |
ENDDO |
105 |
ENDIF |
106 |
|
107 |
coef = coef1lay * (1. + SQRT(u1lay**2 + v1lay**2)) * p1lay / (RD * t1lay) |
108 |
sl = merge(RLSTT, RLVTT, tsurf < RTT) |
109 |
|
110 |
! Q |
111 |
oq = 1. - (beta * coef * peqBcoef * dtime) |
112 |
mq = beta * coef * (peqAcoef - qsat + dq_s_dt * tsurf) / oq |
113 |
nq = beta * coef * (- 1. * dq_s_dt) / oq |
114 |
|
115 |
! H |
116 |
oh = 1. - (coef * petBcoef * dtime) |
117 |
mh = coef * petAcoef / oh |
118 |
dflux_s = - (coef * RCPD)/ oh |
119 |
|
120 |
! Tsurface |
121 |
tsurf_new = (tsurf + cal / RCPD * dtime * (radsol + mh + sl * mq) & |
122 |
+ dif_grnd * t_grnd * dtime) / (1. - dtime * cal / RCPD * (dflux_s & |
123 |
+ sl * nq) + dtime * dif_grnd) |
124 |
|
125 |
evap = - mq - nq * tsurf_new |
126 |
fluxlat = - evap * sl |
127 |
fluxsens = mh + dflux_s * tsurf_new |
128 |
dflux_l = sl * nq |
129 |
|
130 |
! Nouvelle valeur de l'humidité au dessus du sol : |
131 |
qsurf = (peqAcoef - peqBcoef * evap * dtime) * (1. - beta) + beta * (qsat & |
132 |
+ dq_s_dt * (tsurf_new - tsurf)) |
133 |
|
134 |
END SUBROUTINE calcul_fluxs |
135 |
|
136 |
end module calcul_fluxs_m |