phylmd/Interface_surf/interfsurf_hq.f

module interfsurf_hq_m

  implicit none

contains

  SUBROUTINE interfsurf_hq(julien, rmu0, nisurf, knindex, debut, tsoil, qsol, &
       u1_lay, v1_lay, temp_air, spechum, tq_cdrag, tAcoef, qAcoef, tBcoef, &
       qBcoef, precip_rain, precip_snow, rugos, rugoro, snow, qsurf, ts, &
       p1lay, ps, radsol, evap, flux_t, fluxlat, dflux_l, dflux_s, tsurf_new, &
       albedo, z0_new, pctsrf_new_sic, agesno, fqcalving, ffonte, run_off_lic_0)

    ! Cette routine sert d'aiguillage entre l'atmosph\`ere et la surface
    ! en g\'en\'eral (sols continentaux, oc\'eans, glaces) pour les flux de
    ! chaleur et d'humidit\'e.

    ! Laurent Fairhead, February 2000

    USE abort_gcm_m, ONLY: abort_gcm
    use alboc_cd_m, only: alboc_cd
    USE albsno_m, ONLY: albsno
    USE calcul_fluxs_m, ONLY: calcul_fluxs
    USE dimphy, ONLY: klon
    USE fonte_neige_m, ONLY: fonte_neige
    USE indicesol, ONLY: epsfra, is_lic, is_oce, is_sic, is_ter
    USE conf_interface_m, ONLY: conf_interface
    USE interfsur_lim_m, ONLY: interfsur_lim
    use limit_read_sst_m, only: limit_read_sst
    use soil_m, only: soil
    USE suphec_m, ONLY: rcpd, rtt

    integer, intent(IN):: julien ! jour dans l'annee en cours
    real, intent(IN):: rmu0(klon) ! cosinus de l'angle solaire zenithal
    integer, intent(IN):: nisurf ! index de la surface a traiter

    integer, intent(in):: knindex(:) ! (knon)
    ! index des points de la surface a traiter

    logical, intent(IN):: debut ! 1er appel a la physique
    ! (si false calcul simplifie des fluxs sur les continents)

    REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx)

    REAL, intent(INOUT):: qsol(:) ! (knon)
    ! column-density of water in soil, in kg m-2

    real, intent(IN):: u1_lay(:), v1_lay(:) ! (knon) vitesse 1ere couche

    real, intent(IN):: temp_air(:) ! (knon) temperature de l'air 1ere couche
    real, intent(IN):: spechum(:) ! (knon) humidite specifique 1ere couche
    real, intent(IN):: tq_cdrag(:) ! (knon) coefficient d'echange

    real, intent(IN):: tAcoef(:), qAcoef(:) ! (knon)
    ! coefficients A de la r\'esolution de la couche limite pour t et q

    real, intent(IN):: tBcoef(:), qBcoef(:) ! (knon)
    ! coefficients B de la r\'esolution de la couche limite pour t et q

    real, intent(IN):: precip_rain(klon)
    ! precipitation, liquid water mass flux (kg / m2 / s), positive down

    real, intent(IN):: precip_snow(klon)
    ! precipitation, solid water mass flux (kg / m2 / s), positive down

    real, intent(IN):: rugos(:) ! (knon) rugosite
    real, intent(IN):: rugoro(:) ! (knon) rugosite orographique
    real, intent(INOUT):: snow(:) ! (knon)
    real, intent(OUT):: qsurf(:) ! (knon)
    real, intent(IN):: ts(:) ! (knon) temp\'erature de surface
    real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche)
    real, intent(IN):: ps(:) ! (knon) pression au sol
    REAL, INTENT(IN):: radsol(:) ! (knon) rayonnement net au sol (LW + SW)
    real, intent(OUT):: evap(:) ! (knon) evaporation totale

    real, intent(OUT):: flux_t(:) ! (knon) flux de chaleur sensible
    ! (Cp T) à la surface, positif vers le bas, W / m2

    real, intent(OUT):: fluxlat(:) ! (knon) flux de chaleur latente
    real, intent(OUT):: dflux_l(:), dflux_s(:) ! (knon)
    real, intent(OUT):: tsurf_new(:) ! (knon) temp\'erature au sol
    real, intent(OUT):: albedo(:) ! (knon) albedo
    real, intent(OUT):: z0_new(:) ! (knon) surface roughness

    real, intent(in):: pctsrf_new_sic(:) ! (klon) 
    ! nouvelle repartition des surfaces

    real, intent(INOUT):: agesno(:) ! (knon)

    real, intent(OUT):: fqcalving(:) ! (knon)
    ! Flux d'eau "perdue" par la surface et n\'ecessaire pour limiter la
    ! hauteur de neige, en kg / m2 / s

    real, dimension(klon), intent(INOUT):: ffonte
    ! Flux thermique utiliser pour fondre la neige

    real, dimension(klon), intent(INOUT):: run_off_lic_0
    ! run_off_lic_0 runoff glacier du pas de temps precedent

    ! Local:
    integer knon ! nombre de points de la surface a traiter
    REAL soilcap(size(knindex)) ! (knon)
    REAL soilflux(size(knindex)) ! (knon)
    logical:: first_call = .true.
    integer ii
    real cal(size(knindex)) ! (knon)
    real beta(size(knindex)) ! (knon) evap reelle
    real dif_grnd(klon)
    real tsurf(size(knindex)) ! (knon)
    real alb_neig(size(knindex)) ! (knon)
    real zfra(size(knindex)) ! (knon)
    REAL, PARAMETER:: fmagic = 1. ! facteur magique pour r\'egler l'alb\'edo
    REAL, PARAMETER:: max_eau_sol = 150. ! in kg m-2
    REAL, PARAMETER:: tau_gl = 86400. * 5.

    !-------------------------------------------------------------

    knon = size(knindex)

    ! On doit commencer par appeler les sch\'emas de surfaces
    ! continentales car l'oc\'ean a besoin du ruissellement.

    if (first_call) then
       call conf_interface

       if (nisurf /= is_ter .and. klon > 1) then
          print *, ' nisurf = ', nisurf, ' /= is_ter = ', is_ter
          print *, 'or on doit commencer par les surfaces continentales'
          call abort_gcm("interfsurf_hq", &
               'On doit commencer par les surfaces continentales.')
       endif

       if (is_oce > is_sic) then
          print *, 'is_oce = ', is_oce, '> is_sic = ', is_sic
          call abort_gcm("interfsurf_hq", &
               "L'oc\'ean doit \^etre trait\'e avant la banquise.")
       endif

       first_call = .false.
    endif

    ! Initialisations diverses

    ffonte(1:knon) = 0.
    dif_grnd = 999999.

    ! Aiguillage vers les differents schemas de surface

    select case (nisurf)
    case (is_ter)
       ! Surface "terre", appel \`a l'interface avec les sols continentaux

       ! Calcul age de la neige

       ! Read albedo from the file containing boundary conditions then
       ! add the albedo of snow:

       call interfsur_lim(julien, knindex, debut, albedo, z0_new)

       beta = min(2. * qsol / max_eau_sol, 1.)
       dif_grnd(:knon) = 0.
       CALL soil(is_ter, snow, ts, tsoil, soilcap, soilflux)
       cal = RCPD / soilcap

       CALL calcul_fluxs(ts, p1lay, cal, beta, tq_cdrag, ps, qsurf, &
            radsol + soilflux, dif_grnd(:knon), temp_air, spechum, u1_lay, &
            v1_lay, tAcoef, qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, &
            flux_t, dflux_s, dflux_l)
       CALL fonte_neige(is_ter, precip_rain(:knon), precip_snow(:knon), snow, &
            qsol, tsurf_new, evap, fqcalving, ffonte(:knon), &
            run_off_lic_0(:knon))

       call albsno(agesno, alb_neig, precip_snow(:knon))
       where (snow < 0.0001) agesno = 0.
       zfra = max(0., min(1., snow / (snow + 10.)))
       albedo = alb_neig * zfra + albedo * (1. - zfra)
       z0_new = sqrt(z0_new**2 + rugoro**2)
    case (is_oce)
       ! Surface "oc\'ean", appel \`a l'interface avec l'oc\'ean

       call limit_read_sst(julien, knindex, tsurf)
       cal = 0.
       beta = 1.
       dif_grnd = 0.
       call calcul_fluxs(tsurf, p1lay, cal, beta, tq_cdrag, ps, qsurf, radsol, &
            dif_grnd(:knon), temp_air, spechum, u1_lay, v1_lay, tAcoef, &
            qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, &
            dflux_l)
       agesno = 0.
       albedo = alboc_cd(rmu0(knindex)) * fmagic
       z0_new = sqrt(rugos**2 + rugoro**2)
       fqcalving = 0.
    case (is_sic)
       ! Surface "glace de mer" appel a l'interface avec l'ocean

       DO ii = 1, knon
          IF (pctsrf_new_sic(knindex(ii)) < EPSFRA) then
             snow(ii) = 0.
             tsurf_new(ii) = RTT - 1.8
             tsoil(ii, :) = RTT - 1.8
          else
             tsurf_new(ii) = ts(ii)
          endif
       enddo

       CALL soil(is_sic, snow, tsurf_new, tsoil, soilcap, soilflux)
       cal = RCPD / soilcap
       dif_grnd = 1. / tau_gl
       tsurf = tsurf_new
       beta = 1.

       CALL calcul_fluxs(tsurf, p1lay, cal, beta, tq_cdrag, ps, qsurf, &
            radsol + soilflux, dif_grnd(:knon), temp_air, spechum, u1_lay, &
            v1_lay, tAcoef, qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, &
            flux_t, dflux_s, dflux_l)
       CALL fonte_neige(is_sic, precip_rain(:knon), precip_snow(:knon), snow, &
            qsol, tsurf_new, evap, fqcalving, ffonte(:knon), &
            run_off_lic_0(:knon))

       ! Compute the albedo:

       CALL albsno(agesno, alb_neig, precip_snow(:knon))
       WHERE (snow < 0.0001) agesno = 0.
       zfra = MAX(0., MIN(1., snow / (snow + 10.)))
       albedo = alb_neig * zfra + 0.6 * (1. - zfra)

       z0_new = SQRT(0.002**2 + rugoro**2)
    case (is_lic)
       ! Surface "glacier continentaux" appel a l'interface avec le sol

       CALL soil(is_lic, snow, ts, tsoil, soilcap, soilflux)
       cal = RCPD / soilcap
       beta = 1.
       dif_grnd = 0.

       call calcul_fluxs(ts, p1lay, cal, beta, tq_cdrag, ps, qsurf, &
            radsol + soilflux, dif_grnd(:knon), temp_air, spechum, u1_lay, &
            v1_lay, tAcoef, qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, &
            flux_t, dflux_s, dflux_l)
       call fonte_neige(is_lic, precip_rain(:knon), precip_snow(:knon), snow, &
            qsol, tsurf_new, evap, fqcalving, ffonte(:knon), &
            run_off_lic_0(:knon))

       ! calcul albedo
       CALL albsno(agesno, alb_neig, precip_snow(:knon))
       WHERE (snow < 0.0001) agesno = 0.
       albedo = 0.77

       ! Rugosite
       z0_new = rugoro
    case default
       print *, 'Index surface = ', nisurf
       call abort_gcm("interfsurf_hq", 'Index surface non valable')
    end select

  END SUBROUTINE interfsurf_hq

end module interfsurf_hq_m
1	module interfsurf_hq_m
2
3	implicit none
4
5	contains
6
7	SUBROUTINE interfsurf_hq(julien, rmu0, nisurf, knindex, debut, tsoil, qsol, &
8	u1_lay, v1_lay, temp_air, spechum, tq_cdrag, tAcoef, qAcoef, tBcoef, &
9	qBcoef, precip_rain, precip_snow, rugos, rugoro, snow, qsurf, ts, &
10	p1lay, ps, radsol, evap, flux_t, fluxlat, dflux_l, dflux_s, tsurf_new, &
11	albedo, z0_new, pctsrf_new_sic, agesno, fqcalving, ffonte, run_off_lic_0)
12
13	! Cette routine sert d'aiguillage entre l'atmosph\`ere et la surface
14	! en g\'en\'eral (sols continentaux, oc\'eans, glaces) pour les flux de
15	! chaleur et d'humidit\'e.
16
17	! Laurent Fairhead, February 2000
18
19	USE abort_gcm_m, ONLY: abort_gcm
20	use alboc_cd_m, only: alboc_cd
21	USE albsno_m, ONLY: albsno
22	USE calcul_fluxs_m, ONLY: calcul_fluxs
23	USE dimphy, ONLY: klon
24	USE fonte_neige_m, ONLY: fonte_neige
25	USE indicesol, ONLY: epsfra, is_lic, is_oce, is_sic, is_ter
26	USE conf_interface_m, ONLY: conf_interface
27	USE interfsur_lim_m, ONLY: interfsur_lim
28	use limit_read_sst_m, only: limit_read_sst
29	use soil_m, only: soil
30	USE suphec_m, ONLY: rcpd, rtt
31
32	integer, intent(IN):: julien ! jour dans l'annee en cours
33	real, intent(IN):: rmu0(klon) ! cosinus de l'angle solaire zenithal
34	integer, intent(IN):: nisurf ! index de la surface a traiter
35
36	integer, intent(in):: knindex(:) ! (knon)
37	! index des points de la surface a traiter
38
39	logical, intent(IN):: debut ! 1er appel a la physique
40	! (si false calcul simplifie des fluxs sur les continents)
41
42	REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx)
43
44	REAL, intent(INOUT):: qsol(:) ! (knon)
45	! column-density of water in soil, in kg m-2
46
47	real, intent(IN):: u1_lay(:), v1_lay(:) ! (knon) vitesse 1ere couche
48
49	real, intent(IN):: temp_air(:) ! (knon) temperature de l'air 1ere couche
50	real, intent(IN):: spechum(:) ! (knon) humidite specifique 1ere couche
51	real, intent(IN):: tq_cdrag(:) ! (knon) coefficient d'echange
52
53	real, intent(IN):: tAcoef(:), qAcoef(:) ! (knon)
54	! coefficients A de la r\'esolution de la couche limite pour t et q
55
56	real, intent(IN):: tBcoef(:), qBcoef(:) ! (knon)
57	! coefficients B de la r\'esolution de la couche limite pour t et q
58
59	real, intent(IN):: precip_rain(klon)
60	! precipitation, liquid water mass flux (kg / m2 / s), positive down
61
62	real, intent(IN):: precip_snow(klon)
63	! precipitation, solid water mass flux (kg / m2 / s), positive down
64
65	real, intent(IN):: rugos(:) ! (knon) rugosite
66	real, intent(IN):: rugoro(:) ! (knon) rugosite orographique
67	real, intent(INOUT):: snow(:) ! (knon)
68	real, intent(OUT):: qsurf(:) ! (knon)
69	real, intent(IN):: ts(:) ! (knon) temp\'erature de surface
70	real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche)
71	real, intent(IN):: ps(:) ! (knon) pression au sol
72	REAL, INTENT(IN):: radsol(:) ! (knon) rayonnement net au sol (LW + SW)
73	real, intent(OUT):: evap(:) ! (knon) evaporation totale
74
75	real, intent(OUT):: flux_t(:) ! (knon) flux de chaleur sensible
76	! (Cp T) à la surface, positif vers le bas, W / m2
77
78	real, intent(OUT):: fluxlat(:) ! (knon) flux de chaleur latente
79	real, intent(OUT):: dflux_l(:), dflux_s(:) ! (knon)
80	real, intent(OUT):: tsurf_new(:) ! (knon) temp\'erature au sol
81	real, intent(OUT):: albedo(:) ! (knon) albedo
82	real, intent(OUT):: z0_new(:) ! (knon) surface roughness
83
84	real, intent(in):: pctsrf_new_sic(:) ! (klon)
85	! nouvelle repartition des surfaces
86
87	real, intent(INOUT):: agesno(:) ! (knon)
88
89	real, intent(OUT):: fqcalving(:) ! (knon)
90	! Flux d'eau "perdue" par la surface et n\'ecessaire pour limiter la
91	! hauteur de neige, en kg / m2 / s
92
93	real, dimension(klon), intent(INOUT):: ffonte
94	! Flux thermique utiliser pour fondre la neige
95
96	real, dimension(klon), intent(INOUT):: run_off_lic_0
97	! run_off_lic_0 runoff glacier du pas de temps precedent
98
99	! Local:
100	integer knon ! nombre de points de la surface a traiter
101	REAL soilcap(size(knindex)) ! (knon)
102	REAL soilflux(size(knindex)) ! (knon)
103	logical:: first_call = .true.
104	integer ii
105	real cal(size(knindex)) ! (knon)
106	real beta(size(knindex)) ! (knon) evap reelle
107	real dif_grnd(klon)
108	real tsurf(size(knindex)) ! (knon)
109	real alb_neig(size(knindex)) ! (knon)
110	real zfra(size(knindex)) ! (knon)
111	REAL, PARAMETER:: fmagic = 1. ! facteur magique pour r\'egler l'alb\'edo
112	REAL, PARAMETER:: max_eau_sol = 150. ! in kg m-2
113	REAL, PARAMETER:: tau_gl = 86400. * 5.
114
115	!-------------------------------------------------------------
116
117	knon = size(knindex)
118
119	! On doit commencer par appeler les sch\'emas de surfaces
120	! continentales car l'oc\'ean a besoin du ruissellement.
121
122	if (first_call) then
123	call conf_interface
124
125	if (nisurf /= is_ter .and. klon > 1) then
126	print *, ' nisurf = ', nisurf, ' /= is_ter = ', is_ter
127	print *, 'or on doit commencer par les surfaces continentales'
128	call abort_gcm("interfsurf_hq", &
129	'On doit commencer par les surfaces continentales.')
130	endif
131
132	if (is_oce > is_sic) then
133	print *, 'is_oce = ', is_oce, '> is_sic = ', is_sic
134	call abort_gcm("interfsurf_hq", &
135	"L'oc\'ean doit \^etre trait\'e avant la banquise.")
136	endif
137
138	first_call = .false.
139	endif
140
141	! Initialisations diverses
142
143	ffonte(1:knon) = 0.
144	dif_grnd = 999999.
145
146	! Aiguillage vers les differents schemas de surface
147
148	select case (nisurf)
149	case (is_ter)
150	! Surface "terre", appel \`a l'interface avec les sols continentaux
151
152	! Calcul age de la neige
153
154	! Read albedo from the file containing boundary conditions then
155	! add the albedo of snow:
156
157	call interfsur_lim(julien, knindex, debut, albedo, z0_new)
158
159	beta = min(2. * qsol / max_eau_sol, 1.)
160	dif_grnd(:knon) = 0.
161	CALL soil(is_ter, snow, ts, tsoil, soilcap, soilflux)
162	cal = RCPD / soilcap
163
164	CALL calcul_fluxs(ts, p1lay, cal, beta, tq_cdrag, ps, qsurf, &
165	radsol + soilflux, dif_grnd(:knon), temp_air, spechum, u1_lay, &
166	v1_lay, tAcoef, qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, &
167	flux_t, dflux_s, dflux_l)
168	CALL fonte_neige(is_ter, precip_rain(:knon), precip_snow(:knon), snow, &
169	qsol, tsurf_new, evap, fqcalving, ffonte(:knon), &
170	run_off_lic_0(:knon))
171
172	call albsno(agesno, alb_neig, precip_snow(:knon))
173	where (snow < 0.0001) agesno = 0.
174	zfra = max(0., min(1., snow / (snow + 10.)))
175	albedo = alb_neig * zfra + albedo * (1. - zfra)
176	z0_new = sqrt(z0_new2 + rugoro2)
177	case (is_oce)
178	! Surface "oc\'ean", appel \`a l'interface avec l'oc\'ean
179
180	call limit_read_sst(julien, knindex, tsurf)
181	cal = 0.
182	beta = 1.
183	dif_grnd = 0.
184	call calcul_fluxs(tsurf, p1lay, cal, beta, tq_cdrag, ps, qsurf, radsol, &
185	dif_grnd(:knon), temp_air, spechum, u1_lay, v1_lay, tAcoef, &
186	qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, &
187	dflux_l)
188	agesno = 0.
189	albedo = alboc_cd(rmu0(knindex)) * fmagic
190	z0_new = sqrt(rugos2 + rugoro2)
191	fqcalving = 0.
192	case (is_sic)
193	! Surface "glace de mer" appel a l'interface avec l'ocean
194
195	DO ii = 1, knon
196	IF (pctsrf_new_sic(knindex(ii)) < EPSFRA) then
197	snow(ii) = 0.
198	tsurf_new(ii) = RTT - 1.8
199	tsoil(ii, :) = RTT - 1.8
200	else
201	tsurf_new(ii) = ts(ii)
202	endif
203	enddo
204
205	CALL soil(is_sic, snow, tsurf_new, tsoil, soilcap, soilflux)
206	cal = RCPD / soilcap
207	dif_grnd = 1. / tau_gl
208	tsurf = tsurf_new
209	beta = 1.
210
211	CALL calcul_fluxs(tsurf, p1lay, cal, beta, tq_cdrag, ps, qsurf, &
212	radsol + soilflux, dif_grnd(:knon), temp_air, spechum, u1_lay, &
213	v1_lay, tAcoef, qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, &
214	flux_t, dflux_s, dflux_l)
215	CALL fonte_neige(is_sic, precip_rain(:knon), precip_snow(:knon), snow, &
216	qsol, tsurf_new, evap, fqcalving, ffonte(:knon), &
217	run_off_lic_0(:knon))
218
219	! Compute the albedo:
220
221	CALL albsno(agesno, alb_neig, precip_snow(:knon))
222	WHERE (snow < 0.0001) agesno = 0.
223	zfra = MAX(0., MIN(1., snow / (snow + 10.)))
224	albedo = alb_neig * zfra + 0.6 * (1. - zfra)
225
226	z0_new = SQRT(0.0022 + rugoro2)
227	case (is_lic)
228	! Surface "glacier continentaux" appel a l'interface avec le sol
229
230	CALL soil(is_lic, snow, ts, tsoil, soilcap, soilflux)
231	cal = RCPD / soilcap
232	beta = 1.
233	dif_grnd = 0.
234
235	call calcul_fluxs(ts, p1lay, cal, beta, tq_cdrag, ps, qsurf, &
236	radsol + soilflux, dif_grnd(:knon), temp_air, spechum, u1_lay, &
237	v1_lay, tAcoef, qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, &
238	flux_t, dflux_s, dflux_l)
239	call fonte_neige(is_lic, precip_rain(:knon), precip_snow(:knon), snow, &
240	qsol, tsurf_new, evap, fqcalving, ffonte(:knon), &
241	run_off_lic_0(:knon))
242
243	! calcul albedo
244	CALL albsno(agesno, alb_neig, precip_snow(:knon))
245	WHERE (snow < 0.0001) agesno = 0.
246	albedo = 0.77
247
248	! Rugosite
249	z0_new = rugoro
250	case default
251	print *, 'Index surface = ', nisurf
252	call abort_gcm("interfsurf_hq", 'Index surface non valable')
253	end select
254
255	END SUBROUTINE interfsurf_hq
256
257	end module interfsurf_hq_m