| 1 |
module clqh_m |
| 2 |
|
| 3 |
IMPLICIT none |
| 4 |
|
| 5 |
contains |
| 6 |
|
| 7 |
SUBROUTINE clqh(dtime, julien, debut, nisurf, knindex, tsoil, qsol, rmu0, & |
| 8 |
rugos, rugoro, u1lay, v1lay, coef, tq_cdrag, t, q, ts, paprs, pplay, & |
| 9 |
delp, radsol, albedo, snow, qsurf, precip_rain, precip_snow, fluxlat, & |
| 10 |
pctsrf_new_sic, agesno, d_t, d_q, d_ts, z0_new, flux_t, flux_q, & |
| 11 |
dflux_s, dflux_l, fqcalving, ffonte, run_off_lic_0) |
| 12 |
|
| 13 |
! Author: Z. X. Li (LMD/CNRS) |
| 14 |
! Date: 1993 Aug. 18th |
| 15 |
! Objet : diffusion verticale de "q" et de "h" |
| 16 |
|
| 17 |
USE conf_phys_m, ONLY: iflag_pbl |
| 18 |
USE dimphy, ONLY: klev, klon |
| 19 |
USE interfsurf_hq_m, ONLY: interfsurf_hq |
| 20 |
USE suphec_m, ONLY: rcpd, rd, rg, rkappa |
| 21 |
|
| 22 |
REAL, intent(in):: dtime ! intervalle du temps (s) |
| 23 |
integer, intent(in):: julien ! jour de l'annee en cours |
| 24 |
logical, intent(in):: debut |
| 25 |
integer, intent(in):: nisurf |
| 26 |
integer, intent(in):: knindex(:) ! (knon) |
| 27 |
REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx) |
| 28 |
|
| 29 |
REAL, intent(inout):: qsol(:) ! (knon) |
| 30 |
! column-density of water in soil, in kg m-2 |
| 31 |
|
| 32 |
real, intent(in):: rmu0(klon) ! cosinus de l'angle solaire zenithal |
| 33 |
real rugos(klon) ! rugosite |
| 34 |
REAL rugoro(klon) |
| 35 |
|
| 36 |
REAL, intent(in):: u1lay(:), v1lay(:) ! (knon) |
| 37 |
! vitesse de la 1ere couche (m / s) |
| 38 |
|
| 39 |
REAL, intent(in):: coef(:, 2:) ! (knon, 2:klev) |
| 40 |
! Le coefficient d'echange (m**2 / s) multiplie par le cisaillement |
| 41 |
! du vent (dV / dz) |
| 42 |
|
| 43 |
REAL, intent(in):: tq_cdrag(:) ! (knon) sans unite |
| 44 |
|
| 45 |
REAL, intent(in):: t(:, :) ! (knon, klev) temperature (K) |
| 46 |
REAL, intent(in):: q(:, :) ! (knon, klev) humidite specifique (kg / kg) |
| 47 |
REAL, intent(in):: ts(:) ! (knon) temperature du sol (K) |
| 48 |
|
| 49 |
REAL, intent(in):: paprs(:, :) ! (knon, klev + 1) |
| 50 |
! pression a inter-couche (Pa) |
| 51 |
|
| 52 |
REAL, intent(in):: pplay(:, :) ! (knon, klev) |
| 53 |
! pression au milieu de couche (Pa) |
| 54 |
|
| 55 |
REAL delp(klon, klev) ! epaisseur de couche en pression (Pa) |
| 56 |
|
| 57 |
REAL, intent(in):: radsol(:) ! (knon) |
| 58 |
! rayonnement net au sol (Solaire + IR) W / m2 |
| 59 |
|
| 60 |
REAL, intent(inout):: albedo(:) ! (knon) albedo de la surface |
| 61 |
REAL, intent(inout):: snow(:) ! (knon) ! hauteur de neige |
| 62 |
REAL qsurf(klon) ! humidite de l'air au dessus de la surface |
| 63 |
|
| 64 |
real, intent(in):: precip_rain(klon) |
| 65 |
! liquid water mass flux (kg / m2 / s), positive down |
| 66 |
|
| 67 |
real, intent(in):: precip_snow(klon) |
| 68 |
! solid water mass flux (kg / m2 / s), positive down |
| 69 |
|
| 70 |
real, intent(out):: fluxlat(:) ! (knon) |
| 71 |
real, intent(in):: pctsrf_new_sic(:) ! (klon) |
| 72 |
REAL, intent(inout):: agesno(:) ! (knon) |
| 73 |
REAL d_t(klon, klev) ! incrementation de "t" |
| 74 |
REAL d_q(klon, klev) ! incrementation de "q" |
| 75 |
REAL, intent(out):: d_ts(:) ! (knon) variation of surface temperature |
| 76 |
real z0_new(klon) |
| 77 |
|
| 78 |
REAL, intent(out):: flux_t(:) ! (knon) |
| 79 |
! (diagnostic) flux de chaleur sensible (Cp T) à la surface, |
| 80 |
! positif vers le bas, W / m2 |
| 81 |
|
| 82 |
REAL, intent(out):: flux_q(:) ! (knon) |
| 83 |
! flux de la vapeur d'eau à la surface, en kg / (m**2 s) |
| 84 |
|
| 85 |
REAL dflux_s(:) ! (knon) derivee du flux sensible dF / dTs |
| 86 |
REAL dflux_l(:) ! (knon) derivee du flux latent dF / dTs |
| 87 |
|
| 88 |
REAL, intent(out):: fqcalving(:) ! (knon) |
| 89 |
! Flux d'eau "perdue" par la surface et n\'ecessaire pour que limiter la |
| 90 |
! hauteur de neige, en kg / m2 / s |
| 91 |
|
| 92 |
REAL ffonte(klon) |
| 93 |
! Flux thermique utiliser pour fondre la neige |
| 94 |
|
| 95 |
REAL run_off_lic_0(klon)! runof glacier au pas de temps precedent |
| 96 |
|
| 97 |
! Local: |
| 98 |
|
| 99 |
INTEGER knon |
| 100 |
REAL evap(size(knindex)) ! (knon) evaporation au sol |
| 101 |
|
| 102 |
INTEGER i, k |
| 103 |
REAL cq(klon, klev), dq(klon, klev), zx_ch(klon, klev), zx_dh(klon, klev) |
| 104 |
REAL buf1(klon), buf2(klon) |
| 105 |
REAL zx_coef(size(knindex), 2:klev) ! (knon, 2:klev) |
| 106 |
REAL h(size(knindex), klev) ! (knon, klev) enthalpie potentielle |
| 107 |
REAL local_q(size(knindex), klev) ! (knon, klev) |
| 108 |
|
| 109 |
REAL psref(size(knindex)) ! (knon) |
| 110 |
! pression de reference pour temperature potentielle |
| 111 |
|
| 112 |
REAL pkf(size(knindex), klev) ! (knon, klev) |
| 113 |
|
| 114 |
REAL gamt(size(knindex), 2:klev) ! (knon, 2:klev) |
| 115 |
! contre-gradient pour la chaleur sensible, en K m-1 |
| 116 |
|
| 117 |
REAL gamah(size(knindex), 2:klev) ! (knon, 2:klev) |
| 118 |
real temp_air(klon), spechum(klon) |
| 119 |
real petAcoef(klon), peqAcoef(klon) |
| 120 |
real petBcoef(klon), peqBcoef(klon) |
| 121 |
real p1lay(klon) |
| 122 |
real tsurf_new(size(knindex)) ! (knon) |
| 123 |
real zzpk |
| 124 |
|
| 125 |
!---------------------------------------------------------------- |
| 126 |
|
| 127 |
knon = size(knindex) |
| 128 |
|
| 129 |
if (iflag_pbl == 1) then |
| 130 |
gamt(:, 2) = - 2.5e-3 |
| 131 |
gamt(:, 3:)= - 1e-3 |
| 132 |
else |
| 133 |
gamt = 0. |
| 134 |
endif |
| 135 |
|
| 136 |
psref = paprs(:, 1) ! pression de reference est celle au sol |
| 137 |
forall (k = 1:klev) pkf(:, k) = (psref / pplay(:, k))**RKAPPA |
| 138 |
h = RCPD * t * pkf |
| 139 |
|
| 140 |
! Convertir les coefficients en variables convenables au calcul: |
| 141 |
forall (k = 2:klev) zx_coef(:, k) = coef(:, k) * RG & |
| 142 |
/ (pplay(:, k - 1) - pplay(:, k)) & |
| 143 |
* (paprs(:, k) * 2 / (t(:, k) + t(:, k - 1)) / RD)**2 * dtime * RG |
| 144 |
|
| 145 |
! Preparer les flux lies aux contre-gardients |
| 146 |
|
| 147 |
forall (k = 2:klev) gamah(:, k) = gamt(:, k) * (RD * (t(:, k - 1) & |
| 148 |
+ t(:, k)) / 2. / RG / paprs(:, k) * (pplay(:, k - 1) - pplay(:, k))) & |
| 149 |
* RCPD * (psref(:) / paprs(:, k))**RKAPPA |
| 150 |
|
| 151 |
DO i = 1, knon |
| 152 |
buf1(i) = zx_coef(i, klev) + delp(i, klev) |
| 153 |
cq(i, klev) = q(i, klev) * delp(i, klev) / buf1(i) |
| 154 |
dq(i, klev) = zx_coef(i, klev) / buf1(i) |
| 155 |
|
| 156 |
zzpk=(pplay(i, klev) / psref(i))**RKAPPA |
| 157 |
buf2(i) = zzpk * delp(i, klev) + zx_coef(i, klev) |
| 158 |
zx_ch(i, klev) = (h(i, klev) * zzpk * delp(i, klev) & |
| 159 |
- zx_coef(i, klev) * gamah(i, klev)) / buf2(i) |
| 160 |
zx_dh(i, klev) = zx_coef(i, klev) / buf2(i) |
| 161 |
ENDDO |
| 162 |
|
| 163 |
DO k = klev - 1, 2, - 1 |
| 164 |
DO i = 1, knon |
| 165 |
buf1(i) = delp(i, k) + zx_coef(i, k) & |
| 166 |
+ zx_coef(i, k + 1) * (1. - dq(i, k + 1)) |
| 167 |
cq(i, k) = (q(i, k) * delp(i, k) & |
| 168 |
+ zx_coef(i, k + 1) * cq(i, k + 1)) / buf1(i) |
| 169 |
dq(i, k) = zx_coef(i, k) / buf1(i) |
| 170 |
|
| 171 |
zzpk=(pplay(i, k) / psref(i))**RKAPPA |
| 172 |
buf2(i) = zzpk * delp(i, k) + zx_coef(i, k) & |
| 173 |
+ zx_coef(i, k + 1) * (1. - zx_dh(i, k + 1)) |
| 174 |
zx_ch(i, k) = (h(i, k) * zzpk * delp(i, k) & |
| 175 |
+ zx_coef(i, k + 1) * zx_ch(i, k + 1) & |
| 176 |
+ zx_coef(i, k + 1) * gamah(i, k + 1) & |
| 177 |
- zx_coef(i, k) * gamah(i, k)) / buf2(i) |
| 178 |
zx_dh(i, k) = zx_coef(i, k) / buf2(i) |
| 179 |
ENDDO |
| 180 |
ENDDO |
| 181 |
|
| 182 |
DO i = 1, knon |
| 183 |
buf1(i) = delp(i, 1) + zx_coef(i, 2) * (1. - dq(i, 2)) |
| 184 |
cq(i, 1) = (q(i, 1) * delp(i, 1) & |
| 185 |
+ zx_coef(i, 2) * cq(i, 2)) / buf1(i) |
| 186 |
dq(i, 1) = - 1. * RG / buf1(i) |
| 187 |
|
| 188 |
zzpk=(pplay(i, 1) / psref(i))**RKAPPA |
| 189 |
buf2(i) = zzpk * delp(i, 1) + zx_coef(i, 2) * (1. - zx_dh(i, 2)) |
| 190 |
zx_ch(i, 1) = (h(i, 1) * zzpk * delp(i, 1) & |
| 191 |
+ zx_coef(i, 2) * (gamah(i, 2) + zx_ch(i, 2))) / buf2(i) |
| 192 |
zx_dh(i, 1) = - 1. * RG / buf2(i) |
| 193 |
ENDDO |
| 194 |
|
| 195 |
! Initialisation |
| 196 |
petAcoef =0. |
| 197 |
peqAcoef = 0. |
| 198 |
petBcoef =0. |
| 199 |
peqBcoef = 0. |
| 200 |
p1lay =0. |
| 201 |
|
| 202 |
petAcoef(1:knon) = zx_ch(1:knon, 1) |
| 203 |
peqAcoef(1:knon) = cq(1:knon, 1) |
| 204 |
petBcoef(1:knon) = zx_dh(1:knon, 1) |
| 205 |
peqBcoef(1:knon) = dq(1:knon, 1) |
| 206 |
temp_air(1:knon) = t(:, 1) |
| 207 |
spechum(1:knon) = q(:, 1) |
| 208 |
p1lay(1:knon) = pplay(:, 1) |
| 209 |
|
| 210 |
CALL interfsurf_hq(dtime, julien, rmu0, nisurf, knindex, debut, tsoil, & |
| 211 |
qsol, u1lay, v1lay, temp_air, spechum, tq_cdrag(:knon), petAcoef, & |
| 212 |
peqAcoef, petBcoef, peqBcoef, precip_rain, precip_snow, rugos, & |
| 213 |
rugoro, snow, qsurf, ts, p1lay, psref, radsol, evap, flux_t, fluxlat, & |
| 214 |
dflux_l, dflux_s, tsurf_new, albedo, z0_new, pctsrf_new_sic, agesno, & |
| 215 |
fqcalving, ffonte, run_off_lic_0) |
| 216 |
|
| 217 |
flux_q = - evap |
| 218 |
d_ts = tsurf_new - ts |
| 219 |
|
| 220 |
DO i = 1, knon |
| 221 |
h(i, 1) = zx_ch(i, 1) + zx_dh(i, 1) * flux_t(i) * dtime |
| 222 |
local_q(i, 1) = cq(i, 1) + dq(i, 1) * flux_q(i) * dtime |
| 223 |
ENDDO |
| 224 |
DO k = 2, klev |
| 225 |
DO i = 1, knon |
| 226 |
local_q(i, k) = cq(i, k) + dq(i, k) * local_q(i, k - 1) |
| 227 |
h(i, k) = zx_ch(i, k) + zx_dh(i, k) * h(i, k - 1) |
| 228 |
ENDDO |
| 229 |
ENDDO |
| 230 |
|
| 231 |
! Calcul des tendances |
| 232 |
DO k = 1, klev |
| 233 |
DO i = 1, knon |
| 234 |
d_t(i, k) = h(i, k) / pkf(i, k) / RCPD - t(i, k) |
| 235 |
d_q(i, k) = local_q(i, k) - q(i, k) |
| 236 |
ENDDO |
| 237 |
ENDDO |
| 238 |
|
| 239 |
END SUBROUTINE clqh |
| 240 |
|
| 241 |
end module clqh_m |
Parent Directory
| 
Revision Log