trunk/phylmd/cdrag.f

module clcdrag_m

  IMPLICIT NONE

contains

  SUBROUTINE clcdrag(nsrf, speed, t, q, zgeop, psol, ts, qsurf, rugos, pcfm, &
       pcfh, pref)

    ! From LMDZ4/libf/phylmd/clcdrag.F90, version 1.1.1.1, 2004/05/19 12:53:07

    ! Objet : calcul des drag coefficients au sol pour le moment et
    ! les flux de chaleur sensible et latente et calcul de la pression
    ! au niveau de reference.

    ! I. Musat, 01 Jul 2002

    use clesphys, only: f_cdrag_oce, f_cdrag_ter
    use indicesol, only: is_oce
    use nr_util, only: assert_eq
    use SUPHEC_M, only: rcpd, rd, retv, rg
    USE yoethf_m, ONLY: rvtmp2

    INTEGER, intent(in):: nsrf ! indice pour le type de surface

    REAL, intent(in):: speed(:) ! (knon)
    ! norm of the wind at the first model level

    REAL, intent(in):: t(:) ! (knon)
    ! temperature de l'air au 1er niveau du modele

    REAL, intent(in):: q(:) ! (knon) ! humidite de l'air au 1er niveau du modele

    REAL, intent(in):: zgeop(:) ! (knon)
    ! g\'eopotentiel au 1er niveau du mod\`ele
    
    REAL, intent(in) :: psol(:) ! (knon) pression au sol
    REAL, intent(in):: ts(:) ! (knon) temperature de l'air a la surface
    REAL, intent(in):: qsurf(:) ! (knon) humidite de l'air a la surface
    REAL, intent(in):: rugos(:) ! (knon) rugosit\'e
    REAL, intent(out):: pcfm(:) ! (knon) drag coefficient pour le moment 

    REAL, intent(out):: pcfh(:) ! (knon)
    ! drag coefficient pour les flux de chaleur latente et sensible

    REAL, intent(out), optional:: pref(:) ! (knon) pression au niveau zgeop/RG

    ! Local:
    REAL, PARAMETER:: ckap=0.40, cb=5.0, cc=5.0, cd=5.0, cepdu2=0.1**2
    INTEGER i, knon
    REAL zdu2, ztsolv, ztvd, zscf, zucf, zcr, friv, frih
    REAL zcfm1, zcfh1, zcfm2, zcfh2
    real zcdn ! drag coefficient neutre

    REAL zri
    ! nb. Richardson entre la surface et la couche zgeop/RG
    ! nombre de Richardson entre la surface et le niveau de reference (zri)

    !-------------------------------------------------------------------------

    knon = assert_eq([size(speed), size(t), size(q), size(zgeop), size(ts), &
         size(qsurf), size(rugos), size(pcfm), size(pcfh), size(pcfm)], &
         "clcdrag knon")
    
    DO i = 1, knon
       zdu2 = max(cepdu2, speed(i)**2)
       ztsolv = ts(i) * (1. + RETV * max(qsurf(i), 0.))
       ztvd = (t(i)+zgeop(i)/RCPD/(1.+RVTMP2*q(i))) *(1.+RETV*q(i))
       zri = zgeop(i)*(ztvd-ztsolv)/(zdu2*ztvd)
       zcdn = (ckap/log(1.+zgeop(i)/(RG*rugos(i))))**2

       IF (zri > 0.) THEN
          ! Situation stable. Pour eviter les inconsistances dans les cas
          ! tres stables on limite zri a 20. cf Hess et al. (1995).
          zri = min(20., zri)
          zscf = SQRT(1.+cd*ABS(zri))
          friv = max(1. / (1.+2.*CB*zri/ zscf), 0.1)
          zcfm1 = zcdn * friv
          frih = max(1./ (1.+3.*CB*zri*zscf), 0.1)
          zcfh1 = f_cdrag_ter * zcdn * frih
          IF (nsrf == is_oce) zcfh1 = f_cdrag_oce * zcdn * frih
          pcfm(i) = zcfm1
          pcfh(i) = zcfh1
       ELSE
          ! situation instable
          zucf = 1./(1.+3.0*cb*cc*zcdn*SQRT(ABS(zri) &
               *(1.0+zgeop(i)/(RG*rugos(i)))))
          zcfm2 = zcdn*max((1.-2.0*cb*zri*zucf), 0.1)
          zcfh2 = f_cdrag_ter * zcdn*max((1.-3.0*cb*zri*zucf), 0.1)
          pcfm(i) = zcfm2
          pcfh(i) = zcfh2

          ! pcfh sur l'ocean cf. Miller et al. (1992)
          zcr = (0.0016/(zcdn*SQRT(zdu2)))*ABS(ztvd-ztsolv)**(1./3.)
          IF (nsrf == is_oce) pcfh(i) = f_cdrag_oce * zcdn &
               * (1. + zcr**1.25)**(1. / 1.25)
       ENDIF
    END DO

    if (present(pref)) &
         pref = exp(log(psol) - zgeop / (RD * t * (1. + RETV * max(q, 0.))))

  END SUBROUTINE clcdrag

