phylmd/Interface_surf/clvent.f

module clvent_m

  IMPLICIT none

contains

  SUBROUTINE clvent(u1lay, v1lay, coef, cdrag, t, ven, paprs, pplay, delp, &
       d_ven, flux_v)

    ! Author: Z. X. Li (LMD/CNRS)
    ! Date: 1993/08/18
    ! Objet : diffusion verticale de la vitesse

    use nr_util, only: assert

    use comconst, only: dtphys
    USE dimphy, ONLY: klev
    USE suphec_m, ONLY: rd, rg

    REAL, intent(in):: u1lay(:), v1lay(:) ! (knon)
    ! vent de la premiere couche (m / s)

    REAL, intent(in):: coef(:, 2:) ! (knon, 2:klev)
    ! Coefficient d'echange (m**2 / s) multiplié par le cisaillement du
    ! vent (dV / dz)

    REAL, intent(in):: cdrag(:) ! (knon) sans unité
    REAL, intent(in):: t(:, :) ! (knon, klev) ! temperature (K)
    REAL, intent(in):: ven(:, :) ! (knon, klev) vitesse horizontale (m / s)
    REAL, intent(in):: paprs(:, :) ! (knon, klev + 1) pression a
    ! inter-couche (Pa)
    real, intent(in):: pplay(:, :) ! (knon, klev) pression au milieu
    ! de couche (Pa)
    real, intent(in):: delp(:, :) ! (knon, klev) epaisseur de couche (Pa)
    REAL, intent(out):: d_ven(:, :) ! (knon, klev) ! le changement de "ven"

    REAL, intent(out):: flux_v(:) ! (knon)
    ! (diagnostic) flux du vent à la surface, en (kg m / s) / (m**2 s)
    ! flux_v est le flux de moment angulaire (positif vers bas)

    ! Local:
    INTEGER k
    REAL zx_cv(size(u1lay), 2:klev) ! (knon, 2:klev)
    REAL zx_dv(size(u1lay), 2:klev) ! (knon, 2:klev)
    REAL zx_buf(size(u1lay)) ! (knon)
    REAL zx_coef(size(u1lay), klev) ! (knon, klev)
    REAL local_ven(size(u1lay), klev) ! (knon, klev)

    !------------------------------------------------------------------

    call assert(size(u1lay) == [size(v1lay), size(coef, 1), size(t, 1), &
         size(ven, 1), size(paprs, 1), size(pplay, 1), size(delp, 1), &
         size(d_ven, 1), size(flux_v)], "clvent knon")

    zx_coef(:, 1) = cdrag * (1. + SQRT(u1lay**2 + v1lay**2)) * pplay(:, 1) &
         / (RD * t(:, 1)) * dtphys * RG

    DO k = 2, klev
       zx_coef(:, k) = coef(:, k) * RG / (pplay(:, k - 1) - pplay(:, k)) &
            * (paprs(:, k) * 2 / (t(:, k) + t(:, k - 1)) / RD)**2 * dtphys * RG
    ENDDO

    zx_buf = delp(:, 1) + zx_coef(:, 1) + zx_coef(:, 2)
    zx_cv(:, 2) = ven(:, 1) * delp(:, 1) / zx_buf
    zx_dv(:, 2) = zx_coef(:, 2) / zx_buf

    DO k = 3, klev
       zx_buf = delp(:, k - 1) + zx_coef(:, k) &
            + zx_coef(:, k - 1) * (1. - zx_dv(:, k - 1))
       zx_cv(:, k) = (ven(:, k - 1) * delp(:, k - 1) &
            + zx_coef(:, k - 1) * zx_cv(:, k - 1)) / zx_buf
       zx_dv(:, k) = zx_coef(:, k) / zx_buf
    ENDDO

    local_ven(:, klev) = (ven(:, klev) * delp(:, klev) &
         + zx_coef(:, klev) * zx_cv(:, klev)) &
         / (delp(:, klev) + zx_coef(:, klev) &
         - zx_coef(:, klev) * zx_dv(:, klev))

    DO k = klev - 1, 1, - 1
       local_ven(:, k) = zx_cv(:, k + 1) + zx_dv(:, k + 1) * local_ven(:, k + 1)
    ENDDO

    flux_v = zx_coef(:, 1) / (RG * dtphys) * local_ven(:, 1)
    d_ven = local_ven - ven

  END SUBROUTINE clvent

