phylmd/Interface_surf/calcul_fluxs.f

module calcul_fluxs_m

  implicit none

contains

  SUBROUTINE calcul_fluxs(dtime, tsurf, p1lay, cal, beta, coef1lay, ps, &
       qsurf, radsol, dif_grnd, t1lay, q1lay, u1lay, v1lay, petAcoef, &
       peqAcoef, petBcoef, peqBcoef, tsurf_new, evap, fluxlat, fluxsens, &
       dflux_s, dflux_l)

    ! Cette routine calcule les fluxs en h et q à l'interface et une
    ! température de surface.

    ! L. Fairhead April 2000

    USE abort_gcm_m, ONLY: abort_gcm
    USE fcttre, ONLY: dqsatl, dqsats, foede, foeew, qsatl, qsats, thermcep
    USE indicesol, ONLY: is_ter
    use nr_util, only: assert_eq
    USE suphec_m, ONLY: rcpd, rd, retv, rkappa, rlstt, rlvtt, rtt
    USE yoethf_m, ONLY: r2es, r5ies, r5les, rvtmp2

    real, intent(IN):: dtime
    real, intent(IN):: tsurf(:) ! (knon) temperature de surface
    real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche)
    real, intent(IN):: cal(:) ! (knon) capacité calorifique du sol
    real, intent(IN):: beta(:) ! (knon) evap reelle
    real, intent(IN):: coef1lay(:) ! (knon) coefficient d'échange
    real, intent(IN):: ps(:) ! (knon) pression au sol
    real, intent(OUT):: qsurf(:) ! (knon) humidite de l'air au dessus du sol
    real, intent(IN):: radsol(:) ! (knon) rayonnement net au sol (LW + SW)

    real, intent(IN):: dif_grnd(:) ! (knon)
    ! coefficient diffusion vers le sol profond

    real, intent(IN):: t1lay(:), q1lay(:), u1lay(:), v1lay(:) ! (knon)

    real, intent(IN):: petAcoef(:), peqAcoef(:) ! (knon)
    ! coefficients A de la résolution de la couche limite pour t et q

    real, intent(IN):: petBcoef(:), peqBcoef(:) ! (knon)
    ! coeff. B de la resolution de la CL pour t et q

    real, intent(OUT):: tsurf_new(:) ! (knon) température au sol
    real, intent(OUT):: evap(:) ! (knon)

    real, intent(OUT):: fluxlat(:), fluxsens(:) ! (knon)
    ! flux de chaleur latente et sensible

    real, intent(OUT):: dflux_s(:), dflux_l(:) ! (knon)
    ! dérivées des flux de chaleurs sensible et latente par rapport à
    ! Ts (W m-2 K-1)

    ! Local:
    integer i
    integer knon ! nombre de points a traiter
    real, dimension(size(ps)):: mh, oh, mq, nq, oq
    real, dimension(size(ps)):: dq_s_dt, coef
    real qsat(size(ps)) ! qsat en kg/kg
    real sl(size(ps)) ! chaleur latente d'evaporation ou de sublimation
    logical delta
    real zcor
    real, parameter:: t_grnd = 271.35, t_coup = 273.15

    !---------------------------------------------------------------------

    knon = assert_eq((/size(tsurf), size(p1lay), size(cal), size(beta), &
         size(coef1lay), size(ps), size(qsurf), size(radsol), size(dif_grnd), &
         size(t1lay), size(q1lay), size(u1lay), size(v1lay), size(petAcoef), &
         size(peqAcoef), size(petBcoef), size(peqBcoef), size(tsurf_new), &
         size(evap), size(fluxlat), size(fluxsens), size(dflux_s), &
         size(dflux_l)/), "calcul_fluxs knon")

    ! Traitement humidite du sol

    IF (thermcep) THEN
       DO i = 1, knon
          delta = rtt >= tsurf(i)
          qsat(i) = MIN(0.5, r2es * FOEEW(tsurf(i), delta) / ps(i))
          zcor = 1. / (1. - retv * qsat(i))
          qsat(i) = qsat(i) * zcor
          dq_s_dt(i) = RCPD * FOEDE(tsurf(i), delta, merge(R5IES * RLSTT, &
               R5LES * RLVTT, delta) / RCPD / (1. + RVTMP2 * q1lay(i)), &
               qsat(i), zcor) / RLVTT
       ENDDO
    ELSE
       DO i = 1, knon
          IF (tsurf(i) < t_coup) THEN
             qsat(i) = qsats(tsurf(i)) / ps(i)
             dq_s_dt(i) = RCPD * dqsats(tsurf(i), qsat(i)) / RLVTT
          ELSE
             qsat(i) = qsatl(tsurf(i)) / ps(i)
             dq_s_dt(i) = RCPD * dqsatl(tsurf(i), qsat(i)) / RLVTT
          ENDIF
       ENDDO
    ENDIF

    coef = coef1lay * (1. + SQRT(u1lay**2 + v1lay**2)) * p1lay / (RD * t1lay)
    sl = merge(RLSTT, RLVTT, tsurf < RTT)

    ! Q
    oq = 1. - (beta * coef * peqBcoef * dtime)
    mq = beta * coef * (peqAcoef - qsat + dq_s_dt * tsurf) / oq
    nq = beta * coef * (- 1. * dq_s_dt) / oq

    ! H
    oh = 1. - (coef * petBcoef * dtime)
    mh = coef * petAcoef / oh
    dflux_s = - (coef * RCPD)/ oh

    ! Tsurface
    tsurf_new = (tsurf + cal / RCPD * dtime * (radsol + mh + sl * mq) &
         + dif_grnd * t_grnd * dtime) / (1. - dtime * cal / RCPD * (dflux_s &
         + sl * nq) + dtime * dif_grnd)

    evap = - mq - nq * tsurf_new
    fluxlat = - evap * sl
    fluxsens = mh + dflux_s * tsurf_new
    dflux_l = sl * nq

    ! Nouvelle valeur de l'humidité au dessus du sol :
    qsurf = (peqAcoef - peqBcoef * evap * dtime) * (1. - beta) + beta * (qsat &
         + dq_s_dt * (tsurf_new - tsurf))

  END SUBROUTINE calcul_fluxs

