phylmd/Interface_surf/clqh.f

module clqh_m

  IMPLICIT none

contains

  SUBROUTINE clqh(dtime, julien, debut, nisurf, knindex, tsoil, qsol, rmu0, &
       rugos, rugoro, u1lay, v1lay, coef, tq_cdrag, t, q, ts, paprs, pplay, &
       delp, radsol, albedo, snow, qsurf, precip_rain, precip_snow, fluxlat, &
       pctsrf_new_sic, agesno, d_t, d_q, d_ts, z0_new, flux_t, flux_q, &
       dflux_s, dflux_l, fqcalving, ffonte, run_off_lic_0)

    ! Author: Z. X. Li (LMD/CNRS)
    ! Date: 1993 Aug. 18th
    ! Objet : diffusion verticale de "q" et de "h"

    USE conf_phys_m, ONLY: iflag_pbl
    USE dimphy, ONLY: klev, klon
    USE interfsurf_hq_m, ONLY: interfsurf_hq
    USE suphec_m, ONLY: rcpd, rd, rg, rkappa

    REAL, intent(in):: dtime ! intervalle du temps (s)
    integer, intent(in):: julien ! jour de l'annee en cours
    logical, intent(in):: debut
    integer, intent(in):: nisurf
    integer, intent(in):: knindex(:) ! (knon)
    REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx)

    REAL, intent(inout):: qsol(:) ! (knon)
    ! column-density of water in soil, in kg m-2

    real, intent(in):: rmu0(klon) ! cosinus de l'angle solaire zenithal
    real, intent(in):: rugos(:) ! (knon) rugosite
    REAL, intent(in):: rugoro(:) ! (knon)

    REAL, intent(in):: u1lay(:), v1lay(:) ! (knon)
    ! vitesse de la 1ere couche (m / s)

    REAL, intent(in):: coef(:, 2:) ! (knon, 2:klev)
    ! Le coefficient d'echange (m**2 / s) multiplie par le cisaillement
    ! du vent (dV / dz)

    REAL, intent(in):: tq_cdrag(:) ! (knon) sans unite

    REAL, intent(in):: t(:, :) ! (knon, klev) temperature (K)
    REAL, intent(in):: q(:, :) ! (knon, klev) humidite specifique (kg / kg)
    REAL, intent(in):: ts(:) ! (knon) temperature du sol (K)

    REAL, intent(in):: paprs(:, :) ! (knon, klev + 1)
    ! pression a inter-couche (Pa)

    REAL, intent(in):: pplay(:, :) ! (knon, klev)
    ! pression au milieu de couche (Pa)

    REAL, intent(in):: delp(:, :) ! (knon, klev)
    ! epaisseur de couche en pression (Pa)

    REAL, intent(in):: radsol(:) ! (knon)
    ! rayonnement net au sol (Solaire + IR) W / m2

    REAL, intent(inout):: albedo(:) ! (knon) albedo de la surface
    REAL, intent(inout):: snow(:) ! (knon) ! hauteur de neige

    REAL, intent(out):: qsurf(:) ! (knon)
    ! humidite de l'air au dessus de la surface

    real, intent(in):: precip_rain(klon)
    ! liquid water mass flux (kg / m2 / s), positive down

    real, intent(in):: precip_snow(klon)
    ! solid water mass flux (kg / m2 / s), positive down

    real, intent(out):: fluxlat(:) ! (knon)
    real, intent(in):: pctsrf_new_sic(:) ! (klon)
    REAL, intent(inout):: agesno(:) ! (knon)
    REAL, intent(out):: d_t(:, :) ! (knon, klev) incrementation de "t"
    REAL, intent(out):: d_q(:, :) ! (knon, klev) incrementation de "q"
    REAL, intent(out):: d_ts(:) ! (knon) variation of surface temperature
    real, intent(out):: z0_new(:) ! (knon)

    REAL, intent(out):: flux_t(:) ! (knon)
    ! (diagnostic) flux de chaleur sensible (Cp T) à la surface,
    ! positif vers le bas, W / m2

    REAL, intent(out):: flux_q(:) ! (knon)
    ! flux de la vapeur d'eau à la surface, en kg / (m**2 s)

    REAL, intent(out):: dflux_s(:) ! (knon) derivee du flux sensible dF / dTs
    REAL, intent(out):: dflux_l(:) ! (knon) derivee du flux latent dF / dTs

    REAL, intent(out):: fqcalving(:) ! (knon)
    ! Flux d'eau "perdue" par la surface et n\'ecessaire pour que limiter la
    ! hauteur de neige, en kg / m2 / s

    REAL ffonte(klon)
    ! Flux thermique utiliser pour fondre la neige

    REAL run_off_lic_0(klon)! runof glacier au pas de temps precedent

    ! Local:

    INTEGER knon, k
    REAL evap(size(knindex)) ! (knon) evaporation au sol
    REAL, dimension(size(knindex), klev):: cq, dq, ch, dh ! (knon, klev)
    REAL buf1(size(knindex)), buf2(size(knindex))
    REAL zx_coef(size(knindex), 2:klev) ! (knon, 2:klev)
    REAL h(size(knindex), klev) ! (knon, klev) enthalpie potentielle
    REAL local_q(size(knindex), klev) ! (knon, klev)

    REAL psref(size(knindex)) ! (knon)
    ! pression de reference pour temperature potentielle

    REAL pkf(size(knindex), klev) ! (knon, klev)

    REAL gamt(size(knindex), 2:klev) ! (knon, 2:klev)
    ! contre-gradient pour la chaleur sensible, en K m-1

    REAL gamah(size(knindex), 2:klev) ! (knon, 2:klev)
    real tsurf_new(size(knindex)) ! (knon)

    !----------------------------------------------------------------

    knon = size(knindex)

    if (iflag_pbl == 1) then
       gamt(:, 2) = - 2.5e-3
       gamt(:, 3:)= - 1e-3
    else
       gamt = 0.
    endif

    psref = paprs(:, 1) ! pression de reference est celle au sol
    forall (k = 1:klev) pkf(:, k) = (psref / pplay(:, k))**RKAPPA
    h = RCPD * t * pkf

    ! Convertir les coefficients en variables convenables au calcul:
    forall (k = 2:klev) zx_coef(:, k) = coef(:, k) * RG &
         / (pplay(:, k - 1) - pplay(:, k)) &
         * (paprs(:, k) * 2 / (t(:, k) + t(:, k - 1)) / RD)**2 * dtime * RG

    ! Preparer les flux lies aux contre-gardients
    forall (k = 2:klev) gamah(:, k) = gamt(:, k) * (RD * (t(:, k - 1) &
         + t(:, k)) / 2. / RG / paprs(:, k) * (pplay(:, k - 1) - pplay(:, k))) &
         * RCPD * (psref / paprs(:, k))**RKAPPA

    buf1 = zx_coef(:, klev) + delp(:, klev)
    cq(:, klev) = q(:, klev) * delp(:, klev) / buf1
    dq(:, klev) = zx_coef(:, klev) / buf1

    buf2 = delp(:, klev) / pkf(:, klev) + zx_coef(:, klev)
    ch(:, klev) = (h(:, klev) / pkf(:, klev) * delp(:, klev) &
         - zx_coef(:, klev) * gamah(:, klev)) / buf2
    dh(:, klev) = zx_coef(:, klev) / buf2

    DO k = klev - 1, 2, - 1
       buf1 = delp(:, k) + zx_coef(:, k) &
            + zx_coef(:, k + 1) * (1. - dq(:, k + 1))
       cq(:, k) = (q(:, k) * delp(:, k) &
            + zx_coef(:, k + 1) * cq(:, k + 1)) / buf1
       dq(:, k) = zx_coef(:, k) / buf1

       buf2 = delp(:, k) / pkf(:, k) + zx_coef(:, k) &
            + zx_coef(:, k + 1) * (1. - dh(:, k + 1))
       ch(:, k) = (h(:, k) / pkf(:, k) * delp(:, k) &
            + zx_coef(:, k + 1) * ch(:, k + 1) &
            + zx_coef(:, k + 1) * gamah(:, k + 1) &
            - zx_coef(:, k) * gamah(:, k)) / buf2
       dh(:, k) = zx_coef(:, k) / buf2
    ENDDO

    buf1 = delp(:, 1) + zx_coef(:, 2) * (1. - dq(:, 2))
    cq(:, 1) = (q(:, 1) * delp(:, 1) + zx_coef(:, 2) * cq(:, 2)) / buf1
    dq(:, 1) = - 1. * RG / buf1

    buf2 = delp(:, 1) / pkf(:, 1) + zx_coef(:, 2) * (1. - dh(:, 2))
    ch(:, 1) = (h(:, 1) / pkf(:, 1) * delp(:, 1) &
         + zx_coef(:, 2) * (gamah(:, 2) + ch(:, 2))) / buf2
    dh(:, 1) = - 1. * RG / buf2

    CALL interfsurf_hq(dtime, julien, rmu0, nisurf, knindex, debut, tsoil, &
         qsol, u1lay, v1lay, t(:, 1), q(:, 1), tq_cdrag(:knon), ch(:, 1), &
         cq(:, 1), dh(:, 1), dq(:, 1), precip_rain, precip_snow, rugos, &
         rugoro, snow, qsurf, ts, pplay(:, 1), psref, radsol, evap, flux_t, &
         fluxlat, dflux_l, dflux_s, tsurf_new, albedo, z0_new, pctsrf_new_sic, &
         agesno, fqcalving, ffonte, run_off_lic_0)

    flux_q = - evap
    d_ts = tsurf_new - ts

    h(:, 1) = ch(:, 1) + dh(:, 1) * flux_t * dtime
    local_q(:, 1) = cq(:, 1) + dq(:, 1) * flux_q * dtime

    DO k = 2, klev
       h(:, k) = ch(:, k) + dh(:, k) * h(:, k - 1)
       local_q(:, k) = cq(:, k) + dq(:, k) * local_q(:, k - 1)
    ENDDO

    d_t = h / pkf / RCPD - t
    d_q = local_q - q

  END SUBROUTINE clqh

