1 |
module screenp_m |
2 |
|
3 |
IMPLICIT none |
4 |
|
5 |
contains |
6 |
|
7 |
SUBROUTINE screenp(knon, speed, tair, qair, ts, qsurf, rugos, lmon, ustar, & |
8 |
testar, qstar, zref, delu, delte, delq) |
9 |
|
10 |
! From LMDZ4/libf/phylmd/screenp.F90, version 1.1.1.1, 2004/05/19 12:53:09 |
11 |
|
12 |
! Objet : calcul "pr\'edicteur" des anomalies du vent, de la |
13 |
! temp\'erature potentielle et de l'humidit\'e relative au niveau |
14 |
! de r\'ef\'erence zref et par rapport au 1er niveau (pour u) ou |
15 |
! \`a la surface (pour theta et q) \`a partir des relations de |
16 |
! Dyer-Businger. |
17 |
|
18 |
! Reference: Hess, Colman and McAvaney (1995) |
19 |
|
20 |
! I. Musat, 01.07.2002 |
21 |
|
22 |
use dimphy, only: klon |
23 |
|
24 |
INTEGER, intent(in):: knon |
25 |
! knon----input-I- nombre de points pour un type de surface |
26 |
REAL, dimension(klon), intent(in):: speed |
27 |
! speed---input-R- module du vent au 1er niveau du modele |
28 |
REAL, dimension(klon), intent(in):: tair |
29 |
! tair----input-R- temperature de l'air au 1er niveau du modele |
30 |
REAL, dimension(klon), intent(in):: qair |
31 |
! qair----input-R- humidite relative au 1er niveau du modele |
32 |
REAL, dimension(klon), intent(in):: ts |
33 |
! ts------input-R- temperature de l'air a la surface |
34 |
REAL, dimension(klon), intent(in):: qsurf |
35 |
! qsurf---input-R- humidite relative a la surface |
36 |
REAL, dimension(klon), intent(in):: rugos |
37 |
! rugos---input-R- rugosite |
38 |
DOUBLE PRECISION, dimension(klon), intent(in):: lmon |
39 |
! lmon----input-R- longueur de Monin-Obukov |
40 |
REAL, intent(in):: ustar(:) ! (knon) facteur d'\'echelle pour le vent |
41 |
REAL, dimension(klon), intent(in):: testar |
42 |
! testar--input-R- facteur d'echelle pour la temperature potentielle |
43 |
REAL, dimension(klon), intent(in):: qstar |
44 |
! qstar---input-R- facteur d'echelle pour l'humidite relative |
45 |
REAL, intent(in):: zref |
46 |
! zref----input-R- altitude de reference |
47 |
|
48 |
REAL, dimension(klon), intent(out):: delu |
49 |
! delu----input-R- anomalie du vent par rapport au 1er niveau |
50 |
|
51 |
REAL, dimension(klon), intent(out):: delte |
52 |
! anomalie de la temperature potentielle par rapport a la surface |
53 |
|
54 |
REAL, dimension(klon), intent(out):: delq |
55 |
! delq----input-R- anomalie de l'humidite relative par rapport a la surface |
56 |
|
57 |
! Local: |
58 |
REAL, PARAMETER:: RKAR=0.40 |
59 |
INTEGER i |
60 |
REAL xtmp, xtmp0 |
61 |
|
62 |
!------------------------------------------------------------------------- |
63 |
|
64 |
DO i = 1, knon |
65 |
IF (lmon(i) >= 0.) THEN |
66 |
! STABLE CASE |
67 |
IF (speed(i) > 1.5.AND.lmon(i) <= 1.0) THEN |
68 |
delu(i) = (ustar(i)/RKAR)* & |
69 |
(log(zref/(rugos(i))+1.) + & |
70 |
min(5d0, 5d0 *(zref - rugos(i))/lmon(i))) |
71 |
delte(i) = (testar(i)/RKAR)* & |
72 |
(log(zref/(rugos(i))+1.) + & |
73 |
min(5d0, 5d0 * (zref - rugos(i))/lmon(i))) |
74 |
delq(i) = (qstar(i)/RKAR)* & |
75 |
(log(zref/(rugos(i))+1.) + & |
76 |
min(5d0, 5d0 * (zref - rugos(i))/lmon(i))) |
77 |
ELSE |
78 |
delu(i) = 0.1 * speed(i) |
79 |
delte(i) = 0.1 * (tair(i) - ts(i)) |
80 |
delq(i) = 0.1 * (max(qair(i), 0.0) - max(qsurf(i), 0.0)) |
81 |
ENDIF |
82 |
ELSE |
83 |
! UNSTABLE CASE |
84 |
IF (speed(i) > 5.0.AND.abs(lmon(i)) <= 50.0) THEN |
85 |
xtmp = (1. - 16. * (zref/lmon(i)))**(1./4.) |
86 |
xtmp0 = (1. - 16. * (rugos(i)/lmon(i)))**(1./4.) |
87 |
delu(i) = (ustar(i)/RKAR)* & |
88 |
(log(zref/(rugos(i))+1.) & |
89 |
- 2.*log(0.5*(1. + xtmp)) & |
90 |
+ 2.*log(0.5*(1. + xtmp0)) & |
91 |
- log(0.5*(1. + xtmp*xtmp)) & |
92 |
+ log(0.5*(1. + xtmp0*xtmp0)) & |
93 |
+ 2.*atan(xtmp) - 2.*atan(xtmp0)) |
94 |
delte(i) = (testar(i)/RKAR)* & |
95 |
(log(zref/(rugos(i))+1.) & |
96 |
- 2.0 * log(0.5*(1. + xtmp*xtmp)) & |
97 |
+ 2.0 * log(0.5*(1. + xtmp0*xtmp0))) |
98 |
delq(i) = (qstar(i)/RKAR)* & |
99 |
(log(zref/(rugos(i))+1.) & |
100 |
- 2.0 * log(0.5*(1. + xtmp*xtmp)) & |
101 |
+ 2.0 * log(0.5*(1. + xtmp0*xtmp0))) |
102 |
ELSE |
103 |
delu(i) = 0.5 * speed(i) |
104 |
delte(i) = 0.5 * (tair(i) - ts(i)) |
105 |
delq(i) = 0.5 * (max(qair(i), 0.0) - max(qsurf(i), 0.0)) |
106 |
ENDIF |
107 |
ENDIF |
108 |
ENDDO |
109 |
|
110 |
END SUBROUTINE screenp |
111 |
|
112 |
end module screenp_m |