end module calcul_fluxs_m
1	guez	54	module calcul_fluxs_m
2
3			implicit none
4
5			contains
6
7	guez	171	SUBROUTINE calcul_fluxs(dtime, tsurf, p1lay, cal, beta, coef1lay, ps, &
8			qsurf, radsol, dif_grnd, t1lay, q1lay, u1lay, v1lay, petAcoef, &
9	guez	104	peqAcoef, petBcoef, peqBcoef, tsurf_new, evap, fluxlat, fluxsens, &
10			dflux_s, dflux_l)
11	guez	54
12	guez	99	! Cette routine calcule les fluxs en h et q à l'interface et une
13			! température de surface.
14	guez	54
15	guez	104	! L. Fairhead April 2000
16	guez	54
17	guez	104	USE abort_gcm_m, ONLY: abort_gcm
18	guez	171	USE fcttre, ONLY: dqsatl, dqsats, foede, foeew, qsatl, qsats, thermcep
19	guez	104	USE indicesol, ONLY: is_ter
20			use nr_util, only: assert_eq
21			USE suphec_m, ONLY: rcpd, rd, retv, rkappa, rlstt, rlvtt, rtt
22			USE yoethf_m, ONLY: r2es, r5ies, r5les, rvtmp2
23
24			real, intent(IN):: dtime
25			real, intent(IN):: tsurf(:) ! (knon) temperature de surface
26			real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche)
27			real, intent(IN):: cal(:) ! (knon) capacité calorifique du sol
28			real, intent(IN):: beta(:) ! (knon) evap reelle
29			real, intent(IN):: coef1lay(:) ! (knon) coefficient d'échange
30			real, intent(IN):: ps(:) ! (knon) pression au sol
31			real, intent(OUT):: qsurf(:) ! (knon) humidite de l'air au dessus du sol
32			real, intent(IN):: radsol(:) ! (knon) rayonnement net au sol (LW + SW)
33
34			real, intent(IN):: dif_grnd(:) ! (knon)
35			! coefficient diffusion vers le sol profond
36
37			real, intent(IN):: t1lay(:), q1lay(:), u1lay(:), v1lay(:) ! (knon)
38
39			real, intent(IN):: petAcoef(:), peqAcoef(:) ! (knon)
40			! coefficients A de la résolution de la couche limite pour t et q
41
42			real, intent(IN):: petBcoef(:), peqBcoef(:) ! (knon)
43	guez	171	! coeff. B de la resolution de la CL pour t et q
44	guez	54
45	guez	104	real, intent(OUT):: tsurf_new(:) ! (knon) température au sol
46	guez	171	real, intent(OUT):: evap(:) ! (knon)
47
48			real, intent(OUT):: fluxlat(:), fluxsens(:) ! (knon)
49			! flux de chaleur latente et sensible
50
51	guez	104	real, intent(OUT):: dflux_s(:), dflux_l(:) ! (knon)
52	guez	171	! dérivées des flux de chaleurs sensible et latente par rapport à
53			! Ts (W m-2 K-1)
54	guez	54
55	guez	104	! Local:
56			integer i
57			integer knon ! nombre de points a traiter
58	guez	105	real, dimension(size(ps)):: mh, oh, mq, nq, oq
59			real, dimension(size(ps)):: dq_s_dt, coef
60			real qsat(size(ps)) ! qsat en kg/kg
61			real sl(size(ps)) ! chaleur latente d'evaporation ou de sublimation
62			logical delta
63			real zcor
64	guez	104	real, parameter:: t_grnd = 271.35, t_coup = 273.15
65	guez	54
66	guez	104	!---------------------------------------------------------------------
67	guez	54
68	guez	104	knon = assert_eq((/size(tsurf), size(p1lay), size(cal), size(beta), &
69			size(coef1lay), size(ps), size(qsurf), size(radsol), size(dif_grnd), &
70			size(t1lay), size(q1lay), size(u1lay), size(v1lay), size(petAcoef), &
71			size(peqAcoef), size(petBcoef), size(peqBcoef), size(tsurf_new), &
72			size(evap), size(fluxlat), size(fluxsens), size(dflux_s), &
73			size(dflux_l)/), "calcul_fluxs knon")
74	guez	54
75	guez	104	! Traitement humidite du sol
76	guez	54
77	guez	105	IF (thermcep) THEN
78			DO i = 1, knon
79			delta = rtt >= tsurf(i)
80			qsat(i) = MIN(0.5, r2es * FOEEW(tsurf(i), delta) / ps(i))
81			zcor = 1. / (1. - retv * qsat(i))
82			qsat(i) = qsat(i) * zcor
83			dq_s_dt(i) = RCPD * FOEDE(tsurf(i), delta, merge(R5IES * RLSTT, &
84			R5LES * RLVTT, delta) / RCPD / (1. + RVTMP2 * q1lay(i)), &
85			qsat(i), zcor) / RLVTT
86			ENDDO
87			ELSE
88			DO i = 1, knon
89			IF (tsurf(i) < t_coup) THEN
90			qsat(i) = qsats(tsurf(i)) / ps(i)
91			dq_s_dt(i) = RCPD * dqsats(tsurf(i), qsat(i)) / RLVTT
92	guez	54	ELSE
93	guez	105	qsat(i) = qsatl(tsurf(i)) / ps(i)
94			dq_s_dt(i) = RCPD * dqsatl(tsurf(i), qsat(i)) / RLVTT
95	guez	54	ENDIF
96	guez	105	ENDDO
97			ENDIF
98	guez	54
99	guez	105	coef = coef1lay * (1. + SQRT(u1lay2 + v1lay2)) * p1lay / (RD * t1lay)
100			sl = merge(RLSTT, RLVTT, tsurf < RTT)
101	guez	54
102	guez	105	! Q
103			oq = 1. - (beta * coef * peqBcoef * dtime)
104			mq = beta * coef * (peqAcoef - qsat + dq_s_dt * tsurf) / oq
105			nq = beta * coef * (- 1. * dq_s_dt) / oq
106	guez	54
107	guez	105	! H
108			oh = 1. - (coef * petBcoef * dtime)
109			mh = coef * petAcoef / oh
110			dflux_s = - (coef * RCPD)/ oh
111	guez	54
112	guez	105	! Tsurface
113			tsurf_new = (tsurf + cal / RCPD * dtime * (radsol + mh + sl * mq) &
114			+ dif_grnd * t_grnd * dtime) / (1. - dtime * cal / RCPD * (dflux_s &
115			+ sl * nq) + dtime * dif_grnd)
116	guez	54
117	guez	105	evap = - mq - nq * tsurf_new
118			fluxlat = - evap * sl
119			fluxsens = mh + dflux_s * tsurf_new
120			dflux_l = sl * nq
121	guez	54
122	guez	105	! Nouvelle valeur de l'humidité au dessus du sol :
123			qsurf = (peqAcoef - peqBcoef * evap * dtime) * (1. - beta) + beta * (qsat &
124			+ dq_s_dt * (tsurf_new - tsurf))
125	guez	54
126			END SUBROUTINE calcul_fluxs
127
128			end module calcul_fluxs_m