end module clcdrag_m
1	guez	62	module clcdrag_m
2	guez	40
3	guez	62	IMPLICIT NONE
4	guez	40
5	guez	62	contains
6	guez	40
7	guez	272	SUBROUTINE clcdrag(nsrf, speed, t, q, zgeop, psol, ts, qsurf, rugos, pcfm, &
8			pcfh, pref)
9	guez	40
10	guez	221	! From LMDZ4/libf/phylmd/clcdrag.F90, version 1.1.1.1, 2004/05/19 12:53:07
11	guez	40
12	guez	274	! Objet : calcul des drag coefficients au sol pour le moment et
13			! les flux de chaleur sensible et latente et calcul de la pression
14			! au niveau de reference.
15	guez	40
16	guez	274	! I. Musat, 01 Jul 2002
17
18			use clesphys, only: f_cdrag_oce, f_cdrag_ter
19			use indicesol, only: is_oce
20	guez	248	use nr_util, only: assert_eq
21	guez	274	use SUPHEC_M, only: rcpd, rd, retv, rg
22	guez	221	USE yoethf_m, ONLY: rvtmp2
23
24			INTEGER, intent(in):: nsrf ! indice pour le type de surface
25
26	guez	271	REAL, intent(in):: speed(:) ! (knon)
27	guez	274	! norm of the wind at the first model level
28	guez	40
29	guez	248	REAL, intent(in):: t(:) ! (knon)
30			! temperature de l'air au 1er niveau du modele
31
32			REAL, intent(in):: q(:) ! (knon) ! humidite de l'air au 1er niveau du modele
33	guez	274
34			REAL, intent(in):: zgeop(:) ! (knon)
35			! g\'eopotentiel au 1er niveau du mod\`ele
36
37	guez	272	REAL, intent(in) :: psol(:) ! (knon) pression au sol
38	guez	221	REAL, intent(in):: ts(:) ! (knon) temperature de l'air a la surface
39			REAL, intent(in):: qsurf(:) ! (knon) humidite de l'air a la surface
40	guez	248	REAL, intent(in):: rugos(:) ! (knon) rugosit\'e
41	guez	271	REAL, intent(out):: pcfm(:) ! (knon) drag coefficient pour le moment
42	guez	221
43	guez	248	REAL, intent(out):: pcfh(:) ! (knon)
44	guez	271	! drag coefficient pour les flux de chaleur latente et sensible
45	guez	47
46	guez	272	REAL, intent(out), optional:: pref(:) ! (knon) pression au niveau zgeop/RG
47
48	guez	221	! Local:
49	guez	248	REAL, PARAMETER:: ckap=0.40, cb=5.0, cc=5.0, cd=5.0, cepdu2=0.1**2
50	guez	274	INTEGER i, knon
51			REAL zdu2, ztsolv, ztvd, zscf, zucf, zcr, friv, frih
52			REAL zcfm1, zcfh1, zcfm2, zcfh2
53			real zcdn ! drag coefficient neutre
54	guez	40
55	guez	274	REAL zri
56			! nb. Richardson entre la surface et la couche zgeop/RG
57			! nombre de Richardson entre la surface et le niveau de reference (zri)
58	guez	40
59	guez	274	!-------------------------------------------------------------------------
60	guez	40
61	guez	271	knon = assert_eq([size(speed), size(t), size(q), size(zgeop), size(ts), &
62			size(qsurf), size(rugos), size(pcfm), size(pcfh), size(pcfm)], &
63			"clcdrag knon")
64	guez	248
65			DO i = 1, knon
66	guez	274	zdu2 = max(cepdu2, speed(i)**2)
67			ztsolv = ts(i) * (1. + RETV * max(qsurf(i), 0.))
68			ztvd = (t(i)+zgeop(i)/RCPD/(1.+RVTMP2q(i))) (1.+RETV*q(i))
69			zri = zgeop(i)(ztvd-ztsolv)/(zdu2ztvd)
70			zcdn = (ckap/log(1.+zgeop(i)/(RGrugos(i))))*2
71	guez	62
72	guez	274	IF (zri > 0.) THEN
73			! Situation stable. Pour eviter les inconsistances dans les cas
74			! tres stables on limite zri a 20. cf Hess et al. (1995).
75			zri = min(20., zri)
76			zscf = SQRT(1.+cd*ABS(zri))
77			friv = max(1. / (1.+2.CBzri/ zscf), 0.1)
78			zcfm1 = zcdn * friv
79			frih = max(1./ (1.+3.CBzri*zscf), 0.1)
80			zcfh1 = f_cdrag_ter * zcdn * frih
81			IF (nsrf == is_oce) zcfh1 = f_cdrag_oce * zcdn * frih
82			pcfm(i) = zcfm1
83			pcfh(i) = zcfh1
84			ELSE
85	guez	62	! situation instable
86	guez	274	zucf = 1./(1.+3.0cbcczcdnSQRT(ABS(zri) &
87	guez	221	(1.0+zgeop(i)/(RGrugos(i)))))
88	guez	274	zcfm2 = zcdnmax((1.-2.0cbzrizucf), 0.1)
89			zcfh2 = f_cdrag_ter * zcdnmax((1.-3.0cbzrizucf), 0.1)
90			pcfm(i) = zcfm2
91			pcfh(i) = zcfh2
92
93			! pcfh sur l'ocean cf. Miller et al. (1992)
94			zcr = (0.0016/(zcdnSQRT(zdu2)))ABS(ztvd-ztsolv)**(1./3.)
95			IF (nsrf == is_oce) pcfh(i) = f_cdrag_oce * zcdn &
96	guez	62	* (1. + zcr1.25)(1. / 1.25)
97			ENDIF
98			END DO
99
100	guez	274	if (present(pref)) &
101			pref = exp(log(psol) - zgeop / (RD * t * (1. + RETV * max(q, 0.))))
102
103	guez	62	END SUBROUTINE clcdrag
104
105			end module clcdrag_m