| 1 |
module physiq_m |
| 2 |
|
| 3 |
IMPLICIT none |
| 4 |
|
| 5 |
contains |
| 6 |
|
| 7 |
SUBROUTINE physiq(lafin, dayvrai, time, paprs, play, pphi, pphis, u, v, t, & |
| 8 |
qx, omega, d_u, d_v, d_t, d_qx) |
| 9 |
|
| 10 |
! From phylmd/physiq.F, version 1.22 2006/02/20 09:38:28 |
| 11 |
! (subversion revision 678) |
| 12 |
|
| 13 |
! Author: Z. X. Li (LMD/CNRS) 1993 |
| 14 |
|
| 15 |
! This is the main procedure for the "physics" part of the program. |
| 16 |
|
| 17 |
! Libraries: |
| 18 |
use netcdf95, only: NF95_CLOSE |
| 19 |
use nr_util, only: assert |
| 20 |
|
| 21 |
use aaam_bud_m, only: aaam_bud |
| 22 |
USE abort_gcm_m, ONLY: abort_gcm |
| 23 |
use ajsec_m, only: ajsec |
| 24 |
use calltherm_m, only: calltherm |
| 25 |
USE clesphys, ONLY: cdhmax, cdmmax, ecrit_ins, ok_instan |
| 26 |
USE clesphys2, ONLY: conv_emanuel, nbapp_rad, ok_orodr, ok_orolf |
| 27 |
USE conf_interface_m, ONLY: conf_interface |
| 28 |
USE pbl_surface_m, ONLY: pbl_surface |
| 29 |
use clouds_gno_m, only: clouds_gno |
| 30 |
use comconst, only: dtphys |
| 31 |
USE comgeomphy, ONLY: airephy |
| 32 |
USE concvl_m, ONLY: concvl |
| 33 |
USE conf_gcm_m, ONLY: lmt_pas |
| 34 |
USE conf_phys_m, ONLY: conf_phys |
| 35 |
use conflx_m, only: conflx |
| 36 |
USE ctherm_m, ONLY: iflag_thermals, ctherm |
| 37 |
use diagcld1_m, only: diagcld1 |
| 38 |
USE dimensions, ONLY: llm, nqmx |
| 39 |
USE dimphy, ONLY: klon |
| 40 |
USE dimsoil, ONLY: nsoilmx |
| 41 |
use drag_noro_m, only: drag_noro |
| 42 |
use dynetat0_chosen_m, only: day_ref, annee_ref |
| 43 |
USE fcttre, ONLY: foeew |
| 44 |
use fisrtilp_m, only: fisrtilp |
| 45 |
USE hgardfou_m, ONLY: hgardfou |
| 46 |
USE histsync_m, ONLY: histsync |
| 47 |
USE histwrite_phy_m, ONLY: histwrite_phy |
| 48 |
USE indicesol, ONLY: clnsurf, epsfra, nbsrf |
| 49 |
USE ini_histins_m, ONLY: ini_histins, nid_ins |
| 50 |
use lift_noro_m, only: lift_noro |
| 51 |
use newmicro_m, only: newmicro |
| 52 |
USE orbite_m, ONLY: orbite |
| 53 |
USE ozonecm_m, ONLY: ozonecm |
| 54 |
USE phyetat0_m, ONLY: phyetat0 |
| 55 |
USE phyredem_m, ONLY: phyredem |
| 56 |
USE phyredem0_m, ONLY: phyredem0 |
| 57 |
USE phytrac_m, ONLY: phytrac |
| 58 |
use radlwsw_m, only: radlwsw |
| 59 |
use yoegwd, only: sugwd |
| 60 |
USE suphec_m, ONLY: rcpd, retv, rg, rlvtt, romega, rsigma, rtt, rmo3, md |
| 61 |
use time_phylmdz, only: itap, increment_itap |
| 62 |
use transp_m, only: transp |
| 63 |
use transp_lay_m, only: transp_lay |
| 64 |
use unit_nml_m, only: unit_nml |
| 65 |
USE ymds2ju_m, ONLY: ymds2ju |
| 66 |
USE yoethf_m, ONLY: r2es, rvtmp2 |
| 67 |
use zenang_m, only: zenang |
| 68 |
|
| 69 |
logical, intent(in):: lafin ! dernier passage |
| 70 |
|
| 71 |
integer, intent(in):: dayvrai |
| 72 |
! current day number, based at value 1 on January 1st of annee_ref |
| 73 |
|
| 74 |
REAL, intent(in):: time ! heure de la journ\'ee en fraction de jour |
| 75 |
|
| 76 |
REAL, intent(in):: paprs(:, :) ! (klon, llm + 1) |
| 77 |
! pression pour chaque inter-couche, en Pa |
| 78 |
|
| 79 |
REAL, intent(in):: play(:, :) ! (klon, llm) |
| 80 |
! pression pour le mileu de chaque couche (en Pa) |
| 81 |
|
| 82 |
REAL, intent(in):: pphi(:, :) ! (klon, llm) |
| 83 |
! géopotentiel de chaque couche (référence sol) |
| 84 |
|
| 85 |
REAL, intent(in):: pphis(:) ! (klon) géopotentiel du sol |
| 86 |
REAL, intent(in):: u(:, :) ! (klon, llm) zonal wind, in m / s |
| 87 |
REAL, intent(in):: v(:, :) ! (klon, llm) meridional wind, in m / s |
| 88 |
REAL, intent(in):: t(:, :) ! (klon, llm) temperature (K) |
| 89 |
|
| 90 |
REAL, intent(in):: qx(:, :, :) ! (klon, llm, nqmx) |
| 91 |
! (humidit\'e sp\'ecifique et fractions massiques des autres traceurs) |
| 92 |
|
| 93 |
REAL, intent(in):: omega(:, :) ! (klon, llm) vitesse verticale en Pa / s |
| 94 |
REAL, intent(out):: d_u(:, :) ! (klon, llm) tendance physique de "u" (m s-2) |
| 95 |
REAL, intent(out):: d_v(:, :) ! (klon, llm) tendance physique de "v" (m s-2) |
| 96 |
REAL, intent(out):: d_t(:, :) ! (klon, llm) tendance physique de "t" (K / s) |
| 97 |
|
| 98 |
REAL, intent(out):: d_qx(:, :, :) ! (klon, llm, nqmx) |
| 99 |
! tendance physique de "qx" (s-1) |
| 100 |
|
| 101 |
! Local: |
| 102 |
|
| 103 |
LOGICAL:: firstcal = .true. |
| 104 |
|
| 105 |
! pour phystoke avec thermiques |
| 106 |
REAL fm_therm(klon, llm + 1) |
| 107 |
REAL entr_therm(klon, llm) |
| 108 |
real, save:: q2(klon, llm + 1, nbsrf) |
| 109 |
|
| 110 |
INTEGER, PARAMETER:: ivap = 1 ! indice de traceur pour vapeur d'eau |
| 111 |
INTEGER, PARAMETER:: iliq = 2 ! indice de traceur pour eau liquide |
| 112 |
|
| 113 |
REAL, save:: t_ancien(klon, llm), q_ancien(klon, llm) |
| 114 |
LOGICAL, save:: ancien_ok |
| 115 |
|
| 116 |
REAL d_t_dyn(klon, llm) ! tendance dynamique pour "t" (K / s) |
| 117 |
REAL d_q_dyn(klon, llm) ! tendance dynamique pour "q" (kg / kg / s) |
| 118 |
|
| 119 |
real da(klon, llm), phi(klon, llm, llm), mp(klon, llm) |
| 120 |
|
| 121 |
REAL, save:: swdn0(klon, llm + 1), swdn(klon, llm + 1) |
| 122 |
REAL, save:: swup0(klon, llm + 1), swup(klon, llm + 1) |
| 123 |
|
| 124 |
REAL, save:: lwdn0(klon, llm + 1), lwdn(klon, llm + 1) |
| 125 |
REAL, save:: lwup0(klon, llm + 1), lwup(klon, llm + 1) |
| 126 |
|
| 127 |
! prw: precipitable water |
| 128 |
real prw(klon) |
| 129 |
|
| 130 |
! flwp, fiwp = Liquid Water Path & Ice Water Path (kg / m2) |
| 131 |
! flwc, fiwc = Liquid Water Content & Ice Water Content (kg / kg) |
| 132 |
REAL flwp(klon), fiwp(klon) |
| 133 |
REAL flwc(klon, llm), fiwc(klon, llm) |
| 134 |
|
| 135 |
! Variables propres a la physique |
| 136 |
|
| 137 |
INTEGER, save:: radpas |
| 138 |
! Radiative transfer computations are made every "radpas" call to |
| 139 |
! "physiq". |
| 140 |
|
| 141 |
REAL, save:: radsol(klon) |
| 142 |
! Bilan radiatif net au sol (W/m2), positif vers le bas. Must be |
| 143 |
! saved because radlwsw is not called at every time step. |
| 144 |
|
| 145 |
REAL, save:: ftsol(klon, nbsrf) ! skin temperature of surface fraction, in K |
| 146 |
|
| 147 |
REAL, save:: ftsoil(klon, nsoilmx, nbsrf) |
| 148 |
! soil temperature of surface fraction |
| 149 |
|
| 150 |
REAL fluxlat(klon, nbsrf) ! flux de chaleur latente, en W m-2 |
| 151 |
|
| 152 |
REAL, save:: fqsurf(klon, nbsrf) |
| 153 |
! humidite de l'air au contact de la surface |
| 154 |
|
| 155 |
REAL, save:: qsol(klon) ! column-density of water in soil, in kg m-2 |
| 156 |
|
| 157 |
REAL, save:: fsnow(klon, nbsrf) |
| 158 |
! column-density of mass of snow at the surface, in kg m-2 |
| 159 |
|
| 160 |
REAL, save:: falbe(klon, nbsrf) ! albedo visible par type de surface |
| 161 |
|
| 162 |
! Param\`etres de l'orographie \`a l'\'echelle sous-maille (OESM) : |
| 163 |
REAL, save:: zmea(klon) ! orographie moyenne |
| 164 |
REAL, save:: zstd(klon) ! deviation standard de l'OESM |
| 165 |
REAL, save:: zsig(klon) ! pente de l'OESM |
| 166 |
REAL, save:: zgam(klon) ! anisotropie de l'OESM |
| 167 |
REAL, save:: zthe(klon) ! orientation de l'OESM |
| 168 |
REAL, save:: zpic(klon) ! Maximum de l'OESM |
| 169 |
REAL, save:: zval(klon) ! Minimum de l'OESM |
| 170 |
REAL, save:: rugoro(klon) ! longueur de rugosite de l'OESM |
| 171 |
REAL zulow(klon), zvlow(klon) |
| 172 |
INTEGER ktest(klon) |
| 173 |
|
| 174 |
REAL, save:: agesno(klon, nbsrf) ! age de la neige |
| 175 |
REAL, save:: run_off_lic_0(klon) |
| 176 |
|
| 177 |
! Variables li\'ees \`a la convection d'Emanuel : |
| 178 |
REAL, save:: Ma(klon, llm) ! undilute upward mass flux |
| 179 |
REAL, save:: sig1(klon, llm), w01(klon, llm) |
| 180 |
|
| 181 |
! Variables pour la couche limite (Alain Lahellec) : |
| 182 |
REAL cdragh(klon) ! drag coefficient pour T and Q |
| 183 |
REAL cdragm(klon) ! drag coefficient pour vent |
| 184 |
|
| 185 |
REAL coefh(klon, 2:llm) ! coef d'echange pour phytrac |
| 186 |
|
| 187 |
REAL, save:: ffonte(klon, nbsrf) |
| 188 |
! flux thermique utilise pour fondre la neige |
| 189 |
|
| 190 |
REAL fqcalving(klon, nbsrf) |
| 191 |
! flux d'eau "perdue" par la surface et n\'ecessaire pour limiter |
| 192 |
! la hauteur de neige, en kg / m2 / s |
| 193 |
|
| 194 |
REAL zxffonte(klon) |
| 195 |
|
| 196 |
REAL, save:: pfrac_impa(klon, llm)! Produits des coefs lessivage impaction |
| 197 |
REAL, save:: pfrac_nucl(klon, llm)! Produits des coefs lessivage nucleation |
| 198 |
|
| 199 |
REAL, save:: pfrac_1nucl(klon, llm) |
| 200 |
! Produits des coefs lessi nucl (alpha = 1) |
| 201 |
|
| 202 |
REAL frac_impa(klon, llm) ! fraction d'a\'erosols lessiv\'es (impaction) |
| 203 |
REAL frac_nucl(klon, llm) ! idem (nucleation) |
| 204 |
|
| 205 |
REAL, save:: rain_fall(klon) |
| 206 |
! liquid water mass flux (kg / m2 / s), positive down |
| 207 |
|
| 208 |
REAL, save:: snow_fall(klon) |
| 209 |
! solid water mass flux (kg / m2 / s), positive down |
| 210 |
|
| 211 |
REAL rain_tiedtke(klon), snow_tiedtke(klon) |
| 212 |
|
| 213 |
REAL evap(klon) ! flux d'\'evaporation au sol |
| 214 |
real dflux_q(klon) ! derivative of the evaporation flux at the surface |
| 215 |
REAL sens(klon) ! flux de chaleur sensible au sol |
| 216 |
real dflux_t(klon) ! derivee du flux de chaleur sensible au sol |
| 217 |
REAL, save:: dlw(klon) ! derivative of infra-red flux |
| 218 |
REAL fder(klon) ! d\'erive de flux (sensible et latente) |
| 219 |
REAL ve(klon) ! integr. verticale du transport meri. de l'energie |
| 220 |
REAL vq(klon) ! integr. verticale du transport meri. de l'eau |
| 221 |
REAL ue(klon) ! integr. verticale du transport zonal de l'energie |
| 222 |
REAL uq(klon) ! integr. verticale du transport zonal de l'eau |
| 223 |
|
| 224 |
REAL, save:: frugs(klon, nbsrf) ! longueur de rugosite |
| 225 |
REAL zxrugs(klon) ! longueur de rugosite |
| 226 |
|
| 227 |
! Conditions aux limites |
| 228 |
|
| 229 |
INTEGER julien |
| 230 |
REAL, save:: pctsrf(klon, nbsrf) ! percentage of surface |
| 231 |
REAL, save:: albsol(klon) ! albedo du sol total, visible, moyen par maille |
| 232 |
REAL, SAVE:: wo(klon, llm) ! column density of ozone in a cell, in kDU |
| 233 |
real, parameter:: dobson_u = 2.1415e-05 ! Dobson unit, in kg m-2 |
| 234 |
|
| 235 |
real, save:: clwcon(klon, llm), rnebcon(klon, llm) |
| 236 |
real, save:: clwcon0(klon, llm), rnebcon0(klon, llm) |
| 237 |
|
| 238 |
REAL rhcl(klon, llm) ! humidit\'e relative ciel clair |
| 239 |
REAL dialiq(klon, llm) ! eau liquide nuageuse |
| 240 |
REAL diafra(klon, llm) ! fraction nuageuse |
| 241 |
REAL cldliq(klon, llm) ! eau liquide nuageuse |
| 242 |
REAL cldfra(klon, llm) ! fraction nuageuse |
| 243 |
REAL cldtau(klon, llm) ! \'epaisseur optique |
| 244 |
REAL cldemi(klon, llm) ! \'emissivit\'e infrarouge |
| 245 |
|
| 246 |
REAL flux_q(klon, nbsrf) ! flux turbulent d'humidite à la surface |
| 247 |
|
| 248 |
REAL flux_t(klon, nbsrf) |
| 249 |
! flux de chaleur sensible (c_p T) (W / m2) (orientation positive |
| 250 |
! vers le bas) à la surface |
| 251 |
|
| 252 |
REAL flux_u(klon, nbsrf), flux_v(klon, nbsrf) |
| 253 |
! tension du vent (flux turbulent de vent) à la surface, en Pa |
| 254 |
|
| 255 |
! Le rayonnement n'est pas calcul\'e tous les pas, il faut donc que |
| 256 |
! les variables soient r\'emanentes. |
| 257 |
REAL, save:: heat(klon, llm) ! chauffage solaire |
| 258 |
REAL, save:: heat0(klon, llm) ! chauffage solaire ciel clair |
| 259 |
REAL, save:: cool(klon, llm) ! refroidissement infrarouge |
| 260 |
REAL, save:: cool0(klon, llm) ! refroidissement infrarouge ciel clair |
| 261 |
REAL, save:: topsw(klon), toplw(klon), solsw(klon) |
| 262 |
|
| 263 |
REAL, save:: sollw(klon) ! surface net downward longwave flux, in W m-2 |
| 264 |
real, save:: sollwdown(klon) ! downwelling longwave flux at surface |
| 265 |
REAL, save:: topsw0(klon), toplw0(klon), solsw0(klon), sollw0(klon) |
| 266 |
REAL, save:: albpla(klon) |
| 267 |
|
| 268 |
REAL conv_q(klon, llm) ! convergence de l'humidite (kg / kg / s) |
| 269 |
REAL conv_t(klon, llm) ! convergence of temperature (K / s) |
| 270 |
|
| 271 |
REAL cldl(klon), cldm(klon), cldh(klon) ! nuages bas, moyen et haut |
| 272 |
REAL cldt(klon), cldq(klon) ! nuage total, eau liquide integree |
| 273 |
|
| 274 |
REAL zxfluxlat(klon) |
| 275 |
REAL dist, mu0(klon), fract(klon) |
| 276 |
real longi |
| 277 |
REAL z_avant(klon), z_apres(klon), z_factor(klon) |
| 278 |
REAL zb |
| 279 |
REAL zx_qs, zcor |
| 280 |
real zqsat(klon, llm) |
| 281 |
INTEGER i, k, iq, nsrf |
| 282 |
REAL zphi(klon, llm) |
| 283 |
|
| 284 |
! cf. Anne Mathieu, variables pour la couche limite atmosphérique (hbtm) |
| 285 |
|
| 286 |
REAL, SAVE:: pblh(klon, nbsrf) ! Hauteur de couche limite |
| 287 |
REAL, SAVE:: plcl(klon, nbsrf) ! Niveau de condensation de la CLA |
| 288 |
REAL, SAVE:: capCL(klon, nbsrf) ! CAPE de couche limite |
| 289 |
REAL, SAVE:: oliqCL(klon, nbsrf) ! eau_liqu integree de couche limite |
| 290 |
REAL, SAVE:: cteiCL(klon, nbsrf) ! cloud top instab. crit. couche limite |
| 291 |
REAL, SAVE:: pblt(klon, nbsrf) ! T \`a la hauteur de couche limite |
| 292 |
REAL, SAVE:: therm(klon, nbsrf) |
| 293 |
! Grandeurs de sorties |
| 294 |
REAL s_pblh(klon), s_lcl(klon), s_capCL(klon) |
| 295 |
REAL s_oliqCL(klon), s_cteiCL(klon), s_pblt(klon) |
| 296 |
REAL s_therm(klon) |
| 297 |
|
| 298 |
! Variables pour la convection de K. Emanuel : |
| 299 |
|
| 300 |
REAL upwd(klon, llm) ! saturated updraft mass flux |
| 301 |
REAL dnwd(klon, llm) ! saturated downdraft mass flux |
| 302 |
REAL, save:: cape(klon) |
| 303 |
|
| 304 |
INTEGER iflagctrl(klon) ! flag fonctionnement de convect |
| 305 |
|
| 306 |
! Variables du changement |
| 307 |
|
| 308 |
! con: convection |
| 309 |
! lsc: large scale condensation |
| 310 |
! ajs: ajustement sec |
| 311 |
! eva: \'evaporation de l'eau liquide nuageuse |
| 312 |
! vdf: vertical diffusion in boundary layer |
| 313 |
REAL d_t_con(klon, llm), d_q_con(klon, llm) |
| 314 |
REAL, save:: d_u_con(klon, llm), d_v_con(klon, llm) |
| 315 |
REAL d_t_lsc(klon, llm), d_q_lsc(klon, llm), d_ql_lsc(klon, llm) |
| 316 |
REAL d_t_ajs(klon, llm), d_q_ajs(klon, llm) |
| 317 |
REAL d_u_ajs(klon, llm), d_v_ajs(klon, llm) |
| 318 |
REAL rneb(klon, llm) |
| 319 |
|
| 320 |
REAL mfu(klon, llm), mfd(klon, llm) |
| 321 |
REAL pen_u(klon, llm), pen_d(klon, llm) |
| 322 |
REAL pde_u(klon, llm), pde_d(klon, llm) |
| 323 |
INTEGER kcbot(klon), kctop(klon), kdtop(klon) |
| 324 |
REAL pmflxr(klon, llm + 1), pmflxs(klon, llm + 1) |
| 325 |
REAL prfl(klon, llm + 1), psfl(klon, llm + 1) |
| 326 |
|
| 327 |
INTEGER, save:: ibas_con(klon), itop_con(klon) |
| 328 |
real ema_pct(klon) ! Emanuel pressure at cloud top, in Pa |
| 329 |
|
| 330 |
REAL rain_con(klon) |
| 331 |
real rain_lsc(klon) |
| 332 |
REAL snow_con(klon) ! neige (mm / s) |
| 333 |
real snow_lsc(klon) |
| 334 |
|
| 335 |
REAL d_u_vdf(klon, llm), d_v_vdf(klon, llm) |
| 336 |
REAL d_t_vdf(klon, llm), d_q_vdf(klon, llm) |
| 337 |
|
| 338 |
REAL d_u_oro(klon, llm), d_v_oro(klon, llm) |
| 339 |
REAL d_t_oro(klon, llm) |
| 340 |
REAL d_u_lif(klon, llm), d_v_lif(klon, llm) |
| 341 |
REAL d_t_lif(klon, llm) |
| 342 |
|
| 343 |
REAL, save:: ratqs(klon, llm) |
| 344 |
real ratqss(klon, llm), ratqsc(klon, llm) |
| 345 |
real:: ratqsbas = 0.01, ratqshaut = 0.3 |
| 346 |
|
| 347 |
! Param\`etres li\'es au nouveau sch\'ema de nuages : |
| 348 |
real:: fact_cldcon = 0.375 |
| 349 |
real:: facttemps = 1.e-4 |
| 350 |
real facteur |
| 351 |
|
| 352 |
integer:: iflag_cldcon = 1 |
| 353 |
logical ptconv(klon, llm) |
| 354 |
|
| 355 |
! Variables pour effectuer les appels en s\'erie : |
| 356 |
|
| 357 |
REAL t_seri(klon, llm) |
| 358 |
real q_seri(klon, llm) ! mass fraction of water vapor |
| 359 |
REAL ql_seri(klon, llm) |
| 360 |
REAL u_seri(klon, llm), v_seri(klon, llm) ! wind, in m s-1 |
| 361 |
REAL tr_seri(klon, llm, nqmx - 2) |
| 362 |
|
| 363 |
REAL zx_rh(klon, llm) |
| 364 |
|
| 365 |
REAL zustrdr(klon), zvstrdr(klon) |
| 366 |
REAL zustrli(klon), zvstrli(klon) |
| 367 |
REAL aam, torsfc |
| 368 |
|
| 369 |
REAL ve_lay(klon, llm) ! transport meri. de l'energie a chaque niveau vert. |
| 370 |
REAL vq_lay(klon, llm) ! transport meri. de l'eau a chaque niveau vert. |
| 371 |
REAL ue_lay(klon, llm) ! transport zonal de l'energie a chaque niveau vert. |
| 372 |
REAL uq_lay(klon, llm) ! transport zonal de l'eau a chaque niveau vert. |
| 373 |
|
| 374 |
REAL tsol(klon) |
| 375 |
|
| 376 |
REAL d_t_ec(klon, llm) |
| 377 |
! tendance due \`a la conversion d'\'energie cin\'etique en |
| 378 |
! énergie thermique |
| 379 |
|
| 380 |
REAL, save:: t2m(klon, nbsrf), q2m(klon, nbsrf) |
| 381 |
! temperature and humidity at 2 m |
| 382 |
|
| 383 |
REAL, save:: u10m_srf(klon, nbsrf), v10m_srf(klon, nbsrf) |
| 384 |
! composantes du vent \`a 10 m |
| 385 |
|
| 386 |
REAL zt2m(klon), zq2m(klon) ! température, humidité 2 m moyenne sur 1 maille |
| 387 |
REAL u10m(klon), v10m(klon) ! vent \`a 10 m moyenn\' sur les sous-surfaces |
| 388 |
|
| 389 |
! Aerosol effects: |
| 390 |
|
| 391 |
REAL, save:: topswad(klon), solswad(klon) ! aerosol direct effect |
| 392 |
LOGICAL:: ok_ade = .false. ! apply aerosol direct effect |
| 393 |
|
| 394 |
REAL:: bl95_b0 = 2., bl95_b1 = 0.2 |
| 395 |
! Parameters in equation (D) of Boucher and Lohmann (1995, Tellus |
| 396 |
! B). They link cloud droplet number concentration to aerosol mass |
| 397 |
! concentration. |
| 398 |
|
| 399 |
real zmasse(klon, llm) |
| 400 |
! (column-density of mass of air in a cell, in kg m-2) |
| 401 |
|
| 402 |
integer, save:: ncid_startphy |
| 403 |
|
| 404 |
namelist /physiq_nml/ fact_cldcon, facttemps, iflag_cldcon, ratqsbas, & |
| 405 |
ratqshaut, ok_ade, bl95_b0, bl95_b1 |
| 406 |
|
| 407 |
!---------------------------------------------------------------- |
| 408 |
|
| 409 |
IF (nqmx < 2) CALL abort_gcm('physiq', & |
| 410 |
'eaux vapeur et liquide sont indispensables') |
| 411 |
|
| 412 |
test_firstcal: IF (firstcal) THEN |
| 413 |
! initialiser |
| 414 |
u10m_srf = 0. |
| 415 |
v10m_srf = 0. |
| 416 |
t2m = 0. |
| 417 |
q2m = 0. |
| 418 |
ffonte = 0. |
| 419 |
d_u_con = 0. |
| 420 |
d_v_con = 0. |
| 421 |
rnebcon0 = 0. |
| 422 |
clwcon0 = 0. |
| 423 |
rnebcon = 0. |
| 424 |
clwcon = 0. |
| 425 |
pblh =0. ! Hauteur de couche limite |
| 426 |
plcl =0. ! Niveau de condensation de la CLA |
| 427 |
capCL =0. ! CAPE de couche limite |
| 428 |
oliqCL =0. ! eau_liqu integree de couche limite |
| 429 |
cteiCL =0. ! cloud top instab. crit. couche limite |
| 430 |
pblt =0. |
| 431 |
therm =0. |
| 432 |
|
| 433 |
print *, "Enter namelist 'physiq_nml'." |
| 434 |
read(unit=*, nml=physiq_nml) |
| 435 |
write(unit_nml, nml=physiq_nml) |
| 436 |
|
| 437 |
call ctherm |
| 438 |
call conf_phys |
| 439 |
|
| 440 |
! Initialiser les compteurs: |
| 441 |
|
| 442 |
frugs = 0. |
| 443 |
CALL phyetat0(pctsrf, ftsol, ftsoil, fqsurf, qsol, fsnow, falbe, & |
| 444 |
rain_fall, snow_fall, solsw, sollw, dlw, radsol, frugs, agesno, & |
| 445 |
zmea, zstd, zsig, zgam, zthe, zpic, zval, t_ancien, q_ancien, & |
| 446 |
ancien_ok, rnebcon, ratqs, clwcon, run_off_lic_0, sig1, w01, & |
| 447 |
ncid_startphy) |
| 448 |
|
| 449 |
! ATTENTION : il faudra a terme relire q2 dans l'etat initial |
| 450 |
q2 = 1e-8 |
| 451 |
|
| 452 |
radpas = lmt_pas / nbapp_rad |
| 453 |
print *, "radpas = ", radpas |
| 454 |
|
| 455 |
! Initialisation pour le sch\'ema de convection d'Emanuel : |
| 456 |
IF (conv_emanuel) THEN |
| 457 |
ibas_con = 1 |
| 458 |
itop_con = 1 |
| 459 |
ENDIF |
| 460 |
|
| 461 |
IF (ok_orodr) THEN |
| 462 |
rugoro = MAX(1e-5, zstd * zsig / 2) |
| 463 |
CALL SUGWD(paprs, play) |
| 464 |
else |
| 465 |
rugoro = 0. |
| 466 |
ENDIF |
| 467 |
|
| 468 |
! Initialisation des sorties |
| 469 |
call ini_histins |
| 470 |
CALL phyredem0 |
| 471 |
call conf_interface |
| 472 |
ENDIF test_firstcal |
| 473 |
|
| 474 |
! We will modify variables *_seri and we will not touch variables |
| 475 |
! u, v, t, qx: |
| 476 |
t_seri = t |
| 477 |
u_seri = u |
| 478 |
v_seri = v |
| 479 |
q_seri = qx(:, :, ivap) |
| 480 |
ql_seri = qx(:, :, iliq) |
| 481 |
tr_seri = qx(:, :, 3:nqmx) |
| 482 |
|
| 483 |
tsol = sum(ftsol * pctsrf, dim = 2) |
| 484 |
|
| 485 |
! Diagnostic de la tendance dynamique : |
| 486 |
IF (ancien_ok) THEN |
| 487 |
DO k = 1, llm |
| 488 |
DO i = 1, klon |
| 489 |
d_t_dyn(i, k) = (t_seri(i, k) - t_ancien(i, k)) / dtphys |
| 490 |
d_q_dyn(i, k) = (q_seri(i, k) - q_ancien(i, k)) / dtphys |
| 491 |
ENDDO |
| 492 |
ENDDO |
| 493 |
ELSE |
| 494 |
DO k = 1, llm |
| 495 |
DO i = 1, klon |
| 496 |
d_t_dyn(i, k) = 0. |
| 497 |
d_q_dyn(i, k) = 0. |
| 498 |
ENDDO |
| 499 |
ENDDO |
| 500 |
ancien_ok = .TRUE. |
| 501 |
ENDIF |
| 502 |
|
| 503 |
! Ajouter le geopotentiel du sol: |
| 504 |
DO k = 1, llm |
| 505 |
DO i = 1, klon |
| 506 |
zphi(i, k) = pphi(i, k) + pphis(i) |
| 507 |
ENDDO |
| 508 |
ENDDO |
| 509 |
|
| 510 |
! Check temperatures: |
| 511 |
CALL hgardfou(t_seri, ftsol) |
| 512 |
|
| 513 |
call increment_itap |
| 514 |
julien = MOD(dayvrai, 360) |
| 515 |
if (julien == 0) julien = 360 |
| 516 |
|
| 517 |
forall (k = 1: llm) zmasse(:, k) = (paprs(:, k) - paprs(:, k + 1)) / rg |
| 518 |
|
| 519 |
! \'Evaporation de l'eau liquide nuageuse : |
| 520 |
DO k = 1, llm |
| 521 |
DO i = 1, klon |
| 522 |
zb = MAX(0., ql_seri(i, k)) |
| 523 |
t_seri(i, k) = t_seri(i, k) & |
| 524 |
- zb * RLVTT / RCPD / (1. + RVTMP2 * q_seri(i, k)) |
| 525 |
q_seri(i, k) = q_seri(i, k) + zb |
| 526 |
ENDDO |
| 527 |
ENDDO |
| 528 |
ql_seri = 0. |
| 529 |
|
| 530 |
frugs = MAX(frugs, 0.000015) |
| 531 |
zxrugs = sum(frugs * pctsrf, dim = 2) |
| 532 |
|
| 533 |
! Calculs n\'ecessaires au calcul de l'albedo dans l'interface avec |
| 534 |
! la surface. |
| 535 |
|
| 536 |
CALL orbite(REAL(julien), longi, dist) |
| 537 |
CALL zenang(longi, time, dtphys * radpas, mu0, fract) |
| 538 |
|
| 539 |
CALL pbl_surface(pctsrf, t_seri, q_seri, u_seri, v_seri, julien, mu0, & |
| 540 |
ftsol, cdmmax, cdhmax, ftsoil, qsol, paprs, play, fsnow, fqsurf, & |
| 541 |
falbe, fluxlat, rain_fall, snow_fall, frugs, agesno, rugoro, d_t_vdf, & |
| 542 |
d_q_vdf, d_u_vdf, d_v_vdf, flux_t, flux_q, flux_u, flux_v, cdragh, & |
| 543 |
cdragm, q2, dflux_t, dflux_q, coefh, t2m, q2m, u10m_srf, v10m_srf, & |
| 544 |
pblh, capCL, oliqCL, cteiCL, pblT, therm, plcl, fqcalving, ffonte, & |
| 545 |
run_off_lic_0, albsol, sollw, solsw, tsol) |
| 546 |
|
| 547 |
! Incr\'ementation des flux |
| 548 |
|
| 549 |
sens = sum(flux_t * pctsrf, dim = 2) |
| 550 |
evap = - sum(flux_q * pctsrf, dim = 2) |
| 551 |
fder = dlw + dflux_t + dflux_q |
| 552 |
|
| 553 |
DO k = 1, llm |
| 554 |
DO i = 1, klon |
| 555 |
t_seri(i, k) = t_seri(i, k) + d_t_vdf(i, k) |
| 556 |
q_seri(i, k) = q_seri(i, k) + d_q_vdf(i, k) |
| 557 |
u_seri(i, k) = u_seri(i, k) + d_u_vdf(i, k) |
| 558 |
v_seri(i, k) = v_seri(i, k) + d_v_vdf(i, k) |
| 559 |
ENDDO |
| 560 |
ENDDO |
| 561 |
|
| 562 |
call assert(abs(sum(pctsrf, dim = 2) - 1.) <= EPSFRA, 'physiq: pctsrf') |
| 563 |
tsol = sum(ftsol * pctsrf, dim = 2) |
| 564 |
zxfluxlat = sum(fluxlat * pctsrf, dim = 2) |
| 565 |
zt2m = sum(t2m * pctsrf, dim = 2) |
| 566 |
zq2m = sum(q2m * pctsrf, dim = 2) |
| 567 |
u10m = sum(u10m_srf * pctsrf, dim = 2) |
| 568 |
v10m = sum(v10m_srf * pctsrf, dim = 2) |
| 569 |
zxffonte = sum(ffonte * pctsrf, dim = 2) |
| 570 |
s_pblh = sum(pblh * pctsrf, dim = 2) |
| 571 |
s_lcl = sum(plcl * pctsrf, dim = 2) |
| 572 |
s_capCL = sum(capCL * pctsrf, dim = 2) |
| 573 |
s_oliqCL = sum(oliqCL * pctsrf, dim = 2) |
| 574 |
s_cteiCL = sum(cteiCL * pctsrf, dim = 2) |
| 575 |
s_pblT = sum(pblT * pctsrf, dim = 2) |
| 576 |
s_therm = sum(therm * pctsrf, dim = 2) |
| 577 |
|
| 578 |
! Si une sous-fraction n'existe pas, elle prend la valeur moyenne : |
| 579 |
DO nsrf = 1, nbsrf |
| 580 |
DO i = 1, klon |
| 581 |
IF (pctsrf(i, nsrf) < epsfra) then |
| 582 |
ftsol(i, nsrf) = tsol(i) |
| 583 |
t2m(i, nsrf) = zt2m(i) |
| 584 |
q2m(i, nsrf) = zq2m(i) |
| 585 |
u10m_srf(i, nsrf) = u10m(i) |
| 586 |
v10m_srf(i, nsrf) = v10m(i) |
| 587 |
ffonte(i, nsrf) = zxffonte(i) |
| 588 |
pblh(i, nsrf) = s_pblh(i) |
| 589 |
plcl(i, nsrf) = s_lcl(i) |
| 590 |
capCL(i, nsrf) = s_capCL(i) |
| 591 |
oliqCL(i, nsrf) = s_oliqCL(i) |
| 592 |
cteiCL(i, nsrf) = s_cteiCL(i) |
| 593 |
pblT(i, nsrf) = s_pblT(i) |
| 594 |
therm(i, nsrf) = s_therm(i) |
| 595 |
end IF |
| 596 |
ENDDO |
| 597 |
ENDDO |
| 598 |
|
| 599 |
dlw = - 4. * RSIGMA * tsol**3 |
| 600 |
|
| 601 |
! Appeler la convection |
| 602 |
|
| 603 |
if (conv_emanuel) then |
| 604 |
CALL concvl(paprs, play, t_seri, q_seri, u_seri, v_seri, sig1, w01, & |
| 605 |
d_t_con, d_q_con, d_u_con, d_v_con, rain_con, ibas_con, itop_con, & |
| 606 |
upwd, dnwd, Ma, cape, iflagctrl, clwcon0, pmflxr, da, phi, mp) |
| 607 |
snow_con = 0. |
| 608 |
mfu = upwd + dnwd |
| 609 |
|
| 610 |
zqsat = MIN(0.5, r2es * FOEEW(t_seri, rtt >= t_seri) / play) |
| 611 |
zqsat = zqsat / (1. - retv * zqsat) |
| 612 |
|
| 613 |
! Properties of convective clouds |
| 614 |
clwcon0 = fact_cldcon * clwcon0 |
| 615 |
call clouds_gno(klon, llm, q_seri, zqsat, clwcon0, ptconv, ratqsc, & |
| 616 |
rnebcon0) |
| 617 |
|
| 618 |
forall (i = 1:klon) ema_pct(i) = paprs(i, itop_con(i) + 1) |
| 619 |
mfd = 0. |
| 620 |
pen_u = 0. |
| 621 |
pen_d = 0. |
| 622 |
pde_d = 0. |
| 623 |
pde_u = 0. |
| 624 |
else |
| 625 |
conv_q = d_q_dyn + d_q_vdf / dtphys |
| 626 |
conv_t = d_t_dyn + d_t_vdf / dtphys |
| 627 |
z_avant = sum((q_seri + ql_seri) * zmasse, dim=2) |
| 628 |
CALL conflx(paprs, play, t_seri(:, llm:1:- 1), q_seri(:, llm:1:- 1), & |
| 629 |
conv_t, conv_q, - evap, omega, d_t_con, d_q_con, rain_con, & |
| 630 |
snow_con, mfu(:, llm:1:- 1), mfd(:, llm:1:- 1), pen_u, pde_u, & |
| 631 |
pen_d, pde_d, kcbot, kctop, kdtop, pmflxr, pmflxs) |
| 632 |
WHERE (rain_con < 0.) rain_con = 0. |
| 633 |
WHERE (snow_con < 0.) snow_con = 0. |
| 634 |
ibas_con = llm + 1 - kcbot |
| 635 |
itop_con = llm + 1 - kctop |
| 636 |
END if |
| 637 |
|
| 638 |
DO k = 1, llm |
| 639 |
DO i = 1, klon |
| 640 |
t_seri(i, k) = t_seri(i, k) + d_t_con(i, k) |
| 641 |
q_seri(i, k) = q_seri(i, k) + d_q_con(i, k) |
| 642 |
u_seri(i, k) = u_seri(i, k) + d_u_con(i, k) |
| 643 |
v_seri(i, k) = v_seri(i, k) + d_v_con(i, k) |
| 644 |
ENDDO |
| 645 |
ENDDO |
| 646 |
|
| 647 |
IF (.not. conv_emanuel) THEN |
| 648 |
z_apres = sum((q_seri + ql_seri) * zmasse, dim=2) |
| 649 |
z_factor = (z_avant - (rain_con + snow_con) * dtphys) / z_apres |
| 650 |
DO k = 1, llm |
| 651 |
DO i = 1, klon |
| 652 |
IF (z_factor(i) /= 1.) THEN |
| 653 |
q_seri(i, k) = q_seri(i, k) * z_factor(i) |
| 654 |
ENDIF |
| 655 |
ENDDO |
| 656 |
ENDDO |
| 657 |
ENDIF |
| 658 |
|
| 659 |
! Convection s\`eche (thermiques ou ajustement) |
| 660 |
|
| 661 |
d_t_ajs = 0. |
| 662 |
d_u_ajs = 0. |
| 663 |
d_v_ajs = 0. |
| 664 |
d_q_ajs = 0. |
| 665 |
fm_therm = 0. |
| 666 |
entr_therm = 0. |
| 667 |
|
| 668 |
if (iflag_thermals) then |
| 669 |
call calltherm(play, paprs, pphi, u_seri, v_seri, t_seri, q_seri, & |
| 670 |
d_u_ajs, d_v_ajs, d_t_ajs, d_q_ajs, fm_therm, entr_therm) |
| 671 |
else |
| 672 |
CALL ajsec(paprs, play, t_seri, q_seri, d_t_ajs, d_q_ajs) |
| 673 |
t_seri = t_seri + d_t_ajs |
| 674 |
q_seri = q_seri + d_q_ajs |
| 675 |
endif |
| 676 |
|
| 677 |
! Caclul des ratqs |
| 678 |
|
| 679 |
if (iflag_cldcon == 1) then |
| 680 |
! ratqs convectifs \`a l'ancienne en fonction de (q(z = 0) - q) / q |
| 681 |
! on \'ecrase le tableau ratqsc calcul\'e par clouds_gno |
| 682 |
do k = 1, llm |
| 683 |
do i = 1, klon |
| 684 |
if(ptconv(i, k)) then |
| 685 |
ratqsc(i, k) = ratqsbas + fact_cldcon & |
| 686 |
* (q_seri(i, 1) - q_seri(i, k)) / q_seri(i, k) |
| 687 |
else |
| 688 |
ratqsc(i, k) = 0. |
| 689 |
endif |
| 690 |
enddo |
| 691 |
enddo |
| 692 |
endif |
| 693 |
|
| 694 |
! ratqs stables |
| 695 |
do k = 1, llm |
| 696 |
do i = 1, klon |
| 697 |
ratqss(i, k) = ratqsbas + (ratqshaut - ratqsbas) & |
| 698 |
* min((paprs(i, 1) - play(i, k)) / (paprs(i, 1) - 3e4), 1.) |
| 699 |
enddo |
| 700 |
enddo |
| 701 |
|
| 702 |
! ratqs final |
| 703 |
if (iflag_cldcon == 1 .or. iflag_cldcon == 2) then |
| 704 |
! les ratqs sont une conbinaison de ratqss et ratqsc |
| 705 |
! ratqs final |
| 706 |
! 1e4 (en gros 3 heures), en dur pour le moment, est le temps de |
| 707 |
! relaxation des ratqs |
| 708 |
ratqs = max(ratqs * exp(- dtphys * facttemps), ratqss) |
| 709 |
ratqs = max(ratqs, ratqsc) |
| 710 |
else |
| 711 |
! on ne prend que le ratqs stable pour fisrtilp |
| 712 |
ratqs = ratqss |
| 713 |
endif |
| 714 |
|
| 715 |
CALL fisrtilp(paprs, play, t_seri, q_seri, ptconv, ratqs, d_t_lsc, & |
| 716 |
d_q_lsc, d_ql_lsc, rneb, cldliq, rain_lsc, snow_lsc, pfrac_impa, & |
| 717 |
pfrac_nucl, pfrac_1nucl, frac_impa, frac_nucl, prfl, psfl, rhcl) |
| 718 |
|
| 719 |
WHERE (rain_lsc < 0) rain_lsc = 0. |
| 720 |
WHERE (snow_lsc < 0) snow_lsc = 0. |
| 721 |
DO k = 1, llm |
| 722 |
DO i = 1, klon |
| 723 |
t_seri(i, k) = t_seri(i, k) + d_t_lsc(i, k) |
| 724 |
q_seri(i, k) = q_seri(i, k) + d_q_lsc(i, k) |
| 725 |
ql_seri(i, k) = ql_seri(i, k) + d_ql_lsc(i, k) |
| 726 |
cldfra(i, k) = rneb(i, k) |
| 727 |
ENDDO |
| 728 |
ENDDO |
| 729 |
|
| 730 |
! PRESCRIPTION DES NUAGES POUR LE RAYONNEMENT |
| 731 |
|
| 732 |
! 1. NUAGES CONVECTIFS |
| 733 |
|
| 734 |
IF (iflag_cldcon <= - 1) THEN |
| 735 |
! seulement pour Tiedtke |
| 736 |
snow_tiedtke = 0. |
| 737 |
if (iflag_cldcon == - 1) then |
| 738 |
rain_tiedtke = rain_con |
| 739 |
else |
| 740 |
rain_tiedtke = 0. |
| 741 |
do k = 1, llm |
| 742 |
do i = 1, klon |
| 743 |
if (d_q_con(i, k) < 0.) then |
| 744 |
rain_tiedtke(i) = rain_tiedtke(i) - d_q_con(i, k) / dtphys & |
| 745 |
* zmasse(i, k) |
| 746 |
endif |
| 747 |
enddo |
| 748 |
enddo |
| 749 |
endif |
| 750 |
|
| 751 |
! Nuages diagnostiques pour Tiedtke |
| 752 |
CALL diagcld1(paprs, play, rain_tiedtke, snow_tiedtke, ibas_con, & |
| 753 |
itop_con, diafra, dialiq) |
| 754 |
DO k = 1, llm |
| 755 |
DO i = 1, klon |
| 756 |
IF (diafra(i, k) > cldfra(i, k)) THEN |
| 757 |
cldliq(i, k) = dialiq(i, k) |
| 758 |
cldfra(i, k) = diafra(i, k) |
| 759 |
ENDIF |
| 760 |
ENDDO |
| 761 |
ENDDO |
| 762 |
ELSE IF (iflag_cldcon == 3) THEN |
| 763 |
! On prend pour les nuages convectifs le maximum du calcul de |
| 764 |
! la convection et du calcul du pas de temps pr\'ec\'edent diminu\'e |
| 765 |
! d'un facteur facttemps. |
| 766 |
facteur = dtphys * facttemps |
| 767 |
do k = 1, llm |
| 768 |
do i = 1, klon |
| 769 |
rnebcon(i, k) = rnebcon(i, k) * facteur |
| 770 |
if (rnebcon0(i, k) * clwcon0(i, k) & |
| 771 |
> rnebcon(i, k) * clwcon(i, k)) then |
| 772 |
rnebcon(i, k) = rnebcon0(i, k) |
| 773 |
clwcon(i, k) = clwcon0(i, k) |
| 774 |
endif |
| 775 |
enddo |
| 776 |
enddo |
| 777 |
|
| 778 |
! On prend la somme des fractions nuageuses et des contenus en eau |
| 779 |
cldfra = min(max(cldfra, rnebcon), 1.) |
| 780 |
cldliq = cldliq + rnebcon * clwcon |
| 781 |
ENDIF |
| 782 |
|
| 783 |
! Precipitation totale |
| 784 |
DO i = 1, klon |
| 785 |
rain_fall(i) = rain_con(i) + rain_lsc(i) |
| 786 |
snow_fall(i) = snow_con(i) + snow_lsc(i) |
| 787 |
ENDDO |
| 788 |
|
| 789 |
! Humidit\'e relative pour diagnostic : |
| 790 |
DO k = 1, llm |
| 791 |
DO i = 1, klon |
| 792 |
zx_qs = r2es * FOEEW(t_seri(i, k), rtt >= t_seri(i, k)) / play(i, k) |
| 793 |
zx_qs = MIN(0.5, zx_qs) |
| 794 |
zcor = 1. / (1. - retv * zx_qs) |
| 795 |
zx_qs = zx_qs * zcor |
| 796 |
zx_rh(i, k) = q_seri(i, k) / zx_qs |
| 797 |
zqsat(i, k) = zx_qs |
| 798 |
ENDDO |
| 799 |
ENDDO |
| 800 |
|
| 801 |
! Param\`etres optiques des nuages et quelques param\`etres pour |
| 802 |
! diagnostics : |
| 803 |
CALL newmicro(paprs, play, t_seri, cldliq, cldfra, cldtau, cldemi, cldh, & |
| 804 |
cldl, cldm, cldt, cldq, flwp, fiwp, flwc, fiwc) |
| 805 |
|
| 806 |
IF (MOD(itap - 1, radpas) == 0) THEN |
| 807 |
wo = ozonecm(REAL(julien), paprs) |
| 808 |
albsol = sum(falbe * pctsrf, dim = 2) |
| 809 |
CALL radlwsw(dist, mu0, fract, paprs, play, tsol, albsol, t_seri, & |
| 810 |
q_seri, wo, cldfra, cldemi, cldtau, heat, heat0, cool, cool0, & |
| 811 |
radsol, albpla, topsw, toplw, solsw, sollw, sollwdown, topsw0, & |
| 812 |
toplw0, solsw0, sollw0, lwdn0, lwdn, lwup0, lwup, swdn0, swdn, & |
| 813 |
swup0, swup, ok_ade, topswad, solswad) |
| 814 |
ENDIF |
| 815 |
|
| 816 |
! Ajouter la tendance des rayonnements (tous les pas) |
| 817 |
DO k = 1, llm |
| 818 |
DO i = 1, klon |
| 819 |
t_seri(i, k) = t_seri(i, k) + (heat(i, k) - cool(i, k)) * dtphys & |
| 820 |
/ 86400. |
| 821 |
ENDDO |
| 822 |
ENDDO |
| 823 |
|
| 824 |
! Param\'etrisation de l'orographie \`a l'\'echelle sous-maille : |
| 825 |
|
| 826 |
IF (ok_orodr) THEN |
| 827 |
! S\'election des points pour lesquels le sch\'ema est actif : |
| 828 |
DO i = 1, klon |
| 829 |
ktest(i) = 0 |
| 830 |
IF (zpic(i) - zmea(i) > 100. .AND. zstd(i) > 10.) THEN |
| 831 |
ktest(i) = 1 |
| 832 |
ENDIF |
| 833 |
ENDDO |
| 834 |
|
| 835 |
CALL drag_noro(paprs, play, zmea, zstd, zsig, zgam, zthe, zpic, zval, & |
| 836 |
ktest, t_seri, u_seri, v_seri, zulow, zvlow, zustrdr, zvstrdr, & |
| 837 |
d_t_oro, d_u_oro, d_v_oro) |
| 838 |
|
| 839 |
! ajout des tendances |
| 840 |
DO k = 1, llm |
| 841 |
DO i = 1, klon |
| 842 |
t_seri(i, k) = t_seri(i, k) + d_t_oro(i, k) |
| 843 |
u_seri(i, k) = u_seri(i, k) + d_u_oro(i, k) |
| 844 |
v_seri(i, k) = v_seri(i, k) + d_v_oro(i, k) |
| 845 |
ENDDO |
| 846 |
ENDDO |
| 847 |
ENDIF |
| 848 |
|
| 849 |
IF (ok_orolf) THEN |
| 850 |
! S\'election des points pour lesquels le sch\'ema est actif : |
| 851 |
DO i = 1, klon |
| 852 |
ktest(i) = 0 |
| 853 |
IF (zpic(i) - zmea(i) > 100.) THEN |
| 854 |
ktest(i) = 1 |
| 855 |
ENDIF |
| 856 |
ENDDO |
| 857 |
|
| 858 |
CALL lift_noro(paprs, play, zmea, zstd, zpic, ktest, t_seri, u_seri, & |
| 859 |
v_seri, zulow, zvlow, zustrli, zvstrli, d_t_lif, d_u_lif, d_v_lif) |
| 860 |
|
| 861 |
! Ajout des tendances : |
| 862 |
DO k = 1, llm |
| 863 |
DO i = 1, klon |
| 864 |
t_seri(i, k) = t_seri(i, k) + d_t_lif(i, k) |
| 865 |
u_seri(i, k) = u_seri(i, k) + d_u_lif(i, k) |
| 866 |
v_seri(i, k) = v_seri(i, k) + d_v_lif(i, k) |
| 867 |
ENDDO |
| 868 |
ENDDO |
| 869 |
ENDIF |
| 870 |
|
| 871 |
CALL aaam_bud(rg, romega, pphis, zustrdr, zustrli, & |
| 872 |
sum((u_seri - u) / dtphys * zmasse, dim = 2), zvstrdr, & |
| 873 |
zvstrli, sum((v_seri - v) / dtphys * zmasse, dim = 2), paprs, u, v, & |
| 874 |
aam, torsfc) |
| 875 |
|
| 876 |
! Calcul des tendances traceurs |
| 877 |
call phytrac(julien, time, firstcal, lafin, t, paprs, play, mfu, mfd, & |
| 878 |
pde_u, pen_d, coefh, cdragh, fm_therm, entr_therm, u(:, 1), v(:, 1), & |
| 879 |
ftsol, pctsrf, frac_impa, frac_nucl, da, phi, mp, upwd, dnwd, & |
| 880 |
tr_seri, zmasse, ncid_startphy) |
| 881 |
|
| 882 |
! Calculer le transport de l'eau et de l'energie (diagnostique) |
| 883 |
CALL transp(paprs, t_seri, q_seri, u_seri, v_seri, zphi, ve, vq, ue, uq) |
| 884 |
|
| 885 |
! diag. bilKP |
| 886 |
|
| 887 |
CALL transp_lay(paprs, t_seri, q_seri, u_seri, v_seri, zphi, ve_lay, & |
| 888 |
vq_lay, ue_lay, uq_lay) |
| 889 |
|
| 890 |
! Accumuler les variables a stocker dans les fichiers histoire: |
| 891 |
|
| 892 |
! conversion Ec en énergie thermique |
| 893 |
DO k = 1, llm |
| 894 |
DO i = 1, klon |
| 895 |
d_t_ec(i, k) = 0.5 / (RCPD * (1. + RVTMP2 * q_seri(i, k))) & |
| 896 |
* (u(i, k)**2 + v(i, k)**2 - u_seri(i, k)**2 - v_seri(i, k)**2) |
| 897 |
t_seri(i, k) = t_seri(i, k) + d_t_ec(i, k) |
| 898 |
d_t_ec(i, k) = d_t_ec(i, k) / dtphys |
| 899 |
END DO |
| 900 |
END DO |
| 901 |
|
| 902 |
! SORTIES |
| 903 |
|
| 904 |
! prw = eau precipitable |
| 905 |
DO i = 1, klon |
| 906 |
prw(i) = 0. |
| 907 |
DO k = 1, llm |
| 908 |
prw(i) = prw(i) + q_seri(i, k) * zmasse(i, k) |
| 909 |
ENDDO |
| 910 |
ENDDO |
| 911 |
|
| 912 |
! Convertir les incrementations en tendances |
| 913 |
|
| 914 |
DO k = 1, llm |
| 915 |
DO i = 1, klon |
| 916 |
d_u(i, k) = (u_seri(i, k) - u(i, k)) / dtphys |
| 917 |
d_v(i, k) = (v_seri(i, k) - v(i, k)) / dtphys |
| 918 |
d_t(i, k) = (t_seri(i, k) - t(i, k)) / dtphys |
| 919 |
d_qx(i, k, ivap) = (q_seri(i, k) - qx(i, k, ivap)) / dtphys |
| 920 |
d_qx(i, k, iliq) = (ql_seri(i, k) - qx(i, k, iliq)) / dtphys |
| 921 |
ENDDO |
| 922 |
ENDDO |
| 923 |
|
| 924 |
DO iq = 3, nqmx |
| 925 |
DO k = 1, llm |
| 926 |
DO i = 1, klon |
| 927 |
d_qx(i, k, iq) = (tr_seri(i, k, iq - 2) - qx(i, k, iq)) / dtphys |
| 928 |
ENDDO |
| 929 |
ENDDO |
| 930 |
ENDDO |
| 931 |
|
| 932 |
! Sauvegarder les valeurs de t et q a la fin de la physique: |
| 933 |
DO k = 1, llm |
| 934 |
DO i = 1, klon |
| 935 |
t_ancien(i, k) = t_seri(i, k) |
| 936 |
q_ancien(i, k) = q_seri(i, k) |
| 937 |
ENDDO |
| 938 |
ENDDO |
| 939 |
|
| 940 |
CALL histwrite_phy("phis", pphis) |
| 941 |
CALL histwrite_phy("aire", airephy) |
| 942 |
CALL histwrite_phy("psol", paprs(:, 1)) |
| 943 |
CALL histwrite_phy("precip", rain_fall + snow_fall) |
| 944 |
CALL histwrite_phy("plul", rain_lsc + snow_lsc) |
| 945 |
CALL histwrite_phy("pluc", rain_con + snow_con) |
| 946 |
CALL histwrite_phy("tsol", tsol) |
| 947 |
CALL histwrite_phy("t2m", zt2m) |
| 948 |
CALL histwrite_phy("q2m", zq2m) |
| 949 |
CALL histwrite_phy("u10m", u10m) |
| 950 |
CALL histwrite_phy("v10m", v10m) |
| 951 |
CALL histwrite_phy("snow", snow_fall) |
| 952 |
CALL histwrite_phy("cdrm", cdragm) |
| 953 |
CALL histwrite_phy("cdrh", cdragh) |
| 954 |
CALL histwrite_phy("topl", toplw) |
| 955 |
CALL histwrite_phy("evap", evap) |
| 956 |
CALL histwrite_phy("sols", solsw) |
| 957 |
CALL histwrite_phy("rls", sollw) |
| 958 |
CALL histwrite_phy("solldown", sollwdown) |
| 959 |
CALL histwrite_phy("bils", radsol + sens + zxfluxlat) |
| 960 |
CALL histwrite_phy("sens", sens) |
| 961 |
CALL histwrite_phy("fder", fder) |
| 962 |
CALL histwrite_phy("zxfqcalving", sum(fqcalving * pctsrf, dim = 2)) |
| 963 |
CALL histwrite_phy("albs", albsol) |
| 964 |
CALL histwrite_phy("tro3", wo * dobson_u * 1e3 / zmasse / rmo3 * md) |
| 965 |
CALL histwrite_phy("rugs", zxrugs) |
| 966 |
CALL histwrite_phy("s_pblh", s_pblh) |
| 967 |
CALL histwrite_phy("s_pblt", s_pblt) |
| 968 |
CALL histwrite_phy("s_lcl", s_lcl) |
| 969 |
CALL histwrite_phy("s_capCL", s_capCL) |
| 970 |
CALL histwrite_phy("s_oliqCL", s_oliqCL) |
| 971 |
CALL histwrite_phy("s_cteiCL", s_cteiCL) |
| 972 |
CALL histwrite_phy("s_therm", s_therm) |
| 973 |
CALL histwrite_phy("temp", t_seri) |
| 974 |
CALL histwrite_phy("vitu", u_seri) |
| 975 |
CALL histwrite_phy("vitv", v_seri) |
| 976 |
CALL histwrite_phy("geop", zphi) |
| 977 |
CALL histwrite_phy("pres", play) |
| 978 |
CALL histwrite_phy("dtvdf", d_t_vdf) |
| 979 |
CALL histwrite_phy("dqvdf", d_q_vdf) |
| 980 |
CALL histwrite_phy("rhum", zx_rh) |
| 981 |
CALL histwrite_phy("d_t_ec", d_t_ec) |
| 982 |
CALL histwrite_phy("dtsw0", heat0 / 86400.) |
| 983 |
CALL histwrite_phy("dtlw0", - cool0 / 86400.) |
| 984 |
call histwrite_phy("pmflxr", pmflxr(:, :llm)) |
| 985 |
CALL histwrite_phy("msnow", sum(fsnow * pctsrf, dim = 2)) |
| 986 |
call histwrite_phy("qsurf", sum(fqsurf * pctsrf, dim = 2)) |
| 987 |
call histwrite_phy("flat", zxfluxlat) |
| 988 |
call histwrite_phy("rld", lwdn) |
| 989 |
call histwrite_phy("rldcs", lwdn0) |
| 990 |
|
| 991 |
DO nsrf = 1, nbsrf |
| 992 |
CALL histwrite_phy("fract_"//clnsurf(nsrf), pctsrf(:, nsrf)) |
| 993 |
CALL histwrite_phy("sens_"//clnsurf(nsrf), flux_t(:, nsrf)) |
| 994 |
CALL histwrite_phy("lat_"//clnsurf(nsrf), fluxlat(:, nsrf)) |
| 995 |
CALL histwrite_phy("tsol_"//clnsurf(nsrf), ftsol(:, nsrf)) |
| 996 |
CALL histwrite_phy("taux_"//clnsurf(nsrf), flux_u(:, nsrf)) |
| 997 |
CALL histwrite_phy("tauy_"//clnsurf(nsrf), flux_v(:, nsrf)) |
| 998 |
CALL histwrite_phy("rugs_"//clnsurf(nsrf), frugs(:, nsrf)) |
| 999 |
CALL histwrite_phy("albe_"//clnsurf(nsrf), falbe(:, nsrf)) |
| 1000 |
CALL histwrite_phy("u10m_"//clnsurf(nsrf), u10m_srf(:, nsrf)) |
| 1001 |
CALL histwrite_phy("v10m_"//clnsurf(nsrf), v10m_srf(:, nsrf)) |
| 1002 |
END DO |
| 1003 |
|
| 1004 |
if (conv_emanuel) then |
| 1005 |
CALL histwrite_phy("ptop", ema_pct) |
| 1006 |
CALL histwrite_phy("dnwd0", - mp) |
| 1007 |
end if |
| 1008 |
|
| 1009 |
if (ok_instan) call histsync(nid_ins) |
| 1010 |
|
| 1011 |
IF (lafin) then |
| 1012 |
call NF95_CLOSE(ncid_startphy) |
| 1013 |
CALL phyredem(pctsrf, ftsol, ftsoil, fqsurf, qsol, fsnow, falbe, & |
| 1014 |
rain_fall, snow_fall, solsw, sollw, dlw, radsol, frugs, agesno, & |
| 1015 |
zmea, zstd, zsig, zgam, zthe, zpic, zval, t_ancien, q_ancien, & |
| 1016 |
rnebcon, ratqs, clwcon, run_off_lic_0, sig1, w01) |
| 1017 |
end IF |
| 1018 |
|
| 1019 |
firstcal = .FALSE. |
| 1020 |
|
| 1021 |
END SUBROUTINE physiq |
| 1022 |
|
| 1023 |
end module physiq_m |
Parent Directory
| 
Revision Log