| 1 |
module clvent_m |
| 2 |
|
| 3 |
IMPLICIT none |
| 4 |
|
| 5 |
contains |
| 6 |
|
| 7 |
SUBROUTINE clvent(u1lay, v1lay, coef, cdrag, t, ven, paprs, pplay, delp, & |
| 8 |
d_ven, flux_v) |
| 9 |
|
| 10 |
! Author: Z. X. Li (LMD/CNRS) |
| 11 |
! Date: 1993/08/18 |
| 12 |
! Objet : diffusion verticale de la vitesse |
| 13 |
|
| 14 |
! Library: |
| 15 |
use nr_util, only: assert |
| 16 |
|
| 17 |
use comconst, only: dtphys |
| 18 |
USE dimphy, ONLY: klev |
| 19 |
USE suphec_m, ONLY: rd, rg |
| 20 |
|
| 21 |
REAL, intent(in):: u1lay(:), v1lay(:) ! (knon) |
| 22 |
! vent de la premiere couche (m / s) |
| 23 |
|
| 24 |
REAL, intent(in):: coef(:, 2:) ! (knon, 2:klev) |
| 25 |
! Coefficient d'echange (m**2 / s) multiplié par le cisaillement du |
| 26 |
! vent (dV / dz) |
| 27 |
|
| 28 |
REAL, intent(in):: cdrag(:) ! (knon) sans dimension |
| 29 |
REAL, intent(in):: t(:, :) ! (knon, klev) ! temperature (K) |
| 30 |
REAL, intent(in):: ven(:, :) ! (knon, klev) vitesse horizontale (m / s) |
| 31 |
REAL, intent(in):: paprs(:, :) ! (knon, klev + 1) pression a |
| 32 |
! inter-couche (Pa) |
| 33 |
real, intent(in):: pplay(:, :) ! (knon, klev) pression au milieu |
| 34 |
! de couche (Pa) |
| 35 |
real, intent(in):: delp(:, :) ! (knon, klev) epaisseur de couche (Pa) |
| 36 |
|
| 37 |
REAL, intent(out):: d_ven(:, :) ! (knon, klev) |
| 38 |
! le changement de "ven", en m s-1 |
| 39 |
|
| 40 |
REAL, intent(out):: flux_v(:) ! (knon) |
| 41 |
! (diagnostic) stress du vent à la surface, en Pa |
| 42 |
! flux_v est le flux de quantité de mouvement (positif vers bas) |
| 43 |
|
| 44 |
! Local: |
| 45 |
INTEGER k |
| 46 |
REAL zx_cv(size(u1lay), 2:klev) ! (knon, 2:klev) |
| 47 |
REAL zx_dv(size(u1lay), 2:klev) ! (knon, 2:klev) |
| 48 |
REAL zx_buf(size(u1lay)) ! (knon) |
| 49 |
REAL zx_coef(size(u1lay), klev) ! (knon, klev) in Pa |
| 50 |
REAL local_ven(size(u1lay), klev) ! (knon, klev) in m s-1 |
| 51 |
|
| 52 |
!------------------------------------------------------------------ |
| 53 |
|
| 54 |
call assert(size(u1lay) == [size(v1lay), size(coef, 1), size(t, 1), & |
| 55 |
size(ven, 1), size(paprs, 1), size(pplay, 1), size(delp, 1), & |
| 56 |
size(d_ven, 1), size(flux_v)], "clvent knon") |
| 57 |
|
| 58 |
zx_coef(:, 1) = cdrag * (1. + SQRT(u1lay**2 + v1lay**2)) * pplay(:, 1) & |
| 59 |
/ (RD * t(:, 1)) * dtphys * RG |
| 60 |
|
| 61 |
forall (k = 2:klev) zx_coef(:, k) = coef(:, k) * RG / (pplay(:, k - 1) & |
| 62 |
- pplay(:, k)) * (paprs(:, k) * 2 / (t(:, k) + t(:, k - 1)) / RD)**2 & |
| 63 |
* dtphys * RG |
| 64 |
|
| 65 |
zx_buf = delp(:, 1) + zx_coef(:, 1) + zx_coef(:, 2) |
| 66 |
zx_cv(:, 2) = ven(:, 1) * delp(:, 1) / zx_buf |
| 67 |
zx_dv(:, 2) = zx_coef(:, 2) / zx_buf |
| 68 |
|
| 69 |
DO k = 3, klev |
| 70 |
zx_buf = delp(:, k - 1) + zx_coef(:, k) & |
| 71 |
+ zx_coef(:, k - 1) * (1. - zx_dv(:, k - 1)) |
| 72 |
zx_cv(:, k) = (ven(:, k - 1) * delp(:, k - 1) & |
| 73 |
+ zx_coef(:, k - 1) * zx_cv(:, k - 1)) / zx_buf |
| 74 |
zx_dv(:, k) = zx_coef(:, k) / zx_buf |
| 75 |
ENDDO |
| 76 |
|
| 77 |
local_ven(:, klev) = (ven(:, klev) * delp(:, klev) & |
| 78 |
+ zx_coef(:, klev) * zx_cv(:, klev)) & |
| 79 |
/ (delp(:, klev) + zx_coef(:, klev) & |
| 80 |
- zx_coef(:, klev) * zx_dv(:, klev)) |
| 81 |
|
| 82 |
DO k = klev - 1, 1, - 1 |
| 83 |
local_ven(:, k) = zx_cv(:, k + 1) + zx_dv(:, k + 1) * local_ven(:, k + 1) |
| 84 |
ENDDO |
| 85 |
|
| 86 |
flux_v = zx_coef(:, 1) / (RG * dtphys) * local_ven(:, 1) |
| 87 |
d_ven = local_ven - ven |
| 88 |
|
| 89 |
END SUBROUTINE clvent |
| 90 |
|
| 91 |
end module clvent_m |
Parent Directory
| 
Revision Log