source: codes/icosagcm/trunk/src/transport/advect.F90 @ 896

Last change on this file since 896 was 896, checked in by adurocher, 5 years ago

trunk : compute_gradq3d: Remove all useless temporary arrays.
File size: 18.3 KB
Line 
1MODULE advect_mod
2  USE icosa
3  IMPLICIT NONE
4
5  PRIVATE
6 
7  PUBLIC :: init_advect, compute_backward_traj, compute_gradq3d, compute_advect_horiz
8
9CONTAINS
10
11  !==========================================================================
12
13  SUBROUTINE init_advect(normal,tangent,sqrt_leng)
14    IMPLICIT NONE
15    REAL(rstd),INTENT(OUT) :: normal(3*iim*jjm,3)
16    REAL(rstd),INTENT(OUT) :: tangent(3*iim*jjm,3)
17    REAL(rstd),INTENT(OUT) :: sqrt_leng(iim*jjm)
18
19    INTEGER :: ij
20
21!DIR$ SIMD
22      DO ij=ij_begin,ij_end
23
24          CALL cross_product2(xyz_v(ij+z_rdown,:),xyz_v(ij+z_rup,:),normal(ij+u_right,:))
25          normal(ij+u_right,:)=normal(ij+u_right,:)/sqrt(sum(normal(ij+u_right,:)**2)+1e-50)*ne(ij,right)
26
27          CALL cross_product2(xyz_v(ij+z_up,:),xyz_v(ij+z_lup,:),normal(ij+u_lup,:))
28          normal(ij+u_lup,:)=normal(ij+u_lup,:)/sqrt(sum(normal(ij+u_lup,:)**2)+1e-50)*ne(ij,lup)
29
30          CALL cross_product2(xyz_v(ij+z_ldown,:),xyz_v(ij+z_down,:),normal(ij+u_ldown,:))       
31          normal(ij+u_ldown,:)=normal(ij+u_ldown,:)/sqrt(sum(normal(ij+u_ldown,:)**2)+1e-50)*ne(ij,ldown)
32
33          tangent(ij+u_right,:)=xyz_v(ij+z_rup,:)-xyz_v(ij+z_rdown,:) 
34          tangent(ij+u_right,:)=tangent(ij+u_right,:)/sqrt(sum(tangent(ij+u_right,:)**2)+1e-50)
35
36          tangent(ij+u_lup,:)=xyz_v(ij+z_lup,:)-xyz_v(ij+z_up,:) 
37          tangent(ij+u_lup,:)=tangent(ij+u_lup,:)/sqrt(sum(tangent(ij+u_lup,:)**2)+1e-50)
38
39          tangent(ij+u_ldown,:)=xyz_v(ij+z_down,:)-xyz_v(ij+z_ldown,:)
40          tangent(ij+u_ldown,:)=tangent(ij+u_ldown,:)/sqrt(sum(tangent(ij+u_ldown,:)**2)+1e-50)
41
42          sqrt_leng(ij) = sqrt(max(sum((xyz_v(ij+z_up,:) - xyz_i(ij,:))**2),sum((xyz_v(ij+z_down,:) - xyz_i(ij,:))**2), &
43                                   sum((xyz_v(ij+z_rup,:) - xyz_i(ij,:))**2),sum((xyz_v(ij+z_rdown,:) - xyz_i(ij,:))**2),  &
44                                   sum((xyz_v(ij+z_lup,:) - xyz_i(ij,:))**2),sum((xyz_v(ij+z_ldown,:) - xyz_i(ij,:))**2)) )
45    ENDDO
46
47  END SUBROUTINE init_advect
48
49  !=======================================================================================
50
51  SUBROUTINE compute_gradq3d(qi,sqrt_leng,gradq3d,xyz_i,xyz_v)
52    USE trace
53    USE omp_para
54    IMPLICIT NONE
55    REAL(rstd),INTENT(IN)  :: qi(iim*jjm,llm)
56    REAL(rstd),INTENT(IN)  :: sqrt_leng(iim*jjm)
57    REAL(rstd),INTENT(IN)  :: xyz_i(iim*jjm,3)
58    REAL(rstd),INTENT(IN)  :: xyz_v(2*iim*jjm,3)
59    REAL(rstd),INTENT(OUT) :: gradq3d(iim*jjm,llm,3)
60    REAL(rstd) :: maxq,minq,minq_c,maxq_c 
61    REAL(rstd) :: alphamx,alphami,alpha ,maggrd
62    REAL(rstd) :: leng1,leng2
63    REAL(rstd) :: arr(2*iim*jjm)
64    REAL(rstd) :: ar(iim*jjm)
65    REAL(rstd) :: gradtri(2*iim*jjm,llm,3) 
66    INTEGER :: ij,k,ind,l
67    REAL(rstd) :: detx,dety,detz,det
68    REAL(rstd) :: A(3,3), a11,a12,a13,a21,a22,a23,a31,a32,a33
69    REAL(rstd) :: x1,x2,x3
70    REAL(rstd) :: dq(3)
71
72    CALL trace_start("compute_gradq3d1")
73
74    ! TODO : precompute ar, drop arr as output argument of gradq ?
75
76    !========================================================================================== GRADIENT
77    ! Compute gradient at triangles solving a linear system
78    ! arr = area of triangle joining centroids of hexagons
79!     DO l = ll_begin,ll_end
80!!DIR$ SIMD
81!      DO ij=ij_begin_ext,ij_end_ext
82!!             CALL gradq(ij,l,ij+t_rup,ij+t_lup,ij+z_up,qi,gradtri(ij+z_up,l,:),arr(ij+z_up))
83!!             CALL gradq(ij,l,ij+t_ldown,ij+t_rdown,ij+z_down,qi,gradtri(ij+z_down,l,:),arr(ij+z_down))
84!             CALL gradq(ij,l,ij+t_rup,ij+t_lup,ij+z_up,qi,gradtri(ij+z_up,l,1),gradtri(ij+z_up,l,2),gradtri(ij+z_up,l,3),arr(ij+z_up))
85!             CALL gradq(ij,l,ij+t_ldown,ij+t_rdown,ij+z_down,qi,gradtri(ij+z_down,l,1),gradtri(ij+z_down,l,2),gradtri(ij+z_down,l,3),arr(ij+z_down))
86!       END DO
87!    END DO
88
89     DO l = ll_begin,ll_end 
90!DIR$ SIMD
91      DO ij=ij_begin_ext,ij_end_ext
92!       CALL gradq(ij,l,ij+t_rup,ij+t_lup,ij+z_up,qi,gradtri(ij+z_up,l,1),gradtri(ij+z_up,l,2),gradtri(ij+z_up,l,3),arr(ij+z_up))
93
94       
95        A(1,1)=xyz_i(ij+t_rup,1)-xyz_i(ij,1);  A(1,2)=xyz_i(ij+t_rup,2)-xyz_i(ij,2); A(1,3)=xyz_i(ij+t_rup,3)-xyz_i(ij,3) 
96        A(2,1)=xyz_i(ij+t_lup,1)-xyz_i(ij,1);  A(2,2)=xyz_i(ij+t_lup,2)-xyz_i(ij,2); A(2,3)=xyz_i(ij+t_lup,3)-xyz_i(ij,3) 
97        A(3,1)=xyz_v(ij+z_up,1);               A(3,2)= xyz_v(ij+z_up,2);             A(3,3)=xyz_v(ij+z_up,3)
98   
99        dq(1) = qi(ij+t_rup,l)-qi(ij,l)
100        dq(2) = qi(ij+t_lup,l)-qi(ij,l)
101        dq(3) = 0.0
102
103
104!        CALL determinant(A(1,1),A(2,1),A(3,1),A(1,2),A(2,2),A(3,2),A(1,3),A(2,3),A(3,3),det)
105
106         a11=A(1,1) ; a12=A(2,1) ; a13=A(3,1)
107         a21=A(1,2) ; a22=A(2,2) ; a23=A(3,2)
108         a31=A(1,3) ; a32=A(2,3) ; a33=A(3,3)
109
110         x1 =  a11 * (a22 * a33 - a23 * a32)
111         x2 =  a12 * (a21 * a33 - a23 * a31)
112         x3 =  a13 * (a21 * a32 - a22 * a31)
113         det =  x1 - x2 + x3
114                 
115!        CALL determinant(dq(1),dq(2),dq(3),A(1,2),A(2,2),A(3,2),A(1,3),A(2,3),A(3,3),detx)
116
117         a11=dq(1)  ; a12=dq(2)  ; a13=dq(3)
118         a21=A(1,2) ; a22=A(2,2) ; a23=A(3,2)
119         a31=A(1,3) ; a32=A(2,3) ; a33=A(3,3)
120
121         x1 =  a11 * (a22 * a33 - a23 * a32)
122         x2 =  a12 * (a21 * a33 - a23 * a31)
123         x3 =  a13 * (a21 * a32 - a22 * a31)
124         detx =  x1 - x2 + x3
125       
126!        CALL determinant(A(1,1),A(2,1),A(3,1),dq(1),dq(2),dq(3),A(1,3),A(2,3),A(3,3),dety)
127
128         a11=A(1,1) ; a12=A(2,1) ; a13=A(3,1)
129         a21=dq(1)  ; a22=dq(2)  ; a23=dq(3)
130         a31=A(1,3) ; a32=A(2,3) ; a33=A(3,3)
131
132         x1 =  a11 * (a22 * a33 - a23 * a32)
133         x2 =  a12 * (a21 * a33 - a23 * a31)
134         x3 =  a13 * (a21 * a32 - a22 * a31)
135         dety =  x1 - x2 + x3
136
137!        CALL determinant(A(1,1),A(2,1),A(3,1),A(1,2),A(2,2),A(3,2),dq(1),dq(2),dq(3),detz)
138
139         a11=A(1,1) ; a12=A(2,1) ; a13=A(3,1)
140         a21=A(1,2) ; a22=A(2,2) ; a23=A(3,2)
141         a31=dq(1)  ; a32=dq(2)  ; a33=dq(3)
142
143         x1 =  a11 * (a22 * a33 - a23 * a32)
144         x2 =  a12 * (a21 * a33 - a23 * a31)
145         x3 =  a13 * (a21 * a32 - a22 * a31)
146         detz =  x1 - x2 + x3
147
148        gradtri(ij+z_up,l,1) = detx
149        gradtri(ij+z_up,l,2) = dety
150        gradtri(ij+z_up,l,3) = detz
151        arr(ij+z_up) = det
152       
153      ENDDO
154     
155      DO ij=ij_begin_ext,ij_end_ext
156
157
158!        CALL gradq(ij,l,ij+t_ldown,ij+t_rdown,ij+z_down,qi,gradtri(ij+z_down,l,1),gradtri(ij+z_down,l,2),gradtri(ij+z_down,l,3),arr(ij+z_down))
159
160        A(1,1)=xyz_i(ij+t_ldown,1)-xyz_i(ij,1);  A(1,2)=xyz_i(ij+t_ldown,2)-xyz_i(ij,2); A(1,3)=xyz_i(ij+t_ldown,3)-xyz_i(ij,3) 
161        A(2,1)=xyz_i(ij+t_rdown,1)-xyz_i(ij,1);  A(2,2)=xyz_i(ij+t_rdown,2)-xyz_i(ij,2); A(2,3)=xyz_i(ij+t_rdown,3)-xyz_i(ij,3) 
162        A(3,1)=xyz_v(ij+z_down,1);               A(3,2)= xyz_v(ij+z_down,2);             A(3,3)=xyz_v(ij+z_down,3)
163 
164        dq(1) = qi(ij+t_ldown,l)-qi(ij,l)
165        dq(2) = qi(ij+t_rdown,l)-qi(ij,l)
166        dq(3) = 0.0
167
168
169!        CALL determinant(A(1,1),A(2,1),A(3,1),A(1,2),A(2,2),A(3,2),A(1,3),A(2,3),A(3,3),det)
170
171         a11=A(1,1) ; a12=A(2,1) ; a13=A(3,1)
172         a21=A(1,2) ; a22=A(2,2) ; a23=A(3,2)
173         a31=A(1,3) ; a32=A(2,3) ; a33=A(3,3)
174
175         x1 =  a11 * (a22 * a33 - a23 * a32)
176         x2 =  a12 * (a21 * a33 - a23 * a31)
177         x3 =  a13 * (a21 * a32 - a22 * a31)
178         det =  x1 - x2 + x3
179                 
180!        CALL determinant(dq(1),dq(2),dq(3),A(1,2),A(2,2),A(3,2),A(1,3),A(2,3),A(3,3),detx)
181
182         a11=dq(1)  ; a12=dq(2)  ; a13=dq(3)
183         a21=A(1,2) ; a22=A(2,2) ; a23=A(3,2)
184         a31=A(1,3) ; a32=A(2,3) ; a33=A(3,3)
185
186         x1 =  a11 * (a22 * a33 - a23 * a32)
187         x2 =  a12 * (a21 * a33 - a23 * a31)
188         x3 =  a13 * (a21 * a32 - a22 * a31)
189         detx =  x1 - x2 + x3
190       
191!        CALL determinant(A(1,1),A(2,1),A(3,1),dq(1),dq(2),dq(3),A(1,3),A(2,3),A(3,3),dety)
192
193         a11=A(1,1) ; a12=A(2,1) ; a13=A(3,1)
194         a21=dq(1)  ; a22=dq(2)  ; a23=dq(3)
195         a31=A(1,3) ; a32=A(2,3) ; a33=A(3,3)
196
197         x1 =  a11 * (a22 * a33 - a23 * a32)
198         x2 =  a12 * (a21 * a33 - a23 * a31)
199         x3 =  a13 * (a21 * a32 - a22 * a31)
200         dety =  x1 - x2 + x3
201
202!        CALL determinant(A(1,1),A(2,1),A(3,1),A(1,2),A(2,2),A(3,2),dq(1),dq(2),dq(3),detz)
203
204         a11=A(1,1) ; a12=A(2,1) ; a13=A(3,1)
205         a21=A(1,2) ; a22=A(2,2) ; a23=A(3,2)
206         a31=dq(1)  ; a32=dq(2)  ; a33=dq(3)
207
208         x1 =  a11 * (a22 * a33 - a23 * a32)
209         x2 =  a12 * (a21 * a33 - a23 * a31)
210         x3 =  a13 * (a21 * a32 - a22 * a31)
211         detz =  x1 - x2 + x3
212
213         gradtri(ij+z_down,l,1) = detx
214         gradtri(ij+z_down,l,2) = dety
215         gradtri(ij+z_down,l,3) = detz
216         arr(ij+z_down) = det
217
218      END DO
219    END DO
220
221!DIR$ SIMD
222    DO ij=ij_begin,ij_end
223       ar(ij) = arr(ij+z_up)+arr(ij+z_lup)+arr(ij+z_ldown)+arr(ij+z_down)+arr(ij+z_rdown)+arr(ij+z_rup)+1.e-50
224    ENDDO
225    CALL trace_end("compute_gradq3d1")
226    CALL trace_start2("compute_gradq3d2")
227     
228    DO k=1,3
229      DO l =ll_begin,ll_end
230!DIR$ SIMD
231      DO ij=ij_begin,ij_end
232              gradq3d(ij,l,k) = ( gradtri(ij+z_up,l,k) + gradtri(ij+z_down,l,k)   +   &
233                                 gradtri(ij+z_rup,l,k) +  gradtri(ij+z_ldown,l,k)   +   & 
234                                 gradtri(ij+z_lup,l,k)+    gradtri(ij+z_rdown,l,k) ) / ar(ij) 
235        END DO
236      END DO
237    ENDDO
238    CALL trace_end2("compute_gradq3d2")
239    CALL trace_start("compute_gradq3d3")
240
241    !============================================================================================= LIMITING
242    DO l =ll_begin,ll_end
243!DIR$ SIMD
244      DO ij=ij_begin,ij_end
245!             maggrd =  dot_product(gradq3d(ij,l,:),gradq3d(ij,l,:))
246             maggrd = gradq3d(ij,l,1)*gradq3d(ij,l,1) + gradq3d(ij,l,2)*gradq3d(ij,l,2) + gradq3d(ij,l,3)*gradq3d(ij,l,3) 
247             maggrd = sqrt(maggrd) 
248             maxq_c = qi(ij,l) + maggrd*sqrt_leng(ij)
249             minq_c = qi(ij,l) - maggrd*sqrt_leng(ij)
250             maxq = max(qi(ij,l),qi(ij+t_right,l),qi(ij+t_lup,l),qi(ij+t_rup,l),qi(ij+t_left,l), &
251                  qi(ij+t_rdown,l),qi(ij+t_ldown,l))
252             minq = min(qi(ij,l),qi(ij+t_right,l),qi(ij+t_lup,l),qi(ij+t_rup,l),qi(ij+t_left,l), &
253                  qi(ij+t_rdown,l),qi(ij+t_ldown,l))
254             alphamx = (maxq - qi(ij,l)) ; alphamx = alphamx/(maxq_c - qi(ij,l) )
255             alphamx = max(alphamx,0.0)
256             alphami = (minq - qi(ij,l)); alphami = alphami/(minq_c - qi(ij,l))
257             alphami = max(alphami,0.0) 
258             alpha   = min(alphamx,alphami,1.0)
259!             gradq3d(ij,l,:) = alpha*gradq3d(ij,l,:)
260             gradq3d(ij,l,1) = alpha*gradq3d(ij,l,1)
261             gradq3d(ij,l,2) = alpha*gradq3d(ij,l,2)
262             gradq3d(ij,l,3) = alpha*gradq3d(ij,l,3)
263       END DO
264    END DO
265
266  CALL trace_end("compute_gradq3d3")
267 
268  CONTAINS
269
270    SUBROUTINE gradq(n0,l,n1,n2,n3,q,dq1,dq2,dq3,det)
271    IMPLICIT NONE
272    INTEGER, INTENT(IN) :: n0,l,n1,n2,n3
273    REAL(rstd), INTENT(IN)     :: q(iim*jjm,llm)
274!    REAL(rstd), INTENT(OUT)    :: dq(3), det
275    REAL(rstd), INTENT(OUT)    :: dq1,dq2,dq3,det
276    REAL(rstd)    :: dq(3)
277   
278    REAL(rstd)  ::detx,dety,detz
279    INTEGER    :: info
280    INTEGER    :: IPIV(3)
281
282    REAL(rstd) :: A(3,3)
283    REAL(rstd) :: B(3)
284   
285    ! TODO : replace A by A1,A2,A3
286    A(1,1)=xyz_i(n1,1)-xyz_i(n0,1);  A(1,2)=xyz_i(n1,2)-xyz_i(n0,2); A(1,3)=xyz_i(n1,3)-xyz_i(n0,3) 
287    A(2,1)=xyz_i(n2,1)-xyz_i(n0,1);  A(2,2)=xyz_i(n2,2)-xyz_i(n0,2); A(2,3)=xyz_i(n2,3)-xyz_i(n0,3) 
288    A(3,1)=xyz_v(n3,1);              A(3,2)= xyz_v(n3,2);            A(3,3)=xyz_v(n3,3)
289
290    dq(1) = q(n1,l)-q(n0,l)
291    dq(2) = q(n2,l)-q(n0,l)
292    dq(3) = 0.0
293
294    !    CALL DGESV(3,1,A,3,IPIV,dq(:),3,info)
295!    CALL determinant(A(:,1),A(:,2),A(:,3),det)
296!    CALL determinant(dq,A(:,2),A(:,3),detx)
297!    CALL determinant(A(:,1),dq,A(:,3),dety)
298!    CALL determinant(A(:,1),A(:,2),dq,detz)
299!    dq(1) = detx
300!    dq(2) = dety
301!    dq(3) = detz
302
303    CALL determinant(A(1,1),A(2,1),A(3,1),A(1,2),A(2,2),A(3,2),A(1,3),A(2,3),A(3,3),det)
304    CALL determinant(dq(1),dq(2),dq(3),A(1,2),A(2,2),A(3,2),A(1,3),A(2,3),A(3,3),dq1)
305    CALL determinant(A(1,1),A(2,1),A(3,1),dq(1),dq(2),dq(3),A(1,3),A(2,3),A(3,3),dq2)
306    CALL determinant(A(1,1),A(2,1),A(3,1),A(1,2),A(2,2),A(3,2),dq(1),dq(2),dq(3),dq3)
307
308  END SUBROUTINE gradq
309
310  !==========================================================================
311!  PURE SUBROUTINE determinant(a1,a2,a3,det)
312!    IMPLICIT NONE
313!    REAL(rstd), DIMENSION(3), INTENT(IN) :: a1,a2,a3
314!    REAL(rstd), INTENT(OUT) :: det
315!    REAL(rstd) ::  x1,x2,x3
316!    x1 =  a1(1) * (a2(2) * a3(3) - a2(3) * a3(2))
317!    x2 =  a1(2) * (a2(1) * a3(3) - a2(3) * a3(1))
318!    x3 =  a1(3) * (a2(1) * a3(2) - a2(2) * a3(1))
319!    det =  x1 - x2 + x3
320!  END SUBROUTINE determinant
321
322   SUBROUTINE determinant(a11,a12,a13,a21,a22,a23,a31,a32,a33,det)
323    IMPLICIT NONE
324    REAL(rstd), INTENT(IN) :: a11,a12,a13,a21,a22,a23,a31,a32,a33
325    REAL(rstd), INTENT(OUT) :: det
326    REAL(rstd) ::  x1,x2,x3
327    x1 =  a11 * (a22 * a33 - a23 * a32)
328    x2 =  a12 * (a21 * a33 - a23 * a31)
329    x3 =  a13 * (a21 * a32 - a22 * a31)
330    det =  x1 - x2 + x3
331  END SUBROUTINE determinant
332
333
334  END SUBROUTINE compute_gradq3d
335
336  ! Backward trajectories, for use with Miura approach
337  SUBROUTINE compute_backward_traj(normal,tangent,ue,tau, cc)
338    USE trace
339    USE omp_para
340    IMPLICIT NONE
341    REAL(rstd),INTENT(IN)    :: normal(3*iim*jjm,3)
342    REAL(rstd),INTENT(IN)    :: tangent(3*iim*jjm,3)
343    REAL(rstd),INTENT(IN)    :: ue(iim*3*jjm,llm)
344    REAL(rstd),INTENT(OUT)   :: cc(3*iim*jjm,llm,3) ! start of backward trajectory
345    REAL(rstd),INTENT(IN)    :: tau
346
347    REAL(rstd) :: v_e(3), up_e, qe, ed(3)   
348    INTEGER :: ij,l
349
350    CALL trace_start("compute_backward_traj")
351
352    ! TODO : compute normal displacement ue*tau as hfluxt / mass(upwind) then reconstruct tangential displacement
353   
354    ! reconstruct tangential wind then 3D wind at edge then cc = edge midpoint - u*tau
355    DO l = ll_begin,ll_end
356!DIR$ SIMD
357      DO ij=ij_begin,ij_end
358             up_e =1/de(ij+u_right)*(                                                   &
359                  wee(ij+u_right,1,1)*le(ij+u_rup)*ue(ij+u_rup,l)+                        &
360                  wee(ij+u_right,2,1)*le(ij+u_lup)*ue(ij+u_lup,l)+                        &
361                  wee(ij+u_right,3,1)*le(ij+u_left)*ue(ij+u_left,l)+                      &
362                  wee(ij+u_right,4,1)*le(ij+u_ldown)*ue(ij+u_ldown,l)+                    &
363                  wee(ij+u_right,5,1)*le(ij+u_rdown)*ue(ij+u_rdown,l)+                    & 
364                  wee(ij+u_right,1,2)*le(ij+t_right+u_ldown)*ue(ij+t_right+u_ldown,l)+    &
365                  wee(ij+u_right,2,2)*le(ij+t_right+u_rdown)*ue(ij+t_right+u_rdown,l)+    &
366                  wee(ij+u_right,3,2)*le(ij+t_right+u_right)*ue(ij+t_right+u_right,l)+    &
367                  wee(ij+u_right,4,2)*le(ij+t_right+u_rup)*ue(ij+t_right+u_rup,l)+        &
368                  wee(ij+u_right,5,2)*le(ij+t_right+u_lup)*ue(ij+t_right+u_lup,l)         &
369                  )
370             v_e = ue(ij+u_right,l)*normal(ij+u_right,:) + up_e*tangent(ij+u_right,:)
371             cc(ij+u_right,l,:) = xyz_e(ij+u_right,:) - v_e*tau
372
373             up_e=1/de(ij+u_lup)*(                                                      &
374                  wee(ij+u_lup,1,1)*le(ij+u_left)*ue(ij+u_left,l)+                        &
375                  wee(ij+u_lup,2,1)*le(ij+u_ldown)*ue(ij+u_ldown,l)+                      &
376                  wee(ij+u_lup,3,1)*le(ij+u_rdown)*ue(ij+u_rdown,l)+                      &
377                  wee(ij+u_lup,4,1)*le(ij+u_right)*ue(ij+u_right,l)+                      &
378                  wee(ij+u_lup,5,1)*le(ij+u_rup)*ue(ij+u_rup,l)+                          & 
379                  wee(ij+u_lup,1,2)*le(ij+t_lup+u_right)*ue(ij+t_lup+u_right,l)+          &
380                  wee(ij+u_lup,2,2)*le(ij+t_lup+u_rup)*ue(ij+t_lup+u_rup,l)+              &
381                  wee(ij+u_lup,3,2)*le(ij+t_lup+u_lup)*ue(ij+t_lup+u_lup,l)+              &
382                  wee(ij+u_lup,4,2)*le(ij+t_lup+u_left)*ue(ij+t_lup+u_left,l)+            &
383                  wee(ij+u_lup,5,2)*le(ij+t_lup+u_ldown)*ue(ij+t_lup+u_ldown,l)           &
384                  )
385             v_e = ue(ij+u_lup,l)*normal(ij+u_lup,:) + up_e*tangent(ij+u_lup,:)
386             cc(ij+u_lup,l,:) = xyz_e(ij+u_lup,:) - v_e*tau
387           
388
389             up_e=1/de(ij+u_ldown)*(                                                    &
390                  wee(ij+u_ldown,1,1)*le(ij+u_rdown)*ue(ij+u_rdown,l)+                    &
391                  wee(ij+u_ldown,2,1)*le(ij+u_right)*ue(ij+u_right,l)+                    &
392                  wee(ij+u_ldown,3,1)*le(ij+u_rup)*ue(ij+u_rup,l)+                        &
393                  wee(ij+u_ldown,4,1)*le(ij+u_lup)*ue(ij+u_lup,l)+                        &
394                  wee(ij+u_ldown,5,1)*le(ij+u_left)*ue(ij+u_left,l)+                      & 
395                  wee(ij+u_ldown,1,2)*le(ij+t_ldown+u_lup)*ue(ij+t_ldown+u_lup,l)+        &
396                  wee(ij+u_ldown,2,2)*le(ij+t_ldown+u_left)*ue(ij+t_ldown+u_left,l)+      &
397                  wee(ij+u_ldown,3,2)*le(ij+t_ldown+u_ldown)*ue(ij+t_ldown+u_ldown,l)+    &
398                  wee(ij+u_ldown,4,2)*le(ij+t_ldown+u_rdown)*ue(ij+t_ldown+u_rdown,l)+    &
399                  wee(ij+u_ldown,5,2)*le(ij+t_ldown+u_right)*ue(ij+t_ldown+u_right,l)     &
400                  )
401             v_e = ue(ij+u_ldown,l)*normal(ij+u_ldown,:) + up_e*tangent(ij+u_ldown,:)
402             cc(ij+u_ldown,l,:) = xyz_e(ij+u_ldown,:) - v_e*tau
403       ENDDO
404    END DO
405
406    CALL trace_end("compute_backward_traj")
407
408  END SUBROUTINE compute_backward_traj
409
410  ! Horizontal transport (S. Dubey, T. Dubos)
411  ! Slope-limited van Leer approach with hexagons
412  SUBROUTINE compute_advect_horiz(update_mass,diagflux_on, hfluxt,cc,gradq3d, mass,qi,qfluxt)
413    USE trace
414    USE omp_para
415    IMPLICIT NONE
416    LOGICAL, INTENT(IN)       :: update_mass, diagflux_on
417    REAL(rstd), INTENT(IN)    :: gradq3d(iim*jjm,llm,3) 
418    REAL(rstd), INTENT(IN)    :: hfluxt(3*iim*jjm,llm) ! mass flux
419    REAL(rstd), INTENT(IN)    :: cc(3*iim*jjm,llm,3)   ! barycenter of quadrilateral, where q is evaluated (1-point quadrature)
420    REAL(rstd), INTENT(INOUT) :: mass(iim*jjm,llm)
421    REAL(rstd), INTENT(INOUT) :: qi(iim*jjm,llm)
422    REAL(rstd), INTENT(INOUT) :: qfluxt(3*iim*jjm,MERGE(llm,1,diagflux_on)) ! time-integrated tracer flux
423
424    REAL(rstd) :: dq,dmass,qe,ed(3), newmass
425    REAL(rstd) :: qflux(3*iim*jjm,llm)
426    INTEGER :: ij,k,l
427
428    CALL trace_start("compute_advect_horiz")
429#include "../kernels/advect_horiz.k90"
430    CALL trace_end("compute_advect_horiz")
431  END SUBROUTINE compute_advect_horiz
432
433
434END MODULE advect_mod
Note: See TracBrowser for help on using the repository browser.