source: trunk/lib/Epoll/View/Mail.pm @ 377

package Epoll::View::Mail;

use strict;
use base 'Catalyst::View::TT';
use Mail::Mailer;
use Epoll;
use Epoll::DB;

__PACKAGE__->config(
    TEMPLATE_EXTENSION => '.tt',
    INCLUDE_PATH => Epoll->path_to( 'root', 'mail' ),
    PLUGIN_BASE => 'Epoll::Template::Plugin',
    PRE_PROCESS => [ 'includes/loc.tt', ],
);

=head1 NAME

Epoll::View::TT - TT View for Epoll

=head1 DESCRIPTION

TT View for Epoll. 

=cut

sub render {
    my ($self, $c, $template, $args) = @_;

    my ($locale) = split(';', $c->req->header('Accept-Language') || '');
    if (my $plocale = ($c->req->param('locale')|| $c->session->{'locale'})) {
        $c->session->{'locale'} = $locale = $plocale;
    }
    $c->languages($locale ? [ $locale ] : '');
    $c->stash->{locale} = $locale;

    $ENV{MAILADDRESS} = $args->{From};
    my $mailer = new Mail::Mailer 'smtp', Server => (Epoll->config->{smtp} || 'localhost');
    eval { 
        $mailer->open({
            (map { $_ => $args->{$_} } grep { $_ !~ /^(mail)$/ } keys %{ $args || {}}),
            'Content-Type' => 'text/plain; charset=UTF-8; format=flowed',
            'Content-Transfer-Encoding' => '8bit',
            'X-Epoll-version' => $Epoll::DB::VERSION,
        });
        print $mailer
        Catalyst::View::TT::render($self, $c, $template, { %{ $args->{mail} || {} }, c => $c });
        $mailer->close;
    };
    if ($@) {
        $c->stash->{mail_error} = $@;
    }    
}

=head1 SEE ALSO

L<Epoll>

=head1 AUTHOR

Thauvin Olivier

=head1 LICENSE

This library is free software, you can redistribute it and/or modify
it under the same terms as Perl itself or CeCILL.

=cut

1;