source: trunk/lib/Vote/View/Latex.pm @ 194

package Vote::View::Latex;

use strict;
use base 'Vote::View::TT';
use LaTeX::Driver;
use File::Temp;

__PACKAGE__->config(
    TEMPLATE_EXTENSION => '.tt',
    INCLUDE_PATH => Vote->path_to( 'root', 'latex' ),
    PRE_PROCESS => 'includes/header.tt',
    POST_PROCESS => 'includes/footer.tt',
    PLUGIN_BASE => 'Vote::Template::Plugin',
);

=head1 NAME

Vote::View::Latex - Latex View for Vote

=head1 DESCRIPTION

TT View for Vote. 

=cut

sub process {
    my ($self, $c) = @_;

    $c->stash->{format} ||= 'pdf';
    my $output = $self->render(
        $c, $c->stash->{template}
    );
    
    if ($c->stash->{format} eq 'tex') {
        $c->res->body($output);
        return;
    }

    my ($fh, $filename) = File::Temp::tempfile(
        SUFFIX => ($c->stash->{format}),
    );
    close($fh);

    LaTeX::Driver::hack->new(
        source  => \$output,
        output  => $filename,
        format  => $c->stash->{format},
    )->run;
    open($fh, '<', $filename);
    binmode($fh);
    $c->res->body(join('', <$fh>));
}

# This is just a hack
# Don't ask me why, but system() return -1 instead 0
# under catalyst...
# This is just an ugly workaround

package LaTeX::Driver::hack;
use base qw(LaTeX::Driver);

sub run_command {
    my ($self, @args) = @_;
    $self->SUPER::run_command(@args);
    return $self->SUPER::run_command(@args) <= 0 ? 0 : 1;
} 

=head1 SEE ALSO

L<Vote>

=head1 AUTHOR

Thauvin Olivier

=head1 LICENSE

This library is free software, you can redistribute it and/or modify
it under the same terms as Perl itself or CeCILL.

=cut

1;