source: trunk/lib/Vote/Controller/Ballot.pm @ 19

package Vote::Controller::Ballot;

use strict;
use warnings;
use base 'Catalyst::Controller';

=head1 NAME

Vote::Controller::Ballot - Catalyst Controller

=head1 DESCRIPTION

Catalyst Controller.

=head1 METHODS

=cut


=head2 index 

=cut

sub index : Private {
    my ( $self, $c ) = @_;
}

sub default : Private {
    my ( $self, $c, undef, $id ) = @_;

    $c->stash->{voteid} = $id;

    if ($c->model('Vote')->vote_status($id) ne 'RUNNING') {
        $c->stash->{template} = 'ballot/closed.tt';
        return;
    }

    my $uid = $c->session->{uid} || $c->req->param('uid');
    my $password = $c->session->{password} || $c->req->param('password');

    if (!$c->model('Vote')->auth_voting($id, $uid, $password)) {
        $c->delete_session('invalid user/pass');
        $c->stash->{template} = 'ballot/login.tt';
        return;
    }

    $c->session->{uid} = $uid;
    $c->session->{password} = $password;

    # login succeed, but those this user has already voted
    if (my $date = $c->model('Vote')->voting_has_sign($id, $uid)) {
        $c->stash->{uid} = $c->session->{uid};
        $c->stash->{template} = 'ballot/signed.tt';
        $c->stash->{signed_date} = $date;
        $c->delete_session('invalid user/pass');
        return;
    }

    my $vote = $c->model('Vote');
    my %choices;
    foreach ($vote->vote_choices($id)) {
        $choices{$_->{key}} = $_->{label};
    }
    $c->stash->{choices} = { %choices };
    $c->stash->{sbal} = { map { $_ => 1 } $c->req->param('sbal') };
    $c->stash->{fsbal} = [ map {
        s/^\s+//;
        s/\s+$//;
        s/\s+/ /g;
        lc($_)
    } ($c->req->param('fsbal')) ];

    my @torecord = grep { $_ } (
        (map { $choices{$_} } $c->req->param('sbal')),
        @{ $c->stash->{fsbal} }
    );
    
    if (scalar(@torecord) > $vote->vote_info($id)->{choice_count}) {
        $c->req->param('ballot', '');
        $c->stash->{vote_error} = 'Seulement ' .
            $vote->vote_info($id)->{choice_count} . ' choix possible';
        return;
    }
    {
        my %uniq;
        $uniq{lc($_)} foreach(@torecord);
        if (scalar(keys %uniq) != scalar(@torecord)) {
            $c->req->param('ballot', '');
            $c->stash->{vote_error} = 'Une valeur est en double';
            return;
        }
    }

    if ($c->req->param('confirm')) {
        $vote->register_ballot(
            $uid,
            $id,
            [ @torecord ],
            $c->req->address,
        ); # TODO trap error
        $c->forward('done');
    }
}

sub done : Private {
    my ( $self, $c ) = @_;
    $c->response->body('Vote réussi.');
    $c->delete_session('Vote terminé');
}

=head1 AUTHOR

Thauvin Olivier

=head1 LICENSE

This library is free software, you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut

1;