source: codes/icosagcm/devel/src/time/timeloop_gcm.f90 @ 906

Last change on this file since 906 was 906, checked in by dubos, 5 years ago

devel : compute_rhodz for unstructured mesh
File size: 15.8 KB
Line 
1MODULE timeloop_gcm_mod
2  USE profiling_mod
3  USE icosa
4  USE disvert_mod
5  USE trace
6  USE omp_para
7  USE compute_diagnostics_mod, ONLY : compute_rhodz
8  USE euler_scheme_mod
9  USE explicit_scheme_mod
10  USE hevi_scheme_mod
11  USE caldyn_vars_mod
12  IMPLICIT NONE
13  PRIVATE
14 
15  INTEGER, PARAMETER :: itau_sync=10
16  TYPE(t_message),SAVE :: req_ps0, req_mass0, req_theta_rhodz0, req_u0, req_q0, req_W0, req_geopot0
17  LOGICAL, SAVE :: positive_theta
18  INTEGER :: itau_prof, id_timeloop, id_dyn, id_phys, id_dissip, id_adv, id_diags
19  PUBLIC :: init_timeloop, timeloop
20
21CONTAINS
22 
23  SUBROUTINE init_timeloop
24    USE dissip_gcm_mod
25    USE observable_mod
26    USE caldyn_mod
27    USE etat0_mod
28    USE guided_mod
29    USE advect_tracer_mod
30    USE check_conserve_mod
31    USE output_field_mod
32    USE theta2theta_rhodz_mod
33    USE sponge_mod
34
35    CHARACTER(len=255) :: def
36
37    CALL register_id('timeloop',id_timeloop)
38    CALL register_id('dyn',id_dyn)
39    CALL register_id('dissip',id_dissip)
40    CALL register_id('phys',id_phys)
41    CALL register_id('adv',id_adv)
42    CALL register_id('diags',id_diags)
43
44    CALL init_caldyn
45   
46!    IF (xios_output) itau_out=1
47    IF (.NOT. enable_io) itau_out=HUGE(itau_out)
48
49    itau_prof=100
50    CALL getin('itau_profiling',itau_prof)
51
52    positive_theta=.FALSE.
53    CALL getin('positive_theta',positive_theta)
54    IF(positive_theta .AND. nqtot<1) THEN
55       PRINT *, 'nqtot must be >0 if positive_theta is .TRUE.'
56       STOP
57    END IF
58
59    def='ARK2.3'
60    CALL getin('time_scheme',def)
61    SELECT CASE (TRIM(def))
62    CASE('euler')
63       scheme_family=explicit
64       scheme=euler
65       nb_stage=1
66    CASE ('runge_kutta')
67       scheme_family=explicit
68       scheme=rk4
69       nb_stage=4
70    CASE ('RK2.5')
71       scheme_family=explicit
72       scheme=rk25
73       nb_stage=5
74    CASE ('leapfrog_matsuno')
75       scheme_family=explicit
76       scheme=mlf
77       matsuno_period=5
78       CALL getin('matsuno_period',matsuno_period)
79       nb_stage=matsuno_period+1
80    CASE('ARK2.3')
81       scheme_family=hevi
82       scheme=ark23
83       nb_stage=3
84       CALL set_coefs_ark23(dt)
85    CASE('ARK3.3')
86       scheme_family=hevi
87       scheme=ark33
88       nb_stage=3
89       CALL set_coefs_ark33(dt)
90    CASE ('none')
91       nb_stage=0
92    CASE default
93       PRINT*,'Bad selector for variable scheme : <', TRIM(def),             &
94            ' > options are <euler>, <runge_kutta>, <leapfrog_matsuno>,<RK2.5>,<ARK2.3>'
95       STOP
96    END SELECT
97   
98    ! Time-independant orography
99    CALL allocate_field(f_phis,field_t,type_real,name='phis')
100    ! Model state at current time step
101    CALL allocate_field(f_ps,field_t,type_real, name='ps')
102    CALL allocate_field(f_mass,field_t,type_real,llm,name='mass')
103    CALL allocate_field(f_rhodz,field_t,type_real,llm,name='rhodz')
104    CALL allocate_field(f_theta_rhodz,field_t,type_real,llm,nqdyn,name='theta_rhodz')
105    CALL allocate_field(f_u,field_u,type_real,llm,name='u')
106    CALL allocate_field(f_geopot,field_t,type_real,llm+1,name='geopot')
107    CALL allocate_field(f_W,field_t,type_real,llm+1,name='W')
108    CALL allocate_field(f_q,field_t,type_real,llm,nqtot,'q')
109    ! Mass fluxes
110    CALL allocate_field(f_hflux,field_u,type_real,llm)    ! instantaneous mass fluxes
111    CALL allocate_field(f_hfluxt,field_u,type_real,llm)   ! mass "fluxes" accumulated in time
112    CALL allocate_field(f_wflux,field_t,type_real,llm+1)  ! vertical mass fluxes
113    CALL allocate_field(f_wfluxt,field_t,type_real,llm+1,name='wfluxt')
114   
115    SELECT CASE(scheme_family)
116    CASE(explicit)
117       ! Trends
118       CALL allocate_field(f_dps,field_t,type_real,name='dps')
119       CALL allocate_field(f_dmass,field_t,type_real,llm, name='dmass')
120       CALL allocate_field(f_dtheta_rhodz,field_t,type_real,llm,nqdyn,name='dtheta_rhodz')
121       CALL allocate_field(f_du,field_u,type_real,llm,name='du')
122       ! Model state at previous time step (RK/MLF)
123       CALL allocate_field(f_psm1,field_t,type_real,name='psm1')
124       CALL allocate_field(f_massm1,field_t,type_real,llm, name='massm1')
125       CALL allocate_field(f_theta_rhodzm1,field_t,type_real,llm,nqdyn,name='theta_rhodzm1')
126       CALL allocate_field(f_um1,field_u,type_real,llm,name='um1')
127    CASE(hevi)
128       ! Trends
129       CALL allocate_fields(nb_stage,f_dps_slow, field_t,type_real,name='dps_slow')
130       CALL allocate_fields(nb_stage,f_dmass_slow, field_t,type_real,llm, name='dmass_slow')
131       CALL allocate_fields(nb_stage,f_dtheta_rhodz_slow, field_t,type_real,llm,nqdyn,name='dtheta_rhodz_fast')
132       CALL allocate_fields(nb_stage,f_du_slow, field_u,type_real,llm,name='du_slow')
133       CALL allocate_fields(nb_stage,f_du_fast, field_u,type_real,llm,name='du_fast')
134       CALL allocate_fields(nb_stage,f_dW_slow, field_t,type_real,llm+1,name='dW_slow')
135       CALL allocate_fields(nb_stage,f_dW_fast, field_t,type_real,llm+1,name='dW_fast')
136       CALL allocate_fields(nb_stage,f_dPhi_slow, field_t,type_real,llm+1,name='dPhi_slow')
137       CALL allocate_fields(nb_stage,f_dPhi_fast, field_t,type_real,llm+1,name='dPhi_fast')
138       f_dps => f_dps_slow(:,1)
139       f_du => f_du_slow(:,1)
140       f_dtheta_rhodz => f_dtheta_rhodz_slow(:,1)
141    END SELECT
142
143    SELECT CASE(scheme)
144    CASE(mlf)
145       ! Model state 2 time steps ago (MLF)
146       CALL allocate_field(f_psm2,field_t,type_real)
147       CALL allocate_field(f_massm2,field_t,type_real,llm)
148       CALL allocate_field(f_theta_rhodzm2,field_t,type_real,llm,nqdyn)
149       CALL allocate_field(f_um2,field_u,type_real,llm)
150    END SELECT
151
152    CALL init_theta2theta_rhodz
153    CALL init_dissip
154    CALL init_sponge
155    CALL init_observable
156    CALL init_advect_tracer
157    CALL init_check_conserve
158
159    CALL etat0(f_ps,f_mass,f_phis,f_theta_rhodz,f_u, f_geopot,f_W, f_q)
160   
161    CALL init_guided(f_u,f_theta_rhodz)
162
163    CALL transfert_request(f_phis,req_i0) 
164    CALL transfert_request(f_phis,req_i1) 
165
166    CALL init_message(f_ps,req_i0,req_ps0)
167    CALL init_message(f_mass,req_i0,req_mass0)
168    CALL init_message(f_theta_rhodz,req_i0,req_theta_rhodz0)
169    CALL init_message(f_u,req_e0_vect,req_u0)
170    CALL init_message(f_q,req_i0,req_q0)
171    CALL init_message(f_geopot,req_i0,req_geopot0)
172    CALL init_message(f_W,req_i0,req_W0)
173
174  END SUBROUTINE init_timeloop
175 
176  SUBROUTINE timeloop
177    USE dissip_gcm_mod
178    USE sponge_mod
179    USE observable_mod
180    USE etat0_mod
181    USE guided_mod
182    USE caldyn_mod
183    USE advect_tracer_mod
184    USE diagflux_mod
185    USE physics_mod
186    USE mpipara
187    USE transfert_mod
188    USE check_conserve_mod
189    USE xios_mod
190    USE output_field_mod
191    USE write_etat0_mod
192    USE restart_mod
193    USE checksum_mod
194    USE explicit_scheme_mod
195    USE hevi_scheme_mod
196    REAL(rstd),POINTER :: rhodz(:,:), mass(:,:), ps(:)
197
198    REAL(rstd) :: adv_over_out ! ratio itau_adv/itau_out
199    INTEGER :: ind, it,i,j,l,n,  stage
200    LOGICAL :: fluxt_zero(ndomain) ! set to .TRUE. to start accumulating mass fluxes in time
201    LOGICAL, PARAMETER :: check_rhodz=.FALSE.
202    INTEGER :: start_clock, stop_clock, rate_clock
203    LOGICAL,SAVE :: first_physic=.TRUE.
204    !$OMP THREADPRIVATE(first_physic)   
205
206    CALL switch_omp_distrib_level
207    CALL caldyn_BC(f_phis, f_geopot, f_wflux) ! set constant values in first/last interfaces
208
209    !$OMP BARRIER
210    DO ind=1,ndomain
211       IF (.NOT. assigned_domain(ind)) CYCLE
212       CALL swap_dimensions(ind)
213       CALL swap_geometry(ind)
214       rhodz=f_rhodz(ind); mass=f_mass(ind); ps=f_ps(ind)
215       IF(caldyn_eta==eta_mass) THEN
216          CALL compute_rhodz(.TRUE., ps, rhodz) ! save rhodz for transport scheme before dynamics update ps
217       ELSE
218          DO l=ll_begin,ll_end
219             rhodz(:,l)=mass(:,l)
220          ENDDO
221       END IF
222    END DO
223    !$OMP BARRIER
224    fluxt_zero=.TRUE.
225
226    IF(positive_theta) CALL copy_theta_to_q(f_theta_rhodz,f_rhodz,f_q)
227    IF(diagflux_on) THEN
228       adv_over_out = itau_adv*(1./itau_out)
229    ELSE
230       adv_over_out = 0.
231    END IF
232
233    CALL check_conserve(f_ps,f_dps,f_u,f_theta_rhodz,f_phis,itau0) 
234
235    Call trace_on
236
237    IF (xios_output) THEN ! we must call update_calendar before any XIOS output
238      IF (is_omp_master) CALL xios_update_calendar(1)
239    END IF
240   
241!    IF (write_start) CALL write_etat0(itau0,f_ps, f_phis,f_theta_rhodz,f_u,f_q)
242    IF (write_start) CALL write_etat0(itau0,f_ps, f_phis,f_theta_rhodz,f_u,f_q, f_geopot, f_W)
243   
244    CALL write_output_fields_basic(.TRUE., f_phis, f_ps, f_mass, f_geopot, f_theta_rhodz, f_u, f_W, f_q)
245
246    !$OMP MASTER
247    CALL SYSTEM_CLOCK(start_clock, rate_clock)
248    !$OMP END MASTER   
249
250    IF(grid_type == grid_unst) RETURN
251
252    DO it=itau0+1,itau0+itaumax
253       IF (is_master) CALL print_iteration(it, itau0, itaumax, start_clock, rate_clock)
254
255       CALL enter_profile(id_timeloop)
256
257       IF (xios_output) THEN
258
259          IF(it>itau0+1 .AND. is_omp_master) CALL xios_update_calendar(it-itau0)
260       ELSE
261          CALL update_time_counter(dt*it)
262       END IF
263
264       IF (it==itau0+1 .OR. MOD(it,itau_sync)==0) THEN
265          CALL send_message(f_ps,req_ps0)
266          CALL wait_message(req_ps0)
267          CALL send_message(f_mass,req_mass0)
268          CALL wait_message(req_mass0)
269          CALL send_message(f_theta_rhodz,req_theta_rhodz0) 
270          CALL wait_message(req_theta_rhodz0) 
271          CALL send_message(f_u,req_u0)
272          CALL wait_message(req_u0)
273          CALL send_message(f_q,req_q0) 
274          CALL wait_message(req_q0)
275          IF(.NOT. hydrostatic) THEN
276             CALL send_message(f_geopot,req_geopot0)
277             CALL wait_message(req_geopot0)
278             CALL send_message(f_W,req_W0)
279             CALL wait_message(req_W0)
280          END IF
281       ENDIF
282
283       CALL guided(it*dt,f_ps,f_theta_rhodz,f_u,f_q)
284
285       CALL enter_profile(id_dyn)
286       SELECT CASE(scheme_family)
287       CASE(explicit)
288          CALL explicit_scheme(it, fluxt_zero)
289       CASE(hevi)
290          CALL HEVI_scheme(it, fluxt_zero)
291       END SELECT
292       CALL exit_profile(id_dyn)
293
294       CALL enter_profile(id_dissip)
295       IF (MOD(it,itau_dissip)==0) THEN
296         
297          IF(caldyn_eta==eta_mass) THEN
298             !ym flush ps
299             !$OMP BARRIER
300             DO ind=1,ndomain
301                IF (.NOT. assigned_domain(ind)) CYCLE
302                CALL swap_dimensions(ind)
303                CALL swap_geometry(ind)
304                mass=f_mass(ind); ps=f_ps(ind);
305                CALL compute_rhodz(.TRUE., ps, mass)
306             END DO
307          ENDIF
308         
309          CALL enter_profile(id_diags)
310          CALL check_conserve_detailed(it, AAM_dyn, &
311               f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
312          CALL exit_profile(id_diags)
313       
314          CALL dissip(f_ps,f_mass,f_phis,f_geopot,f_theta_rhodz,f_u, f_dtheta_rhodz,f_du)
315         
316          CALL euler_scheme(.FALSE.)  ! update only u, theta
317          IF (iflag_sponge > 0) THEN
318             CALL sponge(f_u,f_du,f_theta_rhodz,f_dtheta_rhodz)
319             CALL euler_scheme(.FALSE.)  ! update only u, theta
320          END IF
321
322          CALL enter_profile(id_diags)
323          CALL check_conserve_detailed(it, AAM_dissip, &
324               f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
325          CALL exit_profile(id_diags)
326       END IF
327       CALL exit_profile(id_dissip)
328       
329       CALL enter_profile(id_adv)
330       IF(MOD(it,itau_adv)==0) THEN
331          CALL advect_tracer(f_hfluxt,f_wfluxt,f_u, f_q,f_rhodz, & ! update q and rhodz after RK step
332               adv_over_out, f_masst,f_qmasst,f_massfluxt, f_qfluxt)  ! accumulate mass and fluxes if diagflux_on
333          fluxt_zero=.TRUE. ! restart accumulation of hfluxt and qfluxt at next call to explicit_scheme / HEVI_scheme
334          ! At this point advect_tracer has obtained the halos of u and rhodz,
335          ! needed for correct computation of kinetic energy
336          IF(diagflux_on) CALL diagflux_energy(adv_over_out, f_phis,f_rhodz,f_theta_rhodz,f_u, f_geopot,f_theta,f_buf_i, f_hfluxt)
337
338          IF (check_rhodz) THEN ! check that rhodz is consistent with ps
339             DO ind=1,ndomain
340                IF (.NOT. assigned_domain(ind)) CYCLE
341                CALL swap_dimensions(ind)
342                CALL swap_geometry(ind)
343                rhodz=f_rhodz(ind); ps=f_ps(ind);
344                CALL compute_rhodz(.FALSE., ps, rhodz)   
345             END DO
346          ENDIF
347          IF(positive_theta) CALL copy_q_to_theta(f_theta_rhodz,f_rhodz,f_q)
348       END IF
349       CALL exit_profile(id_adv)
350       
351       CALL enter_profile(id_diags)
352       IF (MOD(it,itau_physics)==0) THEN
353          CALL check_conserve_detailed(it, AAM_dyn, &
354            f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
355          CALL enter_profile(id_phys)
356          CALL physics(it, f_phis, f_geopot, f_ps, f_theta_rhodz, f_u, f_wflux, f_q)
357          CALL exit_profile(id_phys)
358          CALL check_conserve_detailed(it, AAM_phys, &
359               f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
360          !$OMP MASTER
361          IF (first_physic) CALL SYSTEM_CLOCK(start_clock)
362          !$OMP END MASTER   
363          first_physic=.FALSE.
364       END IF
365
366       IF (MOD(it,itau_check_conserv)==0) THEN
367          CALL check_conserve_detailed(it, AAM_dyn, &
368               f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
369          CALL check_conserve(f_ps,f_dps,f_u,f_theta_rhodz,f_phis,it) 
370       ENDIF
371
372       IF (mod(it,itau_out)==0 ) THEN
373          CALL transfert_request(f_u,req_e1_vect)
374          CALL write_output_fields_basic(.FALSE.,f_phis, f_ps, f_mass, f_geopot, f_theta_rhodz, f_u, f_W, f_q)
375       ENDIF
376       CALL exit_profile(id_diags)
377
378       CALL exit_profile(id_timeloop)
379    END DO
380   
381!    CALL write_etat0(itau0+itaumax,f_ps, f_phis,f_theta_rhodz,f_u,f_q)
382    CALL write_etat0(itau0+itaumax,f_ps, f_phis,f_theta_rhodz,f_u,f_q, f_geopot, f_W) 
383   
384    CALL check_conserve_detailed(it, AAM_dyn, &
385         f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
386    CALL check_conserve(f_ps,f_dps,f_u,f_theta_rhodz,f_phis,it) 
387   
388    !$OMP MASTER
389    CALL SYSTEM_CLOCK(stop_clock)
390   
391    IF (mpi_rank==0) THEN
392       PRINT *,"Time elapsed : ",(stop_clock-start_clock)*1./rate_clock 
393    ENDIF
394    !$OMP END MASTER
395   
396    ! CONTAINS
397  END SUBROUTINE timeloop
398
399  SUBROUTINE print_iteration(it,itau0,itaumax,start_clock,rate_clock)
400    INTEGER :: it, itau0, itaumax, start_clock, stop_clock, rate_clock, throughput
401    REAL :: per_step,total, elapsed
402    WRITE(*,'(A,I7,A,F14.1)') "It No :",it,"   t :",dt*it
403    IF(MOD(it,10)==0) THEN
404       CALL SYSTEM_CLOCK(stop_clock)
405       elapsed = (stop_clock-start_clock)*1./rate_clock
406       per_step = elapsed/(it-itau0)
407       throughput = dt/per_step
408       total = per_step*itaumax
409       WRITE(*,'(A,I5,A,F6.2,A,I6)') 'Time spent (s):',INT(elapsed), &
410            '  -- ms/step : ', 1000*per_step, &
411            '  -- Throughput :', throughput
412       WRITE(*,'(A,I5,A,I5)') 'Whole job (min) :', INT(total/60.), &
413            '  -- Completion in (min) : ', INT((total-elapsed)/60.)
414    END IF
415    IF(MOD(it,itau_prof)==0) CALL print_profile
416
417  END SUBROUTINE print_iteration
418
419  SUBROUTINE copy_theta_to_q(f_theta_rhodz,f_rhodz,f_q)
420    TYPE(t_field),POINTER :: f_theta_rhodz(:),f_rhodz(:), f_q(:)
421    REAL(rstd), POINTER :: theta_rhodz(:,:,:), rhodz(:,:), q(:,:,:)
422    INTEGER :: ind, iq
423    DO ind=1, ndomain
424       IF (.NOT. assigned_domain(ind)) CYCLE
425       CALL swap_dimensions(ind)
426       CALL swap_geometry(ind)
427       theta_rhodz=f_theta_rhodz(ind)
428       rhodz=f_rhodz(ind)
429       q=f_q(ind)
430       DO iq=1, nqdyn
431          q(:,:,iq)  = theta_rhodz(:,:,iq)/rhodz(:,:)
432       END DO
433    END DO
434  END SUBROUTINE copy_theta_to_q
435
436  SUBROUTINE copy_q_to_theta(f_theta_rhodz,f_rhodz,f_q)
437    TYPE(t_field),POINTER :: f_theta_rhodz(:),f_rhodz(:), f_q(:)
438    REAL(rstd), POINTER :: theta_rhodz(:,:,:), rhodz(:,:), q(:,:,:)
439    INTEGER :: ind, iq
440    DO ind=1, ndomain
441       IF (.NOT. assigned_domain(ind)) CYCLE
442       CALL swap_dimensions(ind)
443       CALL swap_geometry(ind)
444       theta_rhodz=f_theta_rhodz(ind)
445       rhodz=f_rhodz(ind)
446       q=f_q(ind)
447       DO iq=1,nqdyn
448          theta_rhodz(:,:,iq) = rhodz(:,:)*q(:,:,iq)
449       END DO
450    END DO
451  END SUBROUTINE copy_q_to_theta
452
453END MODULE timeloop_gcm_mod
Note: See TracBrowser for help on using the repository browser.