phylmd/Interface_surf/interfsurf_hq.f

module interfsurf_hq_m

  implicit none

contains

  SUBROUTINE interfsurf_hq(dtime, julien, rmu0, nisurf, knindex, debut, &
       tsoil, qsol, u1_lay, v1_lay, temp_air, spechum, tq_cdrag, petAcoef, &
       peqAcoef, petBcoef, peqBcoef, precip_rain, precip_snow, rugos, rugoro, &
       snow, qsurf, ts, p1lay, ps, radsol, evap, flux_t, fluxlat, dflux_l, &
       dflux_s, tsurf_new, albedo, z0_new, pctsrf_new_sic, agesno, fqcalving, &
       ffonte, run_off_lic_0)

    ! Cette routine sert d'aiguillage entre l'atmosph\`ere et la surface
    ! en g\'en\'eral (sols continentaux, oc\'eans, glaces) pour les flux de
    ! chaleur et d'humidit\'e.

    ! Laurent Fairhead, February 2000

    USE abort_gcm_m, ONLY: abort_gcm
    use alboc_cd_m, only: alboc_cd
    USE albsno_m, ONLY: albsno
    USE calcul_fluxs_m, ONLY: calcul_fluxs
    USE dimphy, ONLY: klon
    USE fonte_neige_m, ONLY: fonte_neige
    USE indicesol, ONLY: epsfra, is_lic, is_oce, is_sic, is_ter
    USE interface_surf, ONLY: conf_interface
    USE interfsur_lim_m, ONLY: interfsur_lim
    use read_sst_m, only: read_sst
    use soil_m, only: soil
    USE suphec_m, ONLY: rcpd, rtt

    real, intent(IN):: dtime ! pas de temps de la physique (en s)
    integer, intent(IN):: julien ! jour dans l'annee en cours
    real, intent(IN):: rmu0(klon) ! cosinus de l'angle solaire zenithal
    integer, intent(IN):: nisurf ! index de la surface a traiter

    integer, intent(in):: knindex(:) ! (knon)
    ! index des points de la surface a traiter

    logical, intent(IN):: debut ! 1er appel a la physique
    ! (si false calcul simplifie des fluxs sur les continents)

    REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx)

    REAL, intent(INOUT):: qsol(:) ! (knon)
    ! column-density of water in soil, in kg m-2

    real, intent(IN):: u1_lay(:), v1_lay(:) ! (knon) vitesse 1ere couche

    real, intent(IN):: temp_air(:) ! (knon) temperature de l'air 1ere couche
    real, intent(IN):: spechum(:) ! (knon) humidite specifique 1ere couche
    real, intent(IN):: tq_cdrag(:) ! (knon) coefficient d'echange

    real, intent(IN):: petAcoef(:), peqAcoef(:) ! (knon)
    ! coefficients A de la r\'esolution de la couche limite pour t et q

    real, intent(IN):: petBcoef(:), peqBcoef(:) ! (knon)
    ! coefficients B de la r\'esolution de la couche limite pour t et q

    real, intent(IN):: precip_rain(klon)
    ! precipitation, liquid water mass flux (kg / m2 / s), positive down

    real, intent(IN):: precip_snow(klon)
    ! precipitation, solid water mass flux (kg / m2 / s), positive down

    real, intent(IN):: rugos(:) ! (knon) rugosite
    real, intent(IN):: rugoro(:) ! (knon) rugosite orographique
    real, intent(INOUT):: snow(:) ! (knon)
    real, intent(INOUT):: qsurf(klon)
    real, intent(IN):: ts(:) ! (knon) temp\'erature de surface
    real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche)
    real, intent(IN):: ps(:) ! (knon) pression au sol
    REAL, INTENT(IN):: radsol(:) ! (knon) rayonnement net au sol (LW + SW)
    real, intent(OUT):: evap(:) ! (knon) evaporation totale

    real, intent(OUT):: flux_t(:) ! (knon) flux de chaleur sensible
    ! (Cp T) à la surface, positif vers le bas, W / m2

    real, intent(OUT):: fluxlat(:) ! (knon) flux de chaleur latente
    real, intent(OUT):: dflux_l(:), dflux_s(:) ! (knon)
    real, intent(OUT):: tsurf_new(:) ! (knon) temp\'erature au sol
    real, intent(OUT):: albedo(:) ! (knon) albedo
    real, intent(OUT):: z0_new(:) ! (knon) surface roughness

    real, intent(in):: pctsrf_new_sic(:) ! (klon) 
    ! nouvelle repartition des surfaces

    real, intent(INOUT):: agesno(:) ! (knon)

    real, intent(OUT):: fqcalving(:) ! (knon)
    ! Flux d'eau "perdue" par la surface et n\'ecessaire pour limiter la
    ! hauteur de neige, en kg / m2 / s

    real, dimension(klon), intent(INOUT):: ffonte
    ! Flux thermique utiliser pour fondre la neige

    real, dimension(klon), intent(INOUT):: run_off_lic_0
    ! run_off_lic_0 runoff glacier du pas de temps precedent

    ! Local:
    integer knon ! nombre de points de la surface a traiter
    REAL soilcap(size(knindex)) ! (knon)
    REAL soilflux(size(knindex)) ! (knon)
    logical:: first_call = .true.
    integer ii
    real cal(size(knindex)) ! (knon)
    real beta(size(knindex)) ! (knon) evap reelle
    real dif_grnd(klon)
    real tsurf(size(knindex)) ! (knon)
    real alb_neig(size(knindex)) ! (knon)
    real zfra(size(knindex)) ! (knon)
    REAL, PARAMETER:: fmagic = 1. ! facteur magique pour r\'egler l'alb\'edo
    REAL, PARAMETER:: max_eau_sol = 150. ! in kg m-2
    REAL, PARAMETER:: tau_gl = 86400. * 5.

    !-------------------------------------------------------------

    knon = size(knindex)

    ! On doit commencer par appeler les schemas de surfaces continentales
    ! car l'ocean a besoin du ruissellement qui est y calcule

    if (first_call) then
       call conf_interface

       if (nisurf /= is_ter .and. klon > 1) then
          print *, ' nisurf = ', nisurf, ' /= is_ter = ', is_ter
          print *, 'or on doit commencer par les surfaces continentales'
          call abort_gcm("interfsurf_hq", &
               'On doit commencer par les surfaces continentales')
       endif

       if (is_oce > is_sic) then
          print *, 'is_oce = ', is_oce, '> is_sic = ', is_sic
          call abort_gcm("interfsurf_hq", &
               "L'ocean doit etre traite avant la banquise")
       endif

       first_call = .false.
    endif

    ! Initialisations diverses

    ffonte(1:knon) = 0.
    dif_grnd = 999999.

    ! Aiguillage vers les differents schemas de surface

    select case (nisurf)
    case (is_ter)
       ! Surface "terre", appel \`a l'interface avec les sols continentaux

       ! Calcul age de la neige

       ! Read albedo from the file containing boundary conditions then
       ! add the albedo of snow:

       call interfsur_lim(dtime, julien, knindex, debut, albedo, z0_new)

       beta = min(2. * qsol / max_eau_sol, 1.)
       dif_grnd(:knon) = 0.
       CALL soil(dtime, is_ter, snow, ts, tsoil, soilcap, soilflux)
       cal = RCPD / soilcap

       CALL calcul_fluxs(dtime, ts, p1lay, cal, beta, tq_cdrag, ps, &
            qsurf(:knon), radsol + soilflux, dif_grnd(:knon), temp_air, &
            spechum, u1_lay, v1_lay, petAcoef, peqAcoef, petBcoef, &
            peqBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, dflux_l)
       CALL fonte_neige(is_ter, dtime, precip_rain(:knon), precip_snow(:knon), &
            snow, qsol, tsurf_new, evap, fqcalving, ffonte(:knon), &
            run_off_lic_0(:knon))

       call albsno(dtime, agesno, alb_neig, precip_snow(:knon))
       where (snow < 0.0001) agesno = 0.
       zfra = max(0., min(1., snow / (snow + 10.)))
       albedo = alb_neig * zfra + albedo * (1. - zfra)
       z0_new = sqrt(z0_new**2 + rugoro**2)
    case (is_oce)
       ! Surface "oc\'ean", appel \`a l'interface avec l'oc\'ean

       call read_sst(julien, knindex, tsurf)
       cal = 0.
       beta = 1.
       dif_grnd = 0.
       call calcul_fluxs(dtime, tsurf, p1lay, cal, beta, tq_cdrag, ps, &
            qsurf(:knon), radsol, dif_grnd(:knon), temp_air, spechum, u1_lay, &
            v1_lay, petAcoef, peqAcoef, petBcoef, peqBcoef, tsurf_new, evap, &
            fluxlat, flux_t, dflux_s, dflux_l)
       agesno = 0.
       albedo = alboc_cd(rmu0(knindex)) * fmagic
       z0_new = sqrt(rugos**2 + rugoro**2)
       fqcalving = 0.
    case (is_sic)
       ! Surface "glace de mer" appel a l'interface avec l'ocean

       DO ii = 1, knon
          IF (pctsrf_new_sic(knindex(ii)) < EPSFRA) then
             snow(ii) = 0.
             tsurf_new(ii) = RTT - 1.8
             tsoil(ii, :) = RTT - 1.8
          else
             tsurf_new(ii) = ts(ii)
          endif
       enddo

       CALL soil(dtime, is_sic, snow, tsurf_new, tsoil, soilcap, soilflux)
       cal = RCPD / soilcap
       dif_grnd = 1. / tau_gl
       tsurf = tsurf_new
       beta = 1.

       CALL calcul_fluxs(dtime, tsurf, p1lay, cal, beta, tq_cdrag, ps, &
            qsurf(:knon), radsol + soilflux, dif_grnd(:knon), temp_air, &
            spechum, u1_lay, v1_lay, petAcoef, peqAcoef, petBcoef, &
            peqBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, dflux_l)
       CALL fonte_neige(is_sic, dtime, precip_rain(:knon), &
            precip_snow(:knon), snow, qsol, tsurf_new, evap, &
            fqcalving, ffonte(:knon), run_off_lic_0(:knon))

       ! Compute the albedo:

       CALL albsno(dtime, agesno, alb_neig, precip_snow(:knon))
       WHERE (snow < 0.0001) agesno = 0.
       zfra = MAX(0., MIN(1., snow / (snow + 10.)))
       albedo = alb_neig * zfra + 0.6 * (1. - zfra)

       z0_new = SQRT(0.002**2 + rugoro**2)
    case (is_lic)
       ! Surface "glacier continentaux" appel a l'interface avec le sol

       CALL soil(dtime, is_lic, snow, ts, tsoil, soilcap, soilflux)
       cal = RCPD / soilcap
       beta = 1.
       dif_grnd = 0.

       call calcul_fluxs(dtime, ts, p1lay, cal, beta, tq_cdrag, ps, &
            qsurf(:knon), radsol + soilflux, dif_grnd(:knon), temp_air, &
            spechum, u1_lay, v1_lay, petAcoef, peqAcoef, petBcoef, &
            peqBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, dflux_l)
       call fonte_neige(is_lic, dtime, precip_rain(:knon), &
            precip_snow(:knon), snow, qsol, tsurf_new, evap, &
            fqcalving, ffonte(:knon), run_off_lic_0(:knon))

       ! calcul albedo
       CALL albsno(dtime, agesno, alb_neig, precip_snow(:knon))
       WHERE (snow < 0.0001) agesno = 0.
       albedo = 0.77

       ! Rugosite
       z0_new = rugoro
    case default
       print *, 'Index surface = ', nisurf
       call abort_gcm("interfsurf_hq", 'Index surface non valable')
    end select

  END SUBROUTINE interfsurf_hq

end module interfsurf_hq_m
1	module interfsurf_hq_m
2
3	implicit none
4
5	contains
6
7	SUBROUTINE interfsurf_hq(dtime, julien, rmu0, nisurf, knindex, debut, &
8	tsoil, qsol, u1_lay, v1_lay, temp_air, spechum, tq_cdrag, petAcoef, &
9	peqAcoef, petBcoef, peqBcoef, precip_rain, precip_snow, rugos, rugoro, &
10	snow, qsurf, ts, p1lay, ps, radsol, evap, flux_t, fluxlat, dflux_l, &
11	dflux_s, tsurf_new, albedo, z0_new, pctsrf_new_sic, agesno, fqcalving, &
12	ffonte, run_off_lic_0)
13
14	! Cette routine sert d'aiguillage entre l'atmosph\`ere et la surface
15	! en g\'en\'eral (sols continentaux, oc\'eans, glaces) pour les flux de
16	! chaleur et d'humidit\'e.
17
18	! Laurent Fairhead, February 2000
19
20	USE abort_gcm_m, ONLY: abort_gcm
21	use alboc_cd_m, only: alboc_cd
22	USE albsno_m, ONLY: albsno
23	USE calcul_fluxs_m, ONLY: calcul_fluxs
24	USE dimphy, ONLY: klon
25	USE fonte_neige_m, ONLY: fonte_neige
26	USE indicesol, ONLY: epsfra, is_lic, is_oce, is_sic, is_ter
27	USE interface_surf, ONLY: conf_interface
28	USE interfsur_lim_m, ONLY: interfsur_lim
29	use read_sst_m, only: read_sst
30	use soil_m, only: soil
31	USE suphec_m, ONLY: rcpd, rtt
32
33	real, intent(IN):: dtime ! pas de temps de la physique (en s)
34	integer, intent(IN):: julien ! jour dans l'annee en cours
35	real, intent(IN):: rmu0(klon) ! cosinus de l'angle solaire zenithal
36	integer, intent(IN):: nisurf ! index de la surface a traiter
37
38	integer, intent(in):: knindex(:) ! (knon)
39	! index des points de la surface a traiter
40
41	logical, intent(IN):: debut ! 1er appel a la physique
42	! (si false calcul simplifie des fluxs sur les continents)
43
44	REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx)
45
46	REAL, intent(INOUT):: qsol(:) ! (knon)
47	! column-density of water in soil, in kg m-2
48
49	real, intent(IN):: u1_lay(:), v1_lay(:) ! (knon) vitesse 1ere couche
50
51	real, intent(IN):: temp_air(:) ! (knon) temperature de l'air 1ere couche
52	real, intent(IN):: spechum(:) ! (knon) humidite specifique 1ere couche
53	real, intent(IN):: tq_cdrag(:) ! (knon) coefficient d'echange
54
55	real, intent(IN):: petAcoef(:), peqAcoef(:) ! (knon)
56	! coefficients A de la r\'esolution de la couche limite pour t et q
57
58	real, intent(IN):: petBcoef(:), peqBcoef(:) ! (knon)
59	! coefficients B de la r\'esolution de la couche limite pour t et q
60
61	real, intent(IN):: precip_rain(klon)
62	! precipitation, liquid water mass flux (kg / m2 / s), positive down
63
64	real, intent(IN):: precip_snow(klon)
65	! precipitation, solid water mass flux (kg / m2 / s), positive down
66
67	real, intent(IN):: rugos(:) ! (knon) rugosite
68	real, intent(IN):: rugoro(:) ! (knon) rugosite orographique
69	real, intent(INOUT):: snow(:) ! (knon)
70	real, intent(INOUT):: qsurf(klon)
71	real, intent(IN):: ts(:) ! (knon) temp\'erature de surface
72	real, intent(IN):: p1lay(:) ! (knon) pression 1er niveau (milieu de couche)
73	real, intent(IN):: ps(:) ! (knon) pression au sol
74	REAL, INTENT(IN):: radsol(:) ! (knon) rayonnement net au sol (LW + SW)
75	real, intent(OUT):: evap(:) ! (knon) evaporation totale
76
77	real, intent(OUT):: flux_t(:) ! (knon) flux de chaleur sensible
78	! (Cp T) à la surface, positif vers le bas, W / m2
79
80	real, intent(OUT):: fluxlat(:) ! (knon) flux de chaleur latente
81	real, intent(OUT):: dflux_l(:), dflux_s(:) ! (knon)
82	real, intent(OUT):: tsurf_new(:) ! (knon) temp\'erature au sol
83	real, intent(OUT):: albedo(:) ! (knon) albedo
84	real, intent(OUT):: z0_new(:) ! (knon) surface roughness
85
86	real, intent(in):: pctsrf_new_sic(:) ! (klon)
87	! nouvelle repartition des surfaces
88
89	real, intent(INOUT):: agesno(:) ! (knon)
90
91	real, intent(OUT):: fqcalving(:) ! (knon)
92	! Flux d'eau "perdue" par la surface et n\'ecessaire pour limiter la
93	! hauteur de neige, en kg / m2 / s
94
95	real, dimension(klon), intent(INOUT):: ffonte
96	! Flux thermique utiliser pour fondre la neige
97
98	real, dimension(klon), intent(INOUT):: run_off_lic_0
99	! run_off_lic_0 runoff glacier du pas de temps precedent
100
101	! Local:
102	integer knon ! nombre de points de la surface a traiter
103	REAL soilcap(size(knindex)) ! (knon)
104	REAL soilflux(size(knindex)) ! (knon)
105	logical:: first_call = .true.
106	integer ii
107	real cal(size(knindex)) ! (knon)
108	real beta(size(knindex)) ! (knon) evap reelle
109	real dif_grnd(klon)
110	real tsurf(size(knindex)) ! (knon)
111	real alb_neig(size(knindex)) ! (knon)
112	real zfra(size(knindex)) ! (knon)
113	REAL, PARAMETER:: fmagic = 1. ! facteur magique pour r\'egler l'alb\'edo
114	REAL, PARAMETER:: max_eau_sol = 150. ! in kg m-2
115	REAL, PARAMETER:: tau_gl = 86400. * 5.
116
117	!-------------------------------------------------------------
118
119	knon = size(knindex)
120
121	! On doit commencer par appeler les schemas de surfaces continentales
122	! car l'ocean a besoin du ruissellement qui est y calcule
123
124	if (first_call) then
125	call conf_interface
126
127	if (nisurf /= is_ter .and. klon > 1) then
128	print *, ' nisurf = ', nisurf, ' /= is_ter = ', is_ter
129	print *, 'or on doit commencer par les surfaces continentales'
130	call abort_gcm("interfsurf_hq", &
131	'On doit commencer par les surfaces continentales')
132	endif
133
134	if (is_oce > is_sic) then
135	print *, 'is_oce = ', is_oce, '> is_sic = ', is_sic
136	call abort_gcm("interfsurf_hq", &
137	"L'ocean doit etre traite avant la banquise")
138	endif
139
140	first_call = .false.
141	endif
142
143	! Initialisations diverses
144
145	ffonte(1:knon) = 0.
146	dif_grnd = 999999.
147
148	! Aiguillage vers les differents schemas de surface
149
150	select case (nisurf)
151	case (is_ter)
152	! Surface "terre", appel \`a l'interface avec les sols continentaux
153
154	! Calcul age de la neige
155
156	! Read albedo from the file containing boundary conditions then
157	! add the albedo of snow:
158
159	call interfsur_lim(dtime, julien, knindex, debut, albedo, z0_new)
160
161	beta = min(2. * qsol / max_eau_sol, 1.)
162	dif_grnd(:knon) = 0.
163	CALL soil(dtime, is_ter, snow, ts, tsoil, soilcap, soilflux)
164	cal = RCPD / soilcap
165
166	CALL calcul_fluxs(dtime, ts, p1lay, cal, beta, tq_cdrag, ps, &
167	qsurf(:knon), radsol + soilflux, dif_grnd(:knon), temp_air, &
168	spechum, u1_lay, v1_lay, petAcoef, peqAcoef, petBcoef, &
169	peqBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, dflux_l)
170	CALL fonte_neige(is_ter, dtime, precip_rain(:knon), precip_snow(:knon), &
171	snow, qsol, tsurf_new, evap, fqcalving, ffonte(:knon), &
172	run_off_lic_0(:knon))
173
174	call albsno(dtime, agesno, alb_neig, precip_snow(:knon))
175	where (snow < 0.0001) agesno = 0.
176	zfra = max(0., min(1., snow / (snow + 10.)))
177	albedo = alb_neig * zfra + albedo * (1. - zfra)
178	z0_new = sqrt(z0_new2 + rugoro2)
179	case (is_oce)
180	! Surface "oc\'ean", appel \`a l'interface avec l'oc\'ean
181
182	call read_sst(julien, knindex, tsurf)
183	cal = 0.
184	beta = 1.
185	dif_grnd = 0.
186	call calcul_fluxs(dtime, tsurf, p1lay, cal, beta, tq_cdrag, ps, &
187	qsurf(:knon), radsol, dif_grnd(:knon), temp_air, spechum, u1_lay, &
188	v1_lay, petAcoef, peqAcoef, petBcoef, peqBcoef, tsurf_new, evap, &
189	fluxlat, flux_t, dflux_s, dflux_l)
190	agesno = 0.
191	albedo = alboc_cd(rmu0(knindex)) * fmagic
192	z0_new = sqrt(rugos2 + rugoro2)
193	fqcalving = 0.
194	case (is_sic)
195	! Surface "glace de mer" appel a l'interface avec l'ocean
196
197	DO ii = 1, knon
198	IF (pctsrf_new_sic(knindex(ii)) < EPSFRA) then
199	snow(ii) = 0.
200	tsurf_new(ii) = RTT - 1.8
201	tsoil(ii, :) = RTT - 1.8
202	else
203	tsurf_new(ii) = ts(ii)
204	endif
205	enddo
206
207	CALL soil(dtime, is_sic, snow, tsurf_new, tsoil, soilcap, soilflux)
208	cal = RCPD / soilcap
209	dif_grnd = 1. / tau_gl
210	tsurf = tsurf_new
211	beta = 1.
212
213	CALL calcul_fluxs(dtime, tsurf, p1lay, cal, beta, tq_cdrag, ps, &
214	qsurf(:knon), radsol + soilflux, dif_grnd(:knon), temp_air, &
215	spechum, u1_lay, v1_lay, petAcoef, peqAcoef, petBcoef, &
216	peqBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, dflux_l)
217	CALL fonte_neige(is_sic, dtime, precip_rain(:knon), &
218	precip_snow(:knon), snow, qsol, tsurf_new, evap, &
219	fqcalving, ffonte(:knon), run_off_lic_0(:knon))
220
221	! Compute the albedo:
222
223	CALL albsno(dtime, agesno, alb_neig, precip_snow(:knon))
224	WHERE (snow < 0.0001) agesno = 0.
225	zfra = MAX(0., MIN(1., snow / (snow + 10.)))
226	albedo = alb_neig * zfra + 0.6 * (1. - zfra)
227
228	z0_new = SQRT(0.0022 + rugoro2)
229	case (is_lic)
230	! Surface "glacier continentaux" appel a l'interface avec le sol
231
232	CALL soil(dtime, is_lic, snow, ts, tsoil, soilcap, soilflux)
233	cal = RCPD / soilcap
234	beta = 1.
235	dif_grnd = 0.
236
237	call calcul_fluxs(dtime, ts, p1lay, cal, beta, tq_cdrag, ps, &
238	qsurf(:knon), radsol + soilflux, dif_grnd(:knon), temp_air, &
239	spechum, u1_lay, v1_lay, petAcoef, peqAcoef, petBcoef, &
240	peqBcoef, tsurf_new, evap, fluxlat, flux_t, dflux_s, dflux_l)
241	call fonte_neige(is_lic, dtime, precip_rain(:knon), &
242	precip_snow(:knon), snow, qsol, tsurf_new, evap, &
243	fqcalving, ffonte(:knon), run_off_lic_0(:knon))
244
245	! calcul albedo
246	CALL albsno(dtime, agesno, alb_neig, precip_snow(:knon))
247	WHERE (snow < 0.0001) agesno = 0.
248	albedo = 0.77
249
250	! Rugosite
251	z0_new = rugoro
252	case default
253	print *, 'Index surface = ', nisurf
254	call abort_gcm("interfsurf_hq", 'Index surface non valable')
255	end select
256
257	END SUBROUTINE interfsurf_hq
258
259	end module interfsurf_hq_m