trunk/phylmd/coefcdrag.f

module coefcdrag_m

  IMPLICIT NONE

contains

  SUBROUTINE coefcdrag (nsrf, speed, t, q, zgeop, psol, ts, qsurf, rugos, &
       pcfm, pcfh, pref)

    ! From LMDZ4/libf/phylmd/coefcdrag.F90, version 1.1.1.1, 2004/05/19 12:53:07

    ! Objet : calcul des cdrags pour le moment (pcfm) et les flux de
    ! chaleur sensible et latente (pcfh) et de la pression au niveau
    ! de reference (pref).

    ! I. Musat, 01.07.2002

    use clesphys, only: f_cdrag_oce, f_cdrag_ter
    use indicesol, only: is_oce
    use nr_util, only: assert_eq
    use SUPHEC_M, only: rcpd, rd, retv, rg
    use dimphy, only: klon
    USE yoethf_m, ONLY: rvtmp2

    INTEGER, intent(in) :: nsrf
    ! nsrf----input-I- indice pour le type de surface; voir indicesol.inc
    REAL, intent(in) :: speed(:), t(:), q(:), zgeop(:), psol(:) ! (knon)
    ! speed---input-R- module du vent au 1er niveau du modele
    ! t-------input-R- temperature de l'air au 1er niveau du modele
    ! q-------input-R- humidite de l'air au 1er niveau du modele
    ! zgeop---input-R- geopotentiel au 1er niveau du modele
    ! psol----input-R- pression au sol
    REAL, dimension(klon), intent(in) :: ts, qsurf, rugos
    ! ts------input-R- temperature de l'air a la surface
    ! qsurf---input-R- humidite de l'air a la surface
    ! rugos---input-R- rugosite

    REAL, dimension(klon), intent(out) :: pcfm, pcfh
    ! drag coefficients pour le moment et pour les flux de chaleur
    ! latente et sensible
    
    REAL, intent(out), optional:: pref(:) ! (knon) pression au niveau zgeop/RG

    ! Local:
    REAL, parameter :: CKAP=0.40, CB=5.0, CC=5.0, CD=5.0
    INTEGER :: i
    REAL, dimension(klon) :: zdu2, ztsolv, ztvd
    REAL, dimension(klon) :: zscf, friv, frih, zucf, zcr
    REAL, dimension(klon) :: zcfm1, zcfh1
    REAL, dimension(klon) :: zcfm2, zcfh2
    REAL, dimension(klon) :: trm0, trm1
    real cdran(klon) ! drag coefficient neutre
    REAL pref_local(size(speed)) ! (knon) pression au niveau zgeop/RG

    REAL zri1(klon)
    ! nb. Richardson entre la surface et la couche zgeop/RG
    ! nombre de Richardson entre la surface et le niveau de reference (zri1)

    !-------------------------------------------------------------------------

    DO i = 1, size(speed)
       zdu2(i) = speed(i)**2
       pref_local(i) = exp(log(psol(i)) - zgeop(i)/(RD*t(i)* &
            (1.+ RETV * max(q(i), 0.0))))
       ztsolv(i) = ts(i)
       ztvd(i) = (t(i)+zgeop(i)/RCPD/(1.+RVTMP2*q(i))) *(1.+RETV*q(i)) 
       trm0(i) = 1. + RETV * max(qsurf(i), 0.0)
       trm1(i) = 1. + RETV * max(q(i), 0.0)
       ztsolv(i) = ztsolv(i) * trm0(i)
       zri1(i) = zgeop(i)*(ztvd(i)-ztsolv(i))/(zdu2(i)*ztvd(i))
       cdran(i) = (CKAP/log(1.+zgeop(i)/(RG*rugos(i))))**2

       IF (zri1(i) >= 0.) THEN
          ! situation stable : pour eviter les inconsistances dans les cas
          ! tres stables on limite zri1 a 20. cf Hess et al. (1995)
          zri1(i) = min(20., zri1(i))
          zscf(i) = SQRT(1.+CD*ABS(zri1(i)))
          friv(i) = max(1. / (1.+2.*CB*zri1(i)/ zscf(i)), 0.1)
          zcfm1(i) = cdran(i) * friv(i)
          frih(i) = max(1./ (1.+3.*CB*zri1(i)*zscf(i)), 0.1)
          zcfh1(i) = f_cdrag_ter * cdran(i) * frih(i) 
          IF (nsrf == is_oce) zcfh1(i) = f_cdrag_oce * cdran(i) * frih(i)
          pcfm(i) = zcfm1(i)
          pcfh(i) = zcfh1(i)
       ELSE
          ! situation instable
          zucf(i) = 1./(1.+3.0*CB*CC*cdran(i)*SQRT(ABS(zri1(i)) &
               *(1.0+zgeop(i)/(RG*rugos(i)))))
          zcfm2(i) = cdran(i)*max((1.-2.0*CB*zri1(i)*zucf(i)), 0.1)
          zcfh2(i) = f_cdrag_ter * cdran(i)*max((1.-3.0*CB*zri1(i)*zucf(i)), 0.1)
          pcfm(i) = zcfm2(i)
          pcfh(i) = zcfh2(i)

          ! pcfh sur l'ocean cf. Miller et al. (1992)

          zcr(i) = (0.0016/(cdran(i)*SQRT(zdu2(i))))*ABS(ztvd(i)-ztsolv(i)) &
               **(1./3.)
          IF (nsrf == is_oce) pcfh(i) = f_cdrag_oce * cdran(i)*(1.0+zcr(i)**1.25) **(1./1.25)
       ENDIF
    END DO

    if (present(pref)) pref = pref_local

  END SUBROUTINE coefcdrag

