source: branches/iLoveclim/SOURCES/dragging_hwatermax_0.2_mod.f90 @ 187

!> \file dragging_hwatermax_0.2_mod.f90
!! Defini les zones de stream avec un critere
!<

!> \namespace  dragging_hwatstream
!! Defini les zones de stream avec 1 critere
!! \author ...
!! \date ...
!! @note Le critere est:
!! @note   * un critere sur la hauteur d'eau 
!! @note Used module
!! @note   - use module3D_phy
!<
module dragging_hwatstream
  ! Defini les zones de stream avec un critere sur la hauteur d'eau

  use module3D_phy
  use fake_beta_iter_vitbil_mod


  implicit none
  real :: tostick

contains
  !-------------------------------------------------------------------------------
  !> SUBROUTINE: init_dragging
  !!Cette routine fait l'initialisation du dragging.
  !>
  subroutine init_dragging      ! Cette routine fait l'initialisation du dragging.

    implicit none

    namelist/drag_hwat/hwatstream,cf,betamax,toblim,tostick    

    if (itracebug.eq.1)  call tracebug(' Dragging avec hwatermax')


    ! formats pour les ecritures dans 42
428 format(A)

    ! lecture des parametres du run                      block draghwat
    !--------------------------------------------------------------------

    rewind(num_param)        ! pour revenir au debut du fichier param_list.dat
    read(num_param,drag_hwat)

    write(num_rep_42,428)'!___________________________________________________________' 
    write(num_rep_42,428) '&drag_hwat              ! nom du bloc hwatermax '
    write(num_rep_42,*)
    write(num_rep_42,*) 'hwatsream      = ',hwatstream 
    write(num_rep_42,*) 'cf             = ',cf
    write(num_rep_42,*) 'betamax         = ', betamax
    write(num_rep_42,*) 'toblim         = ', toblim
    write(num_rep_42,*)'/'                            
    write(num_rep_42,428) '! hwatstream (m) :  critere de passage en stream si hwater > hwatstream '
    write(num_rep_42,428) '! cf coefficient de la loi de frottement fonction Neff'
    write(num_rep_42,428) '! betamax : (Pa) frottement maxi '
    write(num_rep_42,428) '! toblim : (Pa) tes pour les iles '
    write(num_rep_42,*)

    inv_beta=0
    tostick=1.e5   ! valeurs pour les points non flgzmx

    !-------------------------------------------------------------------
    ! masque stream

    mstream_mx(:,:)=1
    mstream_my(:,:)=1


    ! coefficient permettant de modifier le basal drag.
    drag_mx(:,:)=1.
    drag_my(:,:)=1.


    return
  end subroutine init_dragging
  !________________________________________________________________________________

  !> SUBROUTINE: dragging
  !!Defini la localisation des streams et le frottement basal
  !>
  !-------------------------------------------------------------------------
  subroutine dragging   ! defini la localisation des streams et le frottement basal


    !         les iles n'ont pas de condition neff mais ont la condition toblim
    !         (ce bloc etait avant dans flottab)

    do j=2,ny
       do i=2,nx
          ilemx(i,j)=ilemx(i,j).and.(abs(tobmx(i,j)).lt.toblim)
          ilemy(i,j)=ilemy(i,j).and.(abs(tobmy(i,j)).lt.toblim)
       end do
    end do


    gzm_x: do j=1,ny  ! 2,ny
       do i=2,nx ! -1

          ! gzmx pour les hauteurs d'eau superieures a un seuil
          ! attention, il semble qu'il y avait une erreur dans la precedente
          ! formulation car le test etait seulement sur hwater(i,j).
          ! le gzmx initial a ete calculé dans flottab pour les points a cheval sur la grounding line

          gzmx(i,j)=gzmx(i,j).or. & 
               (((hwater(i,j)+hwater(i-1,j))*0.5.gt.hwatstream) &
               .and..not.flotmx(i,j))
                  fleuvemx(i,j)=gzmx(i,j)

          ! calcul du frottement basal (ce bloc etait avant dans neffect)
          if (gzmx(i,j)) then                          ! stream
             betamx(i,j)=cf*neffmx(i,j) 
          else if (flotmx(i,j).or.ilemx(i,j)) then     ! flottant ou ile
             betamx(i,j)=0.
          else                                         ! grounded, SIA
             betamx(i,j)=tostick                       ! frottement glace posee (1 bar)
          endif

       end do
    end do gzm_x

    gzm_y: do j=2,ny  !-1
       do i=1,nx  ! 2,nx

          ! gzmy pour les hauteurs d'eau superieures a un seuil
          ! attention, il semble qu'il y avait une erreur dans la precedente
          ! formulation car le test etait seulement sur hwater(i,j).

          gzmy(i,j)=gzmy(i,j).or. &
               (((hwater(i,j)+hwater(i,j-1))*0.5.gt.hwatstream) &
               .and..not.flotmy(i,j))
          fleuvemy(i,j)=gzmx(i,j)

          ! calcul du frottement basal (ce bloc etait avant dans neffect)
          if (gzmy(i,j)) then                ! stream
             betamy(i,j)=cf*neffmy(i,j) 
          else if (flotmy(i,j).or.ilemy(i,j)) then     ! flottant ou ile
             betamy(i,j)=0.
          else                               ! grounded, SIA
             betamy(i,j)=tostick             ! frottement glace posee
          endif

       end do
    end do gzm_y

    return
  end subroutine dragging

end module dragging_hwatstream