source: codes/icosagcm/trunk/src/physics/physics.f90 @ 1025

Last change on this file since 1025 was 953, checked in by adurocher, 5 years ago

trunk : GPU implementation with OpenACC ( merge from glcp.idris.fr )
File size: 13.2 KB
Line 
1MODULE physics_mod
2  USE icosa
3  USE field_mod
4  USE physics_interface_mod
5  USE omp_para
6  IMPLICIT NONE
7  PRIVATE
8
9  INTEGER, PARAMETER :: phys_none=0, phys_HS94=1, phys_DCMIP=2, phys_lmdz_generic=3, phys_LB2012=4, phys_external=5,&
10                        phys_DCMIP2016=6
11
12  INTEGER :: phys_type
13  TYPE(t_field),POINTER,SAVE :: f_dulon(:), f_dulat(:)
14  TYPE(t_field),POINTER,SAVE :: f_ulon(:), f_ulat(:)
15  TYPE(t_field),POINTER,SAVE :: f_p(:), f_pk(:)
16  TYPE(t_field),POINTER,SAVE :: f_temp(:)
17  TYPE(t_field),POINTER,SAVE :: f_du_phys(:)
18
19  CHARACTER(LEN=255),SAVE :: physics_type
20!$OMP THREADPRIVATE(physics_type)
21  TYPE(t_message),SAVE :: req_theta0, req_ue0, req_q0
22
23  PUBLIC :: physics, init_physics, zero_du_phys
24
25CONTAINS
26
27  SUBROUTINE init_physics
28    USE mpipara
29    USE abort_mod
30    USE etat0_mod
31    USE physics_dcmip_mod, ONLY : init_physics_dcmip=>init_physics
32    USE physics_dcmip2016_mod, ONLY : init_physics_dcmip2016=>init_physics
33    USE etat0_venus_mod, ONLY : init_phys_venus=>init_physics
34    USE physics_lmdz_generic_mod, ONLY : init_physics_lmdz_generic=>init_physics
35    USE physics_external_mod, ONLY : init_physics_external=>init_physics
36
37    physics_inout%dt_phys = dt*itau_physics
38    physics_type='none'
39    CALL getin("physics",physics_type)
40    SELECT CASE(TRIM(physics_type))
41    CASE ('none')
42
43!$OMP PARALLEL
44       IF(is_mpi_root) PRINT*,"NO PHYSICAL PACKAGE USED"
45       phys_type = phys_none
46!$OMP END PARALLEL
47
48    CASE ('held_suarez')
49
50!$OMP PARALLEL
51       phys_type = phys_HS94
52!$OMP END PARALLEL
53
54    CASE ('Lebonnois2012')
55
56!$OMP PARALLEL
57       phys_type = phys_LB2012
58       CALL init_phys_venus
59!$OMP END PARALLEL
60
61    CASE ('phys_lmdz_generic')
62
63!$OMP PARALLEL
64       CALL init_physics_lmdz_generic
65       phys_type=phys_lmdz_generic
66!$OMP END PARALLEL
67
68    CASE ('phys_external')
69
70       CALL init_physics_external
71!$OMP PARALLEL
72       phys_type=phys_external
73!$OMP END PARALLEL
74
75    CASE ('dcmip')
76
77!$OMP PARALLEL
78       CALL allocate_field(f_dulon,field_t,type_real,llm, name='dulon')
79       CALL allocate_field(f_dulat,field_t,type_real,llm, name='dulat')
80       CALL allocate_field(f_temp,field_t,type_real,llm, name='temp')
81       CALL allocate_field(f_ulon,field_t,type_real,llm, name='ulon')
82       CALL allocate_field(f_ulat,field_t,type_real,llm, name='ulat')
83       CALL allocate_field(f_p,field_t,type_real,llm+1, name='p')
84       CALL allocate_field(f_pk,field_t,type_real,llm, name='pk')
85       CALL init_pack_before ! Compute physics_inout%ngrid and offsets used by pack/unpack
86       CALL init_physics_dcmip
87       CALL init_pack_after ! Defines Ai, lon, lat in physics_inout
88       phys_type = phys_DCMIP
89!$OMP END PARALLEL
90
91    CASE ('dcmip2016')
92
93!$OMP PARALLEL
94       CALL allocate_field(f_dulon,field_t,type_real,llm, name='dulon')
95       CALL allocate_field(f_dulat,field_t,type_real,llm, name='dulat')
96       CALL allocate_field(f_temp,field_t,type_real,llm, name='temp')
97       CALL allocate_field(f_ulon,field_t,type_real,llm, name='ulon')
98       CALL allocate_field(f_ulat,field_t,type_real,llm, name='ulat')
99       CALL allocate_field(f_p,field_t,type_real,llm+1, name='p')
100       CALL allocate_field(f_pk,field_t,type_real,llm, name='pk')
101       CALL init_pack_before ! Compute physics_inout%ngrid and offsets used by pack/unpack
102       CALL init_physics_dcmip2016
103       CALL init_pack_after ! Defines Ai, lon, lat in physics_inout
104       phys_type = phys_DCMIP2016
105!$OMP END PARALLEL
106
107    CASE DEFAULT
108       IF(is_mpi_root) PRINT*, 'init_physics : Bad selector for variable physics <',&
109            TRIM(physics_type), '> options are <none>, <held_suarez>, <Lebonnois2012>, <dcmip>', &
110                                '<phys_lmdz_generic>, <phys_external>'
111       STOP
112    END SELECT
113
114!$OMP PARALLEL
115    CALL allocate_field(f_du_phys,field_u,type_real,llm, name='du_phys')
116
117    IF(is_mpi_root) PRINT *, 'phys_type = ',phys_type
118   
119   
120!$OMP END PARALLEL
121    IF (phys_type /= phys_none) THEN
122       CALL abort_acc("physics /= 'none'")
123    END IF
124  END SUBROUTINE init_physics
125
126  SUBROUTINE zero_du_phys()
127    USE abort_mod
128    REAL(rstd), DIMENSION(:,:), POINTER :: du
129    INTEGER :: ind
130    DO ind=1,ndomain
131       IF (.NOT. assigned_domain(ind)) CYCLE
132       CALL swap_dimensions(ind)
133       CALL swap_geometry(ind)
134       du=f_du_phys(ind)
135       du(:,ll_begin:ll_end) = 0.
136    END DO
137  END SUBROUTINE zero_du_phys
138
139  SUBROUTINE add_du_phys(coef, f_u)
140    REAL(rstd), INTENT(IN) :: coef  ! -1 before physics, +1 after physics
141    TYPE(t_field),POINTER :: f_u(:) ! velocity field before/after call to physics
142    REAL(rstd), DIMENSION(:,:), POINTER :: u, du
143    INTEGER :: ind
144    DO ind=1,ndomain
145       IF (.NOT. assigned_domain(ind)) CYCLE
146       CALL swap_dimensions(ind)
147       CALL swap_geometry(ind)
148       du=f_du_phys(ind)
149       u=f_u(ind)
150       du(:,ll_begin:ll_end) = du(:,ll_begin:ll_end) + coef*u(:,ll_begin:ll_end)
151    END DO
152  END SUBROUTINE add_du_phys
153
154  SUBROUTINE physics(it,f_phis, f_ps, f_theta_rhodz, f_ue, f_wflux, f_q)
155    USE physics_lmdz_generic_mod, ONLY : physics_lmdz_generic => physics
156    USE physics_external_mod, ONLY : physics_external => physics
157    USE physics_dcmip_mod, ONLY : write_physics_dcmip => write_physics
158    USE physics_dcmip2016_mod, ONLY : write_physics_dcmip2016 => write_physics
159    USE etat0_heldsz_mod
160    USE etat0_venus_mod, ONLY : phys_venus => physics
161    USE abort_mod
162    INTEGER, INTENT(IN)   :: it
163    TYPE(t_field),POINTER :: f_phis(:)
164    TYPE(t_field),POINTER :: f_ps(:)
165    TYPE(t_field),POINTER :: f_theta_rhodz(:)
166    TYPE(t_field),POINTER :: f_ue(:)
167    TYPE(t_field),POINTER :: f_wflux(:)
168    TYPE(t_field),POINTER :: f_q(:)
169
170    LOGICAL,SAVE :: first=.TRUE.
171    !$OMP THREADPRIVATE(first)
172    IF (first) THEN
173      CALL init_message(f_theta_rhodz, req_i0, req_theta0)
174      CALL init_message(f_ue, req_e0_vect, req_ue0)
175      CALL init_message(f_q, req_i0, req_q0)
176      first=.FALSE.
177    ENDIF
178   
179    IF (phys_type==phys_external) THEN
180   
181      CALL physics_external(it ,f_phis, f_ps, f_theta_rhodz, f_ue, f_wflux, f_q)
182
183    ELSE
184   
185      IF(MOD(it,itau_physics)==0 .AND. phys_type/=phys_none) THEN
186
187         ! as a result of the the two calls to add_du_phys,
188         ! du_phys increases by u(after physics) - u (before physics)
189         CALL add_du_phys(-1., f_ue)
190
191         SELECT CASE(phys_type)
192         CASE(phys_HS94)
193            CALL held_suarez(f_ps,f_theta_rhodz,f_ue) 
194         CASE (phys_lmdz_generic)
195           CALL physics_lmdz_generic(it ,f_phis, f_ps, f_theta_rhodz, f_ue, f_wflux, f_q)
196         CASE(phys_LB2012)
197            CALL phys_venus(f_ps,f_theta_rhodz,f_ue) 
198         CASE DEFAULT
199            CALL physics_column(it, f_phis, f_ps, f_theta_rhodz, f_ue, f_q)
200         END SELECT
201
202         CALL send_message(f_theta_rhodz, req_theta0)
203         CALL send_message(f_ue, req_ue0)
204         CALL send_message(f_q, req_q0)
205         CALL wait_message(req_theta0)
206         CALL wait_message(req_ue0)
207         CALL wait_message(req_q0)
208       
209         CALL add_du_phys(1., f_ue)
210      END IF
211
212      IF (mod(it,itau_out)==0 ) THEN
213         CALL write_physics_tendencies
214         CALL zero_du_phys
215         SELECT CASE(phys_type)
216         CASE (phys_DCMIP)
217            CALL write_physics_dcmip
218         CASE (phys_DCMIP2016)
219            CALL write_physics_dcmip2016
220         END SELECT
221      END IF
222    ENDIF
223   
224  END SUBROUTINE physics
225
226  SUBROUTINE write_physics_tendencies
227    USE observable_mod, ONLY : f_buf_ulon, f_buf_ulat
228    USE wind_mod
229    USE output_field_mod
230    CALL transfert_request(f_du_phys,req_e1_vect)
231    CALL un2ulonlat(f_du_phys, f_buf_ulon, f_buf_ulat, (1./(dt*itau_out)))
232    CALL output_field("dulon_phys",f_buf_ulon)
233    CALL output_field("dulat_phys",f_buf_ulat)
234  END SUBROUTINE write_physics_tendencies
235   
236  SUBROUTINE physics_column(it, f_phis, f_ps, f_theta_rhodz, f_ue, f_q)
237    USE physics_dcmip_mod, ONLY : full_physics_dcmip => full_physics
238    USE physics_dcmip2016_mod, ONLY : full_physics_dcmip2016 => full_physics
239    USE theta2theta_rhodz_mod
240    USE mpipara
241    USE checksum_mod
242    TYPE(t_field),POINTER :: f_phis(:)
243    TYPE(t_field),POINTER :: f_ps(:)
244    TYPE(t_field),POINTER :: f_theta_rhodz(:)
245    TYPE(t_field),POINTER :: f_ue(:)
246    TYPE(t_field),POINTER :: f_q(:)
247    REAL(rstd),POINTER :: phis(:)
248    REAL(rstd),POINTER :: ps(:)
249    REAL(rstd),POINTER :: temp(:,:)
250    REAL(rstd),POINTER :: ue(:,:)
251    REAL(rstd),POINTER :: dulon(:,:)
252    REAL(rstd),POINTER :: dulat(:,:)
253    REAL(rstd),POINTER :: q(:,:,:)
254    REAL(rstd),POINTER :: p(:,:)
255    REAL(rstd),POINTER :: pk(:,:)
256    REAL(rstd),POINTER :: ulon(:,:)
257    REAL(rstd),POINTER :: ulat(:,:)
258    INTEGER :: it, ind
259
260    CALL theta_rhodz2temperature(f_ps,f_theta_rhodz,f_temp)
261   
262    DO ind=1,ndomain
263       IF (.NOT. assigned_domain(ind)) CYCLE
264       CALL swap_dimensions(ind)
265       CALL swap_geometry(ind)
266       phis=f_phis(ind)
267       ps=f_ps(ind)
268       temp=f_temp(ind)
269       ue=f_ue(ind)
270       q=f_q(ind)
271       p=f_p(ind)
272       pk=f_pk(ind)
273       ulon=f_ulon(ind)
274       ulat=f_ulat(ind)
275       CALL pack_physics(pack_info(ind), phis, ps, temp, ue, q, p, pk, ulon, ulat)
276    END DO
277
278    SELECT CASE(phys_type)
279    CASE (phys_DCMIP)
280       IF (is_omp_level_master) CALL full_physics_dcmip
281    CASE (phys_DCMIP2016)
282       IF (is_omp_level_master) CALL full_physics_dcmip2016
283    CASE DEFAULT
284       IF(is_master) PRINT *,'Internal error : illegal value of phys_type', phys_type
285       STOP
286    END SELECT
287
288    DO ind=1,ndomain
289       IF (.NOT. assigned_domain(ind)) CYCLE
290       CALL swap_dimensions(ind)
291       CALL swap_geometry(ind)
292       ps=f_ps(ind)
293       temp=f_temp(ind)
294       q=f_q(ind)
295       dulon=f_dulon(ind)
296       dulat=f_dulat(ind)
297       CALL unpack_physics(pack_info(ind), ps, temp, q, dulon, dulat)
298    END DO
299   
300    CALL temperature2theta_rhodz(f_ps,f_temp,f_theta_rhodz)
301
302    ! Transfer dulon, dulat
303    CALL transfert_request(f_dulon,req_i0)
304    CALL transfert_request(f_dulat,req_i0)
305
306    DO ind=1,ndomain
307       IF (.NOT. assigned_domain(ind)) CYCLE
308       CALL swap_dimensions(ind)
309       CALL swap_geometry(ind)
310       ue=f_ue(ind)
311       dulon=f_dulon(ind)
312       dulat=f_dulat(ind)
313       CALL compute_update_velocity(dulon, dulat, ue)
314    END DO
315
316  END SUBROUTINE physics_column
317
318  SUBROUTINE pack_physics(info, phis, ps, temp, ue, q, p, pk, ulon, ulat )
319    USE wind_mod
320    USE pression_mod
321    USE theta2theta_rhodz_mod
322    USE exner_mod
323    TYPE(t_pack_info) :: info
324    REAL(rstd) :: phis(iim*jjm)
325    REAL(rstd) :: ps(iim*jjm)
326    REAL(rstd) :: temp(iim*jjm,llm)
327    REAL(rstd) :: pks(iim*jjm)
328    REAL(rstd) :: pk(iim*jjm,llm)
329    REAL(rstd) :: ue(3*iim*jjm,llm)
330    REAL(rstd) :: q(iim*jjm,llm,nqtot)
331
332    REAL(rstd) :: p(iim*jjm,llm+1)
333    REAL(rstd) :: uc(iim*jjm,llm,3)
334    REAL(rstd) :: ulon(iim*jjm,llm)
335    REAL(rstd) :: ulat(iim*jjm,llm)
336
337!$OMP BARRIER
338    CALL compute_pression(ps,p,0)
339!$OMP BARRIER
340    CALL compute_exner(ps,p,pks,pk,0) 
341!$OMP BARRIER
342    CALL compute_wind_centered(ue,uc)
343    CALL compute_wind_centered_lonlat_compound(uc, ulon, ulat)
344!$OMP BARRIER
345    IF (is_omp_level_master) THEN
346      CALL pack_domain(info, phis, physics_inout%phis)
347      CALL pack_domain(info, p, physics_inout%p)
348      CALL pack_domain(info, pk, physics_inout%pk)
349      CALL pack_domain(info, Temp, physics_inout%Temp)
350      CALL pack_domain(info, ulon, physics_inout%ulon)
351      CALL pack_domain(info, ulat, physics_inout%ulat)
352      CALL pack_domain(info, q, physics_inout%q)
353    ENDIF
354!$OMP BARRIER
355  END SUBROUTINE pack_physics
356
357  SUBROUTINE unpack_physics(info, ps,temp, q, dulon, dulat)
358    USE theta2theta_rhodz_mod
359    TYPE(t_pack_info) :: info
360    REAL(rstd) :: ps(iim*jjm)
361    REAL(rstd) :: temp(iim*jjm,llm)
362    REAL(rstd) :: q(iim*jjm,llm,nqtot)
363    REAL(rstd) :: dulon(iim*jjm,llm)
364    REAL(rstd) :: dulat(iim*jjm,llm)
365
366    REAL(rstd) :: dq(iim*jjm,llm,nqtot)
367    REAL(rstd) :: dTemp(iim*jjm,llm)
368
369!$OMP BARRIER
370    IF (is_omp_level_master) THEN
371      CALL unpack_domain(info, dulon, physics_inout%dulon)
372      CALL unpack_domain(info, dulat, physics_inout%dulat)
373      CALL unpack_domain(info, dq, physics_inout%dq)
374      CALL unpack_domain(info, Temp, physics_inout%Temp)
375      CALL unpack_domain(info, dTemp, physics_inout%dTemp)
376      q = q + physics_inout%dt_phys * dq
377      Temp = Temp + physics_inout%dt_phys * dTemp
378    ENDIF
379!$OMP BARRIER
380
381!    CALL compute_temperature2theta_rhodz(ps,Temp,theta_rhodz,0)
382  END SUBROUTINE unpack_physics
383
384  SUBROUTINE compute_update_velocity(dulon, dulat, ue)
385    USE wind_mod
386    REAL(rstd) :: dulon(iim*jjm,llm)
387    REAL(rstd) :: dulat(iim*jjm,llm)
388    REAL(rstd) :: ue(3*iim*jjm,llm)
389    REAL(rstd) :: duc(iim*jjm,llm,3)
390    REAL(rstd) :: dt2, due
391    INTEGER :: i,j,ij,l
392    ! Reconstruct wind tendencies at edges and add to normal wind
393    CALL compute_wind_centered_from_lonlat_compound(dulon,dulat,duc)
394    dt2=.5*physics_inout%dt_phys
395    DO l=ll_begin,ll_end
396      DO j=jj_begin,jj_end
397        DO i=ii_begin,ii_end
398          ij=(j-1)*iim+i
399          due = sum( (duc(ij,l,:) + duc(ij+t_right,l,:))*ep_e(ij+u_right,:) )
400          ue(ij+u_right,l) = ue(ij+u_right,l) + dt2*due
401
402          due = sum( (duc(ij,l,:) + duc(ij+t_lup,l,:))*ep_e(ij+u_lup,:) )
403          ue(ij+u_lup,l)=ue(ij+u_lup,l) + dt2*due
404
405          due = sum( (duc(ij,l,:) + duc(ij+t_ldown,l,:))*ep_e(ij+u_ldown,:) )
406          ue(ij+u_ldown,l)=ue(ij+u_ldown,l) + dt2*due
407        ENDDO
408      ENDDO
409    ENDDO
410  END SUBROUTINE compute_update_velocity
411
412END MODULE physics_mod
Note: See TracBrowser for help on using the repository browser.