phylmd/Mobidic/regr_pr_o3.f

module regr_pr_o3_m

  implicit none

contains

  subroutine regr_pr_o3(p3d, o3_mob_regr)

    ! "regr_pr_o3" stands for "regrid pressure ozone".
    ! This procedure reads Mobidic ozone mole fraction from
    ! "coefoz_LMDZ.nc" at the initial day and regrids it in pressure.
    ! Ozone mole fraction from "coefoz_LMDZ.nc" is a 2D latitude --
    ! pressure variable.
    ! The target horizontal LMDZ grid is the "scalar" grid: "rlonv", "rlatu".
    ! The target vertical LMDZ grid is the grid of layer boundaries.
    ! We assume that the input variable is already on the LMDZ "rlatu"
    ! latitude grid.
    ! The input variable does not depend on longitude, but the
    ! pressure at LMDZ layers does.
    ! Therefore, the values on the LMDZ grid do depend on longitude.
    ! Regridding is by averaging, assuming a step function.
    ! We assume that, in the input file, the pressure levels are in
    ! hPa and strictly increasing.

    use dimensions, only: iim, jjm, llm
    use dynetat0_chosen_m, only: day_ref
    use grid_change, only: dyn_phy
    use netcdf, only:  nf90_nowrite
    use netcdf95, only: nf95_open, nf95_close, nf95_inq_varid, nf95_get_var, &
         nf95_gw_var
    use nr_util, only: assert
    use numer_rec_95, only: regr1_step_av

    REAL, intent(in):: p3d(:, :, :) ! (iim + 1, jjm + 1, llm+1) 
    ! pressure at layer interfaces, in Pa
    ! ("p3d(i, j, l)" is at longitude "rlonv(i)", latitude "rlatu(j)",
    ! for interface "l")

    real, intent(out):: o3_mob_regr(:, :, :) ! (iim + 1, jjm + 1, llm)
    ! (ozone mole fraction from Mobidic adapted to the LMDZ grid)
    ! ("o3_mob_regr(i, j, l)" is at longitude "rlonv(i)", latitude
    ! "rlatu(j)" and pressure level "pls(i, j, l)")

    ! Variables local to the procedure:

    real, allocatable:: plev(:)
    ! (pressure levels of Mobidic data, in Pa, in strictly increasing order)

    real, allocatable:: press_in_edg(:)
    ! (edges of pressure intervals for Mobidic data, in Pa, in strictly
    ! increasing order)

    integer ncid, varid ! for NetCDF
    integer n_plev ! number of pressure levels in Mobidic data
    integer i, j

    real, allocatable:: r_mob(:, :)! (jjm + 1, n_plev)
    ! (ozone mole fraction from Mobidic at day "day_ref")
    ! (r_mob(j, k) is at latitude "rlatu(j)" and pressure level "plev(k)".)

    !------------------------------------------------------------

    print *, "Call sequence information: regr_pr_o3"

    call assert(shape(o3_mob_regr) == (/iim + 1, jjm + 1, llm/), &
         "regr_pr_o3 o3_mob_regr")
    call assert(shape(p3d) == (/iim + 1, jjm + 1, llm + 1/), &
         "regr_pr_o3 p3d")

    call nf95_open("coefoz_LMDZ.nc", nf90_nowrite, ncid)

    call nf95_inq_varid(ncid, "plev", varid)
    call nf95_gw_var(ncid, varid, plev)
    ! Convert from hPa to Pa because "regr_pr_av" requires so:
    plev = plev * 100.
    n_plev = size(plev)

    ! Compute edges of pressure intervals:
    allocate(press_in_edg(n_plev + 1))
    press_in_edg(1) = 0.
    ! We choose edges halfway in logarithm:
    forall (j = 2:n_plev) press_in_edg(j) = sqrt(plev(j - 1) * plev(j))
    press_in_edg(n_plev + 1) = huge(0.)
    ! (infinity, but any value guaranteed to be greater than the
    ! surface pressure would do)

    call nf95_inq_varid(ncid, "r_Mob", varid)
    allocate(r_mob(jjm + 1, n_plev))

    ! Get data at the right day from the input file:
    call nf95_get_var(ncid, varid, r_mob, start=(/1, 1, day_ref/))
    ! Latitudes are in increasing order in the input file while
    ! "rlatu" is in decreasing order so we need to invert order:
    r_mob = r_mob(jjm+1:1:-1, :)

    call nf95_close(ncid)

    ! Regrid in pressure by averaging a step function of pressure:
    do j = 1, jjm + 1
       do i = 1, iim
          if (dyn_phy(i, j)) then
             o3_mob_regr(i, j, llm:1:-1) &
                  = regr1_step_av(r_mob(j, :), press_in_edg, &
                  p3d(i, j, llm+1:1:-1))
             ! (invert order of indices because "p3d" is decreasing)
          end if
       end do
    end do

    ! Duplicate pole values on all longitudes:
    o3_mob_regr(2:, 1, :) = spread(o3_mob_regr(1, 1, :), dim=1, ncopies=iim)
    o3_mob_regr(2:, jjm + 1, :) &
         = spread(o3_mob_regr(1, jjm + 1, :), dim=1, ncopies=iim)

    ! Duplicate first longitude to last longitude:
    o3_mob_regr(iim + 1, 2:jjm, :) = o3_mob_regr(1, 2:jjm, :)

  end subroutine regr_pr_o3

