trunk/phylmd/clqh.f

module clqh_m

  IMPLICIT none

contains

  SUBROUTINE clqh(dtime, julien, debut, nisurf, knindex, tsoil, qsol, rmu0, &
       rugos, rugoro, u1lay, v1lay, coef, t, q, ts, paprs, pplay, delp, &
       radsol, albedo, snow, qsurf, precip_rain, precip_snow, fluxlat, &
       pctsrf_new_sic, agesno, d_t, d_q, d_ts, z0_new, flux_t, flux_q, &
       dflux_s, dflux_l, fqcalving, ffonte, run_off_lic_0)

    ! Author: Z. X. Li (LMD/CNRS)
    ! Date: 1993/08/18
    ! Objet : diffusion verticale de "q" et de "h"

    USE conf_phys_m, ONLY: iflag_pbl
    USE dimphy, ONLY: klev, klon
    USE interfsurf_hq_m, ONLY: interfsurf_hq
    USE suphec_m, ONLY: rcpd, rd, rg, rkappa

    REAL, intent(in):: dtime ! intervalle du temps (s)
    integer, intent(in):: julien ! jour de l'annee en cours
    logical, intent(in):: debut
    integer, intent(in):: nisurf
    integer, intent(in):: knindex(:) ! (knon)
    REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx)

    REAL, intent(inout):: qsol(klon)
    ! column-density of water in soil, in kg m-2

    real, intent(in):: rmu0(klon) ! cosinus de l'angle solaire zenithal
    real rugos(klon) ! rugosite
    REAL rugoro(klon)
    REAL u1lay(klon) ! vitesse u de la 1ere couche (m / s)
    REAL v1lay(klon) ! vitesse v de la 1ere couche (m / s)

    REAL, intent(in):: coef(:, :) ! (knon, klev)
    ! Le coefficient d'echange (m**2 / s) multiplie par le cisaillement
    ! du vent (dV / dz). La premiere valeur indique la valeur de Cdrag
    ! (sans unite).

    REAL t(klon, klev) ! temperature (K)
    REAL q(klon, klev) ! humidite specifique (kg / kg)
    REAL, intent(in):: ts(:) ! (knon) temperature du sol (K)
    REAL paprs(klon, klev + 1) ! pression a inter-couche (Pa)
    REAL pplay(klon, klev) ! pression au milieu de couche (Pa)
    REAL delp(klon, klev) ! epaisseur de couche en pression (Pa)

    REAL, intent(inout):: radsol(:) ! (knon)
    ! rayonnement net au sol (Solaire + IR) W / m2

    REAL, intent(inout):: albedo(:) ! (knon) albedo de la surface
    REAL, intent(inout):: snow(:) ! (knon) ! hauteur de neige
    REAL qsurf(klon) ! humidite de l'air au dessus de la surface

    real, intent(in):: precip_rain(klon)
    ! liquid water mass flux (kg / m2 / s), positive down

    real, intent(in):: precip_snow(klon)
    ! solid water mass flux (kg / m2 / s), positive down

    real, intent(out):: fluxlat(:) ! (knon)
    real, intent(in):: pctsrf_new_sic(:) ! (klon)
    REAL, intent(inout):: agesno(:) ! (knon)
    REAL d_t(klon, klev) ! incrementation de "t"
    REAL d_q(klon, klev) ! incrementation de "q"
    REAL, intent(out):: d_ts(:) ! (knon) variation of surface temperature
    real z0_new(klon)

    REAL, intent(out):: flux_t(:) ! (knon)
    ! (diagnostic) flux de chaleur sensible (Cp T) à la surface,
    ! positif vers le bas, W / m2

    REAL, intent(out):: flux_q(:) ! (knon)
    ! flux de la vapeur d'eau à la surface, en kg / (m**2 s)

    REAL dflux_s(:) ! (knon) derivee du flux sensible dF / dTs
    REAL dflux_l(:) ! (knon) derivee du flux latent dF / dTs

    ! Flux d'eau "perdue" par la surface et n\'ecessaire pour que limiter la
    ! hauteur de neige, en kg / m2 / s
    REAL fqcalving(klon)

    ! Flux thermique utiliser pour fondre la neige
    REAL ffonte(klon)

    REAL run_off_lic_0(klon)! runof glacier au pas de temps precedent

    ! Local:

    INTEGER knon
    REAL evap(size(knindex)) ! (knon) evaporation au sol

    INTEGER i, k
    REAL zx_cq(klon, klev)
    REAL zx_dq(klon, klev)
    REAL zx_ch(klon, klev)
    REAL zx_dh(klon, klev)
    REAL zx_buf1(klon)
    REAL zx_buf2(klon)
    REAL zx_coef(klon, klev)
    REAL local_h(klon, klev) ! enthalpie potentielle
    REAL local_q(klon, klev)
    REAL psref(klon) ! pression de reference pour temperature potent.
    REAL zx_pkh(klon, klev), zx_pkf(klon, klev)

    ! contre-gradient pour la vapeur d'eau: (kg / kg) / metre
    REAL gamq(klon, 2:klev)
    ! contre-gradient pour la chaleur sensible: Kelvin / metre
    REAL gamt(klon, 2:klev)
    REAL z_gamaq(klon, 2:klev), z_gamah(klon, 2:klev)
    REAL zdelz

    real temp_air(klon), spechum(klon)
    real tq_cdrag(klon), petAcoef(klon), peqAcoef(klon)
    real petBcoef(klon), peqBcoef(klon)
    real p1lay(klon)

    real tsurf_new(size(knindex)) ! (knon)
    real zzpk

    !----------------------------------------------------------------

    knon = size(knindex)

    if (iflag_pbl == 1) then
       do k = 3, klev
          do i = 1, knon
             gamq(i, k)= 0.0
             gamt(i, k)= - 1.0e-03
          enddo
       enddo
       do i = 1, knon
          gamq(i, 2) = 0.0
          gamt(i, 2) = - 2.5e-03
       enddo
    else
       do k = 2, klev
          do i = 1, knon
             gamq(i, k) = 0.0
             gamt(i, k) = 0.0
          enddo
       enddo
    endif

    DO i = 1, knon
       psref(i) = paprs(i, 1) !pression de reference est celle au sol
    ENDDO
    DO k = 1, klev
       DO i = 1, knon
          zx_pkh(i, k) = (psref(i) / paprs(i, k))**RKAPPA
          zx_pkf(i, k) = (psref(i) / pplay(i, k))**RKAPPA
          local_h(i, k) = RCPD * t(i, k) * zx_pkf(i, k)
          local_q(i, k) = q(i, k)
       ENDDO
    ENDDO

    ! Convertir les coefficients en variables convenables au calcul:

    DO k = 2, klev
       DO i = 1, knon
          zx_coef(i, k) = coef(i, k) * RG / (pplay(i, k - 1) - pplay(i, k)) &
               * (paprs(i, k) * 2 / (t(i, k) + t(i, k - 1)) / RD)**2
          zx_coef(i, k) = zx_coef(i, k) * dtime * RG
       ENDDO
    ENDDO

    ! Preparer les flux lies aux contre-gardients

    DO k = 2, klev
       DO i = 1, knon
          zdelz = RD * (t(i, k - 1) + t(i, k)) / 2.0 / RG / paprs(i, k) &
               * (pplay(i, k - 1) - pplay(i, k))
          z_gamaq(i, k) = gamq(i, k) * zdelz
          z_gamah(i, k) = gamt(i, k) * zdelz * RCPD * zx_pkh(i, k)
       ENDDO
    ENDDO
    DO i = 1, knon
       zx_buf1(i) = zx_coef(i, klev) + delp(i, klev)
       zx_cq(i, klev) = (local_q(i, klev) * delp(i, klev) &
            - zx_coef(i, klev) * z_gamaq(i, klev)) / zx_buf1(i)
       zx_dq(i, klev) = zx_coef(i, klev) / zx_buf1(i)

       zzpk=(pplay(i, klev) / psref(i))**RKAPPA
       zx_buf2(i) = zzpk * delp(i, klev) + zx_coef(i, klev)
       zx_ch(i, klev) = (local_h(i, klev) * zzpk * delp(i, klev) &
            - zx_coef(i, klev) * z_gamah(i, klev)) / zx_buf2(i)
       zx_dh(i, klev) = zx_coef(i, klev) / zx_buf2(i)
    ENDDO
    DO k = klev - 1, 2, - 1
       DO i = 1, knon
          zx_buf1(i) = delp(i, k) + zx_coef(i, k) &
               + zx_coef(i, k + 1) * (1. - zx_dq(i, k + 1))
          zx_cq(i, k) = (local_q(i, k) * delp(i, k) &
               + zx_coef(i, k + 1) * zx_cq(i, k + 1) &
               + zx_coef(i, k + 1) * z_gamaq(i, k + 1) &
               - zx_coef(i, k) * z_gamaq(i, k)) / zx_buf1(i)
          zx_dq(i, k) = zx_coef(i, k) / zx_buf1(i)

          zzpk=(pplay(i, k) / psref(i))**RKAPPA
          zx_buf2(i) = zzpk * delp(i, k) + zx_coef(i, k) &
               + zx_coef(i, k + 1) * (1. - zx_dh(i, k + 1))
          zx_ch(i, k) = (local_h(i, k) * zzpk * delp(i, k) &
               + zx_coef(i, k + 1) * zx_ch(i, k + 1) &
               + zx_coef(i, k + 1) * z_gamah(i, k + 1) &
               - zx_coef(i, k) * z_gamah(i, k)) / zx_buf2(i)
          zx_dh(i, k) = zx_coef(i, k) / zx_buf2(i)
       ENDDO
    ENDDO

    DO i = 1, knon
       zx_buf1(i) = delp(i, 1) + zx_coef(i, 2) * (1. - zx_dq(i, 2))
       zx_cq(i, 1) = (local_q(i, 1) * delp(i, 1) &
            + zx_coef(i, 2) * (z_gamaq(i, 2) + zx_cq(i, 2))) / zx_buf1(i)
       zx_dq(i, 1) = - 1. * RG / zx_buf1(i)

       zzpk=(pplay(i, 1) / psref(i))**RKAPPA
       zx_buf2(i) = zzpk * delp(i, 1) + zx_coef(i, 2) * (1. - zx_dh(i, 2))
       zx_ch(i, 1) = (local_h(i, 1) * zzpk * delp(i, 1) &
            + zx_coef(i, 2) * (z_gamah(i, 2) + zx_ch(i, 2))) / zx_buf2(i)
       zx_dh(i, 1) = - 1. * RG / zx_buf2(i)
    ENDDO

    ! Appel \`a interfsurf (appel g\'en\'erique) routine d'interface
    ! avec la surface

    ! Initialisation
    petAcoef =0. 
    peqAcoef = 0.
    petBcoef =0.
    peqBcoef = 0.
    p1lay =0.

    petAcoef(1:knon) = zx_ch(1:knon, 1)
    peqAcoef(1:knon) = zx_cq(1:knon, 1)
    petBcoef(1:knon) = zx_dh(1:knon, 1)
    peqBcoef(1:knon) = zx_dq(1:knon, 1)
    tq_cdrag(1:knon) =coef(:knon, 1)
    temp_air(1:knon) =t(1:knon, 1)
    spechum(1:knon)=q(1:knon, 1)
    p1lay(1:knon) = pplay(1:knon, 1)

    CALL interfsurf_hq(dtime, julien, rmu0, nisurf, knindex, debut, tsoil, &
         qsol, u1lay, v1lay, temp_air, spechum, tq_cdrag, petAcoef, peqAcoef, &
         petBcoef, peqBcoef, precip_rain, precip_snow, rugos, rugoro, snow, &
         qsurf, ts, p1lay, psref, radsol, evap, flux_t, fluxlat, dflux_l, &
         dflux_s, tsurf_new, albedo, z0_new, pctsrf_new_sic, agesno, &
         fqcalving, ffonte, run_off_lic_0)

    flux_q = - evap
    d_ts = tsurf_new - ts

    DO i = 1, knon
       local_h(i, 1) = zx_ch(i, 1) + zx_dh(i, 1) * flux_t(i) * dtime
       local_q(i, 1) = zx_cq(i, 1) + zx_dq(i, 1) * flux_q(i) * dtime
    ENDDO
    DO k = 2, klev
       DO i = 1, knon
          local_q(i, k) = zx_cq(i, k) + zx_dq(i, k) * local_q(i, k - 1)
          local_h(i, k) = zx_ch(i, k) + zx_dh(i, k) * local_h(i, k - 1)
       ENDDO
    ENDDO

    ! Calcul des tendances
    DO k = 1, klev
       DO i = 1, knon
          d_t(i, k) = local_h(i, k) / zx_pkf(i, k) / RCPD - t(i, k)
          d_q(i, k) = local_q(i, k) - q(i, k)
       ENDDO
    ENDDO

  END SUBROUTINE clqh

end module clqh_m
1	guez	49	module clqh_m
2	guez	3
3	guez	38	IMPLICIT none
4	guez	3
5	guez	49	contains
6	guez	3
7	guez	221	SUBROUTINE clqh(dtime, julien, debut, nisurf, knindex, tsoil, qsol, rmu0, &
8	guez	209	rugos, rugoro, u1lay, v1lay, coef, t, q, ts, paprs, pplay, delp, &
9	guez	223	radsol, albedo, snow, qsurf, precip_rain, precip_snow, fluxlat, &
10	guez	206	pctsrf_new_sic, agesno, d_t, d_q, d_ts, z0_new, flux_t, flux_q, &
11			dflux_s, dflux_l, fqcalving, ffonte, run_off_lic_0)
12	guez	3
13	guez	62	! Author: Z. X. Li (LMD/CNRS)
14	guez	49	! Date: 1993/08/18
15			! Objet : diffusion verticale de "q" et de "h"
16	guez	3
17	guez	154	USE conf_phys_m, ONLY: iflag_pbl
18			USE dimphy, ONLY: klev, klon
19			USE interfsurf_hq_m, ONLY: interfsurf_hq
20			USE suphec_m, ONLY: rcpd, rd, rg, rkappa
21	guez	38
22	guez	155	REAL, intent(in):: dtime ! intervalle du temps (s)
23	guez	221	integer, intent(in):: julien ! jour de l'annee en cours
24	guez	154	logical, intent(in):: debut
25	guez	175	integer, intent(in):: nisurf
26	guez	154	integer, intent(in):: knindex(:) ! (knon)
27	guez	208	REAL, intent(inout):: tsoil(:, :) ! (knon, nsoilmx)
28	guez	202
29	guez	154	REAL, intent(inout):: qsol(klon)
30			! column-density of water in soil, in kg m-2
31
32	guez	155	real, intent(in):: rmu0(klon) ! cosinus de l'angle solaire zenithal
33			real rugos(klon) ! rugosite
34	guez	154	REAL rugoro(klon)
35	guez	155	REAL u1lay(klon) ! vitesse u de la 1ere couche (m / s)
36			REAL v1lay(klon) ! vitesse v de la 1ere couche (m / s)
37	guez	70
38			REAL, intent(in):: coef(:, :) ! (knon, klev)
39	guez	155	! Le coefficient d'echange (m**2 / s) multiplie par le cisaillement
40			! du vent (dV / dz). La premiere valeur indique la valeur de Cdrag
41	guez	70	! (sans unite).
42
43	guez	155	REAL t(klon, klev) ! temperature (K)
44			REAL q(klon, klev) ! humidite specifique (kg / kg)
45	guez	207	REAL, intent(in):: ts(:) ! (knon) temperature du sol (K)
46	guez	208	REAL paprs(klon, klev + 1) ! pression a inter-couche (Pa)
47	guez	155	REAL pplay(klon, klev) ! pression au milieu de couche (Pa)
48			REAL delp(klon, klev) ! epaisseur de couche en pression (Pa)
49	guez	222
50			REAL, intent(inout):: radsol(:) ! (knon)
51			! rayonnement net au sol (Solaire + IR) W / m2
52
53	guez	155	REAL, intent(inout):: albedo(:) ! (knon) albedo de la surface
54	guez	215	REAL, intent(inout):: snow(:) ! (knon) ! hauteur de neige
55	guez	155	REAL qsurf(klon) ! humidite de l'air au dessus de la surface
56	guez	101
57			real, intent(in):: precip_rain(klon)
58	guez	155	! liquid water mass flux (kg / m2 / s), positive down
59	guez	101
60			real, intent(in):: precip_snow(klon)
61	guez	155	! solid water mass flux (kg / m2 / s), positive down
62	guez	101
63	guez	214	real, intent(out):: fluxlat(:) ! (knon)
64	guez	202	real, intent(in):: pctsrf_new_sic(:) ! (klon)
65	guez	175	REAL, intent(inout):: agesno(:) ! (knon)
66	guez	155	REAL d_t(klon, klev) ! incrementation de "t"
67			REAL d_q(klon, klev) ! incrementation de "q"
68	guez	221	REAL, intent(out):: d_ts(:) ! (knon) variation of surface temperature
69	guez	154	real z0_new(klon)
70	guez	206
71			REAL, intent(out):: flux_t(:) ! (knon)
72			! (diagnostic) flux de chaleur sensible (Cp T) à la surface,
73			! positif vers le bas, W / m2
74
75			REAL, intent(out):: flux_q(:) ! (knon)
76			! flux de la vapeur d'eau à la surface, en kg / (m**2 s)
77
78	guez	222	REAL dflux_s(:) ! (knon) derivee du flux sensible dF / dTs
79			REAL dflux_l(:) ! (knon) derivee du flux latent dF / dTs
80	guez	154
81	guez	150	! Flux d'eau "perdue" par la surface et n\'ecessaire pour que limiter la
82	guez	155	! hauteur de neige, en kg / m2 / s
83	guez	49	REAL fqcalving(klon)
84	guez	101
85	guez	154	! Flux thermique utiliser pour fondre la neige
86			REAL ffonte(klon)
87
88			REAL run_off_lic_0(klon)! runof glacier au pas de temps precedent
89
90			! Local:
91
92	guez	206	INTEGER knon
93			REAL evap(size(knindex)) ! (knon) evaporation au sol
94	guez	154
95	guez	49	INTEGER i, k
96			REAL zx_cq(klon, klev)
97			REAL zx_dq(klon, klev)
98			REAL zx_ch(klon, klev)
99			REAL zx_dh(klon, klev)
100			REAL zx_buf1(klon)
101			REAL zx_buf2(klon)
102			REAL zx_coef(klon, klev)
103			REAL local_h(klon, klev) ! enthalpie potentielle
104			REAL local_q(klon, klev)
105			REAL psref(klon) ! pression de reference pour temperature potent.
106			REAL zx_pkh(klon, klev), zx_pkf(klon, klev)
107	guez	3
108	guez	155	! contre-gradient pour la vapeur d'eau: (kg / kg) / metre
109	guez	49	REAL gamq(klon, 2:klev)
110	guez	155	! contre-gradient pour la chaleur sensible: Kelvin / metre
111	guez	49	REAL gamt(klon, 2:klev)
112			REAL z_gamaq(klon, 2:klev), z_gamah(klon, 2:klev)
113			REAL zdelz
114	guez	3
115	guez	49	real temp_air(klon), spechum(klon)
116			real tq_cdrag(klon), petAcoef(klon), peqAcoef(klon)
117			real petBcoef(klon), peqBcoef(klon)
118			real p1lay(klon)
119	guez	3
120	guez	206	real tsurf_new(size(knindex)) ! (knon)
121	guez	49	real zzpk
122	guez	3
123	guez	49	!----------------------------------------------------------------
124	guez	3
125	guez	206	knon = size(knindex)
126
127	guez	155	if (iflag_pbl == 1) then
128	guez	49	do k = 3, klev
129			do i = 1, knon
130			gamq(i, k)= 0.0
131	guez	155	gamt(i, k)= - 1.0e-03
132	guez	49	enddo
133			enddo
134			do i = 1, knon
135			gamq(i, 2) = 0.0
136	guez	155	gamt(i, 2) = - 2.5e-03
137	guez	49	enddo
138			else
139			do k = 2, klev
140			do i = 1, knon
141			gamq(i, k) = 0.0
142			gamt(i, k) = 0.0
143			enddo
144			enddo
145			endif
146
147			DO i = 1, knon
148			psref(i) = paprs(i, 1) !pression de reference est celle au sol
149			ENDDO
150			DO k = 1, klev
151			DO i = 1, knon
152	guez	155	zx_pkh(i, k) = (psref(i) / paprs(i, k))**RKAPPA
153			zx_pkf(i, k) = (psref(i) / pplay(i, k))**RKAPPA
154	guez	49	local_h(i, k) = RCPD * t(i, k) * zx_pkf(i, k)
155			local_q(i, k) = q(i, k)
156			ENDDO
157			ENDDO
158
159			! Convertir les coefficients en variables convenables au calcul:
160
161			DO k = 2, klev
162			DO i = 1, knon
163	guez	206	zx_coef(i, k) = coef(i, k) * RG / (pplay(i, k - 1) - pplay(i, k)) &
164	guez	208	* (paprs(i, k) * 2 / (t(i, k) + t(i, k - 1)) / RD)**2
165	guez	206	zx_coef(i, k) = zx_coef(i, k) * dtime * RG
166	guez	49	ENDDO
167			ENDDO
168
169			! Preparer les flux lies aux contre-gardients
170
171			DO k = 2, klev
172			DO i = 1, knon
173	guez	208	zdelz = RD * (t(i, k - 1) + t(i, k)) / 2.0 / RG / paprs(i, k) &
174	guez	206	* (pplay(i, k - 1) - pplay(i, k))
175	guez	49	z_gamaq(i, k) = gamq(i, k) * zdelz
176	guez	206	z_gamah(i, k) = gamt(i, k) * zdelz * RCPD * zx_pkh(i, k)
177	guez	49	ENDDO
178			ENDDO
179			DO i = 1, knon
180			zx_buf1(i) = zx_coef(i, klev) + delp(i, klev)
181	guez	206	zx_cq(i, klev) = (local_q(i, klev) * delp(i, klev) &
182			- zx_coef(i, klev) * z_gamaq(i, klev)) / zx_buf1(i)
183	guez	49	zx_dq(i, klev) = zx_coef(i, klev) / zx_buf1(i)
184
185	guez	155	zzpk=(pplay(i, klev) / psref(i))**RKAPPA
186	guez	206	zx_buf2(i) = zzpk * delp(i, klev) + zx_coef(i, klev)
187			zx_ch(i, klev) = (local_h(i, klev) * zzpk * delp(i, klev) &
188			- zx_coef(i, klev) * z_gamah(i, klev)) / zx_buf2(i)
189	guez	49	zx_dh(i, klev) = zx_coef(i, klev) / zx_buf2(i)
190			ENDDO
191	guez	155	DO k = klev - 1, 2, - 1
192	guez	49	DO i = 1, knon
193	guez	208	zx_buf1(i) = delp(i, k) + zx_coef(i, k) &
194			+ zx_coef(i, k + 1) * (1. - zx_dq(i, k + 1))
195	guez	206	zx_cq(i, k) = (local_q(i, k) * delp(i, k) &
196	guez	208	+ zx_coef(i, k + 1) * zx_cq(i, k + 1) &
197			+ zx_coef(i, k + 1) * z_gamaq(i, k + 1) &
198	guez	206	- zx_coef(i, k) * z_gamaq(i, k)) / zx_buf1(i)
199	guez	49	zx_dq(i, k) = zx_coef(i, k) / zx_buf1(i)
200
201	guez	155	zzpk=(pplay(i, k) / psref(i))**RKAPPA
202	guez	208	zx_buf2(i) = zzpk * delp(i, k) + zx_coef(i, k) &
203			+ zx_coef(i, k + 1) * (1. - zx_dh(i, k + 1))
204	guez	206	zx_ch(i, k) = (local_h(i, k) * zzpk * delp(i, k) &
205	guez	208	+ zx_coef(i, k + 1) * zx_ch(i, k + 1) &
206			+ zx_coef(i, k + 1) * z_gamah(i, k + 1) &
207	guez	206	- zx_coef(i, k) * z_gamah(i, k)) / zx_buf2(i)
208	guez	49	zx_dh(i, k) = zx_coef(i, k) / zx_buf2(i)
209			ENDDO
210			ENDDO
211
212			DO i = 1, knon
213	guez	206	zx_buf1(i) = delp(i, 1) + zx_coef(i, 2) * (1. - zx_dq(i, 2))
214			zx_cq(i, 1) = (local_q(i, 1) * delp(i, 1) &
215	guez	208	+ zx_coef(i, 2) * (z_gamaq(i, 2) + zx_cq(i, 2))) / zx_buf1(i)
216	guez	155	zx_dq(i, 1) = - 1. * RG / zx_buf1(i)
217	guez	49
218	guez	155	zzpk=(pplay(i, 1) / psref(i))**RKAPPA
219	guez	206	zx_buf2(i) = zzpk * delp(i, 1) + zx_coef(i, 2) * (1. - zx_dh(i, 2))
220			zx_ch(i, 1) = (local_h(i, 1) * zzpk * delp(i, 1) &
221	guez	208	+ zx_coef(i, 2) * (z_gamah(i, 2) + zx_ch(i, 2))) / zx_buf2(i)
222	guez	155	zx_dh(i, 1) = - 1. * RG / zx_buf2(i)
223	guez	49	ENDDO
224
225	guez	208	! Appel \`a interfsurf (appel g\'en\'erique) routine d'interface
226			! avec la surface
227	guez	49
228	guez	208	! Initialisation
229	guez	49	petAcoef =0.
230			peqAcoef = 0.
231			petBcoef =0.
232			peqBcoef = 0.
233			p1lay =0.
234
235			petAcoef(1:knon) = zx_ch(1:knon, 1)
236			peqAcoef(1:knon) = zx_cq(1:knon, 1)
237	guez	155	petBcoef(1:knon) = zx_dh(1:knon, 1)
238	guez	49	peqBcoef(1:knon) = zx_dq(1:knon, 1)
239	guez	70	tq_cdrag(1:knon) =coef(:knon, 1)
240	guez	49	temp_air(1:knon) =t(1:knon, 1)
241			spechum(1:knon)=q(1:knon, 1)
242			p1lay(1:knon) = pplay(1:knon, 1)
243
244	guez	222	CALL interfsurf_hq(dtime, julien, rmu0, nisurf, knindex, debut, tsoil, &
245			qsol, u1lay, v1lay, temp_air, spechum, tq_cdrag, petAcoef, peqAcoef, &
246	guez	223	petBcoef, peqBcoef, precip_rain, precip_snow, rugos, rugoro, snow, &
247			qsurf, ts, p1lay, psref, radsol, evap, flux_t, fluxlat, dflux_l, &
248			dflux_s, tsurf_new, albedo, z0_new, pctsrf_new_sic, agesno, &
249	guez	222	fqcalving, ffonte, run_off_lic_0)
250	guez	49
251	guez	206	flux_q = - evap
252	guez	207	d_ts = tsurf_new - ts
253	guez	49
254			DO i = 1, knon
255	guez	206	local_h(i, 1) = zx_ch(i, 1) + zx_dh(i, 1) * flux_t(i) * dtime
256			local_q(i, 1) = zx_cq(i, 1) + zx_dq(i, 1) * flux_q(i) * dtime
257	guez	49	ENDDO
258			DO k = 2, klev
259			DO i = 1, knon
260	guez	206	local_q(i, k) = zx_cq(i, k) + zx_dq(i, k) * local_q(i, k - 1)
261			local_h(i, k) = zx_ch(i, k) + zx_dh(i, k) * local_h(i, k - 1)
262	guez	49	ENDDO
263			ENDDO
264	guez	155
265	guez	208	! Calcul des tendances
266	guez	49	DO k = 1, klev
267			DO i = 1, knon
268	guez	155	d_t(i, k) = local_h(i, k) / zx_pkf(i, k) / RCPD - t(i, k)
269	guez	49	d_q(i, k) = local_q(i, k) - q(i, k)
270			ENDDO
271			ENDDO
272
273			END SUBROUTINE clqh
274
275			end module clqh_m