phylmd/Interface_surf/calcul_fluxs.f

module calcul_fluxs_m

  implicit none

contains

  SUBROUTINE calcul_fluxs(nisurf, dtime, tsurf, p1lay, cal, beta, coef1lay, &
       ps, qsurf, radsol, dif_grnd, t1lay, q1lay, u1lay, v1lay, petAcoef, &
       peqAcoef, petBcoef, peqBcoef, tsurf_new, evap, fluxlat, fluxsens, &
       dflux_s, dflux_l)

    ! Cette routine calcule les fluxs en h et q à l'interface et une
    ! température de surface.

    ! L. Fairhead April 2000

    USE abort_gcm_m, ONLY: abort_gcm
    USE indicesol, ONLY: is_ter
    USE fcttre, ONLY: dqsatl, dqsats, foede, foeew, qsatl, qsats, thermcep
    USE interface_surf, ONLY: run_off
    use nr_util, only: assert_eq
    USE suphec_m, ONLY: rcpd, rd, retv, rkappa, rlstt, rlvtt, rtt
    USE yoethf_m, ONLY: r2es, r5ies, r5les, rvtmp2

    integer, intent(IN):: nisurf ! surface a traiter
    real, intent(IN):: dtime
    real, intent(IN):: tsurf(:) ! (knon) temperature de surface
    real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche)
    real, intent(IN):: cal(:) ! (knon) capacité calorifique du sol
    real, intent(IN):: beta(:) ! (knon) evap reelle
    real, intent(IN):: coef1lay(:) ! (knon) coefficient d'échange
    real, intent(IN):: ps(:) ! (knon) pression au sol
    real, intent(OUT):: qsurf(:) ! (knon) humidite de l'air au dessus du sol
    real, intent(IN):: radsol(:) ! (knon) rayonnement net au sol (LW + SW)

    real, intent(IN):: dif_grnd(:) ! (knon)
    ! coefficient diffusion vers le sol profond

    real, intent(IN):: t1lay(:), q1lay(:), u1lay(:), v1lay(:) ! (knon)

    real, intent(IN):: petAcoef(:), peqAcoef(:) ! (knon)
    ! coefficients A de la résolution de la couche limite pour t et q

    real, intent(IN):: petBcoef(:), peqBcoef(:) ! (knon)
    ! petBcoef coeff. B de la resolution de la CL pour t
    ! peqBcoef coeff. B de la resolution de la CL pour q

    real, intent(OUT):: tsurf_new(:) ! (knon) température au sol
    real, intent(OUT):: evap(:), fluxlat(:), fluxsens(:) ! (knon)
    ! fluxlat flux de chaleur latente
    ! fluxsens flux de chaleur sensible
    real, intent(OUT):: dflux_s(:), dflux_l(:) ! (knon)
    ! Dérivées des flux dF/dTs (W m-2 K-1)
    ! dflux_s derivee du flux de chaleur sensible / Ts
    ! dflux_l derivee du flux de chaleur latente / Ts

    ! Local:
    integer i
    integer knon ! nombre de points a traiter
    real, dimension(size(ps)):: mh, oh, mq, nq, oq
    real, dimension(size(ps)):: dq_s_dt, coef
    real qsat(size(ps)) ! qsat en kg/kg
    real sl(size(ps)) ! chaleur latente d'evaporation ou de sublimation
    logical delta
    real zcor
    real, parameter:: t_grnd = 271.35, t_coup = 273.15

    !---------------------------------------------------------------------

    knon = assert_eq((/size(tsurf), size(p1lay), size(cal), size(beta), &
         size(coef1lay), size(ps), size(qsurf), size(radsol), size(dif_grnd), &
         size(t1lay), size(q1lay), size(u1lay), size(v1lay), size(petAcoef), &
         size(peqAcoef), size(petBcoef), size(peqBcoef), size(tsurf_new), &
         size(evap), size(fluxlat), size(fluxsens), size(dflux_s), &
         size(dflux_l)/), "calcul_fluxs knon")

    if (size(run_off) /= knon .AND. nisurf == is_ter) then
       print *, 'Bizarre, le nombre de points continentaux'
       print *, 'a change entre deux appels. J''arrete.'
       call abort_gcm('calcul_fluxs', 'Pb run_off', 1)
    endif

    ! Traitement humidite du sol

    IF (thermcep) THEN
       DO i = 1, knon
          delta = rtt >= tsurf(i)
          qsat(i) = MIN(0.5, r2es * FOEEW(tsurf(i), delta) / ps(i))
          zcor = 1. / (1. - retv * qsat(i))
          qsat(i) = qsat(i) * zcor
          dq_s_dt(i) = RCPD * FOEDE(tsurf(i), delta, merge(R5IES * RLSTT, &
               R5LES * RLVTT, delta) / RCPD / (1. + RVTMP2 * q1lay(i)), &
               qsat(i), zcor) / RLVTT
       ENDDO
    ELSE
       DO i = 1, knon
          IF (tsurf(i) < t_coup) THEN
             qsat(i) = qsats(tsurf(i)) / ps(i)
             dq_s_dt(i) = RCPD * dqsats(tsurf(i), qsat(i)) / RLVTT
          ELSE
             qsat(i) = qsatl(tsurf(i)) / ps(i)
             dq_s_dt(i) = RCPD * dqsatl(tsurf(i), qsat(i)) / RLVTT
          ENDIF
       ENDDO
    ENDIF

    coef = coef1lay * (1. + SQRT(u1lay**2 + v1lay**2)) * p1lay / (RD * t1lay)
    sl = merge(RLSTT, RLVTT, tsurf < RTT)

    ! Q
    oq = 1. - (beta * coef * peqBcoef * dtime)
    mq = beta * coef * (peqAcoef - qsat + dq_s_dt * tsurf) / oq
    nq = beta * coef * (- 1. * dq_s_dt) / oq

    ! H
    oh = 1. - (coef * petBcoef * dtime)
    mh = coef * petAcoef / oh
    dflux_s = - (coef * RCPD)/ oh

    ! Tsurface
    tsurf_new = (tsurf + cal / RCPD * dtime * (radsol + mh + sl * mq) &
         + dif_grnd * t_grnd * dtime) / (1. - dtime * cal / RCPD * (dflux_s &
         + sl * nq) + dtime * dif_grnd)

    evap = - mq - nq * tsurf_new
    fluxlat = - evap * sl
    fluxsens = mh + dflux_s * tsurf_new
    dflux_l = sl * nq

    ! Nouvelle valeur de l'humidité au dessus du sol :
    qsurf = (peqAcoef - peqBcoef * evap * dtime) * (1. - beta) + beta * (qsat &
         + dq_s_dt * (tsurf_new - tsurf))

  END SUBROUTINE calcul_fluxs