end module regr_pr_o3_m
1	module regr_pr_o3_m
2
3	implicit none
4
5	contains
6
7	subroutine regr_pr_o3(p3d, o3_mob_regr)
8
9	! "regr_pr_o3" stands for "regrid pressure ozone".
10	! This procedure reads Mobidic ozone mole fraction from
11	! "coefoz_LMDZ.nc" at the initial day and regrids it in pressure.
12	! Ozone mole fraction from "coefoz_LMDZ.nc" is a 2D latitude --
13	! pressure variable.
14	! The target horizontal LMDZ grid is the "scalar" grid: "rlonv", "rlatu".
15	! The target vertical LMDZ grid is the grid of layer boundaries.
16	! We assume that the input variable is already on the LMDZ "rlatu"
17	! latitude grid.
18	! The input variable does not depend on longitude, but the
19	! pressure at LMDZ layers does.
20	! Therefore, the values on the LMDZ grid do depend on longitude.
21	! Regridding is by averaging, assuming a step function.
22	! We assume that, in the input file, the pressure levels are in
23	! hPa and strictly increasing.
24
25	use dimensions, only: iim, jjm, llm
26	use dynetat0_chosen_m, only: day_ref
27	use grid_change, only: dyn_phy
28	use netcdf, only: nf90_nowrite
29	use netcdf95, only: nf95_open, nf95_close, nf95_inq_varid, nf95_get_var, &
30	nf95_gw_var
31	use nr_util, only: assert
32	use numer_rec_95, only: regr1_step_av
33
34	REAL, intent(in):: p3d(:, :, :) ! (iim + 1, jjm + 1, llm+1)
35	! pressure at layer interfaces, in Pa
36	! ("p3d(i, j, l)" is at longitude "rlonv(i)", latitude "rlatu(j)",
37	! for interface "l")
38
39	real, intent(out):: o3_mob_regr(:, :, :) ! (iim + 1, jjm + 1, llm)
40	! (ozone mole fraction from Mobidic adapted to the LMDZ grid)
41	! ("o3_mob_regr(i, j, l)" is at longitude "rlonv(i)", latitude
42	! "rlatu(j)" and pressure level "pls(i, j, l)")
43
44	! Variables local to the procedure:
45
46	real, allocatable:: plev(:)
47	! (pressure levels of Mobidic data, in Pa, in strictly increasing order)
48
49	real, allocatable:: press_in_edg(:)
50	! (edges of pressure intervals for Mobidic data, in Pa, in strictly
51	! increasing order)
52
53	integer ncid, varid ! for NetCDF
54	integer n_plev ! number of pressure levels in Mobidic data
55	integer i, j
56
57	real, allocatable:: r_mob(:, :)! (jjm + 1, n_plev)
58	! (ozone mole fraction from Mobidic at day "day_ref")
59	! (r_mob(j, k) is at latitude "rlatu(j)" and pressure level "plev(k)".)
60
61	!------------------------------------------------------------
62
63	print *, "Call sequence information: regr_pr_o3"
64
65	call assert(shape(o3_mob_regr) == (/iim + 1, jjm + 1, llm/), &
66	"regr_pr_o3 o3_mob_regr")
67	call assert(shape(p3d) == (/iim + 1, jjm + 1, llm + 1/), &
68	"regr_pr_o3 p3d")
69
70	call nf95_open("coefoz_LMDZ.nc", nf90_nowrite, ncid)
71
72	call nf95_inq_varid(ncid, "plev", varid)
73	call nf95_gw_var(ncid, varid, plev)
74	! Convert from hPa to Pa because "regr_pr_av" requires so:
75	plev = plev * 100.
76	n_plev = size(plev)
77
78	! Compute edges of pressure intervals:
79	allocate(press_in_edg(n_plev + 1))
80	press_in_edg(1) = 0.
81	! We choose edges halfway in logarithm:
82	forall (j = 2:n_plev) press_in_edg(j) = sqrt(plev(j - 1) * plev(j))
83	press_in_edg(n_plev + 1) = huge(0.)
84	! (infinity, but any value guaranteed to be greater than the
85	! surface pressure would do)
86
87	call nf95_inq_varid(ncid, "r_Mob", varid)
88	allocate(r_mob(jjm + 1, n_plev))
89
90	! Get data at the right day from the input file:
91	call nf95_get_var(ncid, varid, r_mob, start=(/1, 1, day_ref/))
92	! Latitudes are in increasing order in the input file while
93	! "rlatu" is in decreasing order so we need to invert order:
94	r_mob = r_mob(jjm+1:1:-1, :)
95
96	call nf95_close(ncid)
97
98	! Regrid in pressure by averaging a step function of pressure:
99	do j = 1, jjm + 1
100	do i = 1, iim
101	if (dyn_phy(i, j)) then
102	o3_mob_regr(i, j, llm:1:-1) &
103	= regr1_step_av(r_mob(j, :), press_in_edg, &
104	p3d(i, j, llm+1:1:-1))
105	! (invert order of indices because "p3d" is decreasing)
106	end if
107	end do
108	end do
109
110	! Duplicate pole values on all longitudes:
111	o3_mob_regr(2:, 1, :) = spread(o3_mob_regr(1, 1, :), dim=1, ncopies=iim)
112	o3_mob_regr(2:, jjm + 1, :) &
113	= spread(o3_mob_regr(1, jjm + 1, :), dim=1, ncopies=iim)
114
115	! Duplicate first longitude to last longitude:
116	o3_mob_regr(iim + 1, 2:jjm, :) = o3_mob_regr(1, 2:jjm, :)
117
118	end subroutine regr_pr_o3
119
120	end module regr_pr_o3_m