phylmd/Interface_surf/fonte_neige.f

module fonte_neige_m

  implicit none

contains

  SUBROUTINE fonte_neige(nisurf, dtime, precip_rain, precip_snow, snow, qsol, &
       tsurf_new, evap, fqcalving, ffonte, run_off_lic_0)

    ! Routine de traitement de la fonte de la neige dans le cas du traitement
    ! de sol simplifi\'e

    ! Laurent Fairhead, March, 2001

    USE fcttre, ONLY: foeew, qsatl, qsats
    USE indicesol, ONLY: epsfra, is_lic, is_sic, is_ter
    USE interface_surf, ONLY: tau_calv
    use nr_util, only: assert_eq
    USE suphec_m, ONLY: rday, rlmlt, rtt

    integer, intent(IN):: nisurf ! surface \`a traiter
    real, intent(IN):: dtime ! pas de temps de la physique (en s)

    real, intent(IN):: precip_rain(:) ! (knon)
    ! precipitation, liquid water mass flux (kg / m2 / s), positive down

    real, intent(IN):: precip_snow(:) ! (knon)
    ! precipitation, solid water mass flux (kg / m2 / s), positive down

    real, intent(INOUT):: snow(:) ! (knon)
    ! column-density of mass of snow, in kg m-2

    real, intent(INOUT):: qsol(:) ! (knon)
    ! column-density of water in soil, in kg m-2

    real, intent(INOUT):: tsurf_new(:) ! (knon) temp\'erature au sol
    real, intent(IN):: evap(:) ! (knon)

    real, intent(OUT):: fqcalving(:) ! (knon)
    ! flux d'eau "perdue" par la surface et n\'ecessaire pour limiter la
    ! hauteur de neige, en kg / m2 / s

    real, intent(OUT):: ffonte(:) ! (knon)
    ! flux thermique utilis\'é pour fondre la neige

    real, intent(INOUT):: run_off_lic_0(:) ! (knon)
    ! run off glacier du pas de temps pr\'ecedent

    ! Local:

    integer knon ! nombre de points \`a traiter
    real, parameter:: snow_max=3000.
    ! Masse maximum de neige (kg / m2). Au dessus de ce seuil, la neige
    ! en exces "s'\'ecoule" (calving).

    integer i
    real fq_fonte
    REAL bil_eau_s(size(precip_rain)) ! (knon) in kg m-2
    real snow_evap(size(precip_rain)) ! (knon) in kg m-2 s-1
    REAL, parameter:: chasno = 3.334E5 / (2.3867E6 * 0.15)
    REAL, parameter:: chaice = 3.334E5 / (2.3867E6 * 0.15)
    real, parameter:: max_eau_sol = 150. ! in kg m-2
    real coeff_rel
    REAL, ALLOCATABLE, SAVE:: run_off_lic(:) ! ruissellement total

    !--------------------------------------------------------------------

    knon = assert_eq((/size(precip_rain), size(precip_snow), size(snow), &
         size(qsol), size(tsurf_new), size(evap), size(fqcalving), &
         size(ffonte), size(run_off_lic_0)/), "fonte_neige knon")

    coeff_rel = dtime / (tau_calv * rday)
    WHERE (precip_snow > 0.) snow = snow + precip_snow * dtime

    WHERE (evap > 0.)
       snow_evap = MIN(snow / dtime, evap)
       snow = snow - snow_evap * dtime
       snow = MAX(0., snow)
    elsewhere
       snow_evap = 0.
    end where

    bil_eau_s = (precip_rain - evap + snow_evap) * dtime

    ! Y a-t-il fonte de neige ?

    do i = 1, knon
       if ((snow(i) > epsfra .OR. nisurf == is_sic &
            .OR. nisurf == is_lic) .AND. tsurf_new(i) >= RTT) then
          fq_fonte = MIN(MAX((tsurf_new(i) - RTT) / chasno, 0.), snow(i))
          ffonte(i) = fq_fonte * RLMLT / dtime
          snow(i) = max(0., snow(i) - fq_fonte)
          bil_eau_s(i) = bil_eau_s(i) + fq_fonte
          tsurf_new(i) = tsurf_new(i) - fq_fonte * chasno

          !IM cf. JLD/ GKtest fonte aussi pour la glace
          IF (nisurf == is_sic .OR. nisurf == is_lic) THEN
             fq_fonte = MAX((tsurf_new(i) - RTT) / chaice, 0.)
             ffonte(i) = ffonte(i) + fq_fonte * RLMLT / dtime
             bil_eau_s(i) = bil_eau_s(i) + fq_fonte
             tsurf_new(i) = RTT
          ENDIF
       else
          ffonte(i) = 0.
       endif

       ! S'il y a une hauteur trop importante de neige, elle s'\'ecoule
       fqcalving(i) = max(0., snow(i) - snow_max) / dtime
       snow(i) = min(snow(i), snow_max)
    enddo

    IF (nisurf == is_ter) then
       qsol = MIN(qsol + bil_eau_s, max_eau_sol)
    else if (nisurf == is_lic) then
       if (.not. allocated(run_off_lic)) allocate(run_off_lic(knon))
       ! assumes that the fraction of land-ice does not change during the run

       do i = 1, knon
          run_off_lic(i) = (coeff_rel * fqcalving(i)) + &
               (1. - coeff_rel) * run_off_lic_0(i)
          run_off_lic_0(i) = run_off_lic(i)
          run_off_lic(i) = run_off_lic(i) + bil_eau_s(i) / dtime
       enddo
    endif

  END SUBROUTINE fonte_neige

end module fonte_neige_m
1	module fonte_neige_m
2
3	implicit none
4
5	contains
6
7	SUBROUTINE fonte_neige(nisurf, dtime, precip_rain, precip_snow, snow, qsol, &
8	tsurf_new, evap, fqcalving, ffonte, run_off_lic_0)
9
10	! Routine de traitement de la fonte de la neige dans le cas du traitement
11	! de sol simplifi\'e
12
13	! Laurent Fairhead, March, 2001
14
15	USE fcttre, ONLY: foeew, qsatl, qsats
16	USE indicesol, ONLY: epsfra, is_lic, is_sic, is_ter
17	USE interface_surf, ONLY: tau_calv
18	use nr_util, only: assert_eq
19	USE suphec_m, ONLY: rday, rlmlt, rtt
20
21	integer, intent(IN):: nisurf ! surface \`a traiter
22	real, intent(IN):: dtime ! pas de temps de la physique (en s)
23
24	real, intent(IN):: precip_rain(:) ! (knon)
25	! precipitation, liquid water mass flux (kg / m2 / s), positive down
26
27	real, intent(IN):: precip_snow(:) ! (knon)
28	! precipitation, solid water mass flux (kg / m2 / s), positive down
29
30	real, intent(INOUT):: snow(:) ! (knon)
31	! column-density of mass of snow, in kg m-2
32
33	real, intent(INOUT):: qsol(:) ! (knon)
34	! column-density of water in soil, in kg m-2
35
36	real, intent(INOUT):: tsurf_new(:) ! (knon) temp\'erature au sol
37	real, intent(IN):: evap(:) ! (knon)
38
39	real, intent(OUT):: fqcalving(:) ! (knon)
40	! flux d'eau "perdue" par la surface et n\'ecessaire pour limiter la
41	! hauteur de neige, en kg / m2 / s
42
43	real, intent(OUT):: ffonte(:) ! (knon)
44	! flux thermique utilis\'é pour fondre la neige
45
46	real, intent(INOUT):: run_off_lic_0(:) ! (knon)
47	! run off glacier du pas de temps pr\'ecedent
48
49	! Local:
50
51	integer knon ! nombre de points \`a traiter
52	real, parameter:: snow_max=3000.
53	! Masse maximum de neige (kg / m2). Au dessus de ce seuil, la neige
54	! en exces "s'\'ecoule" (calving).
55
56	integer i
57	real fq_fonte
58	REAL bil_eau_s(size(precip_rain)) ! (knon) in kg m-2
59	real snow_evap(size(precip_rain)) ! (knon) in kg m-2 s-1
60	REAL, parameter:: chasno = 3.334E5 / (2.3867E6 * 0.15)
61	REAL, parameter:: chaice = 3.334E5 / (2.3867E6 * 0.15)
62	real, parameter:: max_eau_sol = 150. ! in kg m-2
63	real coeff_rel
64	REAL, ALLOCATABLE, SAVE:: run_off_lic(:) ! ruissellement total
65
66	!--------------------------------------------------------------------
67
68	knon = assert_eq((/size(precip_rain), size(precip_snow), size(snow), &
69	size(qsol), size(tsurf_new), size(evap), size(fqcalving), &
70	size(ffonte), size(run_off_lic_0)/), "fonte_neige knon")
71
72	coeff_rel = dtime / (tau_calv * rday)
73	WHERE (precip_snow > 0.) snow = snow + precip_snow * dtime
74
75	WHERE (evap > 0.)
76	snow_evap = MIN(snow / dtime, evap)
77	snow = snow - snow_evap * dtime
78	snow = MAX(0., snow)
79	elsewhere
80	snow_evap = 0.
81	end where
82
83	bil_eau_s = (precip_rain - evap + snow_evap) * dtime
84
85	! Y a-t-il fonte de neige ?
86
87	do i = 1, knon
88	if ((snow(i) > epsfra .OR. nisurf == is_sic &
89	.OR. nisurf == is_lic) .AND. tsurf_new(i) >= RTT) then
90	fq_fonte = MIN(MAX((tsurf_new(i) - RTT) / chasno, 0.), snow(i))
91	ffonte(i) = fq_fonte * RLMLT / dtime
92	snow(i) = max(0., snow(i) - fq_fonte)
93	bil_eau_s(i) = bil_eau_s(i) + fq_fonte
94	tsurf_new(i) = tsurf_new(i) - fq_fonte * chasno
95
96	!IM cf. JLD/ GKtest fonte aussi pour la glace
97	IF (nisurf == is_sic .OR. nisurf == is_lic) THEN
98	fq_fonte = MAX((tsurf_new(i) - RTT) / chaice, 0.)
99	ffonte(i) = ffonte(i) + fq_fonte * RLMLT / dtime
100	bil_eau_s(i) = bil_eau_s(i) + fq_fonte
101	tsurf_new(i) = RTT
102	ENDIF
103	else
104	ffonte(i) = 0.
105	endif
106
107	! S'il y a une hauteur trop importante de neige, elle s'\'ecoule
108	fqcalving(i) = max(0., snow(i) - snow_max) / dtime
109	snow(i) = min(snow(i), snow_max)
110	enddo
111
112	IF (nisurf == is_ter) then
113	qsol = MIN(qsol + bil_eau_s, max_eau_sol)
114	else if (nisurf == is_lic) then
115	if (.not. allocated(run_off_lic)) allocate(run_off_lic(knon))
116	! assumes that the fraction of land-ice does not change during the run
117
118	do i = 1, knon
119	run_off_lic(i) = (coeff_rel * fqcalving(i)) + &
120	(1. - coeff_rel) * run_off_lic_0(i)
121	run_off_lic_0(i) = run_off_lic(i)
122	run_off_lic(i) = run_off_lic(i) + bil_eau_s(i) / dtime
123	enddo
124	endif
125
126	END SUBROUTINE fonte_neige
127
128	end module fonte_neige_m