end module calcul_fluxs_m
1	guez	54	module calcul_fluxs_m
2
3			implicit none
4
5			contains
6
7	guez	104	SUBROUTINE calcul_fluxs(nisurf, dtime, tsurf, p1lay, cal, beta, coef1lay, &
8			ps, qsurf, radsol, dif_grnd, t1lay, q1lay, u1lay, v1lay, petAcoef, &
9			peqAcoef, petBcoef, peqBcoef, tsurf_new, evap, fluxlat, fluxsens, &
10			dflux_s, dflux_l)
11	guez	54
12	guez	99	! Cette routine calcule les fluxs en h et q à l'interface et une
13			! température de surface.
14	guez	54
15	guez	104	! L. Fairhead April 2000
16	guez	54
17	guez	104	USE abort_gcm_m, ONLY: abort_gcm
18			USE indicesol, ONLY: is_ter
19			USE fcttre, ONLY: dqsatl, dqsats, foede, foeew, qsatl, qsats, thermcep
20			USE interface_surf, ONLY: run_off
21			use nr_util, only: assert_eq
22			USE suphec_m, ONLY: rcpd, rd, retv, rkappa, rlstt, rlvtt, rtt
23			USE yoethf_m, ONLY: r2es, r5ies, r5les, rvtmp2
24
25			integer, intent(IN):: nisurf ! surface a traiter
26			real, intent(IN):: dtime
27			real, intent(IN):: tsurf(:) ! (knon) temperature de surface
28			real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche)
29			real, intent(IN):: cal(:) ! (knon) capacité calorifique du sol
30			real, intent(IN):: beta(:) ! (knon) evap reelle
31			real, intent(IN):: coef1lay(:) ! (knon) coefficient d'échange
32			real, intent(IN):: ps(:) ! (knon) pression au sol
33			real, intent(OUT):: qsurf(:) ! (knon) humidite de l'air au dessus du sol
34			real, intent(IN):: radsol(:) ! (knon) rayonnement net au sol (LW + SW)
35
36			real, intent(IN):: dif_grnd(:) ! (knon)
37			! coefficient diffusion vers le sol profond
38
39			real, intent(IN):: t1lay(:), q1lay(:), u1lay(:), v1lay(:) ! (knon)
40
41			real, intent(IN):: petAcoef(:), peqAcoef(:) ! (knon)
42			! coefficients A de la résolution de la couche limite pour t et q
43
44			real, intent(IN):: petBcoef(:), peqBcoef(:) ! (knon)
45	guez	54	! petBcoef coeff. B de la resolution de la CL pour t
46			! peqBcoef coeff. B de la resolution de la CL pour q
47
48	guez	104	real, intent(OUT):: tsurf_new(:) ! (knon) température au sol
49			real, intent(OUT):: evap(:), fluxlat(:), fluxsens(:) ! (knon)
50			! fluxlat flux de chaleur latente
51	guez	54	! fluxsens flux de chaleur sensible
52	guez	104	real, intent(OUT):: dflux_s(:), dflux_l(:) ! (knon)
53			! Dérivées des flux dF/dTs (W m-2 K-1)
54	guez	54	! dflux_s derivee du flux de chaleur sensible / Ts
55			! dflux_l derivee du flux de chaleur latente / Ts
56
57	guez	104	! Local:
58			integer i
59			integer knon ! nombre de points a traiter
60	guez	105	real, dimension(size(ps)):: mh, oh, mq, nq, oq
61			real, dimension(size(ps)):: dq_s_dt, coef
62			real qsat(size(ps)) ! qsat en kg/kg
63			real sl(size(ps)) ! chaleur latente d'evaporation ou de sublimation
64			logical delta
65			real zcor
66	guez	104	real, parameter:: t_grnd = 271.35, t_coup = 273.15
67	guez	54
68	guez	104	!---------------------------------------------------------------------
69	guez	54
70	guez	104	knon = assert_eq((/size(tsurf), size(p1lay), size(cal), size(beta), &
71			size(coef1lay), size(ps), size(qsurf), size(radsol), size(dif_grnd), &
72			size(t1lay), size(q1lay), size(u1lay), size(v1lay), size(petAcoef), &
73			size(peqAcoef), size(petBcoef), size(peqBcoef), size(tsurf_new), &
74			size(evap), size(fluxlat), size(fluxsens), size(dflux_s), &
75			size(dflux_l)/), "calcul_fluxs knon")
76	guez	54
77	guez	101	if (size(run_off) /= knon .AND. nisurf == is_ter) then
78	guez	104	print *, 'Bizarre, le nombre de points continentaux'
79			print *, 'a change entre deux appels. J''arrete.'
80			call abort_gcm('calcul_fluxs', 'Pb run_off', 1)
81	guez	54	endif
82
83	guez	104	! Traitement humidite du sol
84	guez	54
85	guez	105	IF (thermcep) THEN
86			DO i = 1, knon
87			delta = rtt >= tsurf(i)
88			qsat(i) = MIN(0.5, r2es * FOEEW(tsurf(i), delta) / ps(i))
89			zcor = 1. / (1. - retv * qsat(i))
90			qsat(i) = qsat(i) * zcor
91			dq_s_dt(i) = RCPD * FOEDE(tsurf(i), delta, merge(R5IES * RLSTT, &
92			R5LES * RLVTT, delta) / RCPD / (1. + RVTMP2 * q1lay(i)), &
93			qsat(i), zcor) / RLVTT
94			ENDDO
95			ELSE
96			DO i = 1, knon
97			IF (tsurf(i) < t_coup) THEN
98			qsat(i) = qsats(tsurf(i)) / ps(i)
99			dq_s_dt(i) = RCPD * dqsats(tsurf(i), qsat(i)) / RLVTT
100	guez	54	ELSE
101	guez	105	qsat(i) = qsatl(tsurf(i)) / ps(i)
102			dq_s_dt(i) = RCPD * dqsatl(tsurf(i), qsat(i)) / RLVTT
103	guez	54	ENDIF
104	guez	105	ENDDO
105			ENDIF
106	guez	54
107	guez	105	coef = coef1lay * (1. + SQRT(u1lay2 + v1lay2)) * p1lay / (RD * t1lay)
108			sl = merge(RLSTT, RLVTT, tsurf < RTT)
109	guez	54
110	guez	105	! Q
111			oq = 1. - (beta * coef * peqBcoef * dtime)
112			mq = beta * coef * (peqAcoef - qsat + dq_s_dt * tsurf) / oq
113			nq = beta * coef * (- 1. * dq_s_dt) / oq
114	guez	54
115	guez	105	! H
116			oh = 1. - (coef * petBcoef * dtime)
117			mh = coef * petAcoef / oh
118			dflux_s = - (coef * RCPD)/ oh
119	guez	54
120	guez	105	! Tsurface
121			tsurf_new = (tsurf + cal / RCPD * dtime * (radsol + mh + sl * mq) &
122			+ dif_grnd * t_grnd * dtime) / (1. - dtime * cal / RCPD * (dflux_s &
123			+ sl * nq) + dtime * dif_grnd)
124	guez	54
125	guez	105	evap = - mq - nq * tsurf_new
126			fluxlat = - evap * sl
127			fluxsens = mh + dflux_s * tsurf_new
128			dflux_l = sl * nq
129	guez	54
130	guez	105	! Nouvelle valeur de l'humidité au dessus du sol :
131			qsurf = (peqAcoef - peqBcoef * evap * dtime) * (1. - beta) + beta * (qsat &
132			+ dq_s_dt * (tsurf_new - tsurf))
133	guez	54
134			END SUBROUTINE calcul_fluxs
135
136			end module calcul_fluxs_m