1 |
module fonte_neige_m |
2 |
|
3 |
implicit none |
4 |
|
5 |
contains |
6 |
|
7 |
SUBROUTINE fonte_neige(nisurf, dtime, tsurf, p1lay, beta, coef1lay, ps, & |
8 |
precip_rain, precip_snow, snow, qsol, t1lay, q1lay, u1lay, v1lay, & |
9 |
petAcoef, peqAcoef, petBcoef, peqBcoef, tsurf_new, evap, fqcalving, & |
10 |
ffonte, run_off_lic_0) |
11 |
|
12 |
! Routine de traitement de la fonte de la neige dans le cas du traitement |
13 |
! de sol simplifi\'e |
14 |
|
15 |
! Laurent Fairhead, March, 2001 |
16 |
|
17 |
USE fcttre, ONLY: foeew, qsatl, qsats |
18 |
USE indicesol, ONLY: epsfra, is_lic, is_sic, is_ter |
19 |
USE interface_surf, ONLY: run_off_lic, tau_calv |
20 |
use nr_util, only: assert_eq |
21 |
USE suphec_m, ONLY: rcpd, rday, retv, rlmlt, rlstt, rlvtt, rtt |
22 |
USE yoethf_m, ONLY: r2es, r5ies, r5les, rvtmp2 |
23 |
|
24 |
integer, intent(IN):: nisurf ! surface \`a traiter |
25 |
real, intent(IN):: dtime ! pas de temps de la physique (en s) |
26 |
real, intent(IN):: tsurf(:) ! (knon) temperature de surface |
27 |
real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche) |
28 |
real, intent(IN):: beta(:) ! (knon) evap reelle |
29 |
real, intent(IN):: coef1lay(:) ! (knon) coefficient d'echange |
30 |
real, intent(IN):: ps(:) ! (knon) pression au sol |
31 |
|
32 |
real, intent(IN):: precip_rain(:) ! (knon) |
33 |
! precipitation, liquid water mass flux (kg / m2 / s), positive down |
34 |
|
35 |
real, intent(IN):: precip_snow(:) ! (knon) |
36 |
! precipitation, solid water mass flux (kg / m2 / s), positive down |
37 |
|
38 |
real, intent(INOUT):: snow(:) ! (knon) |
39 |
! column-density of mass of snow, in kg m-2 |
40 |
|
41 |
real, intent(INOUT):: qsol(:) ! (knon) |
42 |
! column-density of water in soil, in kg m-2 |
43 |
|
44 |
real, intent(IN):: t1lay(:) ! (knon) |
45 |
real, intent(IN):: q1lay(:) ! (knon) |
46 |
real, intent(IN):: u1lay(:), v1lay(:) ! (knon) |
47 |
|
48 |
real, intent(IN):: petAcoef(:), peqAcoef(:) ! (knon) |
49 |
! coefficients A de la r\'esolution de la couche limite pour t et q |
50 |
|
51 |
real, intent(IN):: petBcoef(:), peqBcoef(:) ! (knon) |
52 |
! coefficients B de la r\'esolution de la couche limite pour t et q |
53 |
|
54 |
real, intent(INOUT):: tsurf_new(:) ! (knon) temp\'erature au sol |
55 |
real, intent(IN):: evap(:) ! (knon) |
56 |
|
57 |
real, intent(OUT):: fqcalving(:) ! (knon) |
58 |
! flux d'eau "perdue" par la surface et n\'ecessaire pour limiter la |
59 |
! hauteur de neige, en kg / m2 / s |
60 |
|
61 |
real, intent(OUT):: ffonte(:) ! (knon) |
62 |
! flux thermique utilis\'é pour fondre la neige |
63 |
|
64 |
real, intent(INOUT):: run_off_lic_0(:) ! (knon) |
65 |
! run off glacier du pas de temps pr\'ecedent |
66 |
|
67 |
! Local: |
68 |
|
69 |
integer knon ! nombre de points \`a traiter |
70 |
real, parameter:: snow_max=3000. |
71 |
! Masse maximum de neige (kg / m2). Au dessus de ce seuil, la neige |
72 |
! en exces "s'ecoule" (calving) |
73 |
|
74 |
integer i |
75 |
logical zdelta |
76 |
real zcvm5, zx_qs, zcor |
77 |
real fq_fonte |
78 |
REAL bil_eau_s(size(ps)) ! in kg m-2 |
79 |
real snow_evap(size(ps)) ! in kg m-2 s-1 |
80 |
REAL, parameter:: chasno = 3.334E5 / (2.3867E6*0.15) |
81 |
REAL, parameter:: chaice = 3.334E5 / (2.3867E6*0.15) |
82 |
real, parameter:: max_eau_sol = 150. ! in kg m-2 |
83 |
real coeff_rel |
84 |
|
85 |
!-------------------------------------------------------------------- |
86 |
|
87 |
knon = assert_eq((/size(tsurf), size(p1lay), size(beta), size(coef1lay), & |
88 |
size(ps), size(precip_rain), size(precip_snow), size(snow), & |
89 |
size(qsol), size(t1lay), size(q1lay), size(u1lay), size(v1lay), & |
90 |
size(petAcoef), size(peqAcoef), size(petBcoef), size(peqBcoef), & |
91 |
size(tsurf_new), size(evap), size(fqcalving), size(ffonte), & |
92 |
size(run_off_lic_0)/), "fonte_neige knon") |
93 |
|
94 |
! Initialisations |
95 |
coeff_rel = dtime / (tau_calv * rday) |
96 |
bil_eau_s = 0. |
97 |
DO i = 1, knon |
98 |
zdelta= rtt >= tsurf(i) |
99 |
zcvm5 = merge(R5IES*RLSTT, R5LES*RLVTT, zdelta) |
100 |
zcvm5 = zcvm5 / RCPD / (1. + RVTMP2*q1lay(i)) |
101 |
zx_qs= r2es * FOEEW(tsurf(i), zdelta) / ps(i) |
102 |
zx_qs=MIN(0.5, zx_qs) |
103 |
zcor=1. / (1. - retv*zx_qs) |
104 |
zx_qs=zx_qs*zcor |
105 |
ENDDO |
106 |
|
107 |
! Calcul de la temperature de surface |
108 |
|
109 |
WHERE (precip_snow > 0.) snow = snow + precip_snow * dtime |
110 |
|
111 |
WHERE (evap > 0.) |
112 |
snow_evap = MIN(snow / dtime, evap) |
113 |
snow = snow - snow_evap * dtime |
114 |
snow = MAX(0., snow) |
115 |
elsewhere |
116 |
snow_evap = 0. |
117 |
end where |
118 |
|
119 |
bil_eau_s = precip_rain * dtime - (evap(:knon) - snow_evap(:knon)) * dtime |
120 |
|
121 |
! Y a-t-il fonte de neige ? |
122 |
|
123 |
ffonte=0. |
124 |
do i = 1, knon |
125 |
if ((snow(i) > epsfra .OR. nisurf == is_sic & |
126 |
.OR. nisurf == is_lic) .AND. tsurf_new(i) >= RTT) then |
127 |
fq_fonte = MIN(MAX((tsurf_new(i) - RTT) / chasno, 0.), snow(i)) |
128 |
ffonte(i) = fq_fonte * RLMLT / dtime |
129 |
snow(i) = max(0., snow(i) - fq_fonte) |
130 |
bil_eau_s(i) = bil_eau_s(i) + fq_fonte |
131 |
tsurf_new(i) = tsurf_new(i) - fq_fonte * chasno |
132 |
!IM cf JLD/ GKtest fonte aussi pour la glace |
133 |
IF (nisurf == is_sic .OR. nisurf == is_lic) THEN |
134 |
fq_fonte = MAX((tsurf_new(i) - RTT) / chaice, 0.) |
135 |
ffonte(i) = ffonte(i) + fq_fonte * RLMLT / dtime |
136 |
bil_eau_s(i) = bil_eau_s(i) + fq_fonte |
137 |
tsurf_new(i) = RTT |
138 |
ENDIF |
139 |
endif |
140 |
|
141 |
! S'il y a une hauteur trop importante de neige, elle s'\'ecoule |
142 |
fqcalving(i) = max(0., snow(i) - snow_max) / dtime |
143 |
snow(i)=min(snow(i), snow_max) |
144 |
|
145 |
IF (nisurf == is_ter) then |
146 |
qsol(i) = qsol(i) + bil_eau_s(i) |
147 |
qsol(i) = MIN(qsol(i), max_eau_sol) |
148 |
else if (nisurf == is_lic) then |
149 |
run_off_lic(i) = (coeff_rel * fqcalving(i)) + & |
150 |
(1. - coeff_rel) * run_off_lic_0(i) |
151 |
run_off_lic_0(i) = run_off_lic(i) |
152 |
run_off_lic(i) = run_off_lic(i) + bil_eau_s(i) / dtime |
153 |
endif |
154 |
enddo |
155 |
|
156 |
END SUBROUTINE fonte_neige |
157 |
|
158 |
end module fonte_neige_m |