end module clqh_m
1	guez	49	module clqh_m
2	guez	3
3	guez	38	IMPLICIT none
4	guez	3
5	guez	49	contains
6	guez	3
7	guez	221	SUBROUTINE clqh(dtime, julien, debut, nisurf, knindex, tsoil, qsol, rmu0, &
8	guez	236	rugos, rugoro, u1lay, v1lay, coef, tq_cdrag, t, q, ts, paprs, pplay, &
9			delp, radsol, albedo, snow, qsurf, precip_rain, precip_snow, fluxlat, &
10	guez	206	pctsrf_new_sic, agesno, d_t, d_q, d_ts, z0_new, flux_t, flux_q, &
11			dflux_s, dflux_l, fqcalving, ffonte, run_off_lic_0)
12	guez	3
13	guez	62	! Author: Z. X. Li (LMD/CNRS)
14	guez	279	! Date: 1993 Aug. 18th
15	guez	49	! Objet : diffusion verticale de "q" et de "h"
16	guez	3
17	guez	154	USE conf_phys_m, ONLY: iflag_pbl
18			USE dimphy, ONLY: klev, klon
19			USE interfsurf_hq_m, ONLY: interfsurf_hq
20			USE suphec_m, ONLY: rcpd, rd, rg, rkappa
21	guez	38
22	guez	155	REAL, intent(in):: dtime ! intervalle du temps (s)
23	guez	221	integer, intent(in):: julien ! jour de l'annee en cours
24	guez	154	logical, intent(in):: debut
25	guez	175	integer, intent(in):: nisurf
26	guez	154	integer, intent(in):: knindex(:) ! (knon)
27	guez	208	REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx)
28	guez	202
29	guez	225	REAL, intent(inout):: qsol(:) ! (knon)
30	guez	154	! column-density of water in soil, in kg m-2
31
32	guez	155	real, intent(in):: rmu0(klon) ! cosinus de l'angle solaire zenithal
33	guez	282	real, intent(in):: rugos(:) ! (knon) rugosite
34			REAL, intent(in):: rugoro(:) ! (knon)
35	guez	70
36	guez	225	REAL, intent(in):: u1lay(:), v1lay(:) ! (knon)
37			! vitesse de la 1ere couche (m / s)
38
39	guez	236	REAL, intent(in):: coef(:, 2:) ! (knon, 2:klev)
40	guez	155	! Le coefficient d'echange (m**2 / s) multiplie par le cisaillement
41	guez	236	! du vent (dV / dz)
42	guez	70
43	guez	236	REAL, intent(in):: tq_cdrag(:) ! (knon) sans unite
44
45	guez	280	REAL, intent(in):: t(:, :) ! (knon, klev) temperature (K)
46			REAL, intent(in):: q(:, :) ! (knon, klev) humidite specifique (kg / kg)
47	guez	207	REAL, intent(in):: ts(:) ! (knon) temperature du sol (K)
48	guez	280
49			REAL, intent(in):: paprs(:, :) ! (knon, klev + 1)
50			! pression a inter-couche (Pa)
51
52			REAL, intent(in):: pplay(:, :) ! (knon, klev)
53			! pression au milieu de couche (Pa)
54
55	guez	283	REAL, intent(in):: delp(:, :) ! (knon, klev)
56			! epaisseur de couche en pression (Pa)
57	guez	222
58	guez	267	REAL, intent(in):: radsol(:) ! (knon)
59	guez	222	! rayonnement net au sol (Solaire + IR) W / m2
60
61	guez	155	REAL, intent(inout):: albedo(:) ! (knon) albedo de la surface
62	guez	215	REAL, intent(inout):: snow(:) ! (knon) ! hauteur de neige
63	guez	101
64	guez	283	REAL, intent(out):: qsurf(:) ! (knon)
65			! humidite de l'air au dessus de la surface
66
67	guez	101	real, intent(in):: precip_rain(klon)
68	guez	155	! liquid water mass flux (kg / m2 / s), positive down
69	guez	101
70			real, intent(in):: precip_snow(klon)
71	guez	155	! solid water mass flux (kg / m2 / s), positive down
72	guez	101
73	guez	214	real, intent(out):: fluxlat(:) ! (knon)
74	guez	202	real, intent(in):: pctsrf_new_sic(:) ! (klon)
75	guez	175	REAL, intent(inout):: agesno(:) ! (knon)
76	guez	281	REAL, intent(out):: d_t(:, :) ! (knon, klev) incrementation de "t"
77			REAL, intent(out):: d_q(:, :) ! (knon, klev) incrementation de "q"
78	guez	221	REAL, intent(out):: d_ts(:) ! (knon) variation of surface temperature
79	guez	282	real, intent(out):: z0_new(:) ! (knon)
80	guez	206
81			REAL, intent(out):: flux_t(:) ! (knon)
82			! (diagnostic) flux de chaleur sensible (Cp T) à la surface,
83			! positif vers le bas, W / m2
84
85			REAL, intent(out):: flux_q(:) ! (knon)
86			! flux de la vapeur d'eau à la surface, en kg / (m**2 s)
87
88	guez	283	REAL, intent(out):: dflux_s(:) ! (knon) derivee du flux sensible dF / dTs
89			REAL, intent(out):: dflux_l(:) ! (knon) derivee du flux latent dF / dTs
90	guez	154
91	guez	279	REAL, intent(out):: fqcalving(:) ! (knon)
92	guez	150	! Flux d'eau "perdue" par la surface et n\'ecessaire pour que limiter la
93	guez	155	! hauteur de neige, en kg / m2 / s
94	guez	101
95	guez	279	REAL ffonte(klon)
96	guez	154	! Flux thermique utiliser pour fondre la neige
97
98			REAL run_off_lic_0(klon)! runof glacier au pas de temps precedent
99
100			! Local:
101	guez	285
102			INTEGER knon, k
103	guez	206	REAL evap(size(knindex)) ! (knon) evaporation au sol
104	guez	281	REAL, dimension(size(knindex), klev):: cq, dq, ch, dh ! (knon, klev)
105	guez	283	REAL buf1(size(knindex)), buf2(size(knindex))
106	guez	280	REAL zx_coef(size(knindex), 2:klev) ! (knon, 2:klev)
107			REAL h(size(knindex), klev) ! (knon, klev) enthalpie potentielle
108			REAL local_q(size(knindex), klev) ! (knon, klev)
109	guez	3
110	guez	280	REAL psref(size(knindex)) ! (knon)
111			! pression de reference pour temperature potentielle
112	guez	279
113	guez	280	REAL pkf(size(knindex), klev) ! (knon, klev)
114
115	guez	279	REAL gamt(size(knindex), 2:klev) ! (knon, 2:klev)
116			! contre-gradient pour la chaleur sensible, en K m-1
117
118	guez	280	REAL gamah(size(knindex), 2:klev) ! (knon, 2:klev)
119	guez	206	real tsurf_new(size(knindex)) ! (knon)
120	guez	3
121	guez	49	!----------------------------------------------------------------
122	guez	3
123	guez	206	knon = size(knindex)
124
125	guez	155	if (iflag_pbl == 1) then
126	guez	279	gamt(:, 2) = - 2.5e-3
127			gamt(:, 3:)= - 1e-3
128	guez	49	else
129	guez	279	gamt = 0.
130	guez	49	endif
131
132	guez	280	psref = paprs(:, 1) ! pression de reference est celle au sol
133			forall (k = 1:klev) pkf(:, k) = (psref / pplay(:, k))**RKAPPA
134			h = RCPD * t * pkf
135	guez	49
136			! Convertir les coefficients en variables convenables au calcul:
137	guez	280	forall (k = 2:klev) zx_coef(:, k) = coef(:, k) * RG &
138			/ (pplay(:, k - 1) - pplay(:, k)) &
139			* (paprs(:, k) * 2 / (t(:, k) + t(:, k - 1)) / RD)*2 dtime * RG
140	guez	49
141			! Preparer les flux lies aux contre-gardients
142	guez	280	forall (k = 2:klev) gamah(:, k) = gamt(:, k) * (RD * (t(:, k - 1) &
143			+ t(:, k)) / 2. / RG / paprs(:, k) * (pplay(:, k - 1) - pplay(:, k))) &
144	guez	284	* RCPD * (psref / paprs(:, k))**RKAPPA
145	guez	279
146	guez	285	buf1 = zx_coef(:, klev) + delp(:, klev)
147			cq(:, klev) = q(:, klev) * delp(:, klev) / buf1
148			dq(:, klev) = zx_coef(:, klev) / buf1
149	guez	49
150	guez	285	buf2 = delp(:, klev) / pkf(:, klev) + zx_coef(:, klev)
151			ch(:, klev) = (h(:, klev) / pkf(:, klev) * delp(:, klev) &
152			- zx_coef(:, klev) * gamah(:, klev)) / buf2
153			dh(:, klev) = zx_coef(:, klev) / buf2
154	guez	279
155	guez	155	DO k = klev - 1, 2, - 1
156	guez	285	buf1 = delp(:, k) + zx_coef(:, k) &
157			+ zx_coef(:, k + 1) * (1. - dq(:, k + 1))
158			cq(:, k) = (q(:, k) * delp(:, k) &
159			+ zx_coef(:, k + 1) * cq(:, k + 1)) / buf1
160			dq(:, k) = zx_coef(:, k) / buf1
161	guez	49
162	guez	285	buf2 = delp(:, k) / pkf(:, k) + zx_coef(:, k) &
163			+ zx_coef(:, k + 1) * (1. - dh(:, k + 1))
164			ch(:, k) = (h(:, k) / pkf(:, k) * delp(:, k) &
165			+ zx_coef(:, k + 1) * ch(:, k + 1) &
166			+ zx_coef(:, k + 1) * gamah(:, k + 1) &
167			- zx_coef(:, k) * gamah(:, k)) / buf2
168			dh(:, k) = zx_coef(:, k) / buf2
169	guez	49	ENDDO
170
171	guez	285	buf1 = delp(:, 1) + zx_coef(:, 2) * (1. - dq(:, 2))
172			cq(:, 1) = (q(:, 1) * delp(:, 1) + zx_coef(:, 2) * cq(:, 2)) / buf1
173			dq(:, 1) = - 1. * RG / buf1
174	guez	49
175	guez	285	buf2 = delp(:, 1) / pkf(:, 1) + zx_coef(:, 2) * (1. - dh(:, 2))
176			ch(:, 1) = (h(:, 1) / pkf(:, 1) * delp(:, 1) &
177			+ zx_coef(:, 2) * (gamah(:, 2) + ch(:, 2))) / buf2
178			dh(:, 1) = - 1. * RG / buf2
179	guez	49
180	guez	222	CALL interfsurf_hq(dtime, julien, rmu0, nisurf, knindex, debut, tsoil, &
181	guez	281	qsol, u1lay, v1lay, t(:, 1), q(:, 1), tq_cdrag(:knon), ch(:, 1), &
182			cq(:, 1), dh(:, 1), dq(:, 1), precip_rain, precip_snow, rugos, &
183			rugoro, snow, qsurf, ts, pplay(:, 1), psref, radsol, evap, flux_t, &
184			fluxlat, dflux_l, dflux_s, tsurf_new, albedo, z0_new, pctsrf_new_sic, &
185			agesno, fqcalving, ffonte, run_off_lic_0)
186	guez	49
187	guez	206	flux_q = - evap
188	guez	207	d_ts = tsurf_new - ts
189	guez	49
190	guez	281	h(:, 1) = ch(:, 1) + dh(:, 1) * flux_t * dtime
191			local_q(:, 1) = cq(:, 1) + dq(:, 1) * flux_q * dtime
192
193	guez	49	DO k = 2, klev
194	guez	281	h(:, k) = ch(:, k) + dh(:, k) * h(:, k - 1)
195			local_q(:, k) = cq(:, k) + dq(:, k) * local_q(:, k - 1)
196	guez	49	ENDDO
197	guez	155
198	guez	281	d_t = h / pkf / RCPD - t
199			d_q = local_q - q
200	guez	49
201			END SUBROUTINE clqh
202
203			end module clqh_m