source: codes/icosagcm/trunk/src/caldyn_hevi.f90 @ 362

MODULE caldyn_hevi_mod
  USE icosa
  USE transfert_mod
  USE caldyn_kernels_base_mod
  USE caldyn_kernels_hevi_mod
  USE caldyn_gcm_mod
  IMPLICIT NONE
  PRIVATE
  PUBLIC caldyn_hevi

CONTAINS
  
  SUBROUTINE caldyn_hevi(write_out,tau, f_phis, f_ps, f_mass, f_theta_rhodz, f_u, f_q, &
       f_geopot, f_hflux, f_wflux, f_dps, f_dmass, f_dtheta_rhodz, f_du_slow, f_du_fast)
    USE icosa
    USE observable_mod
    USE disvert_mod, ONLY : caldyn_eta, eta_mass
    USE vorticity_mod
    USE kinetic_mod
    USE theta2theta_rhodz_mod
    USE wind_mod
    USE mpipara
    USE trace
    USE omp_para
    USE output_field_mod
    USE checksum_mod
    IMPLICIT NONE
    LOGICAL,INTENT(IN)    :: write_out
    REAL(rstd), INTENT(IN) :: tau
    TYPE(t_field),POINTER :: f_phis(:)
    TYPE(t_field),POINTER :: f_ps(:)
    TYPE(t_field),POINTER :: f_mass(:)
    TYPE(t_field),POINTER :: f_theta_rhodz(:)
    TYPE(t_field),POINTER :: f_u(:)
    TYPE(t_field),POINTER :: f_q(:)
    TYPE(t_field),POINTER :: f_geopot(:)
    TYPE(t_field),POINTER :: f_hflux(:), f_wflux(:)
    TYPE(t_field) :: f_dps(:)
    TYPE(t_field) :: f_dmass(:)
    TYPE(t_field) :: f_dtheta_rhodz(:)
    TYPE(t_field) :: f_du_slow(:)
    TYPE(t_field) :: f_du_fast(:)
    
    REAL(rstd),POINTER :: ps(:), dps(:)
    REAL(rstd),POINTER :: mass(:,:), theta_rhodz(:,:), dtheta_rhodz(:,:)
    REAL(rstd),POINTER :: du(:,:), hflux(:,:), wflux(:,:)
    REAL(rstd),POINTER :: u(:,:), qu(:,:), qv(:,:)

! temporary shared variable
    REAL(rstd),POINTER  :: theta(:,:)  
    REAL(rstd),POINTER  :: pk(:,:)
    REAL(rstd),POINTER  :: geopot(:,:)
    REAL(rstd),POINTER  :: convm(:,:) 
    REAL(rstd),POINTER  :: wwuu(:,:)
        
    INTEGER :: ind
    LOGICAL,SAVE :: first=.TRUE.
!$OMP THREADPRIVATE(first)
    
    IF (first) THEN 
      first=.FALSE.
      IF(caldyn_eta==eta_mass) THEN
         CALL init_message(f_ps,req_i1,req_ps)
      ELSE
         CALL init_message(f_mass,req_i1,req_mass)
      END IF
      CALL init_message(f_theta_rhodz,req_i1,req_theta_rhodz)
      CALL init_message(f_u,req_e1_vect,req_u)
      CALL init_message(f_qu,req_e1_scal,req_qu)
    ENDIF
    
    CALL trace_start("caldyn")
    
    IF(caldyn_eta==eta_mass) THEN
       CALL send_message(f_ps,req_ps) ! COM00
       CALL wait_message(req_ps) ! COM00
    ELSE
       CALL send_message(f_mass,req_mass) ! COM00
       CALL wait_message(req_mass) ! COM00
    END IF
    CALL send_message(f_theta_rhodz,req_theta_rhodz) ! COM01
    CALL wait_message(req_theta_rhodz) ! COM01 Moved from caldyn_pvort
    
    DO ind=1,ndomain
       IF (.NOT. assigned_domain(ind)) CYCLE
       CALL swap_dimensions(ind)
       CALL swap_geometry(ind)
       ps=f_ps(ind)
       u=f_u(ind)
       du=f_du_fast(ind)
       theta_rhodz=f_theta_rhodz(ind)
       mass=f_mass(ind)
       theta = f_theta(ind)
       pk = f_pk(ind)
       geopot = f_geopot(ind)
       CALL compute_theta(ps,theta_rhodz, mass,theta)
       CALL compute_geopot(ps,mass,theta, pk,geopot)
       CALL compute_caldyn_fast(tau,u,mass,theta,pk,geopot, du) ! computes du_fast and updates u
    ENDDO
    
    CALL send_message(f_u,req_u) ! COM02
    CALL wait_message(req_u)   ! COM02
    
    DO ind=1,ndomain
       IF (.NOT. assigned_domain(ind)) CYCLE
       CALL swap_dimensions(ind)
       CALL swap_geometry(ind)
       u=f_u(ind)
       mass=f_mass(ind)
       qu=f_qu(ind)
       qv=f_qv(ind)
       CALL compute_pvort_only(u,mass,qu,qv)
    ENDDO
    
    CALL send_message(f_qu,req_qu) ! COM03
    
    DO ind=1,ndomain
       IF (.NOT. assigned_domain(ind)) CYCLE
       CALL swap_dimensions(ind)
       CALL swap_geometry(ind)
       u=f_u(ind)
       mass=f_mass(ind)
       theta = f_theta(ind)
       qu=f_qu(ind)
       hflux=f_hflux(ind)
       convm = f_dmass(ind)
       dtheta_rhodz=f_dtheta_rhodz(ind)
       du=f_du_slow(ind)
       CALL compute_caldyn_slow(u,mass,qu,theta, hflux,convm,dtheta_rhodz,du) ! COM03
       IF(caldyn_eta==eta_mass) THEN
          wflux=f_wflux(ind)
          wwuu=f_wwuu(ind)
          dps=f_dps(ind)
          CALL compute_caldyn_vert(u,theta,mass,convm, wflux,wwuu, dps, dtheta_rhodz, du)
       END IF
    ENDDO
    
!$OMP BARRIER
    !    CALL check_mass_conservation(f_ps,f_dps)
    CALL trace_end("caldyn_hevi")
!!$OMP BARRIER
    
  END SUBROUTINE caldyn_hevi

END MODULE caldyn_hevi_mod