| 1 |
module clvent_m |
| 2 |
|
| 3 |
IMPLICIT none |
| 4 |
|
| 5 |
contains |
| 6 |
|
| 7 |
SUBROUTINE clvent(dtime, u1lay, v1lay, coef, cdrag, t, ven, paprs, pplay, & |
| 8 |
delp, d_ven, flux_v) |
| 9 |
|
| 10 |
! Author: Z. X. Li (LMD/CNRS) |
| 11 |
! Date: 1993/08/18 |
| 12 |
! Objet : diffusion verticale de la vitesse |
| 13 |
|
| 14 |
USE dimphy, ONLY: klev |
| 15 |
use nr_util, only: assert |
| 16 |
USE suphec_m, ONLY: rd, rg |
| 17 |
|
| 18 |
REAL, intent(in):: dtime ! intervalle de temps (en s) |
| 19 |
|
| 20 |
REAL, intent(in):: u1lay(:), v1lay(:) ! (knon) |
| 21 |
! vent de la premiere couche (m / s) |
| 22 |
|
| 23 |
REAL, intent(in):: coef(:, 2:) ! (knon, 2:klev) |
| 24 |
! Coefficient d'echange (m**2 / s) multiplié par le cisaillement du |
| 25 |
! vent (dV / dz) |
| 26 |
|
| 27 |
REAL, intent(in):: cdrag(:) ! (knon) sans unité |
| 28 |
REAL, intent(in):: t(:, :) ! (knon, klev) ! temperature (K) |
| 29 |
REAL, intent(in):: ven(:, :) ! (knon, klev) vitesse horizontale (m / s) |
| 30 |
REAL, intent(in):: paprs(:, :) ! (knon, klev + 1) pression a |
| 31 |
! inter-couche (Pa) |
| 32 |
real, intent(in):: pplay(:, :) ! (knon, klev) pression au milieu |
| 33 |
! de couche (Pa) |
| 34 |
real, intent(in):: delp(:, :) ! (knon, klev) epaisseur de couche (Pa) |
| 35 |
REAL, intent(out):: d_ven(:, :) ! (knon, klev) ! le changement de "ven" |
| 36 |
|
| 37 |
REAL, intent(out):: flux_v(:) ! (knon) |
| 38 |
! (diagnostic) flux du vent à la surface, en (kg m / s) / (m**2 s) |
| 39 |
! flux_v est le flux de moment angulaire (positif vers bas) |
| 40 |
|
| 41 |
! Local: |
| 42 |
INTEGER k |
| 43 |
REAL zx_cv(size(u1lay), 2:klev) ! (knon, 2:klev) |
| 44 |
REAL zx_dv(size(u1lay), 2:klev) ! (knon, 2:klev) |
| 45 |
REAL zx_buf(size(u1lay)) ! (knon) |
| 46 |
REAL zx_coef(size(u1lay), klev) ! (knon, klev) |
| 47 |
REAL local_ven(size(u1lay), klev) ! (knon, klev) |
| 48 |
|
| 49 |
!------------------------------------------------------------------ |
| 50 |
|
| 51 |
call assert(size(u1lay) == [size(v1lay), size(coef, 1), size(t, 1), & |
| 52 |
size(ven, 1), size(paprs, 1), size(pplay, 1), size(delp, 1), & |
| 53 |
size(d_ven, 1), size(flux_v)], "clvent knon") |
| 54 |
|
| 55 |
zx_coef(:, 1) = cdrag * (1. + SQRT(u1lay**2 + v1lay**2)) * pplay(:, 1) & |
| 56 |
/ (RD * t(:, 1)) * dtime * RG |
| 57 |
|
| 58 |
DO k = 2, klev |
| 59 |
zx_coef(:, k) = coef(:, k) * RG / (pplay(:, k - 1) - pplay(:, k)) & |
| 60 |
* (paprs(:, k) * 2 / (t(:, k) + t(:, k - 1)) / RD)**2 * dtime * RG |
| 61 |
ENDDO |
| 62 |
|
| 63 |
zx_buf = delp(:, 1) + zx_coef(:, 1) + zx_coef(:, 2) |
| 64 |
zx_cv(:, 2) = ven(:, 1) * delp(:, 1) / zx_buf |
| 65 |
zx_dv(:, 2) = zx_coef(:, 2) / zx_buf |
| 66 |
|
| 67 |
DO k = 3, klev |
| 68 |
zx_buf = delp(:, k - 1) + zx_coef(:, k) & |
| 69 |
+ zx_coef(:, k - 1) * (1. - zx_dv(:, k - 1)) |
| 70 |
zx_cv(:, k) = (ven(:, k - 1) * delp(:, k - 1) & |
| 71 |
+ zx_coef(:, k - 1) * zx_cv(:, k - 1)) / zx_buf |
| 72 |
zx_dv(:, k) = zx_coef(:, k) / zx_buf |
| 73 |
ENDDO |
| 74 |
|
| 75 |
local_ven(:, klev) = (ven(:, klev) * delp(:, klev) & |
| 76 |
+ zx_coef(:, klev) * zx_cv(:, klev)) & |
| 77 |
/ (delp(:, klev) + zx_coef(:, klev) & |
| 78 |
- zx_coef(:, klev) * zx_dv(:, klev)) |
| 79 |
|
| 80 |
DO k = klev - 1, 1, - 1 |
| 81 |
local_ven(:, k) = zx_cv(:, k + 1) + zx_dv(:, k + 1) * local_ven(:, k + 1) |
| 82 |
ENDDO |
| 83 |
|
| 84 |
flux_v = zx_coef(:, 1) / (RG * dtime) * local_ven(:, 1) |
| 85 |
d_ven = local_ven - ven |
| 86 |
|
| 87 |
END SUBROUTINE clvent |
| 88 |
|
| 89 |
end module clvent_m |
Parent Directory
| 
Revision Log