source: codes/icosagcm/devel/src/dissip/dissip_gcm.f90 @ 924

Last change on this file since 924 was 924, checked in by dubos, 5 years ago

devel : more options for the vertical profile of horizontal dissipation coefficient
File size: 31.8 KB
Line 
1MODULE dissip_gcm_mod
2  USE icosa
3  USE omp_para
4  USE trace
5  IMPLICIT NONE
6  PRIVATE
7
8  TYPE(t_field),POINTER,SAVE :: f_due_diss1(:)
9  TYPE(t_field),POINTER,SAVE :: f_due_diss2(:)
10
11  TYPE(t_field),POINTER,SAVE :: f_dtheta_diss(:)
12  TYPE(t_field),POINTER,SAVE :: f_dtheta_rhodz_diss(:)
13  TYPE(t_message),SAVE :: req_due, req_dtheta 
14 
15  INTEGER,SAVE :: nitergdiv=1
16!$OMP THREADPRIVATE(nitergdiv)
17  INTEGER,SAVE :: nitergrot=1
18!$OMP THREADPRIVATE(nitergrot)
19  INTEGER,SAVE :: niterdivgrad=1
20!$OMP THREADPRIVATE(niterdivgrad)
21
22  REAL,ALLOCATABLE,SAVE :: tau_graddiv(:)
23!$OMP THREADPRIVATE(tau_graddiv)
24  REAL,ALLOCATABLE,SAVE :: tau_gradrot(:)
25!$OMP THREADPRIVATE(tau_gradrot)
26  REAL,ALLOCATABLE,SAVE :: tau_divgrad(:)
27!$OMP THREADPRIVATE(tau_divgrad)
28
29  REAL,SAVE :: cgraddiv
30!$OMP THREADPRIVATE(cgraddiv)
31  REAL,SAVE :: cgradrot
32!$OMP THREADPRIVATE(cgradrot)
33  REAL,SAVE :: cdivgrad
34!$OMP THREADPRIVATE(cdivgrad)
35 
36  INTEGER, SAVE :: rayleigh_friction_type, rayleigh_shear
37!$OMP THREADPRIVATE(rayleigh_friction_type)
38!$OMP THREADPRIVATE(rayleigh_shear)
39  REAL, SAVE    :: rayleigh_tau, rayleigh_limlat
40!$OMP THREADPRIVATE(rayleigh_tau)
41!$OMP THREADPRIVATE(rayleigh_limlat)
42 
43  REAL,SAVE    :: dtdissip
44!$OMP THREADPRIVATE(dtdissip)
45 
46  PUBLIC init_dissip, dissip
47
48CONTAINS
49 
50  SUBROUTINE allocate_dissip
51    CALL allocate_field(f_due_diss1,field_u,type_real,llm)
52    CALL allocate_field(f_due_diss2,field_u,type_real,llm)
53    CALL allocate_field(f_dtheta_diss,field_t,type_real,llm)
54    CALL allocate_field(f_dtheta_rhodz_diss,field_t,type_real,llm)
55    ALLOCATE(tau_graddiv(llm))
56    ALLOCATE(tau_gradrot(llm))   
57    ALLOCATE(tau_divgrad(llm))
58  END SUBROUTINE allocate_dissip
59 
60  SUBROUTINE init_dissip
61    REAL(rstd)            :: tau 
62    CHARACTER(len=255)    :: rayleigh_friction_key
63    rayleigh_friction_key='none'
64    CALL getin("rayleigh_friction_type",rayleigh_friction_key)
65    SELECT CASE(TRIM(rayleigh_friction_key))
66    CASE('none')
67       rayleigh_friction_type=0
68       IF (is_master) PRINT *, 'No Rayleigh friction'
69    CASE('dcmip2_schaer_noshear')
70       rayleigh_friction_type=1
71       rayleigh_shear=0
72       IF (is_master) PRINT *, 'Rayleigh friction : Schaer-like mountain without shear DCMIP2.1'
73    CASE('dcmip2_schaer_shear')
74       rayleigh_shear=1
75       rayleigh_friction_type=2
76       IF (is_master) PRINT *, 'Rayleigh friction : Schaer-like mountain with shear DCMIP2.2'
77    CASE('giant_liu_schneider') 
78       rayleigh_friction_type=99
79       IF (is_master) PRINT *, 'Rayleigh friction : giant planets Liu Schneider 2010'
80    CASE DEFAULT
81       IF (is_master) PRINT *, 'Bad selector : rayleigh_friction_type =', TRIM(rayleigh_friction_key), &
82            ' in dissip_gcm.f90/init_dissip'
83       STOP
84    END SELECT
85   
86    IF(rayleigh_friction_type>0) THEN
87       rayleigh_tau=0.
88       CALL getin("rayleigh_friction_tau",rayleigh_tau)
89       rayleigh_tau = rayleigh_tau / scale_factor
90       IF(rayleigh_tau<=0) THEN
91          IF (is_master) PRINT *, 'Forbidden : negative value for rayleigh_friction_tau =',rayleigh_tau
92          STOP
93       END IF
94       IF(rayleigh_friction_type == 99) THEN
95          rayleigh_limlat=0.
96          CALL getin("rayleigh_limlat",rayleigh_limlat)
97          rayleigh_limlat = rayleigh_limlat*3.14159/180.
98       ENDIF
99    END IF
100   
101    CALL allocate_dissip
102
103    CALL init_message(f_due_diss1,req_e1_vect,req_due)
104    CALL init_message(f_dtheta_diss,req_i1,req_dtheta)
105
106    tau_graddiv(:)=5000
107    CALL getin("tau_graddiv",tau)
108    tau_graddiv(:)=tau/scale_factor
109
110    CALL getin("nitergdiv",nitergdiv)
111   
112    tau_gradrot(:)=5000
113    CALL getin("tau_gradrot",tau)
114    tau_gradrot(:)=tau/scale_factor
115
116    CALL getin("nitergrot",nitergrot)
117   
118
119    tau_divgrad(:)=5000
120    CALL getin("tau_divgrad",tau)
121    tau_divgrad(:)=tau/scale_factor
122
123    CALL getin("niterdivgrad",niterdivgrad)
124
125    IF(grid_type == grid_ico) THEN
126       CALL dissip_constants
127       CALL dissip_profile
128       CALL dissip_timescale
129    END IF
130
131  END SUBROUTINE init_dissip
132
133  SUBROUTINE dissip_constants
134    ! The SAVE attribute is required here, otherwise allocate_field will not work with OpenMP
135    TYPE(t_field),POINTER, SAVE  :: f_u(:)
136    TYPE(t_field),POINTER, SAVE  :: f_du(:)
137    TYPE(t_field),POINTER, SAVE  :: f_theta(:)
138    TYPE(t_field),POINTER, SAVE  :: f_dtheta(:)
139    REAL(rstd),POINTER :: u(:)
140    REAL(rstd),POINTER :: du(:)
141    REAL(rstd),POINTER :: theta(:)
142    REAL(rstd),POINTER :: dtheta(:)
143    REAL(rstd) :: dumax, dthetamax
144    INTEGER :: it, iter, ind
145    CALL allocate_field(f_u,field_u,type_real)
146    CALL allocate_field(f_du,field_u,type_real)
147    CALL allocate_field(f_theta,field_t,type_real)
148    CALL allocate_field(f_dtheta,field_t,type_real)
149
150    PRINT *, '=========', SHAPE(f_u)
151
152    !--------------------------- Compute cgraddiv ----------------------------
153    cgraddiv=-1.
154    CALL random_vel(f_u)   
155    DO it=1,20
156       DO iter=1,nitergdiv
157          CALL transfert_request(f_u,req_e1_vect)
158          DO ind=1,ndomain
159             IF (.NOT. assigned_domain(ind) .OR. .NOT. is_omp_level_master) CYCLE
160             CALL swap_dimensions(ind)
161             CALL swap_geometry(ind)
162             u=f_u(ind)
163             du=f_du(ind)
164             CALL compute_gradiv(u,du,1,1)
165          ENDDO
166       ENDDO
167       CALL transfert_request(f_du,req_e1_vect)       
168       dumax = max_vel(f_du)       
169       CALL rescale_field(1./dumax, f_du, f_u)
170       IF (is_master) PRINT *,"gradiv : it :",it ,": dumax",dumax
171    ENDDO
172
173    cgraddiv=dumax**(-1./nitergdiv)
174    IF (is_master) THEN
175       PRINT *,"gradiv : dumax",dumax
176       PRINT *, 'mean T-cell edge size (km)', 1.45*radius/iim_glo/1000., &
177         'effective T-cell half-edge size (km)', dumax**(-.5/nitergdiv)/1000
178       PRINT *, 'Max. time step assuming c=340 m/s and Courant number=3 (ARK2.3) :', &
179         3./340.*dumax**(-.5/nitergdiv)
180       PRINT *,"cgraddiv : ",cgraddiv
181    END IF
182   
183    !----------------- Compute cgradrot --------------------
184    cgradrot=-1.
185    CALL random_vel(f_u)
186    DO it=1,20
187       DO iter=1,nitergrot
188          CALL transfert_request(f_u,req_e1_vect)
189          DO ind=1,ndomain
190             IF (.NOT. assigned_domain(ind) .OR. .NOT. is_omp_level_master) CYCLE
191             CALL swap_dimensions(ind)
192             CALL swap_geometry(ind)
193             u=f_u(ind)
194             du=f_du(ind)
195             CALL compute_gradrot(u,du,1,1)
196             u=du
197          ENDDO
198       ENDDO
199       CALL transfert_request(f_du,req_e1_vect)
200       dumax = max_vel(f_du)
201       CALL rescale_field(1./dumax, f_du, f_u)
202       IF (is_master) PRINT *,"gradrot : it :",it ,": dumax",dumax
203    ENDDO
204
205    cgradrot=dumax**(-1./nitergrot) 
206    IF (is_master) PRINT *,"gradrot : dumax",dumax 
207    IF (is_master) PRINT *,"cgradrot : ",cgradrot
208   
209    !----------------- Compute cdivgrad --------------------
210
211    cdivgrad=-1.
212    CALL random_scalar(f_theta)   
213    DO it=1,20       
214       DO iter=1,niterdivgrad
215          CALL transfert_request(f_theta,req_i1)
216          DO ind=1,ndomain
217             IF (.NOT. assigned_domain(ind) .OR. .NOT. is_omp_level_master) CYCLE
218             CALL swap_dimensions(ind)
219             CALL swap_geometry(ind)
220             theta=f_theta(ind)
221             dtheta=f_dtheta(ind)
222             CALL compute_divgrad(theta,dtheta,1,1)
223          ENDDO
224       ENDDO       
225       CALL transfert_request(f_dtheta,req_i1)
226       dthetamax = max_scalar(f_dtheta)     
227       IF (is_master) PRINT *,"divgrad : it :",it ,": dthetamax",dthetamax
228       CALL rescale_field(1./dthetamax, f_dtheta, f_theta)
229    END DO
230   
231    cdivgrad=dthetamax**(-1./niterdivgrad) 
232    IF (is_master) PRINT *,"divgrad : divgrad",dthetamax
233    IF (is_master) PRINT *,"cdivgrad : ",cdivgrad
234
235  END SUBROUTINE dissip_constants
236
237  SUBROUTINE dissip_profile
238    USE disvert_mod
239    ! parameters used by the various profiles
240    ! IF planet_type == earth
241    !    IF dissip_vert_prof == 0
242    !      none
243    !    IF dissip_vert_prof == 1
244    !      dissip_zref, dissip_deltaz, dissip_factz
245    ! IF planet_type == other
246    !    IF dissip_vert_prof == 0
247    !      dissip_fac_mid
248    !      + dissip_deltaz, dissip_hdelta, dissip_fac_up, dissip_pupstart IF ok_strato     
249    !    IF dissip_vert_prof == 1
250    !      fac_mid, fac_up, startalt, delta => middle (hardcoded), scaleheight
251    !     
252
253    REAL(rstd), PARAMETER :: fact=2., &
254         fac_mid=3.,   & ! coefficient for lower/middle atmosphere
255         fac_up=30.,   & ! coefficient for upper atmosphere
256         startalt=70., & ! altitude (in km) for the transition from middle to upper atm.
257         delta=30.,    & ! Size (in km) of the transition region between middle/upper atm.
258         middle=startalt+delta/2.
259    REAL(rstd) :: dissip_zref, dissip_deltaz, dissip_factz, &
260         dissip_hdelta, dissip_fac_up, dissip_fac_mid, dissip_pupstart, &
261         scaleheight, &
262         zz, pseudoz, pup, &
263         sigma(llm), zvert(llm)
264    CHARACTER(LEN=255) :: planet_type ! earth, other, other_strato ; other_strato = other + ok_strato
265    LOGICAL :: ok_strato
266    INTEGER    :: l, dissip_vert_prof
267
268    ! select vertical profile of horizontal dissipation coefficients, see also [781]
269
270    planet_type='earth'
271    CALL getin('dissip_planet_type', planet_type)
272    SELECT CASE(planet_type)
273    CASE('earth','other')
274       ok_strato=.FALSE.
275    CASE('other_strato')
276       planet_type='other'
277       ok_strato=.TRUE.
278    CASE DEFAULT
279       STOP "Invalid value of dissip_planet_type, valid values are <earth>, <other>, <other_strato>"
280    END SELECT
281
282    dissip_vert_prof = 0
283    CALL getin('dissip_vert_prof',dissip_vert_prof)
284
285    SELECT CASE(dissip_vert_prof)
286    CASE(0)
287       IF(TRIM(planet_type)=='other') THEN
288          ! Default values given below are for a Venus-like planet
289          CALL getin('dissip_fac_mid',dissip_fac_mid )
290          dissip_fac_mid=2.
291          IF(ok_strato) THEN
292             dissip_fac_up=50.
293             ! deltaz et hdelta in km
294             dissip_deltaz=30.
295             dissip_hdelta=5.
296             ! pupstart in Pa
297             dissip_pupstart=1.e4         
298             CALL getin('dissip_deltaz',dissip_deltaz )
299             CALL getin('dissip_hdelta',dissip_hdelta )
300             CALL getin('dissip_fac_up',dissip_fac_up )
301             CALL getin('dissip_pupstart',dissip_pupstart)
302          END IF
303       END IF
304    CASE(1)
305       IF(TRIM(planet_type)=='earth') THEN
306          dissip_zref = 30.
307          dissip_deltaz = 10.
308          dissip_factz = 4.
309          CALL getin('dissip_zref',dissip_zref )
310          CALL getin('dissip_deltaz',dissip_deltaz )
311          CALL getin('dissip_factz',dissip_factz )
312       ELSE
313          ! fac_mid, fac_up, startalt, delta => middle are hardcoded
314          CALL getin('dissip_scaleheight', scaleheight)
315       END IF
316    CASE DEFAULT
317       STOP 'Invalid value of dissip_vert_prof : valid values are 0,1'
318    END SELECT
319
320    IF(ap_bp_present) THEN
321       sigma(:) = preff/presnivs(:)
322    ELSE
323       sigma(:) = 1.
324    END IF
325
326    SELECT CASE(TRIM(planet_type))
327    CASE('earth')
328       DO l=1,llm
329          IF(dissip_vert_prof == 1) THEN
330             pseudoz=8.*LOG(sigma(l))
331             zvert(l)=1+ &
332                  (TANH((pseudoz-dissip_zref)/dissip_deltaz)+1.)/2. &
333                  *(dissip_factz-1.)
334          ELSE
335             zz = 1.-sigma(l)
336             zvert(l)= fact -( fact-1.)/( 1.+zz*zz )
337          END IF
338       END DO
339    CASE('other')
340       SELECT CASE(dissip_vert_prof)
341       CASE(0)
342          ! First step: going from 1 to dissip_fac_mid (in gcm.def)
343          !============
344          DO l=1,llm
345             zz       = 1. - sigma(l)
346             zvert(l) = dissip_fac_mid -( dissip_fac_mid-1.)/( 1.+zz*zz )
347          END DO
348          !
349          ! Second step if ok_strato:  from dissip_fac_mid to dissip_fac_up (in gcm.def)
350          !==========================
351          ! Utilisation de la fonction tangente hyperbolique pour augmenter
352          ! arbitrairement la dissipation et donc la stabilite du modele a
353          ! partir d'une certaine altitude.
354          !
355          !   Le facteur multiplicatif de basse atmosphere etant deja pris
356          !   en compte, il faut diviser le facteur multiplicatif de haute
357          !   atmosphere par celui-ci.
358
359          IF(ok_strato) THEN
360             Pup = dissip_pupstart*exp(-0.5*dissip_deltaz/dissip_hdelta)
361             DO l=1,llm
362                zvert(l)= zvert(l)*(1.0+( (dissip_fac_up/dissip_fac_mid-1) &
363                     *(1.-(0.5*(1+tanh(-6./dissip_deltaz*              &
364                     (-dissip_hdelta*log(presnivs(l)/Pup))  ))))  ))
365             END DO
366          END IF
367       CASE(1)
368          DO l=1,llm
369             zz      = 1. - sigma(l)
370             zvert(l)= fac_mid -( fac_mid-1.)/( 1.+zz*zz )     
371             zvert(l)= zvert(l)*(1.0+((fac_up/fac_mid-1)*    &
372                  (1.-(0.5*(1+tanh(-6./                 &
373                  delta*(scaleheight*(-log(presnivs(l)/preff))-middle))))) &
374                  ))
375          END DO
376       END SELECT
377    END SELECT
378   
379    DO l=1,llm
380       tau_graddiv(l) = tau_graddiv(l)/zvert(l)
381       tau_gradrot(l) = tau_gradrot(l)/zvert(l)
382       tau_divgrad(l) = tau_divgrad(l)/zvert(l)
383    END DO
384  END SUBROUTINE dissip_profile
385 
386  SUBROUTINE dissip_timescale   
387    INTEGER :: l
388    REAL(rstd) :: mintau
389    mintau=tau_graddiv(1)
390    DO l=1,llm
391       mintau=MIN(mintau,tau_graddiv(l))
392       mintau=MIN(mintau,tau_gradrot(l))
393       mintau=MIN(mintau,tau_divgrad(l))
394    END DO
395   
396    IF(rayleigh_friction_type>0) mintau=MIN(mintau,rayleigh_tau)
397   
398    IF(mintau>0) THEN
399       IF (itau_dissip==0) THEN
400          IF (is_master) PRINT *,"init_dissip: Automatic computation of itau_dissip..."
401          itau_dissip=INT(mintau/dt)
402       ENDIF
403    ELSE
404       IF (is_master) PRINT *,"init_dissip: No dissipation time set, setting itau_dissip to 1000000000"
405       itau_dissip=100000000
406    END IF
407    itau_dissip=MAX(1,itau_dissip)
408    dtdissip=itau_dissip*dt
409    IF (is_master) THEN
410       PRINT *,"init_dissip: rayleigh_tau",rayleigh_tau, "mintau ",mintau
411       PRINT *,"init_dissip: itau_dissip",itau_dissip," dtdissip ",dtdissip
412    ENDIF
413   
414  END SUBROUTINE dissip_timescale
415
416  SUBROUTINE dissip(f_ps,f_mass,f_phis,f_geopot,f_theta_rhodz,f_ue, f_dtheta_rhodz,f_due)
417    TYPE(t_field),POINTER :: f_ps(:), f_mass(:), f_phis(:), f_geopot(:)
418    TYPE(t_field),POINTER :: f_theta_rhodz(:), f_dtheta_rhodz(:)
419    TYPE(t_field),POINTER :: f_ue(:), f_due(:)
420
421    REAL(rstd),POINTER         :: due(:,:)
422    REAL(rstd),POINTER         :: phi(:,:), ue(:,:)
423    REAL(rstd),POINTER         :: due_diss1(:,:)
424    REAL(rstd),POINTER         :: due_diss2(:,:)
425    REAL(rstd),POINTER         :: dtheta_rhodz(:,:,:)
426    REAL(rstd),POINTER         :: dtheta_rhodz_diss(:,:)
427
428    INTEGER :: ind, l,ij,nn
429
430!$OMP BARRIER
431   
432    CALL trace_start("dissip")
433    CALL gradiv(f_ue,f_due_diss1)
434    CALL gradrot(f_ue,f_due_diss2)
435    CALL divgrad_theta_rhodz(f_mass,f_theta_rhodz,f_dtheta_rhodz_diss)
436   
437    DO ind=1,ndomain
438      IF (.NOT. assigned_domain(ind)) CYCLE
439      CALL swap_dimensions(ind)
440      CALL swap_geometry(ind)
441      due=f_due(ind) 
442      due_diss1=f_due_diss1(ind)
443      due_diss2=f_due_diss2(ind)
444      dtheta_rhodz=f_dtheta_rhodz(ind)
445      dtheta_rhodz_diss=f_dtheta_rhodz_diss(ind)
446
447      DO l=ll_begin,ll_end
448!DIR$ SIMD
449        DO ij=ij_begin,ij_end
450            due(ij+u_right,l) = -0.5*( due_diss1(ij+u_right,l)/tau_graddiv(l) + due_diss2(ij+u_right,l)/tau_gradrot(l))*itau_dissip 
451            due(ij+u_lup,l)   = -0.5*( due_diss1(ij+u_lup,l)  /tau_graddiv(l) + due_diss2(ij+u_lup,l)  /tau_gradrot(l))*itau_dissip
452            due(ij+u_ldown,l) = -0.5*( due_diss1(ij+u_ldown,l)/tau_graddiv(l) + due_diss2(ij+u_ldown,l)/tau_gradrot(l))*itau_dissip
453            dtheta_rhodz(ij,l,1) = -0.5*dtheta_rhodz_diss(ij,l)/tau_divgrad(l)*itau_dissip
454        ENDDO
455      ENDDO
456     
457      IF(rayleigh_friction_type>0) THEN
458         IF(rayleigh_friction_type<99) THEN
459            phi=f_geopot(ind)
460            ue=f_ue(ind)
461            DO l=ll_begin,ll_end
462               DO ij=ij_begin,ij_end
463                  CALL relax(t_right, u_right)
464                  CALL relax(t_lup,   u_lup)
465                  CALL relax(t_ldown, u_ldown)
466               ENDDO
467            END DO
468         ELSE
469            ue=f_ue(ind)
470            DO ij=ij_begin,ij_end
471               nn = ij+u_right
472               IF (ABS(lat_e(nn)) .gt. rayleigh_limlat) THEN
473                  !print*, "latitude", lat_e(nn)*180./3.14159
474                  due(nn,ll_begin:ll_begin+1) = due(nn,ll_begin:ll_begin+1) - (ue(nn,ll_begin:ll_begin+1)/rayleigh_tau)
475               ENDIF
476               nn = ij+u_lup
477               IF (ABS(lat_e(nn)) .gt. rayleigh_limlat) THEN
478                  due(nn,ll_begin:ll_begin+1) = due(nn,ll_begin:ll_begin+1) - (ue(nn,ll_begin:ll_begin+1)/rayleigh_tau)
479               ENDIF
480               nn = ij+u_ldown
481               IF (ABS(lat_e(nn)) .gt. rayleigh_limlat) THEN
482                  due(nn,ll_begin:ll_begin+1) = due(nn,ll_begin:ll_begin+1) - (ue(nn,ll_begin:ll_begin+1)/rayleigh_tau)
483               ENDIF
484            ENDDO
485         ENDIF
486      END IF
487   END DO
488   
489   CALL trace_end("dissip")
490   
491   CALL write_dissip_tendencies
492!$OMP BARRIER
493
494 CONTAINS
495   
496   SUBROUTINE relax(shift_t, shift_u)
497     USE dcmip_initial_conditions_test_1_2_3
498     REAL(rstd) :: z, ulon,ulat, lon,lat, & ! input to test2_schaer_mountain
499          p,hyam,hybm,w,t,phis,ps,rho,q, &   ! unused input/output to test2_schaer_mountain
500          fz, u3d(3), uref
501     REAL(rstd), PARAMETER :: zh=2e4,ztop=3e4  ! DCMIP values
502     LOGICAL :: hybrid_eta
503     INTEGER :: shift_u, shift_t, zcoords, nn
504     z = (phi(ij,l)+phi(ij+shift_t,l))/(2.*g)
505     IF(z>zh) THEN  ! relax only in the sponge layer z>zh
506        nn = ij+shift_u
507        zcoords = 1 ; hybrid_eta = .FALSE. ! use z instead of p or hyam/hybm
508        CALL test2_schaer_mountain(lon_e(nn),lat_e(nn),p,z,zcoords,hybrid_eta, &
509             hyam,hybm,rayleigh_shear,ulon,ulat,w,t,phis,ps,rho,q)
510        u3d = ulon*elon_e(nn,:) ! ulat=0
511        uref = sum(u3d*ep_e(nn,:))
512       
513        fz = sin((pi/2)*(z-zh)/(ztop-zh))
514        fz = fz*fz/rayleigh_tau
515        due(nn,l) = due(nn,l) - itau_dissip*fz*(ue(nn,l)-uref)
516     END IF
517   END SUBROUTINE relax
518   
519   SUBROUTINE write_dissip_tendencies
520     USE observable_mod, ONLY : f_buf_ulon, f_buf_ulat
521     USE wind_mod
522     USE output_field_mod
523     
524     CALL transfert_request(f_due_diss1,req_e1_vect)
525     CALL un2ulonlat(f_due_diss1, f_buf_ulon, f_buf_ulat, (1./(tau_graddiv(1))))
526     CALL output_field("dulon_diss1",f_buf_ulon)
527     CALL output_field("dulat_diss1",f_buf_ulat)
528     !
529     CALL transfert_request(f_due_diss2,req_e1_vect)
530     CALL un2ulonlat(f_due_diss2, f_buf_ulon, f_buf_ulat, (1./(tau_graddiv(1))))
531     CALL output_field("dulon_diss2",f_buf_ulon)
532     CALL output_field("dulat_diss2",f_buf_ulat)
533   END SUBROUTINE write_dissip_tendencies
534   
535 END SUBROUTINE dissip
536
537 
538 SUBROUTINE gradiv(f_ue,f_due)
539   TYPE(t_field), POINTER :: f_ue(:)
540   TYPE(t_field), POINTER :: f_due(:)
541   REAL(rstd),POINTER :: ue(:,:)
542   REAL(rstd),POINTER :: due(:,:)
543   INTEGER :: ind
544   INTEGER :: it,l,ij
545   
546   CALL trace_start("gradiv")
547   
548   DO ind=1,ndomain
549      IF (.NOT. assigned_domain(ind)) CYCLE
550      CALL swap_dimensions(ind)
551      CALL swap_geometry(ind)
552      ue=f_ue(ind)
553      due=f_due(ind) 
554      DO  l = ll_begin, ll_end
555         !DIR$ SIMD
556         DO ij=ij_begin,ij_end
557            due(ij+u_right,l)=ue(ij+u_right,l)
558            due(ij+u_lup,l)=ue(ij+u_lup,l)
559            due(ij+u_ldown,l)=ue(ij+u_ldown,l)
560         ENDDO
561      ENDDO
562   ENDDO
563   
564   DO it=1,nitergdiv     
565      CALL send_message(f_due,req_due)
566      CALL wait_message(req_due)
567      DO ind=1,ndomain
568         IF (.NOT. assigned_domain(ind)) CYCLE
569         CALL swap_dimensions(ind)
570         CALL swap_geometry(ind)
571         due=f_due(ind) 
572         CALL compute_gradiv(due,due,ll_begin,ll_end)
573      ENDDO
574   ENDDO
575   
576   CALL trace_end("gradiv")
577 END SUBROUTINE gradiv
578 
579 
580 SUBROUTINE gradrot(f_ue,f_due)
581   TYPE(t_field), POINTER :: f_ue(:)
582    TYPE(t_field), POINTER :: f_due(:)
583    REAL(rstd),POINTER :: ue(:,:)
584    REAL(rstd),POINTER :: due(:,:)
585    INTEGER :: ind, it,l,ij
586    CALL trace_start("gradrot")
587
588    DO ind=1,ndomain
589      IF (.NOT. assigned_domain(ind)) CYCLE
590      CALL swap_dimensions(ind)
591      CALL swap_geometry(ind)
592      ue=f_ue(ind)
593      due=f_due(ind) 
594      DO  l = ll_begin, ll_end
595!DIR$ SIMD
596        DO ij=ij_begin,ij_end
597             due(ij+u_right,l)=ue(ij+u_right,l)
598             due(ij+u_lup,l)=ue(ij+u_lup,l)
599             due(ij+u_ldown,l)=ue(ij+u_ldown,l)
600        ENDDO
601      ENDDO
602    ENDDO
603
604    DO it=1,nitergrot
605       CALL send_message(f_due,req_due)
606       CALL wait_message(req_due)
607       DO ind=1,ndomain
608          IF (.NOT. assigned_domain(ind)) CYCLE
609          CALL swap_dimensions(ind)
610          CALL swap_geometry(ind)
611          due=f_due(ind) 
612          CALL compute_gradrot(due,due,ll_begin,ll_end)
613       ENDDO
614    ENDDO
615   
616    CALL trace_end("gradrot")
617  END SUBROUTINE gradrot
618 
619  SUBROUTINE divgrad(f_theta,f_dtheta)
620    TYPE(t_field), POINTER :: f_theta(:)
621    TYPE(t_field), POINTER :: f_dtheta(:)
622    REAL(rstd),POINTER :: theta(:,:)
623    REAL(rstd),POINTER :: dtheta(:,:)
624    INTEGER :: ind, it
625
626    CALL trace_start("divgrad")
627       
628    DO ind=1,ndomain
629      IF (.NOT. assigned_domain(ind)) CYCLE
630      CALL swap_dimensions(ind)
631      CALL swap_geometry(ind)
632      theta=f_theta(ind)
633      dtheta=f_dtheta(ind) 
634      dtheta=theta
635    ENDDO
636
637    DO it=1,niterdivgrad       
638      CALL transfert_request(f_dtheta,req_i1)       
639      DO ind=1,ndomain
640        IF (.NOT. assigned_domain(ind)) CYCLE
641        CALL swap_dimensions(ind)
642        CALL swap_geometry(ind)
643        dtheta=f_dtheta(ind) 
644        CALL compute_divgrad(dtheta,dtheta,ll_begin,ll_end)
645      ENDDO
646    ENDDO
647
648    CALL trace_end("divgrad")
649  END SUBROUTINE divgrad
650   
651  SUBROUTINE divgrad_theta_rhodz(f_mass,f_theta_rhodz,f_dtheta_rhodz)
652    TYPE(t_field), POINTER :: f_mass(:)
653    TYPE(t_field), POINTER :: f_theta_rhodz(:)
654    TYPE(t_field), POINTER :: f_dtheta_rhodz(:)
655   
656    REAL(rstd),POINTER :: mass(:,:)
657    REAL(rstd),POINTER :: theta_rhodz(:,:,:)
658    REAL(rstd),POINTER :: dtheta_rhodz(:,:)
659
660    INTEGER :: ind
661    INTEGER :: it,l,ij
662
663    CALL trace_start("divgrad")
664
665    DO ind=1,ndomain
666      IF (.NOT. assigned_domain(ind)) CYCLE
667      CALL swap_dimensions(ind)
668      CALL swap_geometry(ind)
669      mass=f_mass(ind)
670      theta_rhodz=f_theta_rhodz(ind)
671      dtheta_rhodz=f_dtheta_rhodz(ind) 
672      DO  l = ll_begin, ll_end
673!DIR$ SIMD
674        DO ij=ij_begin,ij_end
675            dtheta_rhodz(ij,l) = theta_rhodz(ij,l,1) / mass(ij,l)
676        ENDDO
677      ENDDO
678    ENDDO
679
680    DO it=1,niterdivgrad
681       
682      CALL send_message(f_dtheta_rhodz,req_dtheta)
683      CALL wait_message(req_dtheta)
684      DO ind=1,ndomain
685        IF (.NOT. assigned_domain(ind)) CYCLE
686        CALL swap_dimensions(ind)
687        CALL swap_geometry(ind)
688        dtheta_rhodz=f_dtheta_rhodz(ind) 
689        CALL compute_divgrad(dtheta_rhodz,dtheta_rhodz,ll_begin,ll_end)
690      ENDDO
691
692    ENDDO
693
694    DO ind=1,ndomain
695      IF (.NOT. assigned_domain(ind)) CYCLE
696      CALL swap_dimensions(ind)
697      CALL swap_geometry(ind)
698      dtheta_rhodz=f_dtheta_rhodz(ind) 
699      mass=f_mass(ind)
700   
701      DO  l = ll_begin, ll_end
702!DIR$ SIMD
703        DO ij=ij_begin,ij_end
704            dtheta_rhodz(ij,l) = dtheta_rhodz(ij,l) * mass(ij,l)
705        ENDDO
706      ENDDO
707    ENDDO
708
709    CALL trace_end("divgrad")
710  END SUBROUTINE divgrad_theta_rhodz 
711 
712  SUBROUTINE compute_gradiv(ue,gradivu_e,llb,lle)
713    INTEGER,INTENT(IN)     :: llb
714    INTEGER,INTENT(IN)     :: lle
715    REAL(rstd),INTENT(IN)  :: ue(iim*3*jjm,llm)
716    REAL(rstd),INTENT(OUT) :: gradivu_e(iim*3*jjm,llm)
717    REAL(rstd) :: divu_i(iim*jjm,llb:lle)
718   
719    INTEGER :: ij,l
720
721    DO l=llb,lle
722!DIR$ SIMD
723      DO ij=ij_begin,ij_end
724          divu_i(ij,l)=1./Ai(ij)*(ne(ij,right)*ue(ij+u_right,l)*le(ij+u_right)  +  &
725                             ne(ij,rup)*ue(ij+u_rup,l)*le(ij+u_rup)        +  & 
726                             ne(ij,lup)*ue(ij+u_lup,l)*le(ij+u_lup)        +  & 
727                             ne(ij,left)*ue(ij+u_left,l)*le(ij+u_left)     +  & 
728                             ne(ij,ldown)*ue(ij+u_ldown,l)*le(ij+u_ldown)  +  & 
729                             ne(ij,rdown)*ue(ij+u_rdown,l)*le(ij+u_rdown))
730      ENDDO
731    ENDDO
732   
733    DO l=llb,lle
734!DIR$ SIMD
735      DO ij=ij_begin,ij_end 
736          gradivu_e(ij+u_right,l)=-1/de(ij+u_right)*(ne(ij,right)*divu_i(ij,l)+ ne(ij+t_right,left)*divu_i(ij+t_right,l) )       
737          gradivu_e(ij+u_lup,l)=-1/de(ij+u_lup)*(ne(ij,lup)*divu_i(ij,l)+ ne(ij+t_lup,rdown)*divu_i(ij+t_lup,l))   
738          gradivu_e(ij+u_ldown,l)=-1/de(ij+u_ldown)*(ne(ij,ldown)*divu_i(ij,l)+ne(ij+t_ldown,rup)*divu_i(ij+t_ldown,l) )
739      ENDDO
740    ENDDO
741
742    DO l=llb,lle
743!DIR$ SIMD
744      DO ij=ij_begin,ij_end
745          gradivu_e(ij+u_right,l)=-gradivu_e(ij+u_right,l)*cgraddiv
746          gradivu_e(ij+u_lup,l)=-gradivu_e(ij+u_lup,l)*cgraddiv
747          gradivu_e(ij+u_ldown,l)=-gradivu_e(ij+u_ldown,l)*cgraddiv
748      ENDDO
749    ENDDO
750
751   
752  END SUBROUTINE compute_gradiv
753 
754  SUBROUTINE compute_divgrad(theta,divgrad_i,llb,lle)
755    INTEGER,INTENT(IN)     :: llb
756    INTEGER,INTENT(IN)     :: lle
757    REAL(rstd),INTENT(IN)  :: theta(iim*jjm,llm)
758    REAL(rstd),INTENT(OUT) :: divgrad_i(iim*jjm,llm)
759    REAL(rstd)  :: grad_e(3*iim*jjm,llb:lle)
760    INTEGER :: ij,l       
761    DO l=llb,lle
762!DIR$ SIMD
763      DO ij=ij_begin_ext,ij_end_ext
764          grad_e(ij+u_right,l)=-1/de(ij+u_right)*(ne(ij,right)*theta(ij,l)+ ne(ij+t_right,left)*theta(ij+t_right,l) )
765          grad_e(ij+u_lup,l)=-1/de(ij+u_lup)*(ne(ij,lup)*theta(ij,l)+ ne(ij+t_lup,rdown)*theta(ij+t_lup,l ))
766          grad_e(ij+u_ldown,l)=-1/de(ij+u_ldown)*(ne(ij,ldown)*theta(ij,l)+ne(ij+t_ldown,rup)*theta(ij+t_ldown,l) )
767      ENDDO
768    ENDDO   
769   
770    DO l=llb,lle
771!DIR$ SIMD
772      DO ij=ij_begin,ij_end
773          divgrad_i(ij,l)=1./Ai(ij)*(ne(ij,right)*grad_e(ij+u_right,l)*le(ij+u_right)  +  &
774                             ne(ij,rup)*grad_e(ij+u_rup,l)*le(ij+u_rup)              +  & 
775                             ne(ij,lup)*grad_e(ij+u_lup,l)*le(ij+u_lup)              +  & 
776                             ne(ij,left)*grad_e(ij+u_left,l)*le(ij+u_left)           +  & 
777                             ne(ij,ldown)*grad_e(ij+u_ldown,l)*le(ij+u_ldown)        +  & 
778                             ne(ij,rdown)*grad_e(ij+u_rdown,l)*le(ij+u_rdown))
779      ENDDO
780    ENDDO
781   
782    DO l=llb,lle
783      DO ij=ij_begin,ij_end
784          divgrad_i(ij,l)=-divgrad_i(ij,l)*cdivgrad
785      ENDDO
786    ENDDO
787
788  END SUBROUTINE compute_divgrad
789   
790  SUBROUTINE compute_gradrot(ue,gradrot_e,llb,lle)
791    INTEGER,INTENT(IN)     :: llb
792    INTEGER,INTENT(IN)     :: lle
793    REAL(rstd),INTENT(IN)  :: ue(iim*3*jjm,llm)
794    REAL(rstd),INTENT(OUT) :: gradrot_e(iim*3*jjm,llm)
795    REAL(rstd) :: rot_v(2*iim*jjm,llb:lle)
796
797    INTEGER :: ij,l
798     
799    DO l=llb,lle
800!DIR$ SIMD
801      DO ij=ij_begin_ext,ij_end_ext
802       
803          rot_v(ij+z_up,l)= 1./Av(ij+z_up)*(  ne(ij,rup)*ue(ij+u_rup,l)*de(ij+u_rup)                     &
804                                + ne(ij+t_rup,left)*ue(ij+t_rup+u_left,l)*de(ij+t_rup+u_left)          &
805                                - ne(ij,lup)*ue(ij+u_lup,l)*de(ij+u_lup) ) 
806                             
807          rot_v(ij+z_down,l) = 1./Av(ij+z_down)*( ne(ij,ldown)*ue(ij+u_ldown,l)*de(ij+u_ldown)                 &
808                                     + ne(ij+t_ldown,right)*ue(ij+t_ldown+u_right,l)*de(ij+t_ldown+u_right)  &
809                                     - ne(ij,rdown)*ue(ij+u_rdown,l)*de(ij+u_rdown) )
810 
811      ENDDO
812    ENDDO                             
813 
814    DO l=llb,lle
815!DIR$ SIMD
816      DO ij=ij_begin,ij_end
817          gradrot_e(ij+u_right,l)=1/le(ij+u_right)*ne(ij,right)*(rot_v(ij+z_rdown,l)-rot_v(ij+z_rup,l))         
818          gradrot_e(ij+u_lup,l)  =1/le(ij+u_lup)  *ne(ij,lup)  *(rot_v(ij+z_up,l)   -rot_v(ij+z_lup,l))
819          gradrot_e(ij+u_ldown,l)=1/le(ij+u_ldown)*ne(ij,ldown)*(rot_v(ij+z_ldown,l)-rot_v(ij+z_down,l))       
820      ENDDO
821    ENDDO
822
823    DO l=llb,lle
824!DIR$ SIMD
825      DO ij=ij_begin,ij_end   
826          gradrot_e(ij+u_right,l)=-gradrot_e(ij+u_right,l)*cgradrot       
827          gradrot_e(ij+u_lup,l)=-gradrot_e(ij+u_lup,l)*cgradrot
828          gradrot_e(ij+u_ldown,l)=-gradrot_e(ij+u_ldown,l)*cgradrot
829      ENDDO
830    ENDDO 
831   
832  END SUBROUTINE compute_gradrot
833
834!----------------------- Utility routines ------------------
835
836  SUBROUTINE global_max(dumax)
837    USE mpi_mod
838    USE mpipara
839    REAL(rstd) :: dumax, dumax1
840    IF (using_mpi) THEN
841       CALL reduce_max_omp(dumax,dumax1)
842       !$OMP MASTER       
843       CALL MPI_ALLREDUCE(dumax1,dumax,1,MPI_REAL8,MPI_MAX,comm_icosa,ierr)
844       !$OMP END MASTER     
845       CALL bcast_omp(dumax) 
846    ELSE
847       CALL allreduce_max_omp(dumax,dumax1)
848       dumax=dumax1
849    ENDIF
850  END SUBROUTINE global_max   
851
852  FUNCTION max_vel(f_du)
853    TYPE(t_field)       :: f_du(:)
854    REAL(rstd),POINTER  :: du(:)
855    INTEGER :: ind, i,j,ij
856    REAL(rstd) :: max_vel, dumax
857
858    dumax=0.
859    DO ind=1,ndomain
860       IF (.NOT. assigned_domain(ind) .OR. .NOT. is_omp_level_master) CYCLE
861       CALL swap_dimensions(ind)
862       CALL swap_geometry(ind)
863       du=f_du(ind)
864       
865       DO j=jj_begin,jj_end
866          DO i=ii_begin,ii_end
867             ij=(j-1)*iim+i   
868             if (le(ij+u_right)>1e-100) dumax=MAX(dumax,ABS(du(ij+u_right)))
869             if (le(ij+u_lup)>1e-100) dumax=MAX(dumax,ABS(du(ij+u_lup)))
870             if (le(ij+u_ldown)>1e-100) dumax=MAX(dumax,ABS(du(ij+u_ldown)))
871          ENDDO
872       ENDDO
873    ENDDO
874    CALL global_max(dumax)
875    max_vel=dumax
876  END FUNCTION max_vel
877
878  FUNCTION max_scalar(f_dtheta)
879    TYPE(t_field)       :: f_dtheta(:)
880    REAL(rstd),POINTER  :: dtheta(:)
881    INTEGER :: ind, i,j,ij
882    REAL(rstd) :: max_scalar, dthetamax
883    DO ind=1,ndomain
884       IF (.NOT. assigned_domain(ind) .OR. .NOT. is_omp_level_master) CYCLE
885       CALL swap_dimensions(ind)
886       dtheta=f_dtheta(ind)
887       DO j=jj_begin,jj_end
888          DO i=ii_begin,ii_end
889             ij=(j-1)*iim+i
890             dthetamax=MAX(dthetamax,ABS(dtheta(ij)))
891          ENDDO
892       ENDDO
893    ENDDO
894    CALL global_max(dthetamax)
895    max_scalar=dthetamax
896  END FUNCTION max_scalar
897
898  SUBROUTINE random_vel(f_u)
899    TYPE(t_field)      :: f_u(:)
900    REAL(rstd),POINTER :: u(:)
901    INTEGER :: M, ind, i,j,ij
902    REAL(rstd) :: r
903
904    !$OMP BARRIER
905    !$OMP MASTER
906    DO ind=1,ndomain
907       CALL swap_dimensions(ind)
908       CALL swap_geometry(ind)
909       u=f_u(ind)
910       
911       ! set random seed to get reproductibility when using a different number of process
912       CALL RANDOM_SEED(size=M)
913       CALL RANDOM_SEED(put=(/(i,i=1,M)/))
914       
915       DO j=jj_begin,jj_end
916          DO i=ii_begin,ii_end
917             ij=(j-1)*iim+i   
918             CALL RANDOM_NUMBER(r)
919             u(ij+u_right)=r-0.5
920             CALL RANDOM_NUMBER(r)
921             u(ij+u_lup)=r-0.5
922             CALL RANDOM_NUMBER(r)
923             u(ij+u_ldown)=r-0.5
924          ENDDO
925       ENDDO
926    ENDDO
927    !$OMP END MASTER 
928    !$OMP BARRIER
929   
930  END SUBROUTINE random_vel
931 
932  SUBROUTINE random_scalar(f_theta)
933    TYPE(t_field)      :: f_theta(:)
934    REAL(rstd),POINTER :: theta(:)
935    INTEGER :: M, ind, i,j,ij
936    REAL(rstd) :: r
937    !$OMP BARRIER
938    !$OMP MASTER
939    DO ind=1,ndomain
940       CALL swap_dimensions(ind)
941       CALL swap_geometry(ind)
942       theta=f_theta(ind)
943       ! set random seed to get reproductibility when using a different number of process
944       CALL RANDOM_SEED(size=M)
945       CALL RANDOM_SEED(put=(/(i,i=1,M)/))
946       
947       DO j=jj_begin,jj_end
948          DO i=ii_begin,ii_end
949             ij=(j-1)*iim+i   
950             CALL RANDOM_NUMBER(r)
951             theta(ij)=r-0.5
952          ENDDO
953       ENDDO
954    ENDDO
955    !$OMP END MASTER
956    !$OMP BARRIER
957  END SUBROUTINE random_scalar
958 
959  SUBROUTINE rescale_field(scal, f_du, f_u)
960    TYPE(t_field)      :: f_du(:), f_u(:)
961    REAL(rstd),POINTER :: du(:), u(:)
962    REAL(rstd) :: scal
963    INTEGER :: ind
964    DO ind=1,ndomain
965       IF (.NOT. assigned_domain(ind) .OR. .NOT. is_omp_level_master) CYCLE
966       CALL swap_dimensions(ind)
967       u=f_u(ind)
968       du=f_du(ind)
969       u=scal*du
970    ENDDO
971  END SUBROUTINE rescale_field
972
973END MODULE dissip_gcm_mod
Note: See TracBrowser for help on using the repository browser.