source: codes/icosagcm/trunk/src/timeloop_gcm.f90 @ 365

Last change on this file since 365 was 365, checked in by dubos, 9 years ago

Cleanup detailed AAM budget
File size: 11.2 KB
Line 
1MODULE timeloop_gcm_mod
2  USE icosa
3  USE disvert_mod
4  USE trace
5  USE omp_para
6  USE euler_scheme_mod
7  USE explicit_scheme_mod
8  USE hevi_scheme_mod
9  IMPLICIT NONE
10  PRIVATE
11 
12  INTEGER, PARAMETER :: itau_sync=10
13  TYPE(t_message),SAVE :: req_ps0, req_mass0, req_theta_rhodz0, req_u0, req_q0
14
15  PUBLIC :: init_timeloop, timeloop
16
17CONTAINS
18 
19  SUBROUTINE init_timeloop
20    USE dissip_gcm_mod
21    USE observable_mod
22    USE caldyn_mod
23    USE etat0_mod
24    USE guided_mod
25    USE advect_tracer_mod
26    USE check_conserve_mod
27    USE output_field_mod
28    USE theta2theta_rhodz_mod
29    USE sponge_mod
30
31    CHARACTER(len=255) :: def
32   
33    IF (xios_output) itau_out=1
34    IF (.NOT. enable_io) itau_out=HUGE(itau_out)
35   
36    def='RK2.5'
37    CALL getin('time_scheme',def)
38    SELECT CASE (TRIM(def))
39    CASE('euler')
40       scheme_family=explicit
41       scheme=euler
42       nb_stage=1
43    CASE ('runge_kutta')
44       scheme_family=explicit
45       scheme=rk4
46       nb_stage=4
47    CASE ('RK2.5')
48       scheme_family=explicit
49       scheme=rk25
50       nb_stage=5
51    CASE ('leapfrog_matsuno')
52       scheme_family=explicit
53       scheme=mlf
54       matsuno_period=5
55       CALL getin('matsuno_period',matsuno_period)
56       nb_stage=matsuno_period+1
57    CASE('ARK2.3')
58       scheme_family=hevi
59       scheme=ark23
60       nb_stage=3
61       CALL set_coefs_ark23(dt)
62    CASE('ARK3.3')
63       scheme_family=hevi
64       scheme=ark33
65       nb_stage=3
66       CALL set_coefs_ark33(dt)
67    CASE ('none')
68       nb_stage=0
69    CASE default
70       PRINT*,'Bad selector for variable scheme : <', TRIM(def),             &
71            ' > options are <euler>, <runge_kutta>, <leapfrog_matsuno>,<RK2.5>,<ARK2.3>'
72       STOP
73    END SELECT
74   
75    ! Time-independant orography
76    CALL allocate_field(f_phis,field_t,type_real,name='phis')
77    ! Model state at current time step
78    CALL allocate_field(f_geopot,field_t,type_real,llm+1,name='geopot')
79    CALL allocate_field(f_ps,field_t,type_real, name='ps')
80    CALL allocate_field(f_mass,field_t,type_real,llm,name='mass')
81    CALL allocate_field(f_rhodz,field_t,type_real,llm,name='rhodz')
82    CALL allocate_field(f_theta_rhodz,field_t,type_real,llm,name='theta_rhodz')
83    CALL allocate_field(f_u,field_u,type_real,llm,name='u')
84    CALL allocate_field(f_q,field_t,type_real,llm,nqtot,'q')
85    ! Mass fluxes
86    CALL allocate_field(f_hflux,field_u,type_real,llm)    ! instantaneous mass fluxes
87    CALL allocate_field(f_hfluxt,field_u,type_real,llm)   ! mass "fluxes" accumulated in time
88    CALL allocate_field(f_wflux,field_t,type_real,llm+1)  ! vertical mass fluxes
89    CALL allocate_field(f_wfluxt,field_t,type_real,llm+1,name='wfluxt')
90   
91    SELECT CASE(scheme_family)
92    CASE(explicit)
93       ! Trends
94       CALL allocate_field(f_dps,field_t,type_real,name='dps')
95       CALL allocate_field(f_dmass,field_t,type_real,llm, name='dmass')
96       CALL allocate_field(f_dtheta_rhodz,field_t,type_real,llm,name='dtheta_rhodz')
97       CALL allocate_field(f_du,field_u,type_real,llm,name='du')
98       ! Model state at previous time step (RK/MLF)
99       CALL allocate_field(f_psm1,field_t,type_real,name='psm1')
100       CALL allocate_field(f_massm1,field_t,type_real,llm, name='massm1')
101       CALL allocate_field(f_theta_rhodzm1,field_t,type_real,llm,name='theta_rhodzm1')
102       CALL allocate_field(f_um1,field_u,type_real,llm,name='um1')
103    CASE(hevi)
104       ! Trends
105       CALL allocate_fields(nb_stage,f_dps_slow, field_t,type_real,name='dps_slow')
106       CALL allocate_fields(nb_stage,f_dmass_slow, field_t,type_real,llm, name='dmass_slow')
107       CALL allocate_fields(nb_stage,f_dtheta_rhodz_slow, field_t,type_real,llm,name='dtheta_rhodz_fast')
108       CALL allocate_fields(nb_stage,f_du_slow, field_u,type_real,llm,name='du_slow')
109       CALL allocate_fields(nb_stage,f_du_fast, field_u,type_real,llm,name='du_fast')
110       f_dps => f_dps_slow(:,1)
111       f_du => f_du_slow(:,1)
112       f_dtheta_rhodz => f_dtheta_rhodz_slow(:,1)
113    END SELECT
114
115    SELECT CASE(scheme)
116    CASE(mlf)
117       ! Model state 2 time steps ago (MLF)
118       CALL allocate_field(f_psm2,field_t,type_real)
119       CALL allocate_field(f_massm2,field_t,type_real,llm)
120       CALL allocate_field(f_theta_rhodzm2,field_t,type_real,llm)
121       CALL allocate_field(f_um2,field_u,type_real,llm)
122    END SELECT
123
124    CALL init_theta2theta_rhodz
125    CALL init_dissip
126    CALL init_sponge
127    CALL init_observable
128    CALL init_caldyn
129    CALL init_guided
130    CALL init_advect_tracer
131    CALL init_check_conserve
132
133    CALL etat0(f_ps,f_mass,f_phis,f_theta_rhodz,f_u, f_q)
134
135    CALL transfert_request(f_phis,req_i0) 
136    CALL transfert_request(f_phis,req_i1) 
137    CALL writefield("phis",f_phis,once=.TRUE.)
138
139    CALL init_message(f_ps,req_i0,req_ps0)
140    CALL init_message(f_mass,req_i0,req_mass0)
141    CALL init_message(f_theta_rhodz,req_i0,req_theta_rhodz0)
142    CALL init_message(f_u,req_e0_vect,req_u0)
143    CALL init_message(f_q,req_i0,req_q0)
144
145  END SUBROUTINE init_timeloop
146 
147  SUBROUTINE timeloop
148    USE dissip_gcm_mod
149    USE sponge_mod
150    USE observable_mod
151    USE etat0_mod
152    USE guided_mod
153    USE caldyn_mod
154    USE advect_tracer_mod
155    USE physics_mod
156    USE mpipara
157    USE transfert_mod
158    USE check_conserve_mod
159    USE xios_mod
160    USE output_field_mod
161    USE write_etat0_mod
162    USE checksum_mod
163    USE explicit_scheme_mod
164    USE hevi_scheme_mod
165    REAL(rstd),POINTER :: rhodz(:,:), mass(:,:), ps(:)
166
167    INTEGER :: ind
168    INTEGER :: it,i,j,l,n,  stage
169    LOGICAL :: fluxt_zero(ndomain) ! set to .TRUE. to start accumulating fluxes in time
170    LOGICAL, PARAMETER :: check_rhodz=.FALSE.
171    INTEGER :: start_clock, stop_clock, rate_clock
172    LOGICAL,SAVE :: first_physic=.TRUE.
173    !$OMP THREADPRIVATE(first_physic)   
174
175    CALL switch_omp_distrib_level
176    CALL caldyn_BC(f_phis, f_geopot, f_wflux) ! set constant values in first/last interfaces
177
178    !$OMP BARRIER
179    DO ind=1,ndomain
180       IF (.NOT. assigned_domain(ind)) CYCLE
181       CALL swap_dimensions(ind)
182       CALL swap_geometry(ind)
183       rhodz=f_rhodz(ind); mass=f_mass(ind); ps=f_ps(ind)
184       IF(caldyn_eta==eta_mass) THEN
185          CALL compute_rhodz(.TRUE., ps, rhodz) ! save rhodz for transport scheme before dynamics update ps
186       ELSE
187          DO l=ll_begin,ll_end
188             rhodz(:,l)=mass(:,l)
189          ENDDO
190       END IF
191    END DO
192    !$OMP BARRIER
193    fluxt_zero=.TRUE.
194
195    !$OMP MASTER
196    CALL SYSTEM_CLOCK(start_clock)
197    CALL SYSTEM_CLOCK(count_rate=rate_clock)
198    !$OMP END MASTER   
199
200    CALL check_conserve(f_ps,f_dps,f_u,f_theta_rhodz,f_phis,itau0) 
201
202    CALL trace_on
203
204    DO it=itau0+1,itau0+itaumax
205
206       IF (is_master) CALL print_iteration(it, itau0, itaumax, start_clock, rate_clock)
207       IF (xios_output) THEN
208          CALL xios_update_calendar(it)
209       ELSE
210          CALL update_time_counter(dt*it)
211       END IF
212
213       IF (it==itau0+1 .OR. MOD(it,itau_sync)==0) THEN
214          CALL send_message(f_ps,req_ps0)
215          CALL wait_message(req_ps0)
216          CALL send_message(f_mass,req_mass0)
217          CALL wait_message(req_mass0)
218          CALL send_message(f_theta_rhodz,req_theta_rhodz0) 
219          CALL wait_message(req_theta_rhodz0) 
220          CALL send_message(f_u,req_u0)
221          CALL wait_message(req_u0)
222          CALL send_message(f_q,req_q0) 
223          CALL wait_message(req_q0) 
224       ENDIF
225
226       IF (mod(it,itau_out)==0 ) THEN
227          CALL transfert_request(f_u,req_e1_vect)
228          CALL write_output_fields_basic(f_ps, f_u, f_q)
229       ENDIF
230
231       CALL guided(it*dt,f_ps,f_theta_rhodz,f_u,f_q)
232
233       SELECT CASE(scheme_family)
234       CASE(explicit)
235          CALL explicit_scheme(it, fluxt_zero)
236       CASE(hevi)
237          CALL HEVI_scheme(it, fluxt_zero)
238       END SELECT
239       
240       IF (MOD(it,itau_dissip)==0) THEN
241         
242          IF(caldyn_eta==eta_mass) THEN
243             !ym flush ps
244             !$OMP BARRIER
245             DO ind=1,ndomain
246                IF (.NOT. assigned_domain(ind)) CYCLE
247                CALL swap_dimensions(ind)
248                CALL swap_geometry(ind)
249                mass=f_mass(ind); ps=f_ps(ind);
250                CALL compute_rhodz(.TRUE., ps, mass)
251             END DO
252          ENDIF
253         
254          CALL check_conserve_detailed(it, AAM_dyn, &
255               f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
256       
257          CALL dissip(f_u,f_du,f_mass,f_phis, f_theta_rhodz,f_dtheta_rhodz)
258         
259          CALL euler_scheme(.FALSE.)  ! update only u, theta
260          IF (iflag_sponge > 0) THEN
261             CALL sponge(f_u,f_du,f_theta_rhodz,f_dtheta_rhodz)
262             CALL euler_scheme(.FALSE.)  ! update only u, theta
263          END IF
264
265          CALL check_conserve_detailed(it, AAM_dissip, &
266               f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
267       END IF
268       
269       IF(MOD(it,itau_adv)==0) THEN
270          CALL advect_tracer(f_hfluxt,f_wfluxt,f_u, f_q,f_rhodz)  ! update q and rhodz after RK step
271          fluxt_zero=.TRUE.
272          ! FIXME : check that rhodz is consistent with ps
273          IF (check_rhodz) THEN
274             DO ind=1,ndomain
275                IF (.NOT. assigned_domain(ind)) CYCLE
276                CALL swap_dimensions(ind)
277                CALL swap_geometry(ind)
278                rhodz=f_rhodz(ind); ps=f_ps(ind);
279                CALL compute_rhodz(.FALSE., ps, rhodz)   
280             END DO
281          ENDIF
282       END IF
283       
284       IF (MOD(it,itau_physics)==0) THEN
285          CALL check_conserve_detailed(it, AAM_dyn, &
286            f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
287          CALL physics(it,f_phis, f_ps, f_theta_rhodz, f_u, f_wflux, f_q)       
288          CALL check_conserve_detailed(it, AAM_phys, &
289               f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
290          !$OMP MASTER
291          IF (first_physic) CALL SYSTEM_CLOCK(start_clock)
292          !$OMP END MASTER   
293          first_physic=.FALSE.
294       END IF
295
296       IF (MOD(it,itau_check_conserv)==0) THEN
297          CALL check_conserve_detailed(it, AAM_dyn, &
298               f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
299          CALL check_conserve(f_ps,f_dps,f_u,f_theta_rhodz,f_phis,it) 
300       ENDIF       
301    END DO
302   
303    CALL write_etat0(itau0+itaumax,f_ps, f_phis,f_theta_rhodz,f_u,f_q) 
304   
305    CALL check_conserve_detailed(it, AAM_dyn, &
306         f_ps,f_dps,f_u,f_theta_rhodz,f_phis)
307    CALL check_conserve(f_ps,f_dps,f_u,f_theta_rhodz,f_phis,it) 
308   
309    !$OMP MASTER
310    CALL SYSTEM_CLOCK(stop_clock)
311   
312    IF (mpi_rank==0) THEN
313       PRINT *,"Time elapsed : ",(stop_clock-start_clock)*1./rate_clock 
314    ENDIF
315    !$OMP END MASTER
316   
317    ! CONTAINS
318  END SUBROUTINE timeloop
319
320  SUBROUTINE print_iteration(it,itau0,itaumax,start_clock,rate_clock)
321    INTEGER :: it, itau0, itaumax, start_clock, stop_clock, rate_clock, throughput
322    REAL :: per_step,total, elapsed
323    WRITE(*,'(A,I7,A,F14.1)') "It No :",it,"   t :",dt*it
324    IF(MOD(it,10)==0) THEN
325       CALL SYSTEM_CLOCK(stop_clock)
326       elapsed = (stop_clock-start_clock)*1./rate_clock
327       per_step = elapsed/(it-itau0)
328       throughput = dt/per_step
329       total = per_step*(itaumax-itau0)
330       WRITE(*,'(A,I5,A,F6.2,A,I6)') 'Time spent (s):',INT(elapsed), &
331            '  -- ms/step : ', 1000*per_step, &
332            '  -- Throughput :', throughput
333       WRITE(*,'(A,I5,A,I5)') 'Whole job (min) :', INT(total/60.), &
334            '  -- Completion in (min) : ', INT((total-elapsed)/60.)
335    END IF
336  END SUBROUTINE print_iteration
337
338END MODULE timeloop_gcm_mod
Note: See TracBrowser for help on using the repository browser.