1 |
module calcul_fluxs_m |
2 |
|
3 |
implicit none |
4 |
|
5 |
contains |
6 |
|
7 |
SUBROUTINE calcul_fluxs(tsurf, p1lay, cal, beta, coef1lay, ps, qsurf, & |
8 |
radsol, dif_grnd, t1lay, q1lay, u1lay, v1lay, tAcoef, qAcoef, tBcoef, & |
9 |
qBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, dflux_l) |
10 |
|
11 |
! Cette routine calcule les flux en h et q à l'interface et une |
12 |
! température de surface. |
13 |
|
14 |
! L. Fairhead, April 2000 |
15 |
|
16 |
! Note that, if cal = 0, beta = 1 and dif_grnd = 0, then tsurf_new |
17 |
! = tsurf and qsurf = qsat. |
18 |
|
19 |
! Libraries: |
20 |
use nr_util, only: assert_eq |
21 |
|
22 |
use comconst, only: dtphys |
23 |
USE fcttre, ONLY: foede, foeew |
24 |
USE suphec_m, ONLY: rcpd, rd, retv, rlstt, rlvtt, rtt |
25 |
USE yoethf_m, ONLY: r2es, r5ies, r5les, rvtmp2 |
26 |
|
27 |
real, intent(IN):: tsurf(:) ! (knon) température de surface |
28 |
|
29 |
real, intent(IN):: p1lay(:) ! (knon) |
30 |
! pression première couche (milieu de couche) |
31 |
|
32 |
real, intent(IN):: cal(:) ! (knon) capacité calorifique du sol |
33 |
real, intent(IN):: beta(:) ! (knon) évaporation réelle |
34 |
real, intent(IN):: coef1lay(:) ! (knon) coefficient d'échange |
35 |
real, intent(IN):: ps(:) ! (knon) pression au sol |
36 |
real, intent(OUT):: qsurf(:) ! (knon) humidité de l'air au-dessus du sol |
37 |
|
38 |
real, intent(IN):: radsol(:) ! (knon) |
39 |
! rayonnement net au sol (longwave + shortwave) |
40 |
|
41 |
real, intent(IN):: dif_grnd(:) ! (knon) |
42 |
! coefficient de diffusion vers le sol profond |
43 |
|
44 |
real, intent(IN):: t1lay(:), q1lay(:), u1lay(:), v1lay(:) ! (knon) |
45 |
|
46 |
real, intent(IN):: tAcoef(:), qAcoef(:) ! (knon) |
47 |
! coefficients A de la résolution de la couche limite pour T et q |
48 |
|
49 |
real, intent(IN):: tBcoef(:), qBcoef(:) ! (knon) |
50 |
! coefficients B de la résolution de la couche limite pour t et q |
51 |
|
52 |
real, intent(OUT):: tsurf_new(:) ! (knon) température au sol |
53 |
real, intent(OUT):: evap(:) ! (knon) |
54 |
|
55 |
real, intent(OUT):: fluxlat(:), flux_t(:) ! (knon) |
56 |
! flux de chaleurs latente et sensible |
57 |
|
58 |
real, intent(OUT):: dflux_s(:), dflux_l(:) ! (knon) |
59 |
! dérivées des flux de chaleurs sensible et latente par rapport à |
60 |
! Ts (W m-2 K-1) |
61 |
|
62 |
! Local: |
63 |
integer i |
64 |
integer knon ! nombre de points \`a traiter |
65 |
real, dimension(size(ps)):: mh, oh, mq, nq, oq, dq_s_dt, coef ! (knon) |
66 |
real qsat(size(ps)) ! (knon) mass fraction |
67 |
real sl(size(ps)) ! (knon) chaleur latente d'évaporation ou de sublimation |
68 |
logical delta |
69 |
real zcor |
70 |
real, parameter:: t_grnd = 271.35 |
71 |
|
72 |
!--------------------------------------------------------------------- |
73 |
|
74 |
knon = assert_eq([size(tsurf), size(p1lay), size(cal), size(beta), & |
75 |
size(coef1lay), size(ps), size(qsurf), size(radsol), size(dif_grnd), & |
76 |
size(t1lay), size(q1lay), size(u1lay), size(v1lay), size(tAcoef), & |
77 |
size(qAcoef), size(tBcoef), size(qBcoef), size(tsurf_new), & |
78 |
size(evap), size(fluxlat), size(flux_t), size(dflux_s), & |
79 |
size(dflux_l)], "calcul_fluxs knon") |
80 |
|
81 |
! Traitement de l'humidité du sol |
82 |
|
83 |
DO i = 1, knon |
84 |
delta = rtt >= tsurf(i) |
85 |
qsat(i) = MIN(0.5, r2es * FOEEW(tsurf(i), delta) / ps(i)) |
86 |
zcor = 1. / (1. - retv * qsat(i)) |
87 |
qsat(i) = qsat(i) * zcor |
88 |
dq_s_dt(i) = RCPD * FOEDE(tsurf(i), delta, merge(R5IES * RLSTT, & |
89 |
R5LES * RLVTT, delta) / RCPD / (1. + RVTMP2 * q1lay(i)), & |
90 |
qsat(i), zcor) / RLVTT |
91 |
ENDDO |
92 |
|
93 |
coef = coef1lay * (1. + SQRT(u1lay**2 + v1lay**2)) * p1lay / (RD * t1lay) |
94 |
sl = merge(RLSTT, RLVTT, tsurf < RTT) |
95 |
|
96 |
! Q |
97 |
oq = 1. - beta * coef * qBcoef * dtphys |
98 |
mq = beta * coef * (qAcoef - qsat + dq_s_dt * tsurf) / oq |
99 |
nq = - beta * coef * dq_s_dt / oq |
100 |
|
101 |
! H |
102 |
oh = 1. - coef * tBcoef * dtphys |
103 |
mh = coef * tAcoef / oh |
104 |
dflux_s = - coef * RCPD / oh |
105 |
|
106 |
tsurf_new = (tsurf + cal / RCPD * dtphys * (radsol + mh + sl * mq) & |
107 |
+ dif_grnd * t_grnd * dtphys) / (1. - dtphys * cal / RCPD * (dflux_s & |
108 |
+ sl * nq) + dtphys * dif_grnd) |
109 |
evap = - mq - nq * tsurf_new |
110 |
fluxlat = - evap * sl |
111 |
flux_t = mh + dflux_s * tsurf_new |
112 |
dflux_l = sl * nq |
113 |
qsurf = (qAcoef - qBcoef * evap * dtphys) * (1. - beta) + beta * (qsat & |
114 |
+ dq_s_dt * (tsurf_new - tsurf)) |
115 |
|
116 |
END SUBROUTINE calcul_fluxs |
117 |
|
118 |
end module calcul_fluxs_m |