end module clvent_m
1	guez	62	module clvent_m
2
3			IMPLICIT none
4
5			contains
6
7	guez	298	SUBROUTINE clvent(u1lay, v1lay, coef, cdrag, t, ven, paprs, pplay, delp, &
8			d_ven, flux_v)
9	guez	62
10	guez	70	! Author: Z. X. Li (LMD/CNRS)
11			! Date: 1993/08/18
12	guez	62	! Objet : diffusion verticale de la vitesse
13
14	guez	286	use nr_util, only: assert
15
16	guez	298	use comconst, only: dtphys
17	guez	229	USE dimphy, ONLY: klev
18	guez	62	USE suphec_m, ONLY: rd, rg
19
20	guez	225	REAL, intent(in):: u1lay(:), v1lay(:) ! (knon)
21	guez	247	! vent de la premiere couche (m / s)
22	guez	70
23	guez	231	REAL, intent(in):: coef(:, 2:) ! (knon, 2:klev)
24	guez	247	! Coefficient d'echange (m**2 / s) multiplié par le cisaillement du
25			! vent (dV / dz)
26	guez	70
27	guez	231	REAL, intent(in):: cdrag(:) ! (knon) sans unité
28	guez	229	REAL, intent(in):: t(:, :) ! (knon, klev) ! temperature (K)
29	guez	247	REAL, intent(in):: ven(:, :) ! (knon, klev) vitesse horizontale (m / s)
30			REAL, intent(in):: paprs(:, :) ! (knon, klev + 1) pression a
31			! inter-couche (Pa)
32	guez	229	real, intent(in):: pplay(:, :) ! (knon, klev) pression au milieu
33	guez	247	! de couche (Pa)
34	guez	229	real, intent(in):: delp(:, :) ! (knon, klev) epaisseur de couche (Pa)
35			REAL, intent(out):: d_ven(:, :) ! (knon, klev) ! le changement de "ven"
36	guez	62
37	guez	206	REAL, intent(out):: flux_v(:) ! (knon)
38	guez	247	! (diagnostic) flux du vent à la surface, en (kg m / s) / (m**2 s)
39	guez	206	! flux_v est le flux de moment angulaire (positif vers bas)
40
41	guez	70	! Local:
42	guez	247	INTEGER k
43	guez	229	REAL zx_cv(size(u1lay), 2:klev) ! (knon, 2:klev)
44			REAL zx_dv(size(u1lay), 2:klev) ! (knon, 2:klev)
45			REAL zx_buf(size(u1lay)) ! (knon)
46			REAL zx_coef(size(u1lay), klev) ! (knon, klev)
47			REAL local_ven(size(u1lay), klev) ! (knon, klev)
48	guez	62
49			!------------------------------------------------------------------
50
51	guez	247	call assert(size(u1lay) == [size(v1lay), size(coef, 1), size(t, 1), &
52	guez	229	size(ven, 1), size(paprs, 1), size(pplay, 1), size(delp, 1), &
53			size(d_ven, 1), size(flux_v)], "clvent knon")
54	guez	62
55	guez	247	zx_coef(:, 1) = cdrag * (1. + SQRT(u1lay2 + v1lay2)) * pplay(:, 1) &
56	guez	298	/ (RD * t(:, 1)) * dtphys * RG
57	guez	62
58			DO k = 2, klev
59	guez	247	zx_coef(:, k) = coef(:, k) * RG / (pplay(:, k - 1) - pplay(:, k)) &
60	guez	298	* (paprs(:, k) * 2 / (t(:, k) + t(:, k - 1)) / RD)*2 dtphys * RG
61	guez	62	ENDDO
62
63	guez	247	zx_buf = delp(:, 1) + zx_coef(:, 1) + zx_coef(:, 2)
64			zx_cv(:, 2) = ven(:, 1) * delp(:, 1) / zx_buf
65			zx_dv(:, 2) = zx_coef(:, 2) / zx_buf
66
67	guez	62	DO k = 3, klev
68	guez	247	zx_buf = delp(:, k - 1) + zx_coef(:, k) &
69			+ zx_coef(:, k - 1) * (1. - zx_dv(:, k - 1))
70			zx_cv(:, k) = (ven(:, k - 1) * delp(:, k - 1) &
71			+ zx_coef(:, k - 1) * zx_cv(:, k - 1)) / zx_buf
72			zx_dv(:, k) = zx_coef(:, k) / zx_buf
73	guez	62	ENDDO
74
75	guez	247	local_ven(:, klev) = (ven(:, klev) * delp(:, klev) &
76			+ zx_coef(:, klev) * zx_cv(:, klev)) &
77			/ (delp(:, klev) + zx_coef(:, klev) &
78			- zx_coef(:, klev) * zx_dv(:, klev))
79	guez	62
80	guez	247	DO k = klev - 1, 1, - 1
81			local_ven(:, k) = zx_cv(:, k + 1) + zx_dv(:, k + 1) * local_ven(:, k + 1)
82	guez	62	ENDDO
83
84	guez	298	flux_v = zx_coef(:, 1) / (RG * dtphys) * local_ven(:, 1)
85	guez	247	d_ven = local_ven - ven
86
87	guez	62	END SUBROUTINE clvent
88
89			end module clvent_m