phylmd/Interface_surf/interfsurf_hq.f

module interfsurf_hq_m

  implicit none

contains

  SUBROUTINE interfsurf_hq(julien, mu0, nisurf, knindex, tsoil, qsol, u1lay, &
       v1lay, temp_air, q1lay, cdragh, tAcoef, qAcoef, tBcoef, qBcoef, &
       rain_fall, snow_fall, rugos, rugoro, snow, qsurf, ts, p1lay, ps, &
       radsol, evap, flux_t, fluxlat, dflux_l, dflux_s, tsurf_new, albedo, &
       z0_new, pctsrf_new_sic, agesno, fqcalving, ffonte, run_off_lic_0, &
       run_off_lic)

    ! Cette routine sert d'aiguillage entre l'atmosph\`ere et la surface
    ! en g\'en\'eral (sols continentaux, oc\'eans, glaces) pour les flux de
    ! chaleur et d'humidit\'e.

    ! Laurent Fairhead, February 2000

    USE abort_gcm_m, ONLY: abort_gcm
    use alboc_cd_m, only: alboc_cd
    USE albsno_m, ONLY: albsno
    USE calcul_fluxs_m, ONLY: calcul_fluxs
    USE fonte_neige_m, ONLY: fonte_neige
    USE indicesol, ONLY: epsfra, is_lic, is_oce, is_sic, is_ter
    USE interfsur_lim_m, ONLY: interfsur_lim
    use limit_read_sst_m, only: limit_read_sst
    use soil_m, only: soil
    USE suphec_m, ONLY: rcpd, rtt

    integer, intent(IN):: julien ! jour dans l'annee en cours
    real, intent(IN):: mu0(:) ! (knon) cosinus de l'angle solaire zenithal
    integer, intent(IN):: nisurf ! index de la surface a traiter

    integer, intent(in):: knindex(:) ! (knon)
    ! index des points de la surface a traiter

    REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx)

    REAL, intent(INOUT):: qsol(:) ! (knon)
    ! column-density of water in soil, in kg m-2

    real, intent(IN):: u1lay(:), v1lay(:) ! (knon) vitesse 1ere couche

    real, intent(IN):: temp_air(:) ! (knon) temperature de l'air 1ere couche

    real, intent(IN):: q1lay(:) ! (knon)
    ! humidit\'e sp\'ecifique de la premi\`ere couche

    real, intent(IN):: cdragh(:) ! (knon) coefficient d'echange

    real, intent(IN):: tAcoef(:), qAcoef(:) ! (knon)
    ! coefficients A de la r\'esolution de la couche limite pour t et q

    real, intent(IN):: tBcoef(:), qBcoef(:) ! (knon)
    ! coefficients B de la r\'esolution de la couche limite pour t et q

    real, intent(IN):: rain_fall(:) ! (knon)
    ! precipitation, liquid water mass flux (kg / m2 / s), positive down

    real, intent(IN):: snow_fall(:) ! (knon)
    ! precipitation, solid water mass flux (kg / m2 / s), positive down

    real, intent(IN):: rugos(:) ! (knon) rugosite
    real, intent(IN):: rugoro(:) ! (knon) rugosite orographique
    real, intent(INOUT):: snow(:) ! (knon)
    real, intent(OUT):: qsurf(:) ! (knon)
    real, intent(IN):: ts(:) ! (knon) temp\'erature de surface
    real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche)
    real, intent(IN):: ps(:) ! (knon) pression au sol, en Pa

    REAL, INTENT(IN):: radsol(:) ! (knon)
    ! surface net downward radiative flux, in W / m2

    real, intent(OUT):: evap(:) ! (knon) evaporation totale

    real, intent(OUT):: flux_t(:) ! (knon) flux de chaleur sensible
    ! (Cp T) à la surface, positif vers le bas, W / m2

    real, intent(OUT):: fluxlat(:) ! (knon) flux de chaleur latente, en W m-2
    real, intent(OUT):: dflux_l(:), dflux_s(:) ! (knon)
    real, intent(OUT):: tsurf_new(:) ! (knon) temp\'erature au sol
    real, intent(OUT):: albedo(:) ! (knon) albedo
    real, intent(OUT):: z0_new(:) ! (knon) surface roughness

    real, intent(in):: pctsrf_new_sic(:) ! (knon) 
    ! nouvelle repartition des surfaces

    real, intent(INOUT):: agesno(:) ! (knon)

    real, intent(OUT):: fqcalving(:) ! (knon)
    ! Flux d'eau "perdue" par la surface et n\'ecessaire pour limiter la
    ! hauteur de neige, en kg / m2 / s

    real, intent(OUT):: ffonte(:) ! (knon)
    ! flux thermique utilis\'e pour fondre la neige

    real, intent(INOUT):: run_off_lic_0(:) ! (knon)
    ! run_off_lic_0 runoff glacier du pas de temps precedent

    REAL, intent(OUT):: run_off_lic(:) ! (knon) ruissellement total

    ! Local:
    REAL soilcap(size(knindex)) ! (knon)
    REAL soilflux(size(knindex)) ! (knon)
    integer ii
    real cal(size(knindex)) ! (knon)
    real beta(size(knindex)) ! (knon) evap reelle
    real tsurf(size(knindex)) ! (knon)
    real alb_neig(size(knindex)) ! (knon)
    real zfra(size(knindex)) ! (knon)
    REAL, PARAMETER:: fmagic = 1. ! facteur magique pour r\'egler l'alb\'edo
    REAL, PARAMETER:: max_eau_sol = 150. ! in kg m-2
    REAL, PARAMETER:: tau_gl = 86400. * 5.

    !-------------------------------------------------------------

    select case (nisurf)
    case (is_ter)
       ! Surface "terre", appel \`a l'interface avec les sols continentaux

       ! Calcul age de la neige

       ! Read albedo from the file containing boundary conditions then
       ! add the albedo of snow:

       call interfsur_lim(julien, knindex, albedo, z0_new)

       beta = min(2. * qsol / max_eau_sol, 1.)
       CALL soil(is_ter, snow, ts, tsoil, soilcap, soilflux)
       cal = RCPD / soilcap

       CALL calcul_fluxs(ts, p1lay, cal, beta, cdragh, ps, qsurf, &
            radsol + soilflux, temp_air, q1lay, u1lay, v1lay, tAcoef, &
            qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, &
            dflux_l, dif_grnd = 0.)
       CALL fonte_neige(is_ter, rain_fall, snow_fall, snow, qsol, &
            tsurf_new, evap, fqcalving, ffonte, run_off_lic_0, run_off_lic)

       call albsno(agesno, alb_neig, snow_fall)
       where (snow < 0.0001) agesno = 0.
       zfra = max(0., min(1., snow / (snow + 10.)))
       albedo = alb_neig * zfra + albedo * (1. - zfra)
       z0_new = sqrt(z0_new**2 + rugoro**2)
    case (is_oce)
       ! Surface "oc\'ean", appel \`a l'interface avec l'oc\'ean

       ffonte = 0.
       call limit_read_sst(julien, knindex, tsurf)
       cal = 0.
       beta = 1.
       call calcul_fluxs(tsurf, p1lay, cal, beta, cdragh, ps, qsurf, radsol, &
            temp_air, q1lay, u1lay, v1lay, tAcoef, qAcoef, tBcoef, qBcoef, &
            tsurf_new, evap, fluxlat, flux_t, dflux_s, dflux_l, dif_grnd = 0.)
       agesno = 0.
       albedo = alboc_cd(mu0) * fmagic
       z0_new = sqrt(rugos**2 + rugoro**2)
       fqcalving = 0.
    case (is_sic)
       ! Surface "glace de mer" appel a l'interface avec l'ocean

       DO ii = 1, size(knindex)
          IF (pctsrf_new_sic(ii) < EPSFRA) then
             snow(ii) = 0.
             tsurf_new(ii) = RTT - 1.8
             tsoil(ii, :) = RTT - 1.8
          else
             tsurf_new(ii) = ts(ii)
          endif
       enddo

       CALL soil(is_sic, snow, tsurf_new, tsoil, soilcap, soilflux)
       cal = RCPD / soilcap
       tsurf = tsurf_new
       beta = 1.
       CALL calcul_fluxs(tsurf, p1lay, cal, beta, cdragh, ps, qsurf, &
            radsol + soilflux, temp_air, q1lay, u1lay, v1lay, tAcoef, &
            qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, &
            dflux_l, dif_grnd = 1. / tau_gl)
       CALL fonte_neige(is_sic, rain_fall, snow_fall, snow, qsol, &
            tsurf_new, evap, fqcalving, ffonte, run_off_lic_0, run_off_lic)

       ! Compute the albedo:

       CALL albsno(agesno, alb_neig, snow_fall)
       WHERE (snow < 0.0001) agesno = 0.
       zfra = MAX(0., MIN(1., snow / (snow + 10.)))
       albedo = alb_neig * zfra + 0.6 * (1. - zfra)

       z0_new = SQRT(0.002**2 + rugoro**2)
    case (is_lic)
       ! Surface "glacier continentaux" appel a l'interface avec le sol

       CALL soil(is_lic, snow, ts, tsoil, soilcap, soilflux)
       cal = RCPD / soilcap
       beta = 1.
       call calcul_fluxs(ts, p1lay, cal, beta, cdragh, ps, qsurf, &
            radsol + soilflux, temp_air, q1lay, u1lay, v1lay, tAcoef, &
            qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, &
            dflux_l, dif_grnd = 0.)
       call fonte_neige(is_lic, rain_fall, snow_fall, snow, qsol, &
            tsurf_new, evap, fqcalving, ffonte, run_off_lic_0, run_off_lic)

       ! calcul albedo
       CALL albsno(agesno, alb_neig, snow_fall)
       WHERE (snow < 0.0001) agesno = 0.
       albedo = 0.77

       ! Rugosite
       z0_new = rugoro
    case default
       print *, 'Index surface = ', nisurf
       call abort_gcm("interfsurf_hq", 'Index surface non valable')
    end select

  END SUBROUTINE interfsurf_hq

end module interfsurf_hq_m
1	module interfsurf_hq_m
2
3	implicit none
4
5	contains
6
7	SUBROUTINE interfsurf_hq(julien, mu0, nisurf, knindex, tsoil, qsol, u1lay, &
8	v1lay, temp_air, q1lay, cdragh, tAcoef, qAcoef, tBcoef, qBcoef, &
9	rain_fall, snow_fall, rugos, rugoro, snow, qsurf, ts, p1lay, ps, &
10	radsol, evap, flux_t, fluxlat, dflux_l, dflux_s, tsurf_new, albedo, &
11	z0_new, pctsrf_new_sic, agesno, fqcalving, ffonte, run_off_lic_0, &
12	run_off_lic)
13
14	! Cette routine sert d'aiguillage entre l'atmosph\`ere et la surface
15	! en g\'en\'eral (sols continentaux, oc\'eans, glaces) pour les flux de
16	! chaleur et d'humidit\'e.
17
18	! Laurent Fairhead, February 2000
19
20	USE abort_gcm_m, ONLY: abort_gcm
21	use alboc_cd_m, only: alboc_cd
22	USE albsno_m, ONLY: albsno
23	USE calcul_fluxs_m, ONLY: calcul_fluxs
24	USE fonte_neige_m, ONLY: fonte_neige
25	USE indicesol, ONLY: epsfra, is_lic, is_oce, is_sic, is_ter
26	USE interfsur_lim_m, ONLY: interfsur_lim
27	use limit_read_sst_m, only: limit_read_sst
28	use soil_m, only: soil
29	USE suphec_m, ONLY: rcpd, rtt
30
31	integer, intent(IN):: julien ! jour dans l'annee en cours
32	real, intent(IN):: mu0(:) ! (knon) cosinus de l'angle solaire zenithal
33	integer, intent(IN):: nisurf ! index de la surface a traiter
34
35	integer, intent(in):: knindex(:) ! (knon)
36	! index des points de la surface a traiter
37
38	REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx)
39
40	REAL, intent(INOUT):: qsol(:) ! (knon)
41	! column-density of water in soil, in kg m-2
42
43	real, intent(IN):: u1lay(:), v1lay(:) ! (knon) vitesse 1ere couche
44
45	real, intent(IN):: temp_air(:) ! (knon) temperature de l'air 1ere couche
46
47	real, intent(IN):: q1lay(:) ! (knon)
48	! humidit\'e sp\'ecifique de la premi\`ere couche
49
50	real, intent(IN):: cdragh(:) ! (knon) coefficient d'echange
51
52	real, intent(IN):: tAcoef(:), qAcoef(:) ! (knon)
53	! coefficients A de la r\'esolution de la couche limite pour t et q
54
55	real, intent(IN):: tBcoef(:), qBcoef(:) ! (knon)
56	! coefficients B de la r\'esolution de la couche limite pour t et q
57
58	real, intent(IN):: rain_fall(:) ! (knon)
59	! precipitation, liquid water mass flux (kg / m2 / s), positive down
60
61	real, intent(IN):: snow_fall(:) ! (knon)
62	! precipitation, solid water mass flux (kg / m2 / s), positive down
63
64	real, intent(IN):: rugos(:) ! (knon) rugosite
65	real, intent(IN):: rugoro(:) ! (knon) rugosite orographique
66	real, intent(INOUT):: snow(:) ! (knon)
67	real, intent(OUT):: qsurf(:) ! (knon)
68	real, intent(IN):: ts(:) ! (knon) temp\'erature de surface
69	real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche)
70	real, intent(IN):: ps(:) ! (knon) pression au sol, en Pa
71
72	REAL, INTENT(IN):: radsol(:) ! (knon)
73	! surface net downward radiative flux, in W / m2
74
75	real, intent(OUT):: evap(:) ! (knon) evaporation totale
76
77	real, intent(OUT):: flux_t(:) ! (knon) flux de chaleur sensible
78	! (Cp T) à la surface, positif vers le bas, W / m2
79
80	real, intent(OUT):: fluxlat(:) ! (knon) flux de chaleur latente, en W m-2
81	real, intent(OUT):: dflux_l(:), dflux_s(:) ! (knon)
82	real, intent(OUT):: tsurf_new(:) ! (knon) temp\'erature au sol
83	real, intent(OUT):: albedo(:) ! (knon) albedo
84	real, intent(OUT):: z0_new(:) ! (knon) surface roughness
85
86	real, intent(in):: pctsrf_new_sic(:) ! (knon)
87	! nouvelle repartition des surfaces
88
89	real, intent(INOUT):: agesno(:) ! (knon)
90
91	real, intent(OUT):: fqcalving(:) ! (knon)
92	! Flux d'eau "perdue" par la surface et n\'ecessaire pour limiter la
93	! hauteur de neige, en kg / m2 / s
94
95	real, intent(OUT):: ffonte(:) ! (knon)
96	! flux thermique utilis\'e pour fondre la neige
97
98	real, intent(INOUT):: run_off_lic_0(:) ! (knon)
99	! run_off_lic_0 runoff glacier du pas de temps precedent
100
101	REAL, intent(OUT):: run_off_lic(:) ! (knon) ruissellement total
102
103	! Local:
104	REAL soilcap(size(knindex)) ! (knon)
105	REAL soilflux(size(knindex)) ! (knon)
106	integer ii
107	real cal(size(knindex)) ! (knon)
108	real beta(size(knindex)) ! (knon) evap reelle
109	real tsurf(size(knindex)) ! (knon)
110	real alb_neig(size(knindex)) ! (knon)
111	real zfra(size(knindex)) ! (knon)
112	REAL, PARAMETER:: fmagic = 1. ! facteur magique pour r\'egler l'alb\'edo
113	REAL, PARAMETER:: max_eau_sol = 150. ! in kg m-2
114	REAL, PARAMETER:: tau_gl = 86400. * 5.
115
116	!-------------------------------------------------------------
117
118	select case (nisurf)
119	case (is_ter)
120	! Surface "terre", appel \`a l'interface avec les sols continentaux
121
122	! Calcul age de la neige
123
124	! Read albedo from the file containing boundary conditions then
125	! add the albedo of snow:
126
127	call interfsur_lim(julien, knindex, albedo, z0_new)
128
129	beta = min(2. * qsol / max_eau_sol, 1.)
130	CALL soil(is_ter, snow, ts, tsoil, soilcap, soilflux)
131	cal = RCPD / soilcap
132
133	CALL calcul_fluxs(ts, p1lay, cal, beta, cdragh, ps, qsurf, &
134	radsol + soilflux, temp_air, q1lay, u1lay, v1lay, tAcoef, &
135	qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, &
136	dflux_l, dif_grnd = 0.)
137	CALL fonte_neige(is_ter, rain_fall, snow_fall, snow, qsol, &
138	tsurf_new, evap, fqcalving, ffonte, run_off_lic_0, run_off_lic)
139
140	call albsno(agesno, alb_neig, snow_fall)
141	where (snow < 0.0001) agesno = 0.
142	zfra = max(0., min(1., snow / (snow + 10.)))
143	albedo = alb_neig * zfra + albedo * (1. - zfra)
144	z0_new = sqrt(z0_new2 + rugoro2)
145	case (is_oce)
146	! Surface "oc\'ean", appel \`a l'interface avec l'oc\'ean
147
148	ffonte = 0.
149	call limit_read_sst(julien, knindex, tsurf)
150	cal = 0.
151	beta = 1.
152	call calcul_fluxs(tsurf, p1lay, cal, beta, cdragh, ps, qsurf, radsol, &
153	temp_air, q1lay, u1lay, v1lay, tAcoef, qAcoef, tBcoef, qBcoef, &
154	tsurf_new, evap, fluxlat, flux_t, dflux_s, dflux_l, dif_grnd = 0.)
155	agesno = 0.
156	albedo = alboc_cd(mu0) * fmagic
157	z0_new = sqrt(rugos2 + rugoro2)
158	fqcalving = 0.
159	case (is_sic)
160	! Surface "glace de mer" appel a l'interface avec l'ocean
161
162	DO ii = 1, size(knindex)
163	IF (pctsrf_new_sic(ii) < EPSFRA) then
164	snow(ii) = 0.
165	tsurf_new(ii) = RTT - 1.8
166	tsoil(ii, :) = RTT - 1.8
167	else
168	tsurf_new(ii) = ts(ii)
169	endif
170	enddo
171
172	CALL soil(is_sic, snow, tsurf_new, tsoil, soilcap, soilflux)
173	cal = RCPD / soilcap
174	tsurf = tsurf_new
175	beta = 1.
176	CALL calcul_fluxs(tsurf, p1lay, cal, beta, cdragh, ps, qsurf, &
177	radsol + soilflux, temp_air, q1lay, u1lay, v1lay, tAcoef, &
178	qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, &
179	dflux_l, dif_grnd = 1. / tau_gl)
180	CALL fonte_neige(is_sic, rain_fall, snow_fall, snow, qsol, &
181	tsurf_new, evap, fqcalving, ffonte, run_off_lic_0, run_off_lic)
182
183	! Compute the albedo:
184
185	CALL albsno(agesno, alb_neig, snow_fall)
186	WHERE (snow < 0.0001) agesno = 0.
187	zfra = MAX(0., MIN(1., snow / (snow + 10.)))
188	albedo = alb_neig * zfra + 0.6 * (1. - zfra)
189
190	z0_new = SQRT(0.0022 + rugoro2)
191	case (is_lic)
192	! Surface "glacier continentaux" appel a l'interface avec le sol
193
194	CALL soil(is_lic, snow, ts, tsoil, soilcap, soilflux)
195	cal = RCPD / soilcap
196	beta = 1.
197	call calcul_fluxs(ts, p1lay, cal, beta, cdragh, ps, qsurf, &
198	radsol + soilflux, temp_air, q1lay, u1lay, v1lay, tAcoef, &
199	qAcoef, tBcoef, qBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, &
200	dflux_l, dif_grnd = 0.)
201	call fonte_neige(is_lic, rain_fall, snow_fall, snow, qsol, &
202	tsurf_new, evap, fqcalving, ffonte, run_off_lic_0, run_off_lic)
203
204	! calcul albedo
205	CALL albsno(agesno, alb_neig, snow_fall)
206	WHERE (snow < 0.0001) agesno = 0.
207	albedo = 0.77
208
209	! Rugosite
210	z0_new = rugoro
211	case default
212	print *, 'Index surface = ', nisurf
213	call abort_gcm("interfsurf_hq", 'Index surface non valable')
214	end select
215
216	END SUBROUTINE interfsurf_hq
217
218	end module interfsurf_hq_m