1 | *> \brief \b SORMQR |
---|
2 | * |
---|
3 | * =========== DOCUMENTATION =========== |
---|
4 | * |
---|
5 | * Online html documentation available at |
---|
6 | * http://www.netlib.org/lapack/explore-html/ |
---|
7 | * |
---|
8 | *> \htmlonly |
---|
9 | *> Download SORMQR + dependencies |
---|
10 | *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sormqr.f"> |
---|
11 | *> [TGZ]</a> |
---|
12 | *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sormqr.f"> |
---|
13 | *> [ZIP]</a> |
---|
14 | *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sormqr.f"> |
---|
15 | *> [TXT]</a> |
---|
16 | *> \endhtmlonly |
---|
17 | * |
---|
18 | * Definition: |
---|
19 | * =========== |
---|
20 | * |
---|
21 | * SUBROUTINE SORMQR( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, |
---|
22 | * WORK, LWORK, INFO ) |
---|
23 | * |
---|
24 | * .. Scalar Arguments .. |
---|
25 | * CHARACTER SIDE, TRANS |
---|
26 | * INTEGER INFO, K, LDA, LDC, LWORK, M, N |
---|
27 | * .. |
---|
28 | * .. Array Arguments .. |
---|
29 | * REAL A( LDA, * ), C( LDC, * ), TAU( * ), |
---|
30 | * $ WORK( * ) |
---|
31 | * .. |
---|
32 | * |
---|
33 | * |
---|
34 | *> \par Purpose: |
---|
35 | * ============= |
---|
36 | *> |
---|
37 | *> \verbatim |
---|
38 | *> |
---|
39 | *> SORMQR overwrites the general real M-by-N matrix C with |
---|
40 | *> |
---|
41 | *> SIDE = 'L' SIDE = 'R' |
---|
42 | *> TRANS = 'N': Q * C C * Q |
---|
43 | *> TRANS = 'T': Q**T * C C * Q**T |
---|
44 | *> |
---|
45 | *> where Q is a real orthogonal matrix defined as the product of k |
---|
46 | *> elementary reflectors |
---|
47 | *> |
---|
48 | *> Q = H(1) H(2) . . . H(k) |
---|
49 | *> |
---|
50 | *> as returned by SGEQRF. Q is of order M if SIDE = 'L' and of order N |
---|
51 | *> if SIDE = 'R'. |
---|
52 | *> \endverbatim |
---|
53 | * |
---|
54 | * Arguments: |
---|
55 | * ========== |
---|
56 | * |
---|
57 | *> \param[in] SIDE |
---|
58 | *> \verbatim |
---|
59 | *> SIDE is CHARACTER*1 |
---|
60 | *> = 'L': apply Q or Q**T from the Left; |
---|
61 | *> = 'R': apply Q or Q**T from the Right. |
---|
62 | *> \endverbatim |
---|
63 | *> |
---|
64 | *> \param[in] TRANS |
---|
65 | *> \verbatim |
---|
66 | *> TRANS is CHARACTER*1 |
---|
67 | *> = 'N': No transpose, apply Q; |
---|
68 | *> = 'T': Transpose, apply Q**T. |
---|
69 | *> \endverbatim |
---|
70 | *> |
---|
71 | *> \param[in] M |
---|
72 | *> \verbatim |
---|
73 | *> M is INTEGER |
---|
74 | *> The number of rows of the matrix C. M >= 0. |
---|
75 | *> \endverbatim |
---|
76 | *> |
---|
77 | *> \param[in] N |
---|
78 | *> \verbatim |
---|
79 | *> N is INTEGER |
---|
80 | *> The number of columns of the matrix C. N >= 0. |
---|
81 | *> \endverbatim |
---|
82 | *> |
---|
83 | *> \param[in] K |
---|
84 | *> \verbatim |
---|
85 | *> K is INTEGER |
---|
86 | *> The number of elementary reflectors whose product defines |
---|
87 | *> the matrix Q. |
---|
88 | *> If SIDE = 'L', M >= K >= 0; |
---|
89 | *> if SIDE = 'R', N >= K >= 0. |
---|
90 | *> \endverbatim |
---|
91 | *> |
---|
92 | *> \param[in] A |
---|
93 | *> \verbatim |
---|
94 | *> A is REAL array, dimension (LDA,K) |
---|
95 | *> The i-th column must contain the vector which defines the |
---|
96 | *> elementary reflector H(i), for i = 1,2,...,k, as returned by |
---|
97 | *> SGEQRF in the first k columns of its array argument A. |
---|
98 | *> A is modified by the routine but restored on exit. |
---|
99 | *> \endverbatim |
---|
100 | *> |
---|
101 | *> \param[in] LDA |
---|
102 | *> \verbatim |
---|
103 | *> LDA is INTEGER |
---|
104 | *> The leading dimension of the array A. |
---|
105 | *> If SIDE = 'L', LDA >= max(1,M); |
---|
106 | *> if SIDE = 'R', LDA >= max(1,N). |
---|
107 | *> \endverbatim |
---|
108 | *> |
---|
109 | *> \param[in] TAU |
---|
110 | *> \verbatim |
---|
111 | *> TAU is REAL array, dimension (K) |
---|
112 | *> TAU(i) must contain the scalar factor of the elementary |
---|
113 | *> reflector H(i), as returned by SGEQRF. |
---|
114 | *> \endverbatim |
---|
115 | *> |
---|
116 | *> \param[in,out] C |
---|
117 | *> \verbatim |
---|
118 | *> C is REAL array, dimension (LDC,N) |
---|
119 | *> On entry, the M-by-N matrix C. |
---|
120 | *> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q. |
---|
121 | *> \endverbatim |
---|
122 | *> |
---|
123 | *> \param[in] LDC |
---|
124 | *> \verbatim |
---|
125 | *> LDC is INTEGER |
---|
126 | *> The leading dimension of the array C. LDC >= max(1,M). |
---|
127 | *> \endverbatim |
---|
128 | *> |
---|
129 | *> \param[out] WORK |
---|
130 | *> \verbatim |
---|
131 | *> WORK is REAL array, dimension (MAX(1,LWORK)) |
---|
132 | *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. |
---|
133 | *> \endverbatim |
---|
134 | *> |
---|
135 | *> \param[in] LWORK |
---|
136 | *> \verbatim |
---|
137 | *> LWORK is INTEGER |
---|
138 | *> The dimension of the array WORK. |
---|
139 | *> If SIDE = 'L', LWORK >= max(1,N); |
---|
140 | *> if SIDE = 'R', LWORK >= max(1,M). |
---|
141 | *> For optimum performance LWORK >= N*NB if SIDE = 'L', and |
---|
142 | *> LWORK >= M*NB if SIDE = 'R', where NB is the optimal |
---|
143 | *> blocksize. |
---|
144 | *> |
---|
145 | *> If LWORK = -1, then a workspace query is assumed; the routine |
---|
146 | *> only calculates the optimal size of the WORK array, returns |
---|
147 | *> this value as the first entry of the WORK array, and no error |
---|
148 | *> message related to LWORK is issued by XERBLA. |
---|
149 | *> \endverbatim |
---|
150 | *> |
---|
151 | *> \param[out] INFO |
---|
152 | *> \verbatim |
---|
153 | *> INFO is INTEGER |
---|
154 | *> = 0: successful exit |
---|
155 | *> < 0: if INFO = -i, the i-th argument had an illegal value |
---|
156 | *> \endverbatim |
---|
157 | * |
---|
158 | * Authors: |
---|
159 | * ======== |
---|
160 | * |
---|
161 | *> \author Univ. of Tennessee |
---|
162 | *> \author Univ. of California Berkeley |
---|
163 | *> \author Univ. of Colorado Denver |
---|
164 | *> \author NAG Ltd. |
---|
165 | * |
---|
166 | *> \date November 2011 |
---|
167 | * |
---|
168 | *> \ingroup realOTHERcomputational |
---|
169 | * |
---|
170 | * ===================================================================== |
---|
171 | SUBROUTINE SORMQR( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, |
---|
172 | $ WORK, LWORK, INFO ) |
---|
173 | * |
---|
174 | * -- LAPACK computational routine (version 3.4.0) -- |
---|
175 | * -- LAPACK is a software package provided by Univ. of Tennessee, -- |
---|
176 | * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..-- |
---|
177 | * November 2011 |
---|
178 | * |
---|
179 | * .. Scalar Arguments .. |
---|
180 | CHARACTER SIDE, TRANS |
---|
181 | INTEGER INFO, K, LDA, LDC, LWORK, M, N |
---|
182 | * .. |
---|
183 | * .. Array Arguments .. |
---|
184 | REAL A( LDA, * ), C( LDC, * ), TAU( * ), |
---|
185 | $ WORK( * ) |
---|
186 | * .. |
---|
187 | * |
---|
188 | * ===================================================================== |
---|
189 | * |
---|
190 | * .. Parameters .. |
---|
191 | INTEGER NBMAX, LDT |
---|
192 | PARAMETER ( NBMAX = 64, LDT = NBMAX+1 ) |
---|
193 | * .. |
---|
194 | * .. Local Scalars .. |
---|
195 | LOGICAL LEFT, LQUERY, NOTRAN |
---|
196 | INTEGER I, I1, I2, I3, IB, IC, IINFO, IWS, JC, LDWORK, |
---|
197 | $ LWKOPT, MI, NB, NBMIN, NI, NQ, NW |
---|
198 | * .. |
---|
199 | * .. Local Arrays .. |
---|
200 | REAL T( LDT, NBMAX ) |
---|
201 | * .. |
---|
202 | * .. External Functions .. |
---|
203 | LOGICAL LSAME |
---|
204 | INTEGER ILAENV |
---|
205 | EXTERNAL LSAME, ILAENV |
---|
206 | * .. |
---|
207 | * .. External Subroutines .. |
---|
208 | EXTERNAL SLARFB, SLARFT, SORM2R, XERBLA |
---|
209 | * .. |
---|
210 | * .. Intrinsic Functions .. |
---|
211 | INTRINSIC MAX, MIN |
---|
212 | * .. |
---|
213 | * .. Executable Statements .. |
---|
214 | * |
---|
215 | * Test the input arguments |
---|
216 | * |
---|
217 | INFO = 0 |
---|
218 | LEFT = LSAME( SIDE, 'L' ) |
---|
219 | NOTRAN = LSAME( TRANS, 'N' ) |
---|
220 | LQUERY = ( LWORK.EQ.-1 ) |
---|
221 | * |
---|
222 | * NQ is the order of Q and NW is the minimum dimension of WORK |
---|
223 | * |
---|
224 | IF( LEFT ) THEN |
---|
225 | NQ = M |
---|
226 | NW = N |
---|
227 | ELSE |
---|
228 | NQ = N |
---|
229 | NW = M |
---|
230 | END IF |
---|
231 | IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN |
---|
232 | INFO = -1 |
---|
233 | ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN |
---|
234 | INFO = -2 |
---|
235 | ELSE IF( M.LT.0 ) THEN |
---|
236 | INFO = -3 |
---|
237 | ELSE IF( N.LT.0 ) THEN |
---|
238 | INFO = -4 |
---|
239 | ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN |
---|
240 | INFO = -5 |
---|
241 | ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN |
---|
242 | INFO = -7 |
---|
243 | ELSE IF( LDC.LT.MAX( 1, M ) ) THEN |
---|
244 | INFO = -10 |
---|
245 | ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN |
---|
246 | INFO = -12 |
---|
247 | END IF |
---|
248 | * |
---|
249 | IF( INFO.EQ.0 ) THEN |
---|
250 | * |
---|
251 | * Determine the block size. NB may be at most NBMAX, where NBMAX |
---|
252 | * is used to define the local array T. |
---|
253 | * |
---|
254 | NB = MIN( NBMAX, ILAENV( 1, 'SORMQR', SIDE // TRANS, M, N, K, |
---|
255 | $ -1 ) ) |
---|
256 | LWKOPT = MAX( 1, NW )*NB |
---|
257 | WORK( 1 ) = LWKOPT |
---|
258 | END IF |
---|
259 | * |
---|
260 | IF( INFO.NE.0 ) THEN |
---|
261 | CALL XERBLA( 'SORMQR', -INFO ) |
---|
262 | RETURN |
---|
263 | ELSE IF( LQUERY ) THEN |
---|
264 | RETURN |
---|
265 | END IF |
---|
266 | * |
---|
267 | * Quick return if possible |
---|
268 | * |
---|
269 | IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 ) THEN |
---|
270 | WORK( 1 ) = 1 |
---|
271 | RETURN |
---|
272 | END IF |
---|
273 | * |
---|
274 | NBMIN = 2 |
---|
275 | LDWORK = NW |
---|
276 | IF( NB.GT.1 .AND. NB.LT.K ) THEN |
---|
277 | IWS = NW*NB |
---|
278 | IF( LWORK.LT.IWS ) THEN |
---|
279 | NB = LWORK / LDWORK |
---|
280 | NBMIN = MAX( 2, ILAENV( 2, 'SORMQR', SIDE // TRANS, M, N, K, |
---|
281 | $ -1 ) ) |
---|
282 | END IF |
---|
283 | ELSE |
---|
284 | IWS = NW |
---|
285 | END IF |
---|
286 | * |
---|
287 | IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN |
---|
288 | * |
---|
289 | * Use unblocked code |
---|
290 | * |
---|
291 | CALL SORM2R( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, |
---|
292 | $ IINFO ) |
---|
293 | ELSE |
---|
294 | * |
---|
295 | * Use blocked code |
---|
296 | * |
---|
297 | IF( ( LEFT .AND. .NOT.NOTRAN ) .OR. |
---|
298 | $ ( .NOT.LEFT .AND. NOTRAN ) ) THEN |
---|
299 | I1 = 1 |
---|
300 | I2 = K |
---|
301 | I3 = NB |
---|
302 | ELSE |
---|
303 | I1 = ( ( K-1 ) / NB )*NB + 1 |
---|
304 | I2 = 1 |
---|
305 | I3 = -NB |
---|
306 | END IF |
---|
307 | * |
---|
308 | IF( LEFT ) THEN |
---|
309 | NI = N |
---|
310 | JC = 1 |
---|
311 | ELSE |
---|
312 | MI = M |
---|
313 | IC = 1 |
---|
314 | END IF |
---|
315 | * |
---|
316 | DO 10 I = I1, I2, I3 |
---|
317 | IB = MIN( NB, K-I+1 ) |
---|
318 | * |
---|
319 | * Form the triangular factor of the block reflector |
---|
320 | * H = H(i) H(i+1) . . . H(i+ib-1) |
---|
321 | * |
---|
322 | CALL SLARFT( 'Forward', 'Columnwise', NQ-I+1, IB, A( I, I ), |
---|
323 | $ LDA, TAU( I ), T, LDT ) |
---|
324 | IF( LEFT ) THEN |
---|
325 | * |
---|
326 | * H or H**T is applied to C(i:m,1:n) |
---|
327 | * |
---|
328 | MI = M - I + 1 |
---|
329 | IC = I |
---|
330 | ELSE |
---|
331 | * |
---|
332 | * H or H**T is applied to C(1:m,i:n) |
---|
333 | * |
---|
334 | NI = N - I + 1 |
---|
335 | JC = I |
---|
336 | END IF |
---|
337 | * |
---|
338 | * Apply H or H**T |
---|
339 | * |
---|
340 | CALL SLARFB( SIDE, TRANS, 'Forward', 'Columnwise', MI, NI, |
---|
341 | $ IB, A( I, I ), LDA, T, LDT, C( IC, JC ), LDC, |
---|
342 | $ WORK, LDWORK ) |
---|
343 | 10 CONTINUE |
---|
344 | END IF |
---|
345 | WORK( 1 ) = LWKOPT |
---|
346 | RETURN |
---|
347 | * |
---|
348 | * End of SORMQR |
---|
349 | * |
---|
350 | END |
---|