source: branches/iLoveclim/SOURCES/Old-sources/moy_mxmy_shift.f90 @ 77

!> \file moy_mxmy_shift.f90
!!  Fait la moyenne ponderee d'un tableau X2D sur les mailles staggered
!<

!> SUBROUTINE: moy_mxmy()
!! \author ... 
!! \date ...
!! @note Cette routine permet de faire  la moyenne ponderee d'un tableau X2D sur les mailles staggered
!! \param n1   [in]    dimension des tableaux
!! \param n2   [in]    dimension des tableaux
!! \param X2D  [in]    tableau sur les noeuds majeurs
!! \param X_mx [out]  tableau sur les noeuds mineurs x
!! \param X_my [out]  tableau sur les noeuds mineurs y
!! \return X_mx, X_my
!<
subroutine moy_mxmy(n1,n2,X2D,X_mx,X_my)
! fait la moyenne ponderee d'un tableau X2D sur les mailles staggered

implicit none
integer, intent(in) :: n1,n2   !< dimension des tableaux
real, dimension(n1,n2),intent(in) :: X2D   !< tableau sur les noeuds majeurs
real, dimension(n1,n2),intent(out) :: X_mx  !< tableau sur les noeuds mineurs x
real, dimension(n1,n2),intent(out) :: X_my  !< tableau sur les noeuds mineurs y

! tableaux de travail

real, dimension(n1,n2) :: X_sud
real, dimension(n1,n2) :: X_nord
real, dimension(n1,n2) :: X_west
real, dimension(n1,n2) :: X_est
real, dimension(n1,n2) :: X_SW
real, dimension(n1,n2) :: X_SE
real, dimension(n1,n2) :: X_NW
real, dimension(n1,n2) :: X_NE



integer :: i,j
integer :: i_moins1,j_moins1,i_plus1,j_plus1

! l'orientation correspond a la direction vers laquelle on se deplace
!---------------------------------------------------------------------
X_west = eoshift(X2D(:,:),shift=-1,boundary=0.,dim=1)  ! X_west(i,j) = X(i-1,j)
X_est  = eoshift(X2D(:,:),shift=+1,boundary=0.,dim=1)  ! X_est(i,j)  = X(i+1,j)
X_sud  = eoshift(X2D(:,:),shift=-1,boundary=0.,dim=2)  ! X_sud(i,j)  = X(i,j-1)
X_nord = eoshift(X2D(:,:),shift=+1,boundary=0.,dim=2)  ! X_nord(i,j) = X(i,j+1)

X_se   = eoshift( X_sud(:,:),shift=+1,boundary=0.,dim=1)  ! X_se(i,j) = X(i+1,j-1)
X_sw   = eoshift( X_sud(:,:),shift=-1,boundary=0.,dim=1)  ! X_sw(i,j) = X(i-1,j-1)
X_ne   = eoshift(X_nord(:,:),shift=+1,boundary=0.,dim=1)  ! X_ne(i,j) = X(i+1,j+1)
X_nw   = eoshift(X_nord(:,:),shift=-1,boundary=0.,dim=1)  ! X_nw(i,j) = X(i-1,j+1)

X_mx = 0.25*(X2D+X_west)+0.125*((X_nw+X_nord)+(X_sw+X_sud))
X_my = 0.25*(X2D+X_sud)+0.125*((X_est+X_se)+(X_sw+X_west))


return
end subroutine moy_mxmy