source: codes/icosagcm/devel/src/diagnostics/observable.f90 @ 595

Last change on this file since 595 was 595, checked in by dubos, 7 years ago

devel : fix halo issues with computation of energy fluxes
File size: 13.9 KB
Line 
1MODULE observable_mod
2  USE icosa
3  IMPLICIT NONE
4  PRIVATE
5
6  TYPE(t_field),POINTER, SAVE :: f_buf_i(:), &
7       f_buf_Fel(:), f_buf_uh(:), & ! horizontal velocity, different from prognostic velocity if NH
8       f_buf_ulon(:), f_buf_ulat(:), &
9       f_buf_u3d(:) ! unused, remove ?
10  TYPE(t_field),POINTER, SAVE :: f_buf1_i(:), f_buf2_i(:)
11  TYPE(t_field),POINTER, SAVE :: f_buf_v(:), f_buf_s(:), f_buf_p(:)
12  TYPE(t_field),POINTER, SAVE :: f_pmid(:)
13
14! temporary shared variable for caldyn
15  TYPE(t_field),POINTER, SAVE :: f_theta(:)
16
17  PUBLIC init_observable, write_output_fields_basic, f_theta
18
19CONTAINS
20 
21  SUBROUTINE init_observable
22    CALL allocate_field(f_buf_i,   field_t,type_real,llm,name="buffer_i")
23    CALL allocate_field(f_buf1_i,   field_t,type_real,llm,name="buffer1_i")
24    CALL allocate_field(f_buf2_i,   field_t,type_real,llm,name="buffer2_i")
25    CALL allocate_field(f_buf_p,   field_t,type_real,llm+1) 
26    CALL allocate_field(f_buf_u3d, field_t,type_real,3,llm)  ! 3D vel at cell centers
27    CALL allocate_field(f_buf_ulon,field_t,type_real,llm, name="buf_ulon")
28    CALL allocate_field(f_buf_ulat,field_t,type_real,llm, name="buf_ulat")
29    CALL allocate_field(f_buf_uh,  field_u,type_real,llm, name="buf_uh")
30    CALL allocate_field(f_buf_Fel, field_u,type_real,llm+1, name="buf_F_el")
31    CALL allocate_field(f_buf_v,   field_z,type_real,llm, name="buf_v")
32    CALL allocate_field(f_buf_s,   field_t,type_real, name="buf_s")
33
34    CALL allocate_field(f_theta, field_t,type_real,llm,nqdyn,  name='theta') ! potential temperature
35    CALL allocate_field(f_pmid,  field_t,type_real,llm,  name='pmid')       ! mid layer pressure
36  END SUBROUTINE init_observable
37
38  SUBROUTINE write_output_fields_basic(init, f_phis, f_ps, f_mass, f_geopot, f_theta_rhodz, f_u, f_W, f_q)
39    USE xios_mod
40    USE disvert_mod
41    USE wind_mod
42    USE output_field_mod
43    USE omp_para
44    USE time_mod
45    USE xios_mod
46    USE earth_const
47    USE pression_mod
48    USE vertical_interp_mod
49    USE theta2theta_rhodz_mod
50    USE omega_mod
51    USE diagflux_mod
52    LOGICAL, INTENT(IN) :: init
53    INTEGER :: l
54    REAL :: scalar(1)
55    REAL :: mid_ap(llm)
56    REAL :: mid_bp(llm)
57
58    TYPE(t_field),POINTER :: f_phis(:), f_ps(:), f_mass(:), f_geopot(:), f_theta_rhodz(:), f_u(:), f_W(:), f_q(:)
59!    IF (is_master) PRINT *,'CALL write_output_fields_basic'
60
61    CALL transfert_request(f_ps,req_i1)
62   
63    IF(init) THEN
64       IF(is_master) PRINT *, 'Creating output files ...'
65       scalar(1)=dt
66       IF (is_omp_master) CALL xios_send_field("timestep", scalar)
67       scalar(1)=preff
68       IF (is_omp_master) CALL xios_send_field("preff", scalar)
69       IF (is_omp_master) CALL xios_send_field("ap",ap)
70       IF (is_omp_master) CALL xios_send_field("bp",bp)
71       DO l=1,llm
72          mid_ap(l)=(ap(l)+ap(l+1))/2
73          mid_bp(l)=(bp(l)+bp(l+1))/2
74       ENDDO
75       IF (is_omp_master) CALL xios_send_field("mid_ap",mid_ap)
76       IF (is_omp_master) CALL xios_send_field("mid_bp",mid_bp)
77
78       CALL output_field("phis",f_phis)
79       CALL output_field("Ai",geom%Ai) 
80       IF(is_master) PRINT *, '... done creating output files. Writing initial condition ...'
81    END IF
82
83    IF(nqdyn>1) THEN
84       CALL divide_by_mass(2, f_mass, f_theta_rhodz, f_buf_i)
85       IF(init) THEN
86          CALL output_field("dyn_q_init",f_buf_i)
87       ELSE
88          CALL output_field("dyn_q",f_buf_i)
89       END IF
90    END IF
91
92    CALL divide_by_mass(1, f_mass, f_theta_rhodz, f_buf_i)
93    IF(init) THEN
94       CALL output_field("theta_init",f_buf_i)
95    ELSE
96       CALL output_field("theta",f_buf_i)
97    END IF
98
99    CALL pression_mid(f_ps, f_pmid)
100    CALL diagnose_temperature(f_pmid, f_q, f_buf_i) ! f_buf_i : IN = theta, out = T
101
102    IF(init) THEN
103       CALL output_field("temp_init",f_buf_i)
104    ELSE
105       CALL output_field("temp",f_buf_i)
106       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,85000.)
107       CALL output_field("t850",f_buf_s)
108       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,50000.)
109       CALL output_field("t500",f_buf_s)
110       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,preff)
111       CALL output_field("SST",f_buf_s)       
112    END IF
113   
114    CALL progonostic_vel_to_horiz(f_geopot, f_ps, f_mass, f_u, f_W, f_buf_uh, f_buf_i)
115    CALL transfert_request(f_buf_uh,req_e1_vect) 
116    CALL un2ulonlat(f_buf_uh, f_buf_ulon, f_buf_ulat)
117    IF(init) THEN
118       CALL output_field("uz_init",f_buf_i)
119       CALL output_field("ulon_init",f_buf_ulon)
120       CALL output_field("ulat_init",f_buf_ulat)
121       CALL output_field("p_init",f_pmid)
122       CALL output_field("ps_init",f_ps)
123       CALL output_field("mass_init",f_mass)
124       CALL output_field("geopot_init",f_geopot)
125       CALL output_field("q_init",f_q)
126       IF(is_master) PRINT *, 'Done writing initial condition ...'
127    ELSE
128       CALL output_field("uz",f_buf_i)
129       CALL output_field("ulon",f_buf_ulon)
130       CALL output_field("ulat",f_buf_ulat)
131       CALL output_field("p",f_pmid)
132       CALL output_field("ps",f_ps)
133       CALL output_field("mass",f_mass)
134       CALL output_field("geopot",f_geopot)
135       CALL output_field("q",f_q)
136
137       !       CALL output_field("exner",f_pk)
138       !       CALL output_field("pv",f_qv)
139       
140       CALL vertical_interp(f_pmid,f_buf_ulon,f_buf_s,85000.)
141       CALL output_field("u850",f_buf_s)
142       CALL vertical_interp(f_pmid,f_buf_ulon,f_buf_s,50000.)
143       CALL output_field("u500",f_buf_s)
144       
145       CALL vertical_interp(f_pmid,f_buf_ulat,f_buf_s,85000.)
146       CALL output_field("v850",f_buf_s)
147       CALL vertical_interp(f_pmid,f_buf_ulat,f_buf_s,50000.)
148       CALL output_field("v500",f_buf_s)
149
150       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,85000.)
151       CALL output_field("w850",f_buf_s)
152       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,50000.)
153       CALL output_field("w500",f_buf_s)   
154
155       CALL w_omega(f_ps, f_u, f_buf_i)
156       CALL output_field("omega",f_buf_i)
157       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,85000.)
158       CALL output_field("omega850",f_buf_s)
159       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,50000.)
160       CALL output_field("omega500",f_buf_s)
161    END IF
162
163    IF(.NOT. init) THEN
164       IF(diagflux_on) THEN
165          CALL flux_centered_lonlat(1./(itau_out*dt) , f_massfluxt, f_buf_ulon, f_buf_ulat)
166          CALL output_field("mass_t", f_masst)
167          CALL output_field("massflux_lon",f_buf_ulon)
168          CALL output_field("massflux_lat",f_buf_ulat)
169
170          CALL transfert_request(f_epotfluxt,req_e1_vect) 
171          CALL flux_centered_lonlat(1./(itau_out*dt) , f_epotfluxt, f_buf_ulon, f_buf_ulat)
172          CALL output_field("epot_t", f_epot)
173          CALL output_field("epotflux_lon",f_buf_ulon)
174          CALL output_field("epotflux_lat",f_buf_ulat)
175
176          CALL transfert_request(f_ekinfluxt,req_e1_vect) 
177          CALL flux_centered_lonlat(1./(itau_out*dt) , f_ekinfluxt, f_buf_ulon, f_buf_ulat)
178          CALL output_field("ekin_t", f_ekin)
179          CALL output_field("ekinflux_lon",f_buf_ulon)
180          CALL output_field("ekinflux_lat",f_buf_ulat)
181
182          CALL transfert_request(f_enthalpyfluxt,req_e1_vect) 
183          CALL flux_centered_lonlat(1./(itau_out*dt) , f_enthalpyfluxt, f_buf_ulon, f_buf_ulat)
184          CALL output_field("enthalpy_t", f_enthalpy)
185          CALL output_field("enthalpyflux_lon",f_buf_ulon)
186          CALL output_field("enthalpyflux_lat",f_buf_ulat)
187
188          CALL qflux_centered_lonlat(1./(itau_out*dt) , f_qfluxt, f_qfluxt_lon, f_qfluxt_lat)
189          CALL output_field("qmass_t", f_qmasst)
190          CALL output_field("qflux_lon",f_qfluxt_lon)
191          CALL output_field("qflux_lat",f_qfluxt_lat)
192          CALL zero_qfluxt  ! restart accumulating fluxes
193       END IF
194    END IF
195  END SUBROUTINE write_output_fields_basic
196 
197 !------------------- Conversion from prognostic to observable variables ------------------
198
199  SUBROUTINE progonostic_vel_to_horiz(f_geopot, f_ps, f_rhodz, f_u, f_W, f_uh, f_uz)
200    USE disvert_mod
201    TYPE(t_field), POINTER :: f_geopot(:), f_ps(:), f_rhodz(:), &
202         f_u(:), f_W(:), f_uz(:), &  ! IN
203         f_uh(:)                         ! OUT
204    REAL(rstd),POINTER :: geopot(:,:), ps(:), rhodz(:,:), u(:,:), W(:,:), uh(:,:), uz(:,:), F_el(:,:)
205    INTEGER :: ind
206   
207    DO ind=1,ndomain
208       IF (.NOT. assigned_domain(ind)) CYCLE
209       CALL swap_dimensions(ind)
210       CALL swap_geometry(ind)
211       geopot = f_geopot(ind)
212       rhodz = f_rhodz(ind)
213       u = f_u(ind)
214       W = f_W(ind)
215       uh  = f_uh(ind)
216       F_el  = f_buf_Fel(ind)
217       IF(caldyn_eta==eta_mass) THEN
218          ps=f_ps(ind)
219          CALL compute_rhodz(.TRUE., ps, rhodz)
220       END IF
221       uz = f_uz(ind)
222       !$OMP BARRIER
223       CALL compute_prognostic_vel_to_horiz(geopot,rhodz,u,W, F_el, uh,uz)
224       !$OMP BARRIER
225    END DO
226  END SUBROUTINE progonostic_vel_to_horiz
227 
228  SUBROUTINE compute_prognostic_vel_to_horiz(Phi, rhodz, u, W, F_el, uh, uz)
229    USE omp_para
230    REAL(rstd), INTENT(IN) :: Phi(iim*jjm,llm+1)
231    REAL(rstd), INTENT(IN) :: rhodz(iim*jjm,llm)
232    REAL(rstd), INTENT(IN) :: u(3*iim*jjm,llm)
233    REAL(rstd), INTENT(IN) :: W(iim*jjm,llm+1)
234    REAL(rstd), INTENT(OUT) :: uh(3*iim*jjm,llm)
235    REAL(rstd), INTENT(OUT) :: uz(iim*jjm,llm)
236    INTEGER :: ij,l
237    REAL(rstd) :: F_el(3*iim*jjm,llm+1)
238    REAL(rstd) :: uu_right, uu_lup, uu_ldown, W_el, DePhil
239    ! NB : u and uh are not in DEC form, they are normal components   
240    ! => we must divide by de
241    IF(hydrostatic) THEN
242       uh(:,:)=u(:,:)
243       uz(:,:)=0.
244    ELSE
245       DO l=ll_begin, ll_endp1 ! compute on l levels (interfaces)
246          DO ij=ij_begin_ext, ij_end_ext
247             ! Compute on edge 'right'
248             W_el   = .5*( W(ij,l)+W(ij+t_right,l) )
249             DePhil = ne_right*(Phi(ij+t_right,l)-Phi(ij,l))
250             F_el(ij+u_right,l)   = DePhil*W_el/de(ij+u_right)
251             ! Compute on edge 'lup'
252             W_el   = .5*( W(ij,l)+W(ij+t_lup,l) )
253             DePhil = ne_lup*(Phi(ij+t_lup,l)-Phi(ij,l))
254             F_el(ij+u_lup,l)   = DePhil*W_el/de(ij+u_lup)
255             ! Compute on edge 'ldown'
256             W_el   = .5*( W(ij,l)+W(ij+t_ldown,l) )
257             DePhil = ne_ldown*(Phi(ij+t_ldown,l)-Phi(ij,l))
258             F_el(ij+u_ldown,l) = DePhil*W_el/de(ij+u_ldown)
259          END DO
260       END DO
261
262       ! We need a barrier here because we compute F_el above and do a vertical average below
263       !$OMP BARRIER
264
265       DO l=ll_begin, ll_end ! compute on k levels (full levels)
266          DO ij=ij_begin_ext, ij_end_ext
267             ! w = vertical momentum = g^-2*dPhi/dt = uz/g
268             uz(ij,l) = (.5*g)*(W(ij,l)+W(ij,l+1))/rhodz(ij,l)
269             ! uh = u-w.grad(Phi) = u - uz.grad(z)
270             uh(ij+u_right,l) = u(ij+u_right,l) - (F_el(ij+u_right,l)+F_el(ij+u_right,l+1)) / (rhodz(ij,l)+rhodz(ij+t_right,l))
271             uh(ij+u_lup,l)   = u(ij+u_lup,l)   - (F_el(ij+u_lup,l)+F_el(ij+u_lup,l+1))     / (rhodz(ij,l)+rhodz(ij+t_lup,l))
272             uh(ij+u_ldown,l) = u(ij+u_ldown,l) - (F_el(ij+u_ldown,l)+F_el(ij+u_ldown,l+1)) / (rhodz(ij,l)+rhodz(ij+t_ldown,l))
273          END DO
274       END DO
275
276    END IF
277  END SUBROUTINE compute_prognostic_vel_to_horiz
278
279  SUBROUTINE diagnose_temperature(f_pmid,f_q,f_temp)
280    USE icosa
281    USE pression_mod
282    IMPLICIT NONE
283    TYPE(t_field), POINTER :: f_pmid(:)           ! IN
284    TYPE(t_field), POINTER :: f_q(:)            ! IN
285    TYPE(t_field), POINTER :: f_temp(:)         ! INOUT
286   
287    REAL(rstd), POINTER :: pmid(:,:)
288    REAL(rstd), POINTER :: q(:,:,:)
289    REAL(rstd), POINTER :: temp(:,:)
290    INTEGER :: ind
291   
292    DO ind=1,ndomain
293       IF (.NOT. assigned_domain(ind)) CYCLE
294       CALL swap_dimensions(ind)
295       CALL swap_geometry(ind)
296       pmid=f_pmid(ind)
297       q=f_q(ind)
298       temp=f_temp(ind)
299       CALL compute_diagnose_temp(pmid,q,temp)
300    END DO
301  END SUBROUTINE diagnose_temperature
302 
303  SUBROUTINE compute_diagnose_temp(pmid,q,temp)
304    USE omp_para
305    USE pression_mod
306    REAL(rstd),INTENT(IN)    :: pmid(iim*jjm,llm)
307    REAL(rstd),INTENT(IN)    :: q(iim*jjm,llm,nqtot)
308    REAL(rstd),INTENT(INOUT) :: temp(iim*jjm,llm)
309
310    REAL(rstd) :: Rd, p_ik, theta_ik, temp_ik, qv, chi, Rmix
311    INTEGER :: ij,l
312
313    Rd = kappa*cpp
314    DO l=ll_begin,ll_end
315       DO ij=ij_begin,ij_end
316          p_ik = pmid(ij,l)
317          theta_ik = temp(ij,l)
318          qv = q(ij,l,1) ! water vaper mixing ratio = mv/md
319          SELECT CASE(caldyn_thermo)
320          CASE(thermo_theta)
321             temp_ik = theta_ik*((p_ik/preff)**kappa)
322          CASE(thermo_entropy)
323             temp_ik = Treff*exp((theta_ik + Rd*log(p_ik/preff))/cpp)
324          CASE(thermo_moist)
325             Rmix = Rd+qv*Rv
326             chi = ( theta_ik + Rmix*log(p_ik/preff) ) / (cpp + qv*cppv) ! log(T/Treff)
327             temp_ik = Treff*exp(chi)
328          END SELECT
329          IF(physics_thermo==thermo_fake_moist) temp_ik=temp_ik/(1+0.608*qv)
330          temp(ij,l)=temp_ik
331       END DO
332    END DO
333  END SUBROUTINE compute_diagnose_temp
334
335  SUBROUTINE Tv2T(f_Tv, f_q, f_T)
336    TYPE(t_field), POINTER :: f_TV(:)
337    TYPE(t_field), POINTER :: f_q(:)
338    TYPE(t_field), POINTER :: f_T(:)
339   
340    REAL(rstd),POINTER :: Tv(:,:), q(:,:,:), T(:,:)
341    INTEGER :: ind
342   
343    DO ind=1,ndomain
344       IF (.NOT. assigned_domain(ind)) CYCLE
345       CALL swap_dimensions(ind)
346       CALL swap_geometry(ind)
347       Tv=f_Tv(ind)
348       T=f_T(ind)
349       SELECT CASE(physics_thermo)
350       CASE(thermo_dry)
351          T=Tv
352       CASE(thermo_fake_moist)
353          q=f_q(ind)
354          T=Tv/(1+0.608*q(:,:,1))
355       END SELECT
356    END DO
357  END SUBROUTINE Tv2T
358
359  SUBROUTINE divide_by_mass(iq, f_mass, f_theta_rhodz, f_theta)
360    INTEGER, INTENT(IN) :: iq
361    TYPE(t_field), POINTER :: f_mass(:), f_theta_rhodz(:), f_theta(:)
362    REAL(rstd), POINTER :: mass(:,:), theta_rhodz(:,:,:), theta(:,:)
363    INTEGER :: ind
364    DO ind=1,ndomain
365       IF (.NOT. assigned_domain(ind)) CYCLE
366       CALL swap_dimensions(ind)
367       CALL swap_geometry(ind)
368       mass=f_mass(ind)
369       theta_rhodz=f_theta_rhodz(ind)
370       theta=f_theta(ind)
371       theta(:,:) = theta_rhodz(:,:,iq) / mass(:,:)
372    END DO
373  END SUBROUTINE divide_by_mass
374   
375END MODULE observable_mod
Note: See TracBrowser for help on using the repository browser.