trunk/phylmd/orbite.f

MODULE orbite_m

  ! From phylmd/orbite.F, version 1.1.1.1 2004/05/19 12:53:08

  IMPLICIT NONE

CONTAINS

  SUBROUTINE orbite(xjour, longi, dist)

    use nr_util, only: pi
    USE yomcst, ONLY : r_ecc, r_peri

    ! Auteur(s): Z.X. Li (LMD/CNRS)
    ! Date: 1993/08/18

    ! Pour un jour donné, calcule la longitude vraie de la Terre (par
    ! rapport au point vernal, 21 mars) dans son orbite
    ! solaire. Calcule aussi la distance Terre-Soleil, c'est-à-dire
    ! l'unité astronomique.

    REAL, INTENT (IN):: xjour ! jour de l'année à compter du premier janvier

    REAL, INTENT (OUT):: longi
    ! longitude vraie de la Terre dans son orbite solaire, par
    ! rapport au point vernal (21 mars), en degrés

    REAL, INTENT (OUT), OPTIONAL:: dist
    ! distance terre-soleil (par rapport a la moyenne)

    ! Variables locales
    REAL pir, xl, xllp, xee, xse, xlam, anm, ranm, ranv

    !----------------------------------------------------------------------

    pir = pi / 180.
    xl = r_peri + 180.
    xllp = xl * pir
    xee = r_ecc * r_ecc
    xse = sqrt(1. - xee)
    xlam = (r_ecc / 2 + r_ecc * xee / 8.) * (1. + xse) * sin(xllp) &
         - xee / 4. * (0.5 + xse) * sin(2.*xllp) &
         + r_ecc * xee / 8. * (1. / 3. + xse) * sin(3.*xllp)
    xlam = 2. * xlam / pir
    anm = xlam + (xjour - 81.) - xl
    ranm = anm * pir
    xee = xee * r_ecc
    ranv = ranm + (2. * r_ecc - xee / 4.) * sin(ranm) + &
         5. / 4. * r_ecc * r_ecc * sin(2 * ranm) &
         + 13. / 12. * xee * sin(3.*ranm)

    longi = ranv / pir + xl

    IF (present(dist)) then
       dist = (1 - r_ecc*r_ecc) &
            / (1 + r_ecc*cos(pir*(longi - (r_peri + 180.))))
    end IF

  END SUBROUTINE orbite

END MODULE orbite_m
1	MODULE orbite_m
2
3	! From phylmd/orbite.F, version 1.1.1.1 2004/05/19 12:53:08
4
5	IMPLICIT NONE
6
7	CONTAINS
8
9	SUBROUTINE orbite(xjour, longi, dist)
10
11	use nr_util, only: pi
12	USE yomcst, ONLY : r_ecc, r_peri
13
14	! Auteur(s): Z.X. Li (LMD/CNRS)
15	! Date: 1993/08/18
16
17	! Pour un jour donné, calcule la longitude vraie de la Terre (par
18	! rapport au point vernal, 21 mars) dans son orbite
19	! solaire. Calcule aussi la distance Terre-Soleil, c'est-à-dire
20	! l'unité astronomique.
21
22	REAL, INTENT (IN):: xjour ! jour de l'année à compter du premier janvier
23
24	REAL, INTENT (OUT):: longi
25	! longitude vraie de la Terre dans son orbite solaire, par
26	! rapport au point vernal (21 mars), en degrés
27
28	REAL, INTENT (OUT), OPTIONAL:: dist
29	! distance terre-soleil (par rapport a la moyenne)
30
31	! Variables locales
32	REAL pir, xl, xllp, xee, xse, xlam, anm, ranm, ranv
33
34	!----------------------------------------------------------------------
35
36	pir = pi / 180.
37	xl = r_peri + 180.
38	xllp = xl * pir
39	xee = r_ecc * r_ecc
40	xse = sqrt(1. - xee)
41	xlam = (r_ecc / 2 + r_ecc * xee / 8.) * (1. + xse) * sin(xllp) &
42	- xee / 4. * (0.5 + xse) * sin(2.*xllp) &
43	+ r_ecc * xee / 8. * (1. / 3. + xse) * sin(3.*xllp)
44	xlam = 2. * xlam / pir
45	anm = xlam + (xjour - 81.) - xl
46	ranm = anm * pir
47	xee = xee * r_ecc
48	ranv = ranm + (2. * r_ecc - xee / 4.) * sin(ranm) + &
49	5. / 4. * r_ecc * r_ecc * sin(2 * ranm) &
50	+ 13. / 12. * xee * sin(3.*ranm)
51
52	longi = ranv / pir + xl
53
54	IF (present(dist)) then
55	dist = (1 - r_ecc*r_ecc) &
56	/ (1 + r_ecccos(pir(longi - (r_peri + 180.))))
57	end IF
58
59	END SUBROUTINE orbite
60
61	END MODULE orbite_m