1 |
module clqh_m |
2 |
|
3 |
IMPLICIT none |
4 |
|
5 |
contains |
6 |
|
7 |
SUBROUTINE clqh(dtime, julien, debut, nisurf, knindex, tsoil, qsol, rmu0, & |
8 |
rugos, rugoro, u1lay, v1lay, coef, tq_cdrag, t, q, ts, paprs, pplay, & |
9 |
delp, radsol, albedo, snow, qsurf, precip_rain, precip_snow, fluxlat, & |
10 |
pctsrf_new_sic, agesno, d_t, d_q, d_ts, z0_new, flux_t, flux_q, & |
11 |
dflux_s, dflux_l, fqcalving, ffonte, run_off_lic_0) |
12 |
|
13 |
! Author: Z. X. Li (LMD/CNRS) |
14 |
! Date: 1993 Aug. 18th |
15 |
! Objet : diffusion verticale de "q" et de "h" |
16 |
|
17 |
USE conf_phys_m, ONLY: iflag_pbl |
18 |
USE dimphy, ONLY: klev, klon |
19 |
USE interfsurf_hq_m, ONLY: interfsurf_hq |
20 |
USE suphec_m, ONLY: rcpd, rd, rg, rkappa |
21 |
|
22 |
REAL, intent(in):: dtime ! intervalle du temps (s) |
23 |
integer, intent(in):: julien ! jour de l'annee en cours |
24 |
logical, intent(in):: debut |
25 |
integer, intent(in):: nisurf |
26 |
integer, intent(in):: knindex(:) ! (knon) |
27 |
REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx) |
28 |
|
29 |
REAL, intent(inout):: qsol(:) ! (knon) |
30 |
! column-density of water in soil, in kg m-2 |
31 |
|
32 |
real, intent(in):: rmu0(klon) ! cosinus de l'angle solaire zenithal |
33 |
real, intent(in):: rugos(:) ! (knon) rugosite |
34 |
REAL, intent(in):: rugoro(:) ! (knon) |
35 |
|
36 |
REAL, intent(in):: u1lay(:), v1lay(:) ! (knon) |
37 |
! vitesse de la 1ere couche (m / s) |
38 |
|
39 |
REAL, intent(in):: coef(:, 2:) ! (knon, 2:klev) |
40 |
! Le coefficient d'echange (m**2 / s) multiplie par le cisaillement |
41 |
! du vent (dV / dz) |
42 |
|
43 |
REAL, intent(in):: tq_cdrag(:) ! (knon) sans unite |
44 |
|
45 |
REAL, intent(in):: t(:, :) ! (knon, klev) temperature (K) |
46 |
REAL, intent(in):: q(:, :) ! (knon, klev) humidite specifique (kg / kg) |
47 |
REAL, intent(in):: ts(:) ! (knon) temperature du sol (K) |
48 |
|
49 |
REAL, intent(in):: paprs(:, :) ! (knon, klev + 1) |
50 |
! pression a inter-couche (Pa) |
51 |
|
52 |
REAL, intent(in):: pplay(:, :) ! (knon, klev) |
53 |
! pression au milieu de couche (Pa) |
54 |
|
55 |
REAL, intent(in):: delp(:, :) ! (knon, klev) |
56 |
! epaisseur de couche en pression (Pa) |
57 |
|
58 |
REAL, intent(in):: radsol(:) ! (knon) |
59 |
! rayonnement net au sol (Solaire + IR) W / m2 |
60 |
|
61 |
REAL, intent(inout):: albedo(:) ! (knon) albedo de la surface |
62 |
REAL, intent(inout):: snow(:) ! (knon) ! hauteur de neige |
63 |
|
64 |
REAL, intent(out):: qsurf(:) ! (knon) |
65 |
! humidite de l'air au dessus de la surface |
66 |
|
67 |
real, intent(in):: precip_rain(klon) |
68 |
! liquid water mass flux (kg / m2 / s), positive down |
69 |
|
70 |
real, intent(in):: precip_snow(klon) |
71 |
! solid water mass flux (kg / m2 / s), positive down |
72 |
|
73 |
real, intent(out):: fluxlat(:) ! (knon) |
74 |
real, intent(in):: pctsrf_new_sic(:) ! (klon) |
75 |
REAL, intent(inout):: agesno(:) ! (knon) |
76 |
REAL, intent(out):: d_t(:, :) ! (knon, klev) incrementation de "t" |
77 |
REAL, intent(out):: d_q(:, :) ! (knon, klev) incrementation de "q" |
78 |
REAL, intent(out):: d_ts(:) ! (knon) variation of surface temperature |
79 |
real, intent(out):: z0_new(:) ! (knon) |
80 |
|
81 |
REAL, intent(out):: flux_t(:) ! (knon) |
82 |
! (diagnostic) flux de chaleur sensible (Cp T) à la surface, |
83 |
! positif vers le bas, W / m2 |
84 |
|
85 |
REAL, intent(out):: flux_q(:) ! (knon) |
86 |
! flux de la vapeur d'eau à la surface, en kg / (m**2 s) |
87 |
|
88 |
REAL, intent(out):: dflux_s(:) ! (knon) derivee du flux sensible dF / dTs |
89 |
REAL, intent(out):: dflux_l(:) ! (knon) derivee du flux latent dF / dTs |
90 |
|
91 |
REAL, intent(out):: fqcalving(:) ! (knon) |
92 |
! Flux d'eau "perdue" par la surface et n\'ecessaire pour que limiter la |
93 |
! hauteur de neige, en kg / m2 / s |
94 |
|
95 |
REAL ffonte(klon) |
96 |
! Flux thermique utiliser pour fondre la neige |
97 |
|
98 |
REAL run_off_lic_0(klon)! runof glacier au pas de temps precedent |
99 |
|
100 |
! Local: |
101 |
|
102 |
INTEGER knon, k |
103 |
REAL evap(size(knindex)) ! (knon) evaporation au sol |
104 |
REAL, dimension(size(knindex), klev):: cq, dq, ch, dh ! (knon, klev) |
105 |
REAL buf1(size(knindex)), buf2(size(knindex)) |
106 |
REAL zx_coef(size(knindex), 2:klev) ! (knon, 2:klev) |
107 |
REAL h(size(knindex), klev) ! (knon, klev) enthalpie potentielle |
108 |
REAL local_q(size(knindex), klev) ! (knon, klev) |
109 |
|
110 |
REAL psref(size(knindex)) ! (knon) |
111 |
! pression de reference pour temperature potentielle |
112 |
|
113 |
REAL pkf(size(knindex), klev) ! (knon, klev) |
114 |
|
115 |
REAL gamt(size(knindex), 2:klev) ! (knon, 2:klev) |
116 |
! contre-gradient pour la chaleur sensible, en K m-1 |
117 |
|
118 |
REAL gamah(size(knindex), 2:klev) ! (knon, 2:klev) |
119 |
real tsurf_new(size(knindex)) ! (knon) |
120 |
|
121 |
!---------------------------------------------------------------- |
122 |
|
123 |
knon = size(knindex) |
124 |
|
125 |
if (iflag_pbl == 1) then |
126 |
gamt(:, 2) = - 2.5e-3 |
127 |
gamt(:, 3:)= - 1e-3 |
128 |
else |
129 |
gamt = 0. |
130 |
endif |
131 |
|
132 |
psref = paprs(:, 1) ! pression de reference est celle au sol |
133 |
forall (k = 1:klev) pkf(:, k) = (psref / pplay(:, k))**RKAPPA |
134 |
h = RCPD * t * pkf |
135 |
|
136 |
! Convertir les coefficients en variables convenables au calcul: |
137 |
forall (k = 2:klev) zx_coef(:, k) = coef(:, k) & |
138 |
/ (pplay(:, k - 1) - pplay(:, k)) & |
139 |
* (paprs(:, k) * 2 / (t(:, k) + t(:, k - 1)) / RD)**2 * dtime * RG**2 |
140 |
|
141 |
! Preparer les flux lies aux contre-gardients |
142 |
forall (k = 2:klev) gamah(:, k) = gamt(:, k) * (RD * (t(:, k - 1) & |
143 |
+ t(:, k)) / 2. / RG / paprs(:, k) * (pplay(:, k - 1) - pplay(:, k))) & |
144 |
* RCPD * (psref / paprs(:, k))**RKAPPA |
145 |
|
146 |
buf1 = zx_coef(:, klev) + delp(:, klev) |
147 |
cq(:, klev) = q(:, klev) * delp(:, klev) / buf1 |
148 |
dq(:, klev) = zx_coef(:, klev) / buf1 |
149 |
|
150 |
buf2 = delp(:, klev) / pkf(:, klev) + zx_coef(:, klev) |
151 |
ch(:, klev) = (h(:, klev) / pkf(:, klev) * delp(:, klev) & |
152 |
- zx_coef(:, klev) * gamah(:, klev)) / buf2 |
153 |
dh(:, klev) = zx_coef(:, klev) / buf2 |
154 |
|
155 |
DO k = klev - 1, 2, - 1 |
156 |
buf1 = delp(:, k) + zx_coef(:, k) & |
157 |
+ zx_coef(:, k + 1) * (1. - dq(:, k + 1)) |
158 |
cq(:, k) = (q(:, k) * delp(:, k) & |
159 |
+ zx_coef(:, k + 1) * cq(:, k + 1)) / buf1 |
160 |
dq(:, k) = zx_coef(:, k) / buf1 |
161 |
|
162 |
buf2 = delp(:, k) / pkf(:, k) + zx_coef(:, k) & |
163 |
+ zx_coef(:, k + 1) * (1. - dh(:, k + 1)) |
164 |
ch(:, k) = (h(:, k) / pkf(:, k) * delp(:, k) & |
165 |
+ zx_coef(:, k + 1) * ch(:, k + 1) & |
166 |
+ zx_coef(:, k + 1) * gamah(:, k + 1) & |
167 |
- zx_coef(:, k) * gamah(:, k)) / buf2 |
168 |
dh(:, k) = zx_coef(:, k) / buf2 |
169 |
ENDDO |
170 |
|
171 |
buf1 = delp(:, 1) + zx_coef(:, 2) * (1. - dq(:, 2)) |
172 |
cq(:, 1) = (q(:, 1) * delp(:, 1) + zx_coef(:, 2) * cq(:, 2)) / buf1 |
173 |
dq(:, 1) = - 1. * RG / buf1 |
174 |
|
175 |
buf2 = delp(:, 1) / pkf(:, 1) + zx_coef(:, 2) * (1. - dh(:, 2)) |
176 |
ch(:, 1) = (h(:, 1) / pkf(:, 1) * delp(:, 1) & |
177 |
+ zx_coef(:, 2) * (gamah(:, 2) + ch(:, 2))) / buf2 |
178 |
dh(:, 1) = - 1. * RG / buf2 |
179 |
|
180 |
CALL interfsurf_hq(dtime, julien, rmu0, nisurf, knindex, debut, tsoil, & |
181 |
qsol, u1lay, v1lay, t(:, 1), q(:, 1), tq_cdrag(:knon), ch(:, 1), & |
182 |
cq(:, 1), dh(:, 1), dq(:, 1), precip_rain, precip_snow, rugos, & |
183 |
rugoro, snow, qsurf, ts, pplay(:, 1), psref, radsol, evap, flux_t, & |
184 |
fluxlat, dflux_l, dflux_s, tsurf_new, albedo, z0_new, pctsrf_new_sic, & |
185 |
agesno, fqcalving, ffonte, run_off_lic_0) |
186 |
|
187 |
flux_q = - evap |
188 |
d_ts = tsurf_new - ts |
189 |
|
190 |
h(:, 1) = ch(:, 1) + dh(:, 1) * flux_t * dtime |
191 |
local_q(:, 1) = cq(:, 1) + dq(:, 1) * flux_q * dtime |
192 |
|
193 |
DO k = 2, klev |
194 |
h(:, k) = ch(:, k) + dh(:, k) * h(:, k - 1) |
195 |
local_q(:, k) = cq(:, k) + dq(:, k) * local_q(:, k - 1) |
196 |
ENDDO |
197 |
|
198 |
d_t = h / pkf / RCPD - t |
199 |
d_q = local_q - q |
200 |
|
201 |
END SUBROUTINE clqh |
202 |
|
203 |
end module clqh_m |