end module coefcdrag_m
1	guez	108	module coefcdrag_m
2
3	guez	246	IMPLICIT NONE
4	guez	108
5			contains
6
7	guez	246	SUBROUTINE coefcdrag (nsrf, speed, t, q, zgeop, psol, ts, qsurf, rugos, &
8	guez	272	pcfm, pcfh, pref)
9	guez	108
10	guez	227	! From LMDZ4/libf/phylmd/coefcdrag.F90, version 1.1.1.1, 2004/05/19 12:53:07
11	guez	108
12	guez	272	! Objet : calcul des cdrags pour le moment (pcfm) et les flux de
13			! chaleur sensible et latente (pcfh) et de la pression au niveau
14			! de reference (pref).
15	guez	227
16	guez	108	! I. Musat, 01.07.2002
17	guez	227
18	guez	273	use clesphys, only: f_cdrag_oce, f_cdrag_ter
19	guez	227	use indicesol, only: is_oce
20	guez	272	use nr_util, only: assert_eq
21	guez	273	use SUPHEC_M, only: rcpd, rd, retv, rg
22	guez	227	use dimphy, only: klon
23	guez	273	USE yoethf_m, ONLY: rvtmp2
24	guez	227
25	guez	246	INTEGER, intent(in) :: nsrf
26	guez	108	! nsrf----input-I- indice pour le type de surface; voir indicesol.inc
27	guez	227	REAL, intent(in) :: speed(:), t(:), q(:), zgeop(:), psol(:) ! (knon)
28	guez	108	! speed---input-R- module du vent au 1er niveau du modele
29			! t-------input-R- temperature de l'air au 1er niveau du modele
30			! q-------input-R- humidite de l'air au 1er niveau du modele
31			! zgeop---input-R- geopotentiel au 1er niveau du modele
32	guez	227	! psol----input-R- pression au sol
33			REAL, dimension(klon), intent(in) :: ts, qsurf, rugos
34	guez	108	! ts------input-R- temperature de l'air a la surface
35			! qsurf---input-R- humidite de l'air a la surface
36			! rugos---input-R- rugosite
37	guez	227
38	guez	272	REAL, dimension(klon), intent(out) :: pcfm, pcfh
39			! drag coefficients pour le moment et pour les flux de chaleur
40			! latente et sensible
41
42			REAL, intent(out), optional:: pref(:) ! (knon) pression au niveau zgeop/RG
43	guez	227
44			! Local:
45	guez	272	REAL, parameter :: CKAP=0.40, CB=5.0, CC=5.0, CD=5.0
46	guez	108	INTEGER :: i
47	guez	272	REAL, dimension(klon) :: zdu2, ztsolv, ztvd
48	guez	108	REAL, dimension(klon) :: zscf, friv, frih, zucf, zcr
49			REAL, dimension(klon) :: zcfm1, zcfh1
50			REAL, dimension(klon) :: zcfm2, zcfh2
51			REAL, dimension(klon) :: trm0, trm1
52	guez	272	real cdran(klon) ! drag coefficient neutre
53			REAL pref_local(size(speed)) ! (knon) pression au niveau zgeop/RG
54	guez	227
55	guez	272	REAL zri1(klon)
56			! nb. Richardson entre la surface et la couche zgeop/RG
57			! nombre de Richardson entre la surface et le niveau de reference (zri1)
58
59	guez	108	!-------------------------------------------------------------------------
60	guez	227
61	guez	246	DO i = 1, size(speed)
62	guez	3	zdu2(i) = speed(i)**2
63	guez	272	pref_local(i) = exp(log(psol(i)) - zgeop(i)/(RDt(i) &
64	guez	227	(1.+ RETV * max(q(i), 0.0))))
65	guez	3	ztsolv(i) = ts(i)
66	guez	273	ztvd(i) = (t(i)+zgeop(i)/RCPD/(1.+RVTMP2q(i))) (1.+RETV*q(i))
67	guez	227	trm0(i) = 1. + RETV * max(qsurf(i), 0.0)
68			trm1(i) = 1. + RETV * max(q(i), 0.0)
69	guez	3	ztsolv(i) = ztsolv(i) * trm0(i)
70	guez	272	zri1(i) = zgeop(i)(ztvd(i)-ztsolv(i))/(zdu2(i)ztvd(i))
71			cdran(i) = (CKAP/log(1.+zgeop(i)/(RGrugos(i))))*2
72	guez	3
73	guez	227	IF (zri1(i) >= 0.) THEN
74			! situation stable : pour eviter les inconsistances dans les cas
75	guez	108	! tres stables on limite zri1 a 20. cf Hess et al. (1995)
76	guez	227	zri1(i) = min(20., zri1(i))
77			zscf(i) = SQRT(1.+CD*ABS(zri1(i)))
78			friv(i) = max(1. / (1.+2.CBzri1(i)/ zscf(i)), 0.1)
79			zcfm1(i) = cdran(i) * friv(i)
80			frih(i) = max(1./ (1.+3.CBzri1(i)*zscf(i)), 0.1)
81	guez	273	zcfh1(i) = f_cdrag_ter * cdran(i) * frih(i)
82			IF (nsrf == is_oce) zcfh1(i) = f_cdrag_oce * cdran(i) * frih(i)
83	guez	272	pcfm(i) = zcfm1(i)
84			pcfh(i) = zcfh1(i)
85	guez	3	ELSE
86	guez	108	! situation instable
87	guez	227	zucf(i) = 1./(1.+3.0CBCCcdran(i)SQRT(ABS(zri1(i)) &
88	guez	272	(1.0+zgeop(i)/(RGrugos(i)))))
89	guez	227	zcfm2(i) = cdran(i)max((1.-2.0CBzri1(i)zucf(i)), 0.1)
90	guez	273	zcfh2(i) = f_cdrag_ter * cdran(i)max((1.-3.0CBzri1(i)zucf(i)), 0.1)
91	guez	272	pcfm(i) = zcfm2(i)
92			pcfh(i) = zcfh2(i)
93	guez	227
94	guez	272	! pcfh sur l'ocean cf. Miller et al. (1992)
95	guez	227
96	guez	108	zcr(i) = (0.0016/(cdran(i)SQRT(zdu2(i))))ABS(ztvd(i)-ztsolv(i)) &
97	guez	3	**(1./3.)
98	guez	273	IF (nsrf == is_oce) pcfh(i) = f_cdrag_oce * cdran(i)(1.0+zcr(i)1.25) *(1./1.25)
99	guez	3	ENDIF
100	guez	108	END DO
101
102	guez	272	if (present(pref)) pref = pref_local
103
104	guez	108	END SUBROUTINE coefcdrag
105
106			end module coefcdrag_m