1 | *> \brief \b SGEQP3 |
---|
2 | * |
---|
3 | * =========== DOCUMENTATION =========== |
---|
4 | * |
---|
5 | * Online html documentation available at |
---|
6 | * http://www.netlib.org/lapack/explore-html/ |
---|
7 | * |
---|
8 | *> \htmlonly |
---|
9 | *> Download SGEQP3 + dependencies |
---|
10 | *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sgeqp3.f"> |
---|
11 | *> [TGZ]</a> |
---|
12 | *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sgeqp3.f"> |
---|
13 | *> [ZIP]</a> |
---|
14 | *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sgeqp3.f"> |
---|
15 | *> [TXT]</a> |
---|
16 | *> \endhtmlonly |
---|
17 | * |
---|
18 | * Definition: |
---|
19 | * =========== |
---|
20 | * |
---|
21 | * SUBROUTINE SGEQP3( M, N, A, LDA, JPVT, TAU, WORK, LWORK, INFO ) |
---|
22 | * |
---|
23 | * .. Scalar Arguments .. |
---|
24 | * INTEGER INFO, LDA, LWORK, M, N |
---|
25 | * .. |
---|
26 | * .. Array Arguments .. |
---|
27 | * INTEGER JPVT( * ) |
---|
28 | * REAL A( LDA, * ), TAU( * ), WORK( * ) |
---|
29 | * .. |
---|
30 | * |
---|
31 | * |
---|
32 | *> \par Purpose: |
---|
33 | * ============= |
---|
34 | *> |
---|
35 | *> \verbatim |
---|
36 | *> |
---|
37 | *> SGEQP3 computes a QR factorization with column pivoting of a |
---|
38 | *> matrix A: A*P = Q*R using Level 3 BLAS. |
---|
39 | *> \endverbatim |
---|
40 | * |
---|
41 | * Arguments: |
---|
42 | * ========== |
---|
43 | * |
---|
44 | *> \param[in] M |
---|
45 | *> \verbatim |
---|
46 | *> M is INTEGER |
---|
47 | *> The number of rows of the matrix A. M >= 0. |
---|
48 | *> \endverbatim |
---|
49 | *> |
---|
50 | *> \param[in] N |
---|
51 | *> \verbatim |
---|
52 | *> N is INTEGER |
---|
53 | *> The number of columns of the matrix A. N >= 0. |
---|
54 | *> \endverbatim |
---|
55 | *> |
---|
56 | *> \param[in,out] A |
---|
57 | *> \verbatim |
---|
58 | *> A is REAL array, dimension (LDA,N) |
---|
59 | *> On entry, the M-by-N matrix A. |
---|
60 | *> On exit, the upper triangle of the array contains the |
---|
61 | *> min(M,N)-by-N upper trapezoidal matrix R; the elements below |
---|
62 | *> the diagonal, together with the array TAU, represent the |
---|
63 | *> orthogonal matrix Q as a product of min(M,N) elementary |
---|
64 | *> reflectors. |
---|
65 | *> \endverbatim |
---|
66 | *> |
---|
67 | *> \param[in] LDA |
---|
68 | *> \verbatim |
---|
69 | *> LDA is INTEGER |
---|
70 | *> The leading dimension of the array A. LDA >= max(1,M). |
---|
71 | *> \endverbatim |
---|
72 | *> |
---|
73 | *> \param[in,out] JPVT |
---|
74 | *> \verbatim |
---|
75 | *> JPVT is INTEGER array, dimension (N) |
---|
76 | *> On entry, if JPVT(J).ne.0, the J-th column of A is permuted |
---|
77 | *> to the front of A*P (a leading column); if JPVT(J)=0, |
---|
78 | *> the J-th column of A is a free column. |
---|
79 | *> On exit, if JPVT(J)=K, then the J-th column of A*P was the |
---|
80 | *> the K-th column of A. |
---|
81 | *> \endverbatim |
---|
82 | *> |
---|
83 | *> \param[out] TAU |
---|
84 | *> \verbatim |
---|
85 | *> TAU is REAL array, dimension (min(M,N)) |
---|
86 | *> The scalar factors of the elementary reflectors. |
---|
87 | *> \endverbatim |
---|
88 | *> |
---|
89 | *> \param[out] WORK |
---|
90 | *> \verbatim |
---|
91 | *> WORK is REAL array, dimension (MAX(1,LWORK)) |
---|
92 | *> On exit, if INFO=0, WORK(1) returns the optimal LWORK. |
---|
93 | *> \endverbatim |
---|
94 | *> |
---|
95 | *> \param[in] LWORK |
---|
96 | *> \verbatim |
---|
97 | *> LWORK is INTEGER |
---|
98 | *> The dimension of the array WORK. LWORK >= 3*N+1. |
---|
99 | *> For optimal performance LWORK >= 2*N+( N+1 )*NB, where NB |
---|
100 | *> is the optimal blocksize. |
---|
101 | *> |
---|
102 | *> If LWORK = -1, then a workspace query is assumed; the routine |
---|
103 | *> only calculates the optimal size of the WORK array, returns |
---|
104 | *> this value as the first entry of the WORK array, and no error |
---|
105 | *> message related to LWORK is issued by XERBLA. |
---|
106 | *> \endverbatim |
---|
107 | *> |
---|
108 | *> \param[out] INFO |
---|
109 | *> \verbatim |
---|
110 | *> INFO is INTEGER |
---|
111 | *> = 0: successful exit. |
---|
112 | *> < 0: if INFO = -i, the i-th argument had an illegal value. |
---|
113 | *> \endverbatim |
---|
114 | * |
---|
115 | * Authors: |
---|
116 | * ======== |
---|
117 | * |
---|
118 | *> \author Univ. of Tennessee |
---|
119 | *> \author Univ. of California Berkeley |
---|
120 | *> \author Univ. of Colorado Denver |
---|
121 | *> \author NAG Ltd. |
---|
122 | * |
---|
123 | *> \date November 2011 |
---|
124 | * |
---|
125 | *> \ingroup realGEcomputational |
---|
126 | * |
---|
127 | *> \par Further Details: |
---|
128 | * ===================== |
---|
129 | *> |
---|
130 | *> \verbatim |
---|
131 | *> |
---|
132 | *> The matrix Q is represented as a product of elementary reflectors |
---|
133 | *> |
---|
134 | *> Q = H(1) H(2) . . . H(k), where k = min(m,n). |
---|
135 | *> |
---|
136 | *> Each H(i) has the form |
---|
137 | *> |
---|
138 | *> H(i) = I - tau * v * v**T |
---|
139 | *> |
---|
140 | *> where tau is a real/complex scalar, and v is a real/complex vector |
---|
141 | *> with v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in |
---|
142 | *> A(i+1:m,i), and tau in TAU(i). |
---|
143 | *> \endverbatim |
---|
144 | * |
---|
145 | *> \par Contributors: |
---|
146 | * ================== |
---|
147 | *> |
---|
148 | *> G. Quintana-Orti, Depto. de Informatica, Universidad Jaime I, Spain |
---|
149 | *> X. Sun, Computer Science Dept., Duke University, USA |
---|
150 | *> |
---|
151 | * ===================================================================== |
---|
152 | SUBROUTINE SGEQP3( M, N, A, LDA, JPVT, TAU, WORK, LWORK, INFO ) |
---|
153 | * |
---|
154 | * -- LAPACK computational routine (version 3.4.0) -- |
---|
155 | * -- LAPACK is a software package provided by Univ. of Tennessee, -- |
---|
156 | * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..-- |
---|
157 | * November 2011 |
---|
158 | * |
---|
159 | * .. Scalar Arguments .. |
---|
160 | INTEGER INFO, LDA, LWORK, M, N |
---|
161 | * .. |
---|
162 | * .. Array Arguments .. |
---|
163 | INTEGER JPVT( * ) |
---|
164 | REAL A( LDA, * ), TAU( * ), WORK( * ) |
---|
165 | * .. |
---|
166 | * |
---|
167 | * ===================================================================== |
---|
168 | * |
---|
169 | * .. Parameters .. |
---|
170 | INTEGER INB, INBMIN, IXOVER |
---|
171 | PARAMETER ( INB = 1, INBMIN = 2, IXOVER = 3 ) |
---|
172 | * .. |
---|
173 | * .. Local Scalars .. |
---|
174 | LOGICAL LQUERY |
---|
175 | INTEGER FJB, IWS, J, JB, LWKOPT, MINMN, MINWS, NA, NB, |
---|
176 | $ NBMIN, NFXD, NX, SM, SMINMN, SN, TOPBMN |
---|
177 | * .. |
---|
178 | * .. External Subroutines .. |
---|
179 | EXTERNAL SGEQRF, SLAQP2, SLAQPS, SORMQR, SSWAP, XERBLA |
---|
180 | * .. |
---|
181 | * .. External Functions .. |
---|
182 | INTEGER ILAENV |
---|
183 | REAL SNRM2 |
---|
184 | EXTERNAL ILAENV, SNRM2 |
---|
185 | * .. |
---|
186 | * .. Intrinsic Functions .. |
---|
187 | INTRINSIC INT, MAX, MIN |
---|
188 | * .. |
---|
189 | * .. Executable Statements .. |
---|
190 | * |
---|
191 | INFO = 0 |
---|
192 | LQUERY = ( LWORK.EQ.-1 ) |
---|
193 | IF( M.LT.0 ) THEN |
---|
194 | INFO = -1 |
---|
195 | ELSE IF( N.LT.0 ) THEN |
---|
196 | INFO = -2 |
---|
197 | ELSE IF( LDA.LT.MAX( 1, M ) ) THEN |
---|
198 | INFO = -4 |
---|
199 | END IF |
---|
200 | * |
---|
201 | IF( INFO.EQ.0 ) THEN |
---|
202 | MINMN = MIN( M, N ) |
---|
203 | IF( MINMN.EQ.0 ) THEN |
---|
204 | IWS = 1 |
---|
205 | LWKOPT = 1 |
---|
206 | ELSE |
---|
207 | IWS = 3*N + 1 |
---|
208 | NB = ILAENV( INB, 'SGEQRF', ' ', M, N, -1, -1 ) |
---|
209 | LWKOPT = 2*N + ( N + 1 )*NB |
---|
210 | END IF |
---|
211 | WORK( 1 ) = LWKOPT |
---|
212 | * |
---|
213 | IF( ( LWORK.LT.IWS ) .AND. .NOT.LQUERY ) THEN |
---|
214 | INFO = -8 |
---|
215 | END IF |
---|
216 | END IF |
---|
217 | * |
---|
218 | IF( INFO.NE.0 ) THEN |
---|
219 | CALL XERBLA( 'SGEQP3', -INFO ) |
---|
220 | RETURN |
---|
221 | ELSE IF( LQUERY ) THEN |
---|
222 | RETURN |
---|
223 | END IF |
---|
224 | * |
---|
225 | * Quick return if possible. |
---|
226 | * |
---|
227 | IF( MINMN.EQ.0 ) THEN |
---|
228 | RETURN |
---|
229 | END IF |
---|
230 | * |
---|
231 | * Move initial columns up front. |
---|
232 | * |
---|
233 | NFXD = 1 |
---|
234 | DO 10 J = 1, N |
---|
235 | IF( JPVT( J ).NE.0 ) THEN |
---|
236 | IF( J.NE.NFXD ) THEN |
---|
237 | CALL SSWAP( M, A( 1, J ), 1, A( 1, NFXD ), 1 ) |
---|
238 | JPVT( J ) = JPVT( NFXD ) |
---|
239 | JPVT( NFXD ) = J |
---|
240 | ELSE |
---|
241 | JPVT( J ) = J |
---|
242 | END IF |
---|
243 | NFXD = NFXD + 1 |
---|
244 | ELSE |
---|
245 | JPVT( J ) = J |
---|
246 | END IF |
---|
247 | 10 CONTINUE |
---|
248 | NFXD = NFXD - 1 |
---|
249 | * |
---|
250 | * Factorize fixed columns |
---|
251 | * ======================= |
---|
252 | * |
---|
253 | * Compute the QR factorization of fixed columns and update |
---|
254 | * remaining columns. |
---|
255 | * |
---|
256 | IF( NFXD.GT.0 ) THEN |
---|
257 | NA = MIN( M, NFXD ) |
---|
258 | *CC CALL SGEQR2( M, NA, A, LDA, TAU, WORK, INFO ) |
---|
259 | CALL SGEQRF( M, NA, A, LDA, TAU, WORK, LWORK, INFO ) |
---|
260 | IWS = MAX( IWS, INT( WORK( 1 ) ) ) |
---|
261 | IF( NA.LT.N ) THEN |
---|
262 | *CC CALL SORM2R( 'Left', 'Transpose', M, N-NA, NA, A, LDA, |
---|
263 | *CC $ TAU, A( 1, NA+1 ), LDA, WORK, INFO ) |
---|
264 | CALL SORMQR( 'Left', 'Transpose', M, N-NA, NA, A, LDA, TAU, |
---|
265 | $ A( 1, NA+1 ), LDA, WORK, LWORK, INFO ) |
---|
266 | IWS = MAX( IWS, INT( WORK( 1 ) ) ) |
---|
267 | END IF |
---|
268 | END IF |
---|
269 | * |
---|
270 | * Factorize free columns |
---|
271 | * ====================== |
---|
272 | * |
---|
273 | IF( NFXD.LT.MINMN ) THEN |
---|
274 | * |
---|
275 | SM = M - NFXD |
---|
276 | SN = N - NFXD |
---|
277 | SMINMN = MINMN - NFXD |
---|
278 | * |
---|
279 | * Determine the block size. |
---|
280 | * |
---|
281 | NB = ILAENV( INB, 'SGEQRF', ' ', SM, SN, -1, -1 ) |
---|
282 | NBMIN = 2 |
---|
283 | NX = 0 |
---|
284 | * |
---|
285 | IF( ( NB.GT.1 ) .AND. ( NB.LT.SMINMN ) ) THEN |
---|
286 | * |
---|
287 | * Determine when to cross over from blocked to unblocked code. |
---|
288 | * |
---|
289 | NX = MAX( 0, ILAENV( IXOVER, 'SGEQRF', ' ', SM, SN, -1, |
---|
290 | $ -1 ) ) |
---|
291 | * |
---|
292 | * |
---|
293 | IF( NX.LT.SMINMN ) THEN |
---|
294 | * |
---|
295 | * Determine if workspace is large enough for blocked code. |
---|
296 | * |
---|
297 | MINWS = 2*SN + ( SN+1 )*NB |
---|
298 | IWS = MAX( IWS, MINWS ) |
---|
299 | IF( LWORK.LT.MINWS ) THEN |
---|
300 | * |
---|
301 | * Not enough workspace to use optimal NB: Reduce NB and |
---|
302 | * determine the minimum value of NB. |
---|
303 | * |
---|
304 | NB = ( LWORK-2*SN ) / ( SN+1 ) |
---|
305 | NBMIN = MAX( 2, ILAENV( INBMIN, 'SGEQRF', ' ', SM, SN, |
---|
306 | $ -1, -1 ) ) |
---|
307 | * |
---|
308 | * |
---|
309 | END IF |
---|
310 | END IF |
---|
311 | END IF |
---|
312 | * |
---|
313 | * Initialize partial column norms. The first N elements of work |
---|
314 | * store the exact column norms. |
---|
315 | * |
---|
316 | DO 20 J = NFXD + 1, N |
---|
317 | WORK( J ) = SNRM2( SM, A( NFXD+1, J ), 1 ) |
---|
318 | WORK( N+J ) = WORK( J ) |
---|
319 | 20 CONTINUE |
---|
320 | * |
---|
321 | IF( ( NB.GE.NBMIN ) .AND. ( NB.LT.SMINMN ) .AND. |
---|
322 | $ ( NX.LT.SMINMN ) ) THEN |
---|
323 | * |
---|
324 | * Use blocked code initially. |
---|
325 | * |
---|
326 | J = NFXD + 1 |
---|
327 | * |
---|
328 | * Compute factorization: while loop. |
---|
329 | * |
---|
330 | * |
---|
331 | TOPBMN = MINMN - NX |
---|
332 | 30 CONTINUE |
---|
333 | IF( J.LE.TOPBMN ) THEN |
---|
334 | JB = MIN( NB, TOPBMN-J+1 ) |
---|
335 | * |
---|
336 | * Factorize JB columns among columns J:N. |
---|
337 | * |
---|
338 | CALL SLAQPS( M, N-J+1, J-1, JB, FJB, A( 1, J ), LDA, |
---|
339 | $ JPVT( J ), TAU( J ), WORK( J ), WORK( N+J ), |
---|
340 | $ WORK( 2*N+1 ), WORK( 2*N+JB+1 ), N-J+1 ) |
---|
341 | * |
---|
342 | J = J + FJB |
---|
343 | GO TO 30 |
---|
344 | END IF |
---|
345 | ELSE |
---|
346 | J = NFXD + 1 |
---|
347 | END IF |
---|
348 | * |
---|
349 | * Use unblocked code to factor the last or only block. |
---|
350 | * |
---|
351 | * |
---|
352 | IF( J.LE.MINMN ) |
---|
353 | $ CALL SLAQP2( M, N-J+1, J-1, A( 1, J ), LDA, JPVT( J ), |
---|
354 | $ TAU( J ), WORK( J ), WORK( N+J ), |
---|
355 | $ WORK( 2*N+1 ) ) |
---|
356 | * |
---|
357 | END IF |
---|
358 | * |
---|
359 | WORK( 1 ) = IWS |
---|
360 | RETURN |
---|
361 | * |
---|
362 | * End of SGEQP3 |
---|
363 | * |
---|
364 | END |
---|