| 1 |
module zenang_m |
| 2 |
|
| 3 |
IMPLICIT NONE |
| 4 |
|
| 5 |
contains |
| 6 |
|
| 7 |
SUBROUTINE zenang(longi, gmtime, pdtrad, mu0, fract) |
| 8 |
|
| 9 |
! Author: O. Boucher (LMD/CNRS), d'après les routines "zenith" et |
| 10 |
! "angle" de Z. X. Li |
| 11 |
|
| 12 |
! Date : première version le 13 décembre 1994, revu pour GCM le 30 |
| 13 |
! septembre 1996 |
| 14 |
|
| 15 |
! Calcule les valeurs moyennes du cosinus de l'angle zénithal et |
| 16 |
! l'ensoleillement moyen entre "gmtime" et "gmtime + pdtrad" |
| 17 |
! connaissant la déclinaison, la latitude et la longitude. |
| 18 |
! Différent de la routine "angle" parce que "zenang" fournit des |
| 19 |
! moyennes de "mu0" et non des valeurs instantanées. Du coup |
| 20 |
! "fract" prend toutes les valeurs entre 0 et 1. Cf. Capderou (2003 |
| 21 |
! 784, equation 9.11). |
| 22 |
|
| 23 |
USE dimphy, ONLY: klon |
| 24 |
USE yomcst, ONLY: r_incl |
| 25 |
USE phyetat0_m, ONLY: rlat, rlon |
| 26 |
use nr_util, only: assert, pi, twopi |
| 27 |
|
| 28 |
REAL, INTENT(IN):: longi |
| 29 |
! longitude vraie de la terre dans son plan solaire à partir de |
| 30 |
! l'équinoxe de printemps (in degrees) |
| 31 |
|
| 32 |
REAL, INTENT(IN):: gmtime ! temps universel en fraction de jour |
| 33 |
REAL, INTENT(IN):: pdtrad ! pas de temps du rayonnement (s) |
| 34 |
|
| 35 |
REAL, INTENT(OUT):: mu0(:) ! (klon) |
| 36 |
! cosine of mean zenith angle between "gmtime" and "gmtime + pdtrad" |
| 37 |
|
| 38 |
REAL, INTENT(OUT), OPTIONAL:: fract(:) ! (klon) |
| 39 |
! ensoleillement moyen entre gmtime et gmtime + pdtrad |
| 40 |
|
| 41 |
! Local: |
| 42 |
|
| 43 |
INTEGER i |
| 44 |
REAL gmtime1, gmtime2 |
| 45 |
REAL omega1, omega2 ! temps 1 et 2 exprimés en radians avec 0 à midi |
| 46 |
|
| 47 |
REAL omega ! heure en rad du coucher de soleil |
| 48 |
! "- omega" est donc l'heure en rad de lever du soleil. |
| 49 |
|
| 50 |
REAL omegadeb, omegafin |
| 51 |
REAL zfrac1, zfrac2, z1_mu, z2_mu |
| 52 |
REAL lat_sun ! déclinaison en radians |
| 53 |
REAL latr ! latitude du point de grille en radians |
| 54 |
|
| 55 |
!---------------------------------------------------------------------- |
| 56 |
|
| 57 |
if (present(fract)) call assert((/size(mu0), size(fract)/) == klon, & |
| 58 |
"zenang") |
| 59 |
|
| 60 |
lat_sun = asin(sin(longi * pi / 180.) * sin(r_incl * pi / 180.)) |
| 61 |
! Capderou (2003 784, equation 4.49) |
| 62 |
|
| 63 |
gmtime1 = gmtime * 86400. |
| 64 |
gmtime2 = gmtime1 + pdtrad |
| 65 |
|
| 66 |
DO i = 1, klon |
| 67 |
latr = rlat(i) * pi / 180. |
| 68 |
|
| 69 |
IF (latr >= pi / 2. - lat_sun .OR. latr <= - pi / 2. - lat_sun) then |
| 70 |
omega = pi ! journée polaire |
| 71 |
else IF (latr < pi / 2. + lat_sun .AND. latr > - pi / 2. + lat_sun) THEN |
| 72 |
omega = acos(- tan(latr) * tan(lat_sun)) |
| 73 |
else |
| 74 |
omega = 0. ! nuit polaire |
| 75 |
END IF |
| 76 |
|
| 77 |
omega1 = mod((gmtime1 + rlon(i) * 86400. / 360.) / 86400. * twopi & |
| 78 |
+ twopi, twopi) - pi |
| 79 |
omega2 = mod((gmtime2 + rlon(i) * 86400. / 360.) / 86400. * twopi & |
| 80 |
+ twopi, twopi) - pi |
| 81 |
|
| 82 |
IF (omega1 <= omega2) THEN |
| 83 |
! on est dans la meme journee locale |
| 84 |
IF (omega2 <= - omega .OR. omega1 >= omega .OR. omega < 1E-5) THEN |
| 85 |
! nuit |
| 86 |
IF (present(fract)) fract(i) = 0. |
| 87 |
mu0(i) = 0. |
| 88 |
ELSE |
| 89 |
! jour + nuit / jour |
| 90 |
omegadeb = max(- omega, omega1) |
| 91 |
omegafin = min(omega, omega2) |
| 92 |
IF (present(fract)) fract(i) = (omegafin - omegadeb) & |
| 93 |
/ (omega2 - omega1) |
| 94 |
mu0(i) = sin(latr) * sin(lat_sun) + cos(latr) * cos(lat_sun) & |
| 95 |
* (sin(omegafin) - sin(omegadeb)) / (omegafin - omegadeb) |
| 96 |
END IF |
| 97 |
ELSE |
| 98 |
! omega1 > omega2, à cheval sur deux journées |
| 99 |
! entre omega1 et pi |
| 100 |
IF (omega1 >= omega) THEN ! nuit |
| 101 |
zfrac1 = 0. |
| 102 |
z1_mu = 0. |
| 103 |
ELSE ! jour + nuit |
| 104 |
omegadeb = max(- omega, omega1) |
| 105 |
omegafin = omega |
| 106 |
zfrac1 = omegafin - omegadeb |
| 107 |
z1_mu = sin(latr) * sin(lat_sun) + cos(latr) * cos(lat_sun) & |
| 108 |
* (sin(omegafin) - sin(omegadeb)) / (omegafin - omegadeb) |
| 109 |
END IF |
| 110 |
! entre - pi et omega2 |
| 111 |
IF (omega2 <= - omega) THEN ! nuit |
| 112 |
zfrac2 = 0. |
| 113 |
z2_mu = 0. |
| 114 |
ELSE ! jour + nuit |
| 115 |
omegadeb = - omega |
| 116 |
omegafin = min(omega, omega2) |
| 117 |
zfrac2 = omegafin - omegadeb |
| 118 |
z2_mu = sin(latr) * sin(lat_sun) + cos(latr) * cos(lat_sun) & |
| 119 |
* (sin(omegafin) - sin(omegadeb)) / (omegafin - omegadeb) |
| 120 |
END IF |
| 121 |
! moyenne |
| 122 |
IF (present(fract)) fract(i) = (zfrac1 + zfrac2) & |
| 123 |
/ (omega2 + twopi - omega1) |
| 124 |
mu0(i) = (zfrac1 * z1_mu + zfrac2 * z2_mu) & |
| 125 |
/ max(zfrac1 + zfrac2, 1e-10) |
| 126 |
END IF |
| 127 |
END DO |
| 128 |
|
| 129 |
END SUBROUTINE zenang |
| 130 |
|
| 131 |
end module zenang_m |
Parent Directory
| 